1 | MODULE nemogcm |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE nemogcm *** |
---|
4 | !! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice) |
---|
5 | !!====================================================================== |
---|
6 | !! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code |
---|
7 | !! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec) |
---|
8 | !! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar, |
---|
9 | !! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1 |
---|
10 | !! - ! 1992-06 (L.Terray) coupling implementation |
---|
11 | !! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice |
---|
12 | !! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar, |
---|
13 | !! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0 |
---|
14 | !! 8.1 ! 1997-06 (M. Imbard, G. Madec) |
---|
15 | !! 8.2 ! 1999-11 (M. Imbard, H. Goosse) LIM sea-ice model |
---|
16 | !! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP |
---|
17 | !! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER) |
---|
18 | !! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules |
---|
19 | !! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces |
---|
20 | !! - ! 2004-08 (C. Talandier) New trends organization |
---|
21 | !! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility |
---|
22 | !! - ! 2005-11 (V. Garnier) Surface pressure gradient organization |
---|
23 | !! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation |
---|
24 | !! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization |
---|
25 | !! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY) |
---|
26 | !! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp |
---|
27 | !! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface |
---|
28 | !! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase |
---|
29 | !! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation |
---|
30 | !! 3.4 ! 2011-11 (C. Harris) decomposition changes for running with CICE |
---|
31 | !!---------------------------------------------------------------------- |
---|
32 | |
---|
33 | !!---------------------------------------------------------------------- |
---|
34 | !! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice |
---|
35 | !! nemo_init : initialization of the NEMO system |
---|
36 | !! nemo_ctl : initialisation of the contol print |
---|
37 | !! nemo_closefile : close remaining open files |
---|
38 | !! nemo_alloc : dynamical allocation |
---|
39 | !! nemo_partition : calculate MPP domain decomposition |
---|
40 | !! factorise : calculate the factors of the no. of MPI processes |
---|
41 | !!---------------------------------------------------------------------- |
---|
42 | USE step_oce ! module used in the ocean time stepping module |
---|
43 | USE sbc_oce ! surface boundary condition: ocean |
---|
44 | USE cla ! cross land advection (tra_cla routine) |
---|
45 | USE domcfg ! domain configuration (dom_cfg routine) |
---|
46 | USE mppini ! shared/distributed memory setting (mpp_init routine) |
---|
47 | USE domain ! domain initialization (dom_init routine) |
---|
48 | USE obcini ! open boundary cond. initialization (obc_ini routine) |
---|
49 | USE bdyini ! open boundary cond. initialization (bdy_init routine) |
---|
50 | USE bdydta ! open boundary cond. initialization (bdy_dta_init routine) |
---|
51 | USE bdytides ! open boundary cond. initialization (tide_init routine) |
---|
52 | USE istate ! initial state setting (istate_init routine) |
---|
53 | USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine) |
---|
54 | USE ldftra ! lateral diffusivity setting (ldftra_init routine) |
---|
55 | USE zdfini ! vertical physics setting (zdf_init routine) |
---|
56 | USE phycst ! physical constant (par_cst routine) |
---|
57 | USE trdmod ! momentum/tracers trends (trd_mod_init routine) |
---|
58 | USE asmtrj ! writing out state trajectory |
---|
59 | USE diaptr ! poleward transports (dia_ptr_init routine) |
---|
60 | USE diadct ! sections transports (dia_dct_init routine) |
---|
61 | USE diaobs ! Observation diagnostics (dia_obs_init routine) |
---|
62 | USE step ! NEMO time-stepping (stp routine) |
---|
63 | #if defined key_oasis3 |
---|
64 | USE cpl_oasis3 ! OASIS3 coupling |
---|
65 | #elif defined key_oasis4 |
---|
66 | USE cpl_oasis4 ! OASIS4 coupling (not working) |
---|
67 | #endif |
---|
68 | USE c1d ! 1D configuration |
---|
69 | USE step_c1d ! Time stepping loop for the 1D configuration |
---|
70 | #if defined key_top |
---|
71 | USE trcini ! passive tracer initialisation |
---|
72 | #endif |
---|
73 | USE lib_mpp ! distributed memory computing |
---|
74 | #if defined key_iomput |
---|
75 | USE mod_ioclient |
---|
76 | #endif |
---|
77 | |
---|
78 | IMPLICIT NONE |
---|
79 | PRIVATE |
---|
80 | |
---|
81 | PUBLIC nemo_gcm ! called by model.F90 |
---|
82 | PUBLIC nemo_init ! needed by AGRIF |
---|
83 | |
---|
84 | CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing |
---|
85 | |
---|
86 | !!---------------------------------------------------------------------- |
---|
87 | !! NEMO/OPA 4.0 , NEMO Consortium (2011) |
---|
88 | !! $Id$ |
---|
89 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
90 | !!---------------------------------------------------------------------- |
---|
91 | CONTAINS |
---|
92 | |
---|
93 | SUBROUTINE nemo_gcm |
---|
94 | !!---------------------------------------------------------------------- |
---|
95 | !! *** ROUTINE nemo_gcm *** |
---|
96 | !! |
---|
97 | !! ** Purpose : NEMO solves the primitive equations on an orthogonal |
---|
98 | !! curvilinear mesh on the sphere. |
---|
99 | !! |
---|
100 | !! ** Method : - model general initialization |
---|
101 | !! - launch the time-stepping (stp routine) |
---|
102 | !! - finalize the run by closing files and communications |
---|
103 | !! |
---|
104 | !! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL. |
---|
105 | !! Madec, 2008, internal report, IPSL. |
---|
106 | !!---------------------------------------------------------------------- |
---|
107 | INTEGER :: istp ! time step index |
---|
108 | !!---------------------------------------------------------------------- |
---|
109 | ! |
---|
110 | #if defined key_agrif |
---|
111 | CALL Agrif_Init_Grids() ! AGRIF: set the meshes |
---|
112 | #endif |
---|
113 | |
---|
114 | ! !-----------------------! |
---|
115 | CALL nemo_init !== Initialisations ==! |
---|
116 | ! !-----------------------! |
---|
117 | #if defined key_agrif |
---|
118 | CALL Agrif_Declare_Var_dom ! AGRIF: set the meshes for DOM |
---|
119 | CALL Agrif_Declare_Var ! " " " " " DYN/TRA |
---|
120 | # if defined key_top |
---|
121 | CALL Agrif_Declare_Var_top ! " " " " " TOP |
---|
122 | # endif |
---|
123 | # if defined key_lim2 |
---|
124 | CALL Agrif_Declare_Var_lim2 ! " " " " " LIM |
---|
125 | # endif |
---|
126 | #endif |
---|
127 | ! check that all process are still there... If some process have an error, |
---|
128 | ! they will never enter in step and other processes will wait until the end of the cpu time! |
---|
129 | IF( lk_mpp ) CALL mpp_max( nstop ) |
---|
130 | |
---|
131 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
---|
132 | |
---|
133 | ! !-----------------------! |
---|
134 | ! !== time stepping ==! |
---|
135 | ! !-----------------------! |
---|
136 | istp = nit000 |
---|
137 | #if defined key_c1d |
---|
138 | DO WHILE ( istp <= nitend .AND. nstop == 0 ) |
---|
139 | CALL stp_c1d( istp ) |
---|
140 | istp = istp + 1 |
---|
141 | END DO |
---|
142 | #else |
---|
143 | IF( lk_asminc ) THEN |
---|
144 | IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 ) ! Output background fields |
---|
145 | IF( ln_trjwri ) CALL asm_trj_wri( nit000 - 1 ) ! Output trajectory fields |
---|
146 | IF( ln_asmdin ) THEN ! Direct initialization |
---|
147 | IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 ) ! Tracers |
---|
148 | IF( ln_dyninc ) THEN |
---|
149 | CALL dyn_asm_inc( nit000 - 1 ) ! Dynamics |
---|
150 | IF ( ln_asmdin ) CALL ssh_wzv ( nit000 - 1 ) ! update vertical velocity |
---|
151 | ENDIF |
---|
152 | IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 ) ! SSH |
---|
153 | ENDIF |
---|
154 | ENDIF |
---|
155 | |
---|
156 | DO WHILE ( istp <= nitend .AND. nstop == 0 ) |
---|
157 | #if defined key_agrif |
---|
158 | CALL Agrif_Step( stp ) ! AGRIF: time stepping |
---|
159 | #else |
---|
160 | CALL stp( istp ) ! standard time stepping |
---|
161 | #endif |
---|
162 | istp = istp + 1 |
---|
163 | IF( lk_mpp ) CALL mpp_max( nstop ) |
---|
164 | END DO |
---|
165 | #endif |
---|
166 | |
---|
167 | IF( lk_diaobs ) CALL dia_obs_wri |
---|
168 | |
---|
169 | ! !------------------------! |
---|
170 | ! !== finalize the run ==! |
---|
171 | ! !------------------------! |
---|
172 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
---|
173 | ! |
---|
174 | IF( nstop /= 0 .AND. lwp ) THEN ! error print |
---|
175 | WRITE(numout,cform_err) |
---|
176 | WRITE(numout,*) nstop, ' error have been found' |
---|
177 | ENDIF |
---|
178 | ! |
---|
179 | #if defined key_agrif |
---|
180 | CALL Agrif_ParentGrid_To_ChildGrid() |
---|
181 | IF( lk_diaobs ) CALL dia_obs_wri |
---|
182 | IF( nn_timing == 1 ) CALL timing_finalize |
---|
183 | CALL Agrif_ChildGrid_To_ParentGrid() |
---|
184 | #endif |
---|
185 | IF( nn_timing == 1 ) CALL timing_finalize |
---|
186 | ! |
---|
187 | CALL nemo_closefile |
---|
188 | #if defined key_oasis3 || defined key_oasis4 |
---|
189 | CALL cpl_prism_finalize ! end coupling and mpp communications with OASIS |
---|
190 | #else |
---|
191 | IF( lk_mpp ) CALL mppstop ! end mpp communications |
---|
192 | #endif |
---|
193 | ! |
---|
194 | END SUBROUTINE nemo_gcm |
---|
195 | |
---|
196 | |
---|
197 | SUBROUTINE nemo_init |
---|
198 | !!---------------------------------------------------------------------- |
---|
199 | !! *** ROUTINE nemo_init *** |
---|
200 | !! |
---|
201 | !! ** Purpose : initialization of the NEMO GCM |
---|
202 | !!---------------------------------------------------------------------- |
---|
203 | INTEGER :: ji ! dummy loop indices |
---|
204 | INTEGER :: ilocal_comm ! local integer |
---|
205 | CHARACTER(len=80), DIMENSION(16) :: cltxt |
---|
206 | !! |
---|
207 | NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, & |
---|
208 | & nn_isplt, nn_jsplt, nn_jctls, nn_jctle, & |
---|
209 | & nn_bench, nn_timing |
---|
210 | !!---------------------------------------------------------------------- |
---|
211 | ! |
---|
212 | cltxt = '' |
---|
213 | ! |
---|
214 | ! ! open Namelist file |
---|
215 | CALL ctl_opn( numnam, 'namelist', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. ) |
---|
216 | ! |
---|
217 | READ( numnam, namctl ) ! Namelist namctl : Control prints & Benchmark |
---|
218 | ! |
---|
219 | ! !--------------------------------------------! |
---|
220 | ! ! set communicator & select the local node ! |
---|
221 | ! !--------------------------------------------! |
---|
222 | #if defined key_iomput |
---|
223 | IF( Agrif_Root() ) THEN |
---|
224 | # if defined key_oasis3 || defined key_oasis4 |
---|
225 | CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis |
---|
226 | # endif |
---|
227 | CALL init_ioclient( ilocal_comm ) ! exchange io_server nemo local communicator with the io_server |
---|
228 | ENDIF |
---|
229 | narea = mynode( cltxt, numnam, nstop, ilocal_comm ) ! Nodes selection |
---|
230 | #else |
---|
231 | # if defined key_oasis3 || defined key_oasis4 |
---|
232 | IF( Agrif_Root() ) THEN |
---|
233 | CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis |
---|
234 | ENDIF |
---|
235 | narea = mynode( cltxt, numnam, nstop, ilocal_comm ) ! Nodes selection (control print return in cltxt) |
---|
236 | # else |
---|
237 | ilocal_comm = 0 |
---|
238 | narea = mynode( cltxt, numnam, nstop ) ! Nodes selection (control print return in cltxt) |
---|
239 | # endif |
---|
240 | #endif |
---|
241 | narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 ) |
---|
242 | |
---|
243 | lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print |
---|
244 | |
---|
245 | ! If dimensions of processor grid weren't specified in the namelist file |
---|
246 | ! then we calculate them here now that we have our communicator size |
---|
247 | IF( (jpni < 1) .OR. (jpnj < 1) )THEN |
---|
248 | #if defined key_mpp_mpi |
---|
249 | IF( Agrif_Root() ) CALL nemo_partition(mppsize) |
---|
250 | #else |
---|
251 | jpni = 1 |
---|
252 | jpnj = 1 |
---|
253 | jpnij = jpni*jpnj |
---|
254 | #endif |
---|
255 | END IF |
---|
256 | |
---|
257 | ! Calculate domain dimensions given calculated jpni and jpnj |
---|
258 | ! This used to be done in par_oce.F90 when they were parameters rather |
---|
259 | ! than variables |
---|
260 | IF( Agrif_Root() ) THEN |
---|
261 | jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci ! first dim. |
---|
262 | #if defined key_nemocice_decomp |
---|
263 | jpj = ( jpjglo+1-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim. |
---|
264 | #else |
---|
265 | jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim. |
---|
266 | #endif |
---|
267 | jpk = jpkdta ! third dim |
---|
268 | jpim1 = jpi-1 ! inner domain indices |
---|
269 | jpjm1 = jpj-1 ! " " |
---|
270 | jpkm1 = jpk-1 ! " " |
---|
271 | jpij = jpi*jpj ! jpi x j |
---|
272 | ENDIF |
---|
273 | |
---|
274 | IF(lwp) THEN ! open listing units |
---|
275 | ! |
---|
276 | CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea ) |
---|
277 | ! |
---|
278 | WRITE(numout,*) |
---|
279 | WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC' |
---|
280 | WRITE(numout,*) ' NEMO team' |
---|
281 | WRITE(numout,*) ' Ocean General Circulation Model' |
---|
282 | WRITE(numout,*) ' version 3.4 (2011) ' |
---|
283 | WRITE(numout,*) |
---|
284 | WRITE(numout,*) |
---|
285 | DO ji = 1, SIZE(cltxt) |
---|
286 | IF( TRIM(cltxt(ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode |
---|
287 | END DO |
---|
288 | WRITE(numout,cform_aaa) ! Flag AAAAAAA |
---|
289 | ! |
---|
290 | ENDIF |
---|
291 | |
---|
292 | ! Now we know the dimensions of the grid and numout has been set we can |
---|
293 | ! allocate arrays |
---|
294 | CALL nemo_alloc() |
---|
295 | |
---|
296 | ! !-------------------------------! |
---|
297 | ! ! NEMO general initialization ! |
---|
298 | ! !-------------------------------! |
---|
299 | |
---|
300 | CALL nemo_ctl ! Control prints & Benchmark |
---|
301 | |
---|
302 | ! ! Domain decomposition |
---|
303 | IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out |
---|
304 | ELSE ; CALL mpp_init2 ! eliminate land processors |
---|
305 | ENDIF |
---|
306 | ! |
---|
307 | IF( nn_timing == 1 ) CALL timing_init |
---|
308 | ! |
---|
309 | ! ! General initialization |
---|
310 | CALL phy_cst ! Physical constants |
---|
311 | CALL eos_init ! Equation of state |
---|
312 | CALL dom_cfg ! Domain configuration |
---|
313 | CALL dom_init ! Domain |
---|
314 | |
---|
315 | IF( ln_nnogather ) CALL nemo_northcomms ! Initialise the northfold neighbour lists (must be done after the masks are defined) |
---|
316 | |
---|
317 | IF( ln_ctl ) CALL prt_ctl_init ! Print control |
---|
318 | |
---|
319 | IF( lk_obc ) CALL obc_init ! Open boundaries |
---|
320 | IF( lk_bdy ) CALL bdy_init ! Open boundaries initialisation |
---|
321 | IF( lk_bdy ) CALL bdy_dta_init ! Open boundaries initialisation of external data arrays |
---|
322 | IF( lk_bdy ) CALL tide_init ! Open boundaries initialisation of tidal harmonic forcing |
---|
323 | |
---|
324 | CALL flush(numout) |
---|
325 | CALL dyn_nept_init ! simplified form of Neptune effect |
---|
326 | CALL flush(numout) |
---|
327 | |
---|
328 | CALL istate_init ! ocean initial state (Dynamics and tracers) |
---|
329 | |
---|
330 | ! ! Ocean physics |
---|
331 | CALL sbc_init ! Forcings : surface module |
---|
332 | ! ! Vertical physics |
---|
333 | CALL zdf_init ! namelist read |
---|
334 | CALL zdf_bfr_init ! bottom friction |
---|
335 | IF( lk_zdfric ) CALL zdf_ric_init ! Richardson number dependent Kz |
---|
336 | IF( lk_zdftke ) CALL zdf_tke_init ! TKE closure scheme |
---|
337 | IF( lk_zdfgls ) CALL zdf_gls_init ! GLS closure scheme |
---|
338 | IF( lk_zdfkpp ) CALL zdf_kpp_init ! KPP closure scheme |
---|
339 | IF( lk_zdftmx ) CALL zdf_tmx_init ! tidal vertical mixing |
---|
340 | IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) & |
---|
341 | & CALL zdf_ddm_init ! double diffusive mixing |
---|
342 | ! ! Lateral physics |
---|
343 | CALL ldf_tra_init ! Lateral ocean tracer physics |
---|
344 | CALL ldf_dyn_init ! Lateral ocean momentum physics |
---|
345 | IF( lk_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing |
---|
346 | |
---|
347 | ! ! Active tracers |
---|
348 | CALL tra_qsr_init ! penetrative solar radiation qsr |
---|
349 | CALL tra_bbc_init ! bottom heat flux |
---|
350 | IF( lk_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme |
---|
351 | IF( ln_tradmp ) CALL tra_dmp_init ! internal damping trends |
---|
352 | CALL tra_adv_init ! horizontal & vertical advection |
---|
353 | CALL tra_ldf_init ! lateral mixing |
---|
354 | CALL tra_zdf_init ! vertical mixing and after tracer fields |
---|
355 | |
---|
356 | ! ! Dynamics |
---|
357 | CALL dyn_adv_init ! advection (vector or flux form) |
---|
358 | CALL dyn_vor_init ! vorticity term including Coriolis |
---|
359 | CALL dyn_ldf_init ! lateral mixing |
---|
360 | CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure |
---|
361 | CALL dyn_zdf_init ! vertical diffusion |
---|
362 | CALL dyn_spg_init ! surface pressure gradient |
---|
363 | |
---|
364 | ! ! Misc. options |
---|
365 | IF( nn_cla == 1 ) CALL cla_init ! Cross Land Advection |
---|
366 | |
---|
367 | #if defined key_top |
---|
368 | ! ! Passive tracers |
---|
369 | CALL trc_init |
---|
370 | #endif |
---|
371 | ! ! Diagnostics |
---|
372 | IF( lk_floats ) CALL flo_init ! drifting Floats |
---|
373 | CALL iom_init ! iom_put initialization |
---|
374 | IF( lk_diaar5 ) CALL dia_ar5_init ! ar5 diag |
---|
375 | CALL dia_ptr_init ! Poleward TRansports initialization |
---|
376 | IF( lk_diadct ) CALL dia_dct_init ! Sections tranports |
---|
377 | CALL dia_hsb_init ! heat content, salt content and volume budgets |
---|
378 | CALL trd_mod_init ! Mixed-layer/Vorticity/Integral constraints trends |
---|
379 | IF( lk_diaobs ) THEN ! Observation & model comparison |
---|
380 | CALL dia_obs_init ! Initialize observational data |
---|
381 | CALL dia_obs( nit000 - 1 ) ! Observation operator for restart |
---|
382 | ENDIF |
---|
383 | ! ! Assimilation increments |
---|
384 | IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments |
---|
385 | IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler |
---|
386 | ! |
---|
387 | END SUBROUTINE nemo_init |
---|
388 | |
---|
389 | |
---|
390 | SUBROUTINE nemo_ctl |
---|
391 | !!---------------------------------------------------------------------- |
---|
392 | !! *** ROUTINE nemo_ctl *** |
---|
393 | !! |
---|
394 | !! ** Purpose : control print setting |
---|
395 | !! |
---|
396 | !! ** Method : - print namctl information and check some consistencies |
---|
397 | !!---------------------------------------------------------------------- |
---|
398 | ! |
---|
399 | IF(lwp) THEN ! control print |
---|
400 | WRITE(numout,*) |
---|
401 | WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark' |
---|
402 | WRITE(numout,*) '~~~~~~~ ' |
---|
403 | WRITE(numout,*) ' Namelist namctl' |
---|
404 | WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl |
---|
405 | WRITE(numout,*) ' level of print nn_print = ', nn_print |
---|
406 | WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls |
---|
407 | WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle |
---|
408 | WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls |
---|
409 | WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle |
---|
410 | WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt |
---|
411 | WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt |
---|
412 | WRITE(numout,*) ' benchmark parameter (0/1) nn_bench = ', nn_bench |
---|
413 | WRITE(numout,*) ' timing activated (0/1) nn_timing = ', nn_timing |
---|
414 | ENDIF |
---|
415 | ! |
---|
416 | nprint = nn_print ! convert DOCTOR namelist names into OLD names |
---|
417 | nictls = nn_ictls |
---|
418 | nictle = nn_ictle |
---|
419 | njctls = nn_jctls |
---|
420 | njctle = nn_jctle |
---|
421 | isplt = nn_isplt |
---|
422 | jsplt = nn_jsplt |
---|
423 | nbench = nn_bench |
---|
424 | ! ! Parameter control |
---|
425 | ! |
---|
426 | IF( ln_ctl ) THEN ! sub-domain area indices for the control prints |
---|
427 | IF( lk_mpp .AND. jpnij > 1 ) THEN |
---|
428 | isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain |
---|
429 | ELSE |
---|
430 | IF( isplt == 1 .AND. jsplt == 1 ) THEN |
---|
431 | CALL ctl_warn( ' - isplt & jsplt are equal to 1', & |
---|
432 | & ' - the print control will be done over the whole domain' ) |
---|
433 | ENDIF |
---|
434 | ijsplt = isplt * jsplt ! total number of processors ijsplt |
---|
435 | ENDIF |
---|
436 | IF(lwp) WRITE(numout,*)' - The total number of processors over which the' |
---|
437 | IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt |
---|
438 | ! |
---|
439 | ! ! indices used for the SUM control |
---|
440 | IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area |
---|
441 | lsp_area = .FALSE. |
---|
442 | ELSE ! print control done over a specific area |
---|
443 | lsp_area = .TRUE. |
---|
444 | IF( nictls < 1 .OR. nictls > jpiglo ) THEN |
---|
445 | CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' ) |
---|
446 | nictls = 1 |
---|
447 | ENDIF |
---|
448 | IF( nictle < 1 .OR. nictle > jpiglo ) THEN |
---|
449 | CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' ) |
---|
450 | nictle = jpiglo |
---|
451 | ENDIF |
---|
452 | IF( njctls < 1 .OR. njctls > jpjglo ) THEN |
---|
453 | CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' ) |
---|
454 | njctls = 1 |
---|
455 | ENDIF |
---|
456 | IF( njctle < 1 .OR. njctle > jpjglo ) THEN |
---|
457 | CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' ) |
---|
458 | njctle = jpjglo |
---|
459 | ENDIF |
---|
460 | ENDIF |
---|
461 | ENDIF |
---|
462 | ! |
---|
463 | IF( nbench == 1 ) THEN ! Benchmark |
---|
464 | SELECT CASE ( cp_cfg ) |
---|
465 | CASE ( 'gyre' ) ; CALL ctl_warn( ' The Benchmark is activated ' ) |
---|
466 | CASE DEFAULT ; CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:', & |
---|
467 | & ' key_gyre must be used or set nbench = 0' ) |
---|
468 | END SELECT |
---|
469 | ENDIF |
---|
470 | ! |
---|
471 | IF( lk_c1d .AND. .NOT.lk_iomput ) CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ', & |
---|
472 | & 'with the IOM Input/Output manager. ' , & |
---|
473 | & 'Compile with key_iomput enabled' ) |
---|
474 | ! |
---|
475 | END SUBROUTINE nemo_ctl |
---|
476 | |
---|
477 | |
---|
478 | SUBROUTINE nemo_closefile |
---|
479 | !!---------------------------------------------------------------------- |
---|
480 | !! *** ROUTINE nemo_closefile *** |
---|
481 | !! |
---|
482 | !! ** Purpose : Close the files |
---|
483 | !!---------------------------------------------------------------------- |
---|
484 | ! |
---|
485 | IF( lk_mpp ) CALL mppsync |
---|
486 | ! |
---|
487 | CALL iom_close ! close all input/output files managed by iom_* |
---|
488 | ! |
---|
489 | IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file |
---|
490 | IF( numsol /= -1 ) CLOSE( numsol ) ! solver file |
---|
491 | IF( numnam /= -1 ) CLOSE( numnam ) ! oce namelist |
---|
492 | IF( numnam_ice /= -1 ) CLOSE( numnam_ice ) ! ice namelist |
---|
493 | IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution) |
---|
494 | IF( numout /= 6 ) CLOSE( numout ) ! standard model output file |
---|
495 | IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports |
---|
496 | IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports |
---|
497 | IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports |
---|
498 | |
---|
499 | ! |
---|
500 | numout = 6 ! redefine numout in case it is used after this point... |
---|
501 | ! |
---|
502 | END SUBROUTINE nemo_closefile |
---|
503 | |
---|
504 | |
---|
505 | SUBROUTINE nemo_alloc |
---|
506 | !!---------------------------------------------------------------------- |
---|
507 | !! *** ROUTINE nemo_alloc *** |
---|
508 | !! |
---|
509 | !! ** Purpose : Allocate all the dynamic arrays of the OPA modules |
---|
510 | !! |
---|
511 | !! ** Method : |
---|
512 | !!---------------------------------------------------------------------- |
---|
513 | USE diawri , ONLY: dia_wri_alloc |
---|
514 | USE dom_oce , ONLY: dom_oce_alloc |
---|
515 | USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc |
---|
516 | USE ldftra_oce, ONLY: ldftra_oce_alloc |
---|
517 | USE trc_oce , ONLY: trc_oce_alloc |
---|
518 | #if defined key_diadct |
---|
519 | USE diadct , ONLY: diadct_alloc |
---|
520 | #endif |
---|
521 | ! |
---|
522 | INTEGER :: ierr |
---|
523 | !!---------------------------------------------------------------------- |
---|
524 | ! |
---|
525 | ierr = oce_alloc () ! ocean |
---|
526 | ierr = ierr + dia_wri_alloc () |
---|
527 | ierr = ierr + dom_oce_alloc () ! ocean domain |
---|
528 | ierr = ierr + ldfdyn_oce_alloc() ! ocean lateral physics : dynamics |
---|
529 | ierr = ierr + ldftra_oce_alloc() ! ocean lateral physics : tracers |
---|
530 | ierr = ierr + zdf_oce_alloc () ! ocean vertical physics |
---|
531 | ! |
---|
532 | ierr = ierr + lib_mpp_alloc (numout) ! mpp exchanges |
---|
533 | ierr = ierr + trc_oce_alloc () ! shared TRC / TRA arrays |
---|
534 | ! |
---|
535 | #if defined key_diadct |
---|
536 | ierr = ierr + diadct_alloc () ! |
---|
537 | #endif |
---|
538 | ! |
---|
539 | IF( lk_mpp ) CALL mpp_sum( ierr ) |
---|
540 | IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' ) |
---|
541 | ! |
---|
542 | END SUBROUTINE nemo_alloc |
---|
543 | |
---|
544 | |
---|
545 | SUBROUTINE nemo_partition( num_pes ) |
---|
546 | !!---------------------------------------------------------------------- |
---|
547 | !! *** ROUTINE nemo_partition *** |
---|
548 | !! |
---|
549 | !! ** Purpose : |
---|
550 | !! |
---|
551 | !! ** Method : |
---|
552 | !!---------------------------------------------------------------------- |
---|
553 | INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have |
---|
554 | ! |
---|
555 | INTEGER, PARAMETER :: nfactmax = 20 |
---|
556 | INTEGER :: nfact ! The no. of factors returned |
---|
557 | INTEGER :: ierr ! Error flag |
---|
558 | INTEGER :: ji |
---|
559 | INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value |
---|
560 | INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors |
---|
561 | !!---------------------------------------------------------------------- |
---|
562 | |
---|
563 | ierr = 0 |
---|
564 | |
---|
565 | CALL factorise( ifact, nfactmax, nfact, num_pes, ierr ) |
---|
566 | |
---|
567 | IF( nfact <= 1 ) THEN |
---|
568 | WRITE (numout, *) 'WARNING: factorisation of number of PEs failed' |
---|
569 | WRITE (numout, *) ' : using grid of ',num_pes,' x 1' |
---|
570 | jpnj = 1 |
---|
571 | jpni = num_pes |
---|
572 | ELSE |
---|
573 | ! Search through factors for the pair that are closest in value |
---|
574 | mindiff = 1000000 |
---|
575 | imin = 1 |
---|
576 | DO ji = 1, nfact-1, 2 |
---|
577 | idiff = ABS( ifact(ji) - ifact(ji+1) ) |
---|
578 | IF( idiff < mindiff ) THEN |
---|
579 | mindiff = idiff |
---|
580 | imin = ji |
---|
581 | ENDIF |
---|
582 | END DO |
---|
583 | jpnj = ifact(imin) |
---|
584 | jpni = ifact(imin + 1) |
---|
585 | ENDIF |
---|
586 | ! |
---|
587 | jpnij = jpni*jpnj |
---|
588 | ! |
---|
589 | END SUBROUTINE nemo_partition |
---|
590 | |
---|
591 | |
---|
592 | SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr ) |
---|
593 | !!---------------------------------------------------------------------- |
---|
594 | !! *** ROUTINE factorise *** |
---|
595 | !! |
---|
596 | !! ** Purpose : return the prime factors of n. |
---|
597 | !! knfax factors are returned in array kfax which is of |
---|
598 | !! maximum dimension kmaxfax. |
---|
599 | !! ** Method : |
---|
600 | !!---------------------------------------------------------------------- |
---|
601 | INTEGER , INTENT(in ) :: kn, kmaxfax |
---|
602 | INTEGER , INTENT( out) :: kerr, knfax |
---|
603 | INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax |
---|
604 | ! |
---|
605 | INTEGER :: ifac, jl, inu |
---|
606 | INTEGER, PARAMETER :: ntest = 14 |
---|
607 | INTEGER :: ilfax(ntest) |
---|
608 | |
---|
609 | ! lfax contains the set of allowed factors. |
---|
610 | data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256, & |
---|
611 | & 128, 64, 32, 16, 8, 4, 2 / |
---|
612 | !!---------------------------------------------------------------------- |
---|
613 | |
---|
614 | ! Clear the error flag and initialise output vars |
---|
615 | kerr = 0 |
---|
616 | kfax = 1 |
---|
617 | knfax = 0 |
---|
618 | |
---|
619 | ! Find the factors of n. |
---|
620 | IF( kn == 1 ) GOTO 20 |
---|
621 | |
---|
622 | ! nu holds the unfactorised part of the number. |
---|
623 | ! knfax holds the number of factors found. |
---|
624 | ! l points to the allowed factor list. |
---|
625 | ! ifac holds the current factor. |
---|
626 | |
---|
627 | inu = kn |
---|
628 | knfax = 0 |
---|
629 | |
---|
630 | DO jl = ntest, 1, -1 |
---|
631 | ! |
---|
632 | ifac = ilfax(jl) |
---|
633 | IF( ifac > inu ) CYCLE |
---|
634 | |
---|
635 | ! Test whether the factor will divide. |
---|
636 | |
---|
637 | IF( MOD(inu,ifac) == 0 ) THEN |
---|
638 | ! |
---|
639 | knfax = knfax + 1 ! Add the factor to the list |
---|
640 | IF( knfax > kmaxfax ) THEN |
---|
641 | kerr = 6 |
---|
642 | write (*,*) 'FACTOR: insufficient space in factor array ', knfax |
---|
643 | return |
---|
644 | ENDIF |
---|
645 | kfax(knfax) = ifac |
---|
646 | ! Store the other factor that goes with this one |
---|
647 | knfax = knfax + 1 |
---|
648 | kfax(knfax) = inu / ifac |
---|
649 | !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax) |
---|
650 | ENDIF |
---|
651 | ! |
---|
652 | END DO |
---|
653 | |
---|
654 | 20 CONTINUE ! Label 20 is the exit point from the factor search loop. |
---|
655 | ! |
---|
656 | END SUBROUTINE factorise |
---|
657 | |
---|
658 | #if defined key_mpp_mpi |
---|
659 | SUBROUTINE nemo_northcomms |
---|
660 | !!====================================================================== |
---|
661 | !! *** ROUTINE nemo_northcomms *** |
---|
662 | !! nemo_northcomms : Setup for north fold exchanges with explicit peer to peer messaging |
---|
663 | !!===================================================================== |
---|
664 | !!---------------------------------------------------------------------- |
---|
665 | !! |
---|
666 | !! ** Purpose : Initialization of the northern neighbours lists. |
---|
667 | !!---------------------------------------------------------------------- |
---|
668 | !! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE) |
---|
669 | !!---------------------------------------------------------------------- |
---|
670 | |
---|
671 | INTEGER :: ji, jj, jk, ij, jtyp ! dummy loop indices |
---|
672 | INTEGER :: ijpj ! number of rows involved in north-fold exchange |
---|
673 | INTEGER :: northcomms_alloc ! allocate return status |
---|
674 | REAL(wp), ALLOCATABLE, DIMENSION ( :,: ) :: znnbrs ! workspace |
---|
675 | LOGICAL, ALLOCATABLE, DIMENSION ( : ) :: lrankset ! workspace |
---|
676 | |
---|
677 | IF(lwp) WRITE(numout,*) |
---|
678 | IF(lwp) WRITE(numout,*) 'nemo_northcomms : Initialization of the northern neighbours lists' |
---|
679 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~' |
---|
680 | |
---|
681 | !!---------------------------------------------------------------------- |
---|
682 | ALLOCATE( znnbrs(jpi,jpj), stat = northcomms_alloc ) |
---|
683 | ALLOCATE( lrankset(jpnij), stat = northcomms_alloc ) |
---|
684 | IF( northcomms_alloc /= 0 ) THEN |
---|
685 | WRITE(numout,cform_war) |
---|
686 | WRITE(numout,*) 'northcomms_alloc : failed to allocate arrays' |
---|
687 | CALL ctl_stop( 'STOP', 'nemo_northcomms : unable to allocate temporary arrays' ) |
---|
688 | ENDIF |
---|
689 | nsndto = 0 |
---|
690 | isendto = -1 |
---|
691 | ijpj = 4 |
---|
692 | ! |
---|
693 | ! This routine has been called because ln_nnogather has been set true ( nammpp ) |
---|
694 | ! However, these first few exchanges have to use the mpi_allgather method to |
---|
695 | ! establish the neighbour lists to use in subsequent peer to peer exchanges. |
---|
696 | ! Consequently, set l_north_nogather to be false here and set it true only after |
---|
697 | ! the lists have been established. |
---|
698 | ! |
---|
699 | l_north_nogather = .FALSE. |
---|
700 | ! |
---|
701 | ! Exchange and store ranks on northern rows |
---|
702 | |
---|
703 | DO jtyp = 1,4 |
---|
704 | |
---|
705 | lrankset = .FALSE. |
---|
706 | znnbrs = narea |
---|
707 | SELECT CASE (jtyp) |
---|
708 | CASE(1) |
---|
709 | CALL lbc_lnk( znnbrs, 'T', 1. ) ! Type 1: T,W-points |
---|
710 | CASE(2) |
---|
711 | CALL lbc_lnk( znnbrs, 'U', 1. ) ! Type 2: U-point |
---|
712 | CASE(3) |
---|
713 | CALL lbc_lnk( znnbrs, 'V', 1. ) ! Type 3: V-point |
---|
714 | CASE(4) |
---|
715 | CALL lbc_lnk( znnbrs, 'F', 1. ) ! Type 4: F-point |
---|
716 | END SELECT |
---|
717 | |
---|
718 | IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN |
---|
719 | DO jj = nlcj-ijpj+1, nlcj |
---|
720 | ij = jj - nlcj + ijpj |
---|
721 | DO ji = 1,jpi |
---|
722 | IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) & |
---|
723 | & lrankset(INT(znnbrs(ji,jj))) = .true. |
---|
724 | END DO |
---|
725 | END DO |
---|
726 | |
---|
727 | DO jj = 1,jpnij |
---|
728 | IF ( lrankset(jj) ) THEN |
---|
729 | nsndto(jtyp) = nsndto(jtyp) + 1 |
---|
730 | IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN |
---|
731 | CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', & |
---|
732 | & ' jpmaxngh will need to be increased ') |
---|
733 | ENDIF |
---|
734 | isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank |
---|
735 | ENDIF |
---|
736 | END DO |
---|
737 | ENDIF |
---|
738 | |
---|
739 | END DO |
---|
740 | |
---|
741 | ! |
---|
742 | ! Type 5: I-point |
---|
743 | ! |
---|
744 | ! ICE point exchanges may involve some averaging. The neighbours list is |
---|
745 | ! built up using two exchanges to ensure that the whole stencil is covered. |
---|
746 | ! lrankset should not be reset between these 'J' and 'K' point exchanges |
---|
747 | |
---|
748 | jtyp = 5 |
---|
749 | lrankset = .FALSE. |
---|
750 | znnbrs = narea |
---|
751 | CALL lbc_lnk( znnbrs, 'J', 1. ) ! first ice U-V point |
---|
752 | |
---|
753 | IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN |
---|
754 | DO jj = nlcj-ijpj+1, nlcj |
---|
755 | ij = jj - nlcj + ijpj |
---|
756 | DO ji = 1,jpi |
---|
757 | IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) & |
---|
758 | & lrankset(INT(znnbrs(ji,jj))) = .true. |
---|
759 | END DO |
---|
760 | END DO |
---|
761 | ENDIF |
---|
762 | |
---|
763 | znnbrs = narea |
---|
764 | CALL lbc_lnk( znnbrs, 'K', 1. ) ! second ice U-V point |
---|
765 | |
---|
766 | IF ( njmppt(narea) .EQ. MAXVAL( njmppt )) THEN |
---|
767 | DO jj = nlcj-ijpj+1, nlcj |
---|
768 | ij = jj - nlcj + ijpj |
---|
769 | DO ji = 1,jpi |
---|
770 | IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) & |
---|
771 | & lrankset( INT(znnbrs(ji,jj))) = .true. |
---|
772 | END DO |
---|
773 | END DO |
---|
774 | |
---|
775 | DO jj = 1,jpnij |
---|
776 | IF ( lrankset(jj) ) THEN |
---|
777 | nsndto(jtyp) = nsndto(jtyp) + 1 |
---|
778 | IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN |
---|
779 | CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', & |
---|
780 | & ' jpmaxngh will need to be increased ') |
---|
781 | ENDIF |
---|
782 | isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank |
---|
783 | ENDIF |
---|
784 | END DO |
---|
785 | ! |
---|
786 | ! For northern row areas, set l_north_nogather so that all subsequent exchanges |
---|
787 | ! can use peer to peer communications at the north fold |
---|
788 | ! |
---|
789 | l_north_nogather = .TRUE. |
---|
790 | ! |
---|
791 | ENDIF |
---|
792 | DEALLOCATE( znnbrs ) |
---|
793 | DEALLOCATE( lrankset ) |
---|
794 | |
---|
795 | END SUBROUTINE nemo_northcomms |
---|
796 | #else |
---|
797 | SUBROUTINE nemo_northcomms ! Dummy routine |
---|
798 | WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?' |
---|
799 | END SUBROUTINE nemo_northcomms |
---|
800 | #endif |
---|
801 | !!====================================================================== |
---|
802 | END MODULE nemogcm |
---|