New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

fldread.F90 in branches/2012/dev_LOCEAN_UKMO_CMCC_INGV_2012/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

Context Navigation

source: branches/2012/dev_LOCEAN_UKMO_CMCC_INGV_2012/NEMOGCM/NEMO/OPA_SRC/SBC/fldread.F90 @ 3666

Last change on this file since 3666 was 3666, checked in by cetlod, 12 years ago
commit the changes resulting for the merged branches, see ticket #1025
Property svn:keywords set to `Id`
File size: 67.7 KB

Line
1	MODULE fldread
2	!!======================================================================
3	!! * MODULE fldread *
4	!! Ocean forcing: read input field for surface boundary condition
5	!!=====================================================================
6	!! History : 2.0 ! 06-2006 (S. Masson, G. Madec) Original code
7	!! ! 05-2008 (S. Alderson) Modified for Interpolation in memory
8	!! ! from input grid to model grid
9	!!----------------------------------------------------------------------
10
11	!!----------------------------------------------------------------------
12	!! fld_read : read input fields used for the computation of the
13	!! surface boundary condition
14	!!----------------------------------------------------------------------
15	USE oce ! ocean dynamics and tracers
16	USE dom_oce ! ocean space and time domain
17	USE phycst ! ???
18	USE in_out_manager ! I/O manager
19	USE iom ! I/O manager library
20	USE geo2ocean ! for vector rotation on to model grid
21	USE lib_mpp ! MPP library
22	USE wrk_nemo ! work arrays
23	USE ioipsl, ONLY : ymds2ju, ju2ymds ! for calendar
24
25	IMPLICIT NONE
26	PRIVATE
27
28	PUBLIC fld_map ! routine called by tides_init
29
30	TYPE, PUBLIC :: FLD_N !: Namelist field informations
31	CHARACTER(len = 256) :: clname ! generic name of the NetCDF flux file
32	INTEGER :: nfreqh ! frequency of each flux file
33	CHARACTER(len = 34) :: clvar ! generic name of the variable in the NetCDF flux file
34	LOGICAL :: ln_tint ! time interpolation or not (T/F)
35	LOGICAL :: ln_clim ! climatology or not (T/F)
36	CHARACTER(len = 8) :: cltype ! type of data file 'daily', 'monthly' or yearly'
37	CHARACTER(len = 34) :: wname ! generic name of a NetCDF weights file to be used, blank if not
38	CHARACTER(len = 34) :: vcomp ! symbolic component name if a vector that needs rotation
39	! ! a string starting with "U" or "V" for each component
40	! ! chars 2 onwards identify which components go together
41	END TYPE FLD_N
42
43	TYPE, PUBLIC :: FLD !: Input field related variables
44	CHARACTER(len = 256) :: clrootname ! generic name of the NetCDF file
45	CHARACTER(len = 256) :: clname ! current name of the NetCDF file
46	INTEGER :: nfreqh ! frequency of each flux file
47	CHARACTER(len = 34) :: clvar ! generic name of the variable in the NetCDF flux file
48	LOGICAL :: ln_tint ! time interpolation or not (T/F)
49	LOGICAL :: ln_clim ! climatology or not (T/F)
50	CHARACTER(len = 8) :: cltype ! type of data file 'daily', 'monthly' or yearly'
51	INTEGER :: num ! iom id of the jpfld files to be read
52	INTEGER , DIMENSION(2) :: nrec_b ! before record (1: index, 2: second since Jan. 1st 00h of nit000 year)
53	INTEGER , DIMENSION(2) :: nrec_a ! after record (1: index, 2: second since Jan. 1st 00h of nit000 year)
54	REAL(wp) , ALLOCATABLE, DIMENSION(:,:,: ) :: fnow ! input fields interpolated to now time step
55	REAL(wp) , ALLOCATABLE, DIMENSION(:,:,:,:) :: fdta ! 2 consecutive record of input fields
56	CHARACTER(len = 256) :: wgtname ! current name of the NetCDF weight file acting as a key
57	! ! into the WGTLIST structure
58	CHARACTER(len = 34) :: vcomp ! symbolic name for a vector component that needs rotation
59	LOGICAL :: rotn ! flag to indicate whether field has been rotated
60	END TYPE FLD
61
62	TYPE, PUBLIC :: MAP_POINTER !: Array of integer pointers to 1D arrays
63	INTEGER, POINTER :: ptr(:)
64	END TYPE MAP_POINTER
65
66	!$AGRIF_DO_NOT_TREAT
67
68	!! keep list of all weights variables so they're only read in once
69	!! need to add AGRIF directives not to process this structure
70	!! also need to force wgtname to include AGRIF nest number
71	TYPE :: WGT !: Input weights related variables
72	CHARACTER(len = 256) :: wgtname ! current name of the NetCDF weight file
73	INTEGER , DIMENSION(2) :: ddims ! shape of input grid
74	INTEGER , DIMENSION(2) :: botleft ! top left corner of box in input grid containing
75	! ! current processor grid
76	INTEGER , DIMENSION(2) :: topright ! top right corner of box
77	INTEGER :: jpiwgt ! width of box on input grid
78	INTEGER :: jpjwgt ! height of box on input grid
79	INTEGER :: numwgt ! number of weights (4=bilinear, 16=bicubic)
80	INTEGER :: nestid ! for agrif, keep track of nest we're in
81	INTEGER :: overlap ! =0 when cyclic grid has no overlapping EW columns
82	! ! =>1 when they have one or more overlapping columns
83	! ! =-1 not cyclic
84	LOGICAL :: cyclic ! east-west cyclic or not
85	INTEGER, DIMENSION(:,:,:), POINTER :: data_jpi ! array of source integers
86	INTEGER, DIMENSION(:,:,:), POINTER :: data_jpj ! array of source integers
87	REAL(wp), DIMENSION(:,:,:), POINTER :: data_wgt ! array of weights on model grid
88	REAL(wp), DIMENSION(:,:,:), POINTER :: fly_dta ! array of values on input grid
89	REAL(wp), DIMENSION(:,:,:), POINTER :: col ! temporary array for reading in columns
90	END TYPE WGT
91
92	INTEGER, PARAMETER :: tot_wgts = 10
93	TYPE( WGT ), DIMENSION(tot_wgts) :: ref_wgts ! array of wgts
94	INTEGER :: nxt_wgt = 1 ! point to next available space in ref_wgts array
95
96	!$AGRIF_END_DO_NOT_TREAT
97
98	PUBLIC fld_read, fld_fill ! called by sbc... modules
99
100	!!----------------------------------------------------------------------
101	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
102	!! $Id$
103	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
104	!!----------------------------------------------------------------------
105	CONTAINS
106
107	SUBROUTINE fld_read( kt, kn_fsbc, sd, map, jit, time_offset )
108	!!---------------------------------------------------------------------
109	!! * ROUTINE fld_read *
110	!!
111	!! ** Purpose : provide at each time step the surface ocean fluxes
112	!! (momentum, heat, freshwater and runoff)
113	!!
114	!! ** Method : READ each input fields in NetCDF files using IOM
115	!! and intepolate it to the model time-step.
116	!! Several assumptions are made on the input file:
117	!! blahblahblah....
118	!!----------------------------------------------------------------------
119	INTEGER , INTENT(in ) :: kt ! ocean time step
120	INTEGER , INTENT(in ) :: kn_fsbc ! sbc computation period (in time step)
121	TYPE(FLD), INTENT(inout), DIMENSION(:) :: sd ! input field related variables
122	TYPE(MAP_POINTER),INTENT(in), OPTIONAL, DIMENSION(:) :: map ! global-to-local mapping index
123	INTEGER , INTENT(in ), OPTIONAL :: jit ! subcycle timestep for timesplitting option
124	INTEGER , INTENT(in ), OPTIONAL :: time_offset ! provide fields at time other than "now"
125	! time_offset = -1 => fields at "before" time level
126	! time_offset = +1 => fields at "after" time levels
127	! etc.
128	!!
129	INTEGER :: imf ! size of the structure sd
130	INTEGER :: jf ! dummy indices
131	INTEGER :: ireclast ! last record to be read in the current year file
132	INTEGER :: isecend ! number of second since Jan. 1st 00h of nit000 year at nitend
133	INTEGER :: isecsbc ! number of seconds between Jan. 1st 00h of nit000 year and the middle of sbc time step
134	INTEGER :: itime_add ! local time offset variable
135	LOGICAL :: llnxtyr ! open next year file?
136	LOGICAL :: llnxtmth ! open next month file?
137	LOGICAL :: llstop ! stop is the file does not exist
138	LOGICAL :: ll_firstcall ! true if this is the first call to fld_read for this set of fields
139	REAL(wp) :: ztinta ! ratio applied to after records when doing time interpolation
140	REAL(wp) :: ztintb ! ratio applied to before records when doing time interpolation
141	CHARACTER(LEN=1000) :: clfmt ! write format
142	!!---------------------------------------------------------------------
143	ll_firstcall = .false.
144	IF( PRESENT(jit) ) THEN
145	IF(kt == nit000 .and. jit == 1) ll_firstcall = .true.
146	ELSE
147	IF(kt == nit000) ll_firstcall = .true.
148	ENDIF
149
150	itime_add = 0
151	IF( PRESENT(time_offset) ) itime_add = time_offset
152
153	! Note that shifting time to be centrered in the middle of sbc time step impacts only nsec_* variables of the calendar
154	IF( present(jit) ) THEN
155	! ignore kn_fsbc in this case
156	isecsbc = nsec_year + nsec1jan000 + (jit+itime_add)*rdt/REAL(nn_baro,wp)
157	ELSE
158	isecsbc = nsec_year + nsec1jan000 + NINT(0.5 * REAL(kn_fsbc - 1,wp) * rdttra(1)) + itime_add * rdttra(1) ! middle of sbc time step
159	ENDIF
160	imf = SIZE( sd )
161	!
162	IF( ll_firstcall ) THEN ! initialization
163	IF( PRESENT(map) ) THEN
164	DO jf = 1, imf
165	CALL fld_init( kn_fsbc, sd(jf), map(jf)%ptr ) ! read each before field (put them in after as they will be swapped)
166	END DO
167	ELSE
168	DO jf = 1, imf
169	CALL fld_init( kn_fsbc, sd(jf) ) ! read each before field (put them in after as they will be swapped)
170	END DO
171	ENDIF
172	IF( lwp ) CALL wgt_print() ! control print
173	CALL fld_rot( kt, sd ) ! rotate vector fiels if needed
174	ENDIF
175	! ! ====================================== !
176	IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN ! update field at each kn_fsbc time-step !
177	! ! ====================================== !
178	!
179	DO jf = 1, imf ! --- loop over field --- !
180
181	IF( isecsbc > sd(jf)%nrec_a(2) .OR. ll_firstcall ) THEN ! read/update the after data?
182
183	IF( sd(jf)%ln_tint ) THEN ! swap before record field and informations
184	sd(jf)%nrec_b(:) = sd(jf)%nrec_a(:)
185	!CDIR COLLAPSE
186	sd(jf)%fdta(:,:,:,1) = sd(jf)%fdta(:,:,:,2)
187	ENDIF
188
189	IF( PRESENT(jit) ) THEN
190	CALL fld_rec( kn_fsbc, sd(jf), time_offset=itime_add, jit=jit ) ! update record informations
191	ELSE
192	CALL fld_rec( kn_fsbc, sd(jf), time_offset=itime_add ) ! update record informations
193	ENDIF
194
195	! do we have to change the year/month/week/day of the forcing field??
196	IF( sd(jf)%ln_tint ) THEN
197	! if we do time interpolation we will need to open next year/month/week/day file before the end of the current
198	! one. If so, we are still before the end of the year/month/week/day when calling fld_rec so sd(jf)%nrec_a(1)
199	! will be larger than the record number that should be read for current year/month/week/day
200
201	! last record to be read in the current file
202	IF ( sd(jf)%nfreqh == -12 ) THEN ; ireclast = 1 ! yearly mean
203	ELSEIF( sd(jf)%nfreqh == -1 ) THEN ! monthly mean
204	IF( sd(jf)%cltype == 'monthly' ) THEN ; ireclast = 1
205	ELSE ; ireclast = 12
206	ENDIF
207	ELSE ! higher frequency mean (in hours)
208	IF( sd(jf)%cltype == 'monthly' ) THEN ; ireclast = 24 * nmonth_len(nmonth) / sd(jf)%nfreqh
209	ELSEIF( sd(jf)%cltype(1:4) == 'week' ) THEN ; ireclast = 24 * 7 / sd(jf)%nfreqh
210	ELSEIF( sd(jf)%cltype == 'daily' ) THEN ; ireclast = 24 / sd(jf)%nfreqh
211	ELSE ; ireclast = 24 * nyear_len( 1 ) / sd(jf)%nfreqh
212	ENDIF
213	ENDIF
214
215	! do we need next file data?
216	IF( sd(jf)%nrec_a(1) > ireclast ) THEN
217
218	sd(jf)%nrec_a(1) = 1 ! force to read the first record of the next file
219
220	IF( .NOT. sd(jf)%ln_clim ) THEN ! close the current file and open a new one.
221
222	llnxtmth = sd(jf)%cltype == 'monthly' .OR. nday == nmonth_len(nmonth) ! open next month file?
223	llnxtyr = sd(jf)%cltype == 'yearly' .OR. (nmonth == 12 .AND. llnxtmth) ! open next year file?
224
225	! if the run finishes at the end of the current year/month/week/day, we will allow next
226	! year/month/week/day file to be not present. If the run continue further than the current
227	! year/month/week/day, next year/month/week/day file must exist
228	isecend = nsec_year + nsec1jan000 + (nitend - kt) * NINT(rdttra(1)) ! second at the end of the run
229	llstop = isecend > sd(jf)%nrec_a(2) ! read more than 1 record of next year
230
231	CALL fld_clopn( sd(jf), nyear + COUNT((/llnxtyr /)) , &
232	& nmonth + COUNT((/llnxtmth/)) - 12 * COUNT((/llnxtyr /)), &
233	& nday + 1 - nmonth_len(nmonth) * COUNT((/llnxtmth/)), llstop )
234
235	IF( sd(jf)%num <= 0 .AND. .NOT. llstop ) THEN ! next year file does not exist
236	CALL ctl_warn('next year/month/week/day file: '//TRIM(sd(jf)%clname)// &
237	& ' not present -> back to current year/month/day')
238	CALL fld_clopn( sd(jf), nyear, nmonth, nday ) ! back to the current year/month/day
239	sd(jf)%nrec_a(1) = ireclast ! force to read the last record to be read in the current year file
240	ENDIF
241
242	ENDIF
243	ENDIF
244
245	ELSE
246	! if we are not doing time interpolation, we must change the year/month/week/day of the file just after
247	! switching to the NEW year/month/week/day. If it is the case, we are at the beginning of the
248	! year/month/week/day when calling fld_rec so sd(jf)%nrec_a(1) = 1
249	IF( sd(jf)%nrec_a(1) == 1 .AND. .NOT. ( sd(jf)%ln_clim .AND. sd(jf)%cltype == 'yearly' ) ) &
250	& CALL fld_clopn( sd(jf), nyear, nmonth, nday )
251	ENDIF
252
253	! read after data
254	IF( PRESENT(map) ) THEN
255	CALL fld_get( sd(jf), map(jf)%ptr )
256	ELSE
257	CALL fld_get( sd(jf) )
258	ENDIF
259
260	ENDIF
261	END DO ! --- end loop over field --- !
262
263	CALL fld_rot( kt, sd ) ! rotate vector fiels if needed
264
265	DO jf = 1, imf ! --- loop over field --- !
266	!
267	IF( sd(jf)%ln_tint ) THEN ! temporal interpolation
268	IF(lwp .AND. kt - nit000 <= 100 ) THEN
269	clfmt = "('fld_read: var ', a, ' kt = ', i8, ' (', f7.2,' days), Y/M/D = ', i4.4,'/', i2.2,'/', i2.2," // &
270	& "', records b/a: ', i4.4, '/', i4.4, ' (days ', f7.2,'/', f7.2, ')')"
271	WRITE(numout, clfmt) TRIM( sd(jf)%clvar ), kt, REAL(isecsbc,wp)/rday, nyear, nmonth, nday, &
272	& sd(jf)%nrec_b(1), sd(jf)%nrec_a(1), REAL(sd(jf)%nrec_b(2),wp)/rday, REAL(sd(jf)%nrec_a(2),wp)/rday
273	WRITE(numout, *) 'itime_add is : ',itime_add
274	ENDIF
275	! temporal interpolation weights
276	ztinta = REAL( isecsbc - sd(jf)%nrec_b(2), wp ) / REAL( sd(jf)%nrec_a(2) - sd(jf)%nrec_b(2), wp )
277	ztintb = 1. - ztinta
278	!CDIR COLLAPSE
279	sd(jf)%fnow(:,:,:) = ztintb * sd(jf)%fdta(:,:,:,1) + ztinta * sd(jf)%fdta(:,:,:,2)
280	ELSE ! nothing to do...
281	IF(lwp .AND. kt - nit000 <= 100 ) THEN
282	clfmt = "('fld_read: var ', a, ' kt = ', i8,' (', f7.2,' days), Y/M/D = ', i4.4,'/', i2.2,'/', i2.2," // &
283	& "', record: ', i4.4, ' (days ', f7.2, ' <-> ', f7.2, ')')"
284	WRITE(numout, clfmt) TRIM(sd(jf)%clvar), kt, REAL(isecsbc,wp)/rday, nyear, nmonth, nday, &
285	& sd(jf)%nrec_a(1), REAL(sd(jf)%nrec_b(2),wp)/rday, REAL(sd(jf)%nrec_a(2),wp)/rday
286	ENDIF
287	ENDIF
288	!
289	IF( kt == nitend - kn_fsbc + 1 ) CALL iom_close( sd(jf)%num ) ! Close the input files
290
291	END DO ! --- end loop over field --- !
292	!
293	! ! ====================================== !
294	ENDIF ! update field at each kn_fsbc time-step !
295	! ! ====================================== !
296	!
297	END SUBROUTINE fld_read
298
299
300	SUBROUTINE fld_init( kn_fsbc, sdjf, map )
301	!!---------------------------------------------------------------------
302	!! * ROUTINE fld_init *
303	!!
304	!! ** Purpose : - if time interpolation, read before data
305	!! - open current year file
306	!!----------------------------------------------------------------------
307	INTEGER , INTENT(in ) :: kn_fsbc ! sbc computation period (in time step)
308	TYPE(FLD), INTENT(inout) :: sdjf ! input field related variables
309	INTEGER , INTENT(in), OPTIONAL, DIMENSION(:) :: map ! global-to-local mapping indices
310	!!
311	LOGICAL :: llprevyr ! are we reading previous year file?
312	LOGICAL :: llprevmth ! are we reading previous month file?
313	LOGICAL :: llprevweek ! are we reading previous week file?
314	LOGICAL :: llprevday ! are we reading previous day file?
315	LOGICAL :: llprev ! llprevyr .OR. llprevmth .OR. llprevweek .OR. llprevday
316	INTEGER :: idvar ! variable id
317	INTEGER :: inrec ! number of record existing for this variable
318	INTEGER :: iyear, imonth, iday ! first day of the current file in yyyy mm dd
319	INTEGER :: isec_week ! number of seconds since start of the weekly file
320	CHARACTER(LEN=1000) :: clfmt ! write format
321	!!---------------------------------------------------------------------
322
323	! some default definitions...
324	sdjf%num = 0 ! default definition for non-opened file
325	IF( sdjf%ln_clim ) sdjf%clname = TRIM( sdjf%clrootname ) ! file name defaut definition, never change in this case
326	llprevyr = .FALSE.
327	llprevmth = .FALSE.
328	llprevweek = .FALSE.
329	llprevday = .FALSE.
330	isec_week = 0
331
332	IF( sdjf%cltype(1:4) == 'week' .AND. nn_leapy == 0 ) &
333	& CALL ctl_stop('fld_clopn: weekly file ('//TRIM(sdjf%clrootname)//') needs nn_leapy = 1')
334	IF( sdjf%cltype(1:4) == 'week' .AND. sdjf%ln_clim ) &
335	& CALL ctl_stop('fld_clopn: weekly file ('//TRIM(sdjf%clrootname)//') needs ln_clim = .FALSE.')
336
337	! define record informations
338	CALL fld_rec( kn_fsbc, sdjf, ldbefore = .TRUE. ) ! return before values in sdjf%nrec_a (as we will swap it later)
339
340	! Note that shifting time to be centrered in the middle of sbc time step impacts only nsec_* variables of the calendar
341
342	IF( sdjf%ln_tint ) THEN ! we need to read the previous record and we will put it in the current record structure
343
344	IF( sdjf%nrec_a(1) == 0 ) THEN ! we redefine record sdjf%nrec_a(1) with the last record of previous year file
345	IF ( sdjf%nfreqh == -12 ) THEN ! yearly mean
346	IF( sdjf%cltype == 'yearly' ) THEN ! yearly file
347	sdjf%nrec_a(1) = 1 ! force to read the unique record
348	llprevyr = .NOT. sdjf%ln_clim ! use previous year file?
349	ELSE
350	CALL ctl_stop( "fld_init: yearly mean file must be in a yearly type of file: "//TRIM(sdjf%clname) )
351	ENDIF
352	ELSEIF( sdjf%nfreqh == -1 ) THEN ! monthly mean
353	IF( sdjf%cltype == 'monthly' ) THEN ! monthly file
354	sdjf%nrec_a(1) = 1 ! force to read the unique record
355	llprevmth = .TRUE. ! use previous month file?
356	llprevyr = llprevmth .AND. nmonth == 1 ! use previous year file?
357	ELSE ! yearly file
358	sdjf%nrec_a(1) = 12 ! force to read december mean
359	llprevyr = .NOT. sdjf%ln_clim ! use previous year file?
360	ENDIF
361	ELSE ! higher frequency mean (in hours)
362	IF ( sdjf%cltype == 'monthly' ) THEN ! monthly file
363	sdjf%nrec_a(1) = 24 * nmonth_len(nmonth-1) / sdjf%nfreqh ! last record of previous month
364	llprevmth = .TRUE. ! use previous month file?
365	llprevyr = llprevmth .AND. nmonth == 1 ! use previous year file?
366	ELSEIF( sdjf%cltype(1:4) == 'week' ) THEN ! weekly file
367	llprevweek = .TRUE. ! use previous week file?
368	sdjf%nrec_a(1) = 24 * 7 / sdjf%nfreqh ! last record of previous week
369	isec_week = NINT(rday) * 7 ! add a shift toward previous week
370	ELSEIF( sdjf%cltype == 'daily' ) THEN ! daily file
371	sdjf%nrec_a(1) = 24 / sdjf%nfreqh ! last record of previous day
372	llprevday = .TRUE. ! use previous day file?
373	llprevmth = llprevday .AND. nday == 1 ! use previous month file?
374	llprevyr = llprevmth .AND. nmonth == 1 ! use previous year file?
375	ELSE ! yearly file
376	sdjf%nrec_a(1) = 24 * nyear_len(0) / sdjf%nfreqh ! last record of previous year
377	llprevyr = .NOT. sdjf%ln_clim ! use previous year file?
378	ENDIF
379	ENDIF
380	ENDIF
381	IF ( sdjf%cltype(1:4) == 'week' ) THEN
382	isec_week = isec_week + ksec_week( sdjf%cltype(6:8) ) ! second since the beginning of the week
383	llprevmth = isec_week > nsec_month ! longer time since the beginning of the week than the month
384	llprevyr = llprevmth .AND. nmonth == 1
385	ENDIF
386	llprev = llprevyr .OR. llprevmth .OR. llprevweek .OR. llprevday
387	!
388	iyear = nyear - COUNT((/llprevyr /))
389	imonth = nmonth - COUNT((/llprevmth/)) + 12 * COUNT((/llprevyr /))
390	iday = nday - COUNT((/llprevday/)) + nmonth_len(nmonth-1) * COUNT((/llprevmth/)) - isec_week / NINT(rday)
391	!
392	CALL fld_clopn( sdjf, iyear, imonth, iday, .NOT. llprev )
393
394	! if previous year/month/day file does not exist, we switch to the current year/month/day
395	IF( llprev .AND. sdjf%num <= 0 ) THEN
396	CALL ctl_warn( 'previous year/month/week/day file: '//TRIM(sdjf%clname)// &
397	& ' not present -> back to current year/month/week/day' )
398	! we force to read the first record of the current year/month/day instead of last record of previous year/month/day
399	llprev = .FALSE.
400	sdjf%nrec_a(1) = 1
401	CALL fld_clopn( sdjf, nyear, nmonth, nday )
402	ENDIF
403
404	IF( llprev ) THEN ! check if the last record sdjf%nrec_n(1) exists in the file
405	idvar = iom_varid( sdjf%num, sdjf%clvar ) ! id of the variable sdjf%clvar
406	IF( idvar <= 0 ) RETURN
407	inrec = iom_file( sdjf%num )%dimsz( iom_file( sdjf%num )%ndims(idvar), idvar ) ! size of the last dim of idvar
408	sdjf%nrec_a(1) = MIN( sdjf%nrec_a(1), inrec ) ! make sure we select an existing record
409	ENDIF
410
411	! read before data
412	IF( PRESENT(map) ) THEN
413	CALL fld_get( sdjf, map ) ! read before values in after arrays(as we will swap it later)
414	ELSE
415	CALL fld_get( sdjf ) ! read before values in after arrays(as we will swap it later)
416	ENDIF
417
418	clfmt = "('fld_init : time-interpolation for ', a, ' read previous record = ', i4, ' at time = ', f7.2, ' days')"
419	IF(lwp) WRITE(numout, clfmt) TRIM(sdjf%clvar), sdjf%nrec_a(1), REAL(sdjf%nrec_a(2),wp)/rday
420
421	IF( llprev ) CALL iom_close( sdjf%num ) ! force to close previous year file (-> redefine sdjf%num to 0)
422
423	ENDIF
424
425	! make sure current year/month/day file is opened
426	IF( sdjf%num <= 0 ) THEN
427	!
428	IF ( sdjf%cltype(1:4) == 'week' ) THEN
429	isec_week = ksec_week( sdjf%cltype(6:8) ) ! second since the beginning of the week
430	llprevmth = isec_week > nsec_month ! longer time since beginning of the week than the month
431	llprevyr = llprevmth .AND. nmonth == 1
432	ELSE
433	isec_week = 0
434	llprevmth = .FALSE.
435	llprevyr = .FALSE.
436	ENDIF
437	!
438	iyear = nyear - COUNT((/llprevyr /))
439	imonth = nmonth - COUNT((/llprevmth/)) + 12 * COUNT((/llprevyr /))
440	iday = nday + nmonth_len(nmonth-1) * COUNT((/llprevmth/)) - isec_week / NINT(rday)
441	!
442	CALL fld_clopn( sdjf, iyear, imonth, iday )
443	ENDIF
444	!
445	END SUBROUTINE fld_init
446
447
448	SUBROUTINE fld_rec( kn_fsbc, sdjf, ldbefore, jit, time_offset )
449	!!---------------------------------------------------------------------
450	!! * ROUTINE fld_rec *
451	!!
452	!! ** Purpose : Compute
453	!! if sdjf%ln_tint = .TRUE.
454	!! nrec_a: record number and its time (nrec_b is obtained from nrec_a when swapping)
455	!! if sdjf%ln_tint = .FALSE.
456	!! nrec_a(1): record number
457	!! nrec_b(2) and nrec_a(2): time of the beginning and end of the record (for print only)
458	!!----------------------------------------------------------------------
459	INTEGER , INTENT(in ) :: kn_fsbc ! sbc computation period (in time step)
460	TYPE(FLD), INTENT(inout) :: sdjf ! input field related variables
461	LOGICAL , INTENT(in ), OPTIONAL :: ldbefore ! sent back before record values (default = .FALSE.)
462	INTEGER , INTENT(in ), OPTIONAL :: jit ! index of barotropic subcycle
463	! used only if sdjf%ln_tint = .TRUE.
464	INTEGER , INTENT(in ), OPTIONAL :: time_offset ! Offset of required time level compared to "now"
465	! time level in units of time steps.
466	!!
467	LOGICAL :: llbefore ! local definition of ldbefore
468	INTEGER :: iendrec ! end of this record (in seconds)
469	INTEGER :: imth ! month number
470	INTEGER :: ifreq_sec ! frequency mean (in seconds)
471	INTEGER :: isec_week ! number of seconds since the start of the weekly file
472	INTEGER :: itime_add ! local time offset variable
473	REAL(wp) :: ztmp ! temporary variable
474	!!----------------------------------------------------------------------
475	!
476	! Note that shifting time to be centrered in the middle of sbc time step impacts only nsec_* variables of the calendar
477	!
478	IF( PRESENT(ldbefore) ) THEN ; llbefore = ldbefore .AND. sdjf%ln_tint ! needed only if sdjf%ln_tint = .TRUE.
479	ELSE ; llbefore = .FALSE.
480	ENDIF
481	!
482	itime_add = 0
483	IF( PRESENT(time_offset) ) itime_add = time_offset
484	!
485	! ! =========== !
486	IF ( sdjf%nfreqh == -12 ) THEN ! yearly mean
487	! ! =========== !
488	!
489	IF( sdjf%ln_tint ) THEN ! time interpolation, shift by 1/2 record
490	!
491	! INT( ztmp )
492	! /\|\
493	! 1 \| *----
494	! 0 \|----(
495	! \|----+----\|--> time
496	! 0 /\|\ 1 (nday/nyear_len(1))
497	! \|
498	! \|
499	! forcing record : 1
500	!
501	ztmp = REAL( nday, wp ) / REAL( nyear_len(1), wp ) + 0.5
502	IF( PRESENT(jit) ) THEN
503	ztmp = ztmp + (jit+itime_add)*rdt/REAL(nn_baro,wp)
504	ELSE
505	ztmp = ztmp + itime_add*rdttra(1)
506	ENDIF
507	sdjf%nrec_a(1) = 1 + INT( ztmp ) - COUNT((/llbefore/))
508	! swap at the middle of the year
509	IF( llbefore ) THEN ; sdjf%nrec_a(2) = nsec1jan000 - NINT(0.5 * rday) * nyear_len(0)
510	ELSE ; sdjf%nrec_a(2) = nsec1jan000 + NINT(0.5 * rday) * nyear_len(1)
511	ENDIF
512	ELSE ! no time interpolation
513	sdjf%nrec_a(1) = 1
514	sdjf%nrec_a(2) = NINT(rday) * nyear_len(1) + nsec1jan000 ! swap at the end of the year
515	sdjf%nrec_b(2) = nsec1jan000 ! beginning of the year (only for print)
516	ENDIF
517	!
518	! ! ============ !
519	ELSEIF( sdjf%nfreqh == -1 ) THEN ! monthly mean !
520	! ! ============ !
521	!
522	IF( sdjf%ln_tint ) THEN ! time interpolation, shift by 1/2 record
523	!
524	! INT( ztmp )
525	! /\|\
526	! 1 \| *----
527	! 0 \|----(
528	! \|----+----\|--> time
529	! 0 /\|\ 1 (nday/nmonth_len(nmonth))
530	! \|
531	! \|
532	! forcing record : nmonth
533	!
534	ztmp = REAL( nday, wp ) / REAL( nmonth_len(nmonth), wp ) + 0.5
535	IF( PRESENT(jit) ) THEN
536	ztmp = ztmp + (jit+itime_add)*rdt/REAL(nn_baro,wp)
537	ELSE
538	ztmp = ztmp + itime_add*rdttra(1)
539	ENDIF
540	imth = nmonth + INT( ztmp ) - COUNT((/llbefore/))
541	IF( sdjf%cltype == 'monthly' ) THEN ; sdjf%nrec_a(1) = 1 + INT( ztmp ) - COUNT((/llbefore/))
542	ELSE ; sdjf%nrec_a(1) = imth
543	ENDIF
544	sdjf%nrec_a(2) = nmonth_half( imth ) + nsec1jan000 ! swap at the middle of the month
545	ELSE ! no time interpolation
546	IF( sdjf%cltype == 'monthly' ) THEN ; sdjf%nrec_a(1) = 1
547	ELSE ; sdjf%nrec_a(1) = nmonth
548	ENDIF
549	sdjf%nrec_a(2) = nmonth_end(nmonth ) + nsec1jan000 ! swap at the end of the month
550	sdjf%nrec_b(2) = nmonth_end(nmonth-1) + nsec1jan000 ! beginning of the month (only for print)
551	ENDIF
552	!
553	! ! ================================ !
554	ELSE ! higher frequency mean (in hours)
555	! ! ================================ !
556	!
557	ifreq_sec = sdjf%nfreqh * 3600 ! frequency mean (in seconds)
558	IF( sdjf%cltype(1:4) == 'week' ) isec_week = ksec_week( sdjf%cltype(6:8) ) ! since the first day of the current week
559	! number of second since the beginning of the file
560	IF( sdjf%cltype == 'monthly' ) THEN ; ztmp = REAL(nsec_month,wp) ! since the first day of the current month
561	ELSEIF( sdjf%cltype(1:4) == 'week' ) THEN ; ztmp = REAL(isec_week ,wp) ! since the first day of the current week
562	ELSEIF( sdjf%cltype == 'daily' ) THEN ; ztmp = REAL(nsec_day ,wp) ! since 00h of the current day
563	ELSE ; ztmp = REAL(nsec_year ,wp) ! since 00h on Jan 1 of the current year
564	ENDIF
565	ztmp = ztmp + 0.5 * REAL(kn_fsbc - 1, wp) * rdttra(1) ! shift time to be centrered in the middle of sbc time step
566	ztmp = ztmp + 0.01 * rdttra(1) ! add 0.01 time step to avoid truncation error
567	IF( PRESENT(jit) ) THEN
568	ztmp = ztmp + (jit+itime_add)*rdt/REAL(nn_baro,wp)
569	ELSE
570	ztmp = ztmp + itime_add*rdttra(1)
571	ENDIF
572	IF( sdjf%ln_tint ) THEN ! time interpolation, shift by 1/2 record
573	!
574	! INT( ztmp )
575	! /\|\
576	! 2 \| *-----(
577	! 1 \| *-----(
578	! 0 \|--(
579	! \|--+--\|--+--\|--+--\|--> time
580	! 0 /\|\ 1 /\|\ 2 /\|\ 3 (nsec_year/ifreq_sec) or (nsec_month/ifreq_sec)
581	! \| \| \|
582	! \| \| \|
583	! forcing record : 1 2 3
584	!
585	ztmp= ztmp / REAL(ifreq_sec, wp) + 0.5
586	ELSE ! no time interpolation
587	!
588	! INT( ztmp )
589	! /\|\
590	! 2 \| *-----(
591	! 1 \| *-----(
592	! 0 \|-----(
593	! \|--+--\|--+--\|--+--\|--> time
594	! 0 /\|\ 1 /\|\ 2 /\|\ 3 (nsec_year/ifreq_sec) or (nsec_month/ifreq_sec)
595	! \| \| \|
596	! \| \| \|
597	! forcing record : 1 2 3
598	!
599	ztmp= ztmp / REAL(ifreq_sec, wp)
600	ENDIF
601	sdjf%nrec_a(1) = 1 + INT( ztmp ) - COUNT((/llbefore/)) ! record nomber to be read
602
603	iendrec = ifreq_sec * sdjf%nrec_a(1) + nsec1jan000 ! end of this record (in second)
604	! add the number of seconds between 00h Jan 1 and the end of previous month/week/day (ok if nmonth=1)
605	IF( sdjf%cltype == 'monthly' ) iendrec = iendrec + NINT(rday) * SUM(nmonth_len(1:nmonth -1))
606	IF( sdjf%cltype(1:4) == 'week' ) iendrec = iendrec + ( nsec_year - isec_week )
607	IF( sdjf%cltype == 'daily' ) iendrec = iendrec + NINT(rday) * ( nday_year - 1 )
608	IF( sdjf%ln_tint ) THEN
609	sdjf%nrec_a(2) = iendrec - ifreq_sec / 2 ! swap at the middle of the record
610	ELSE
611	sdjf%nrec_a(2) = iendrec ! swap at the end of the record
612	sdjf%nrec_b(2) = iendrec - ifreq_sec ! beginning of the record (only for print)
613	ENDIF
614	!
615	ENDIF
616	!
617	END SUBROUTINE fld_rec
618
619
620	SUBROUTINE fld_get( sdjf, map )
621	!!---------------------------------------------------------------------
622	!! * ROUTINE fld_get *
623	!!
624	!! ** Purpose : read the data
625	!!----------------------------------------------------------------------
626	TYPE(FLD), INTENT(inout) :: sdjf ! input field related variables
627	INTEGER , INTENT(in), OPTIONAL, DIMENSION(:) :: map ! global-to-local mapping indices
628	!!
629	INTEGER :: ipk ! number of vertical levels of sdjf%fdta ( 2D: ipk=1 ; 3D: ipk=jpk )
630	INTEGER :: iw ! index into wgts array
631	INTEGER :: ipdom ! index of the domain
632	!!---------------------------------------------------------------------
633	!
634	ipk = SIZE( sdjf%fnow, 3 )
635	!
636	IF( PRESENT(map) ) THEN
637	IF( sdjf%ln_tint ) THEN ; CALL fld_map( sdjf%num, sdjf%clvar, sdjf%fdta(:,:,:,2), sdjf%nrec_a(1), map )
638	ELSE ; CALL fld_map( sdjf%num, sdjf%clvar, sdjf%fnow(:,:,: ), sdjf%nrec_a(1), map )
639	ENDIF
640	ELSE IF( LEN(TRIM(sdjf%wgtname)) > 0 ) THEN
641	CALL wgt_list( sdjf, iw )
642	IF( sdjf%ln_tint ) THEN ; CALL fld_interp( sdjf%num, sdjf%clvar, iw , ipk , sdjf%fdta(:,:,:,2), sdjf%nrec_a(1) )
643	ELSE ; CALL fld_interp( sdjf%num, sdjf%clvar, iw , ipk , sdjf%fnow(:,:,: ), sdjf%nrec_a(1) )
644	ENDIF
645	ELSE
646	IF( SIZE(sdjf%fnow, 1) == jpi ) THEN ; ipdom = jpdom_data
647	ELSE ; ipdom = jpdom_unknown
648	ENDIF
649	SELECT CASE( ipk )
650	CASE(1)
651	IF( sdjf%ln_tint ) THEN ; CALL iom_get( sdjf%num, ipdom, sdjf%clvar, sdjf%fdta(:,:,1,2), sdjf%nrec_a(1) )
652	ELSE ; CALL iom_get( sdjf%num, ipdom, sdjf%clvar, sdjf%fnow(:,:,1 ), sdjf%nrec_a(1) )
653	ENDIF
654	CASE DEFAULT
655	IF( sdjf%ln_tint ) THEN ; CALL iom_get( sdjf%num, ipdom, sdjf%clvar, sdjf%fdta(:,:,:,2), sdjf%nrec_a(1) )
656	ELSE ; CALL iom_get( sdjf%num, ipdom, sdjf%clvar, sdjf%fnow(:,:,: ), sdjf%nrec_a(1) )
657	ENDIF
658	END SELECT
659	ENDIF
660	!
661	sdjf%rotn = .false. ! vector not yet rotated
662
663	END SUBROUTINE fld_get
664
665	SUBROUTINE fld_map( num, clvar, dta, nrec, map )
666	!!---------------------------------------------------------------------
667	!! * ROUTINE fld_get *
668	!!
669	!! ** Purpose : read global data from file and map onto local data
670	!! using a general mapping (for open boundaries)
671	!!----------------------------------------------------------------------
672	#if defined key_bdy
673	USE bdy_oce, ONLY: dta_global ! workspace to read in global data arrays
674	#endif
675
676	INTEGER , INTENT(in ) :: num ! stream number
677	CHARACTER(LEN=*) , INTENT(in ) :: clvar ! variable name
678	REAL(wp), DIMENSION(:,:,:), INTENT(out) :: dta ! output field on model grid (2 dimensional)
679	INTEGER , INTENT(in ) :: nrec ! record number to read (ie time slice)
680	INTEGER, DIMENSION(:) , INTENT(in ) :: map ! global-to-local mapping indices
681	!!
682	INTEGER :: ipi ! length of boundary data on local process
683	INTEGER :: ipj ! length of dummy dimension ( = 1 )
684	INTEGER :: ipk ! number of vertical levels of dta ( 2D: ipk=1 ; 3D: ipk=jpk )
685	INTEGER :: ilendta ! length of data in file
686	INTEGER :: idvar ! variable ID
687	INTEGER :: ib, ik ! loop counters
688	INTEGER :: ierr
689	REAL(wp), POINTER, DIMENSION(:,:,:) :: dta_read ! work space for global data
690	!!---------------------------------------------------------------------
691
692	#if defined key_bdy
693	dta_read => dta_global
694	#endif
695
696	ipi = SIZE( dta, 1 )
697	ipj = 1
698	ipk = SIZE( dta, 3 )
699
700	idvar = iom_varid( num, clvar )
701	ilendta = iom_file(num)%dimsz(1,idvar)
702	IF(lwp) WRITE(numout,*) 'Dim size for ',TRIM(clvar),' is ', ilendta
703	IF(lwp) WRITE(numout,*) 'Number of levels for ',TRIM(clvar),' is ', ipk
704
705	SELECT CASE( ipk )
706	CASE(1)
707	CALL iom_get ( num, jpdom_unknown, clvar, dta_read(1:ilendta,1:ipj,1 ), nrec )
708	CASE DEFAULT
709	CALL iom_get ( num, jpdom_unknown, clvar, dta_read(1:ilendta,1:ipj,1:ipk), nrec )
710	END SELECT
711	!
712	DO ib = 1, ipi
713	DO ik = 1, ipk
714	dta(ib,1,ik) = dta_read(map(ib),1,ik)
715	END DO
716	END DO
717
718	END SUBROUTINE fld_map
719
720
721	SUBROUTINE fld_rot( kt, sd )
722	!!---------------------------------------------------------------------
723	!! * ROUTINE fld_rot *
724	!!
725	!! ** Purpose : Vector fields may need to be rotated onto the local grid direction
726	!!----------------------------------------------------------------------
727	INTEGER , INTENT(in ) :: kt ! ocean time step
728	TYPE(FLD), INTENT(inout), DIMENSION(:) :: sd ! input field related variables
729	!!
730	INTEGER :: ju, jv, jk ! loop indices
731	INTEGER :: imf ! size of the structure sd
732	INTEGER :: ill ! character length
733	INTEGER :: iv ! indice of V component
734	REAL(wp), POINTER, DIMENSION(:,:) :: utmp, vtmp ! temporary arrays for vector rotation
735	CHARACTER (LEN=100) :: clcomp ! dummy weight name
736	!!---------------------------------------------------------------------
737
738	CALL wrk_alloc( jpi,jpj, utmp, vtmp )
739
740	!! (sga: following code should be modified so that pairs arent searched for each time
741	!
742	imf = SIZE( sd )
743	DO ju = 1, imf
744	ill = LEN_TRIM( sd(ju)%vcomp )
745	IF( ill > 0 .AND. .NOT. sd(ju)%rotn ) THEN ! find vector rotations required
746	IF( sd(ju)%vcomp(1:1) == 'U' ) THEN ! east-west component has symbolic name starting with 'U'
747	! look for the north-south component which has same symbolic name but with 'U' replaced with 'V'
748	clcomp = 'V' // sd(ju)%vcomp(2:ill) ! works even if ill == 1
749	iv = -1
750	DO jv = 1, imf
751	IF( TRIM(sd(jv)%vcomp) == TRIM(clcomp) ) iv = jv
752	END DO
753	IF( iv > 0 ) THEN ! fields ju and iv are two components which need to be rotated together
754	DO jk = 1, SIZE( sd(ju)%fnow, 3 )
755	IF( sd(ju)%ln_tint )THEN
756	CALL rot_rep( sd(ju)%fdta(:,:,jk,2), sd(iv)%fdta(:,:,jk,2), 'T', 'en->i', utmp(:,:) )
757	CALL rot_rep( sd(ju)%fdta(:,:,jk,2), sd(iv)%fdta(:,:,jk,2), 'T', 'en->j', vtmp(:,:) )
758	sd(ju)%fdta(:,:,jk,2) = utmp(:,:) ; sd(iv)%fdta(:,:,jk,2) = vtmp(:,:)
759	ELSE
760	CALL rot_rep( sd(ju)%fnow(:,:,jk ), sd(iv)%fnow(:,:,jk ), 'T', 'en->i', utmp(:,:) )
761	CALL rot_rep( sd(ju)%fnow(:,:,jk ), sd(iv)%fnow(:,:,jk ), 'T', 'en->j', vtmp(:,:) )
762	sd(ju)%fnow(:,:,jk ) = utmp(:,:) ; sd(iv)%fnow(:,:,jk ) = vtmp(:,:)
763	ENDIF
764	END DO
765	sd(ju)%rotn = .TRUE. ! vector was rotated
766	IF( lwp .AND. kt == nit000 ) WRITE(numout,*) &
767	& 'fld_read: vector pair ('//TRIM(sd(ju)%clvar)//', '//TRIM(sd(iv)%clvar)//') rotated on to model grid'
768	ENDIF
769	ENDIF
770	ENDIF
771	END DO
772	!
773	CALL wrk_dealloc( jpi,jpj, utmp, vtmp )
774	!
775	END SUBROUTINE fld_rot
776
777
778	SUBROUTINE fld_clopn( sdjf, kyear, kmonth, kday, ldstop )
779	!!---------------------------------------------------------------------
780	!! * ROUTINE fld_clopn *
781	!!
782	!! ** Purpose : update the file name and open the file
783	!!----------------------------------------------------------------------
784	TYPE(FLD) , INTENT(inout) :: sdjf ! input field related variables
785	INTEGER , INTENT(in ) :: kyear ! year value
786	INTEGER , INTENT(in ) :: kmonth ! month value
787	INTEGER , INTENT(in ) :: kday ! day value
788	LOGICAL, OPTIONAL, INTENT(in ) :: ldstop ! stop if open to read a non-existing file (default = .TRUE.)
789	!!----------------------------------------------------------------------
790
791	IF( sdjf%num /= 0 ) CALL iom_close( sdjf%num ) ! close file if already open
792	! build the new filename if not climatological data
793	sdjf%clname=TRIM(sdjf%clrootname)
794	!
795	! note that sdjf%ln_clim is is only acting on presence of the year in the file
796	IF( .NOT. sdjf%ln_clim ) THEN
797	WRITE(sdjf%clname, '(a,"_y",i4.4)' ) TRIM( sdjf%clrootname ), kyear ! add year
798	IF( sdjf%cltype /= 'yearly' ) WRITE(sdjf%clname, '(a,"m" ,i2.2)' ) TRIM( sdjf%clname ), kmonth ! add month
799	ELSE
800	! build the new filename if climatological data
801	IF( sdjf%cltype /= 'yearly' ) WRITE(sdjf%clname, '(a,"_m",i2.2)' ) TRIM( sdjf%clrootname ), kmonth ! add month
802	ENDIF
803	IF( sdjf%cltype == 'daily' .OR. sdjf%cltype(1:4) == 'week' ) &
804	& WRITE(sdjf%clname, '(a,"d" ,i2.2)' ) TRIM( sdjf%clname ), kday ! add day
805	!
806	CALL iom_open( sdjf%clname, sdjf%num, ldstop = ldstop, ldiof = LEN(TRIM(sdjf%wgtname)) > 0 )
807	!
808	END SUBROUTINE fld_clopn
809
810
811	SUBROUTINE fld_fill( sdf, sdf_n, cdir, cdcaller, cdtitle, cdnam )
812	!!---------------------------------------------------------------------
813	!! * ROUTINE fld_fill *
814	!!
815	!! ** Purpose : fill sdf with sdf_n and control print
816	!!----------------------------------------------------------------------
817	TYPE(FLD) , DIMENSION(:), INTENT(inout) :: sdf ! structure of input fields (file informations, fields read)
818	TYPE(FLD_N), DIMENSION(:), INTENT(in ) :: sdf_n ! array of namelist information structures
819	CHARACTER(len=*) , INTENT(in ) :: cdir ! Root directory for location of flx files
820	CHARACTER(len=*) , INTENT(in ) :: cdcaller !
821	CHARACTER(len=*) , INTENT(in ) :: cdtitle !
822	CHARACTER(len=*) , INTENT(in ) :: cdnam !
823	!
824	INTEGER :: jf ! dummy indices
825	!!---------------------------------------------------------------------
826
827	DO jf = 1, SIZE(sdf)
828	sdf(jf)%clrootname = TRIM( cdir )//TRIM( sdf_n(jf)%clname )
829	sdf(jf)%nfreqh = sdf_n(jf)%nfreqh
830	sdf(jf)%clvar = sdf_n(jf)%clvar
831	sdf(jf)%ln_tint = sdf_n(jf)%ln_tint
832	sdf(jf)%ln_clim = sdf_n(jf)%ln_clim
833	sdf(jf)%cltype = sdf_n(jf)%cltype
834	sdf(jf)%wgtname = " "
835	IF( LEN( TRIM(sdf_n(jf)%wname) ) > 0 ) sdf(jf)%wgtname = TRIM( cdir )//TRIM( sdf_n(jf)%wname )
836	sdf(jf)%vcomp = sdf_n(jf)%vcomp
837	sdf(jf)%rotn = .FALSE.
838	END DO
839
840	IF(lwp) THEN ! control print
841	WRITE(numout,*)
842	WRITE(numout,*) TRIM( cdcaller )//' : '//TRIM( cdtitle )
843	WRITE(numout,*) (/ ('~', jf = 1, LEN_TRIM( cdcaller ) ) /)
844	WRITE(numout,*) ' '//TRIM( cdnam )//' Namelist'
845	WRITE(numout,*) ' list of files and frequency (>0: in hours ; <0 in months)'
846	DO jf = 1, SIZE(sdf)
847	WRITE(numout,*) ' root filename: ' , TRIM( sdf(jf)%clrootname ), &
848	& ' variable name: ' , TRIM( sdf(jf)%clvar )
849	WRITE(numout,*) ' frequency: ' , sdf(jf)%nfreqh , &
850	& ' time interp: ' , sdf(jf)%ln_tint , &
851	& ' climatology: ' , sdf(jf)%ln_clim , &
852	& ' weights : ' , TRIM( sdf(jf)%wgtname ), &
853	& ' pairing : ' , TRIM( sdf(jf)%vcomp ), &
854	& ' data type: ' , sdf(jf)%cltype
855	call flush(numout)
856	END DO
857	ENDIF
858
859	END SUBROUTINE fld_fill
860
861
862	SUBROUTINE wgt_list( sd, kwgt )
863	!!---------------------------------------------------------------------
864	!! * ROUTINE wgt_list *
865	!!
866	!! ** Purpose : search array of WGTs and find a weights file
867	!! entry, or return a new one adding it to the end
868	!! if it is a new entry, the weights data is read in and
869	!! restructured (fld_weight)
870	!!----------------------------------------------------------------------
871	TYPE( FLD ), INTENT(in ) :: sd ! field with name of weights file
872	INTEGER , INTENT(inout) :: kwgt ! index of weights
873	!!
874	INTEGER :: kw, nestid ! local integer
875	LOGICAL :: found ! local logical
876	!!----------------------------------------------------------------------
877	!
878	!! search down linked list
879	!! weights filename is either present or we hit the end of the list
880	found = .FALSE.
881
882	!! because agrif nest part of filenames are now added in iom_open
883	!! to distinguish between weights files on the different grids, need to track
884	!! nest number explicitly
885	nestid = 0
886	#if defined key_agrif
887	nestid = Agrif_Fixed()
888	#endif
889	DO kw = 1, nxt_wgt-1
890	IF( TRIM(ref_wgts(kw)%wgtname) == TRIM(sd%wgtname) .AND. &
891	ref_wgts(kw)%nestid == nestid) THEN
892	kwgt = kw
893	found = .TRUE.
894	EXIT
895	ENDIF
896	END DO
897	IF( .NOT.found ) THEN
898	kwgt = nxt_wgt
899	CALL fld_weight( sd )
900	ENDIF
901	!
902	END SUBROUTINE wgt_list
903
904
905	SUBROUTINE wgt_print( )
906	!!---------------------------------------------------------------------
907	!! * ROUTINE wgt_print *
908	!!
909	!! ** Purpose : print the list of known weights
910	!!----------------------------------------------------------------------
911	INTEGER :: kw !
912	!!----------------------------------------------------------------------
913	!
914	DO kw = 1, nxt_wgt-1
915	WRITE(numout,*) 'weight file: ',TRIM(ref_wgts(kw)%wgtname)
916	WRITE(numout,*) ' ddims: ',ref_wgts(kw)%ddims(1),ref_wgts(kw)%ddims(2)
917	WRITE(numout,*) ' numwgt: ',ref_wgts(kw)%numwgt
918	WRITE(numout,*) ' jpiwgt: ',ref_wgts(kw)%jpiwgt
919	WRITE(numout,*) ' jpjwgt: ',ref_wgts(kw)%jpjwgt
920	WRITE(numout,*) ' botleft: ',ref_wgts(kw)%botleft
921	WRITE(numout,*) ' topright: ',ref_wgts(kw)%topright
922	IF( ref_wgts(kw)%cyclic ) THEN
923	WRITE(numout,*) ' cyclical'
924	IF( ref_wgts(kw)%overlap > 0 ) WRITE(numout,*) ' with overlap of ', ref_wgts(kw)%overlap
925	ELSE
926	WRITE(numout,*) ' not cyclical'
927	ENDIF
928	IF( ASSOCIATED(ref_wgts(kw)%data_wgt) ) WRITE(numout,*) ' allocated'
929	END DO
930	!
931	END SUBROUTINE wgt_print
932
933
934	SUBROUTINE fld_weight( sd )
935	!!---------------------------------------------------------------------
936	!! * ROUTINE fld_weight *
937	!!
938	!! ** Purpose : create a new WGT structure and fill in data from
939	!! file, restructuring as required
940	!!----------------------------------------------------------------------
941	TYPE( FLD ), INTENT(in) :: sd ! field with name of weights file
942	!!
943	INTEGER :: jn ! dummy loop indices
944	INTEGER :: inum ! temporary logical unit
945	INTEGER :: id ! temporary variable id
946	INTEGER :: ipk ! temporary vertical dimension
947	CHARACTER (len=5) :: aname
948	INTEGER , DIMENSION(3) :: ddims
949	INTEGER , POINTER, DIMENSION(:,:) :: data_src
950	REAL(wp), POINTER, DIMENSION(:,:) :: data_tmp
951	LOGICAL :: cyclical
952	INTEGER :: zwrap ! local integer
953	!!----------------------------------------------------------------------
954	!
955	CALL wrk_alloc( jpi,jpj, data_src ) ! integer
956	CALL wrk_alloc( jpi,jpj, data_tmp )
957	!
958	IF( nxt_wgt > tot_wgts ) THEN
959	CALL ctl_stop("fld_weight: weights array size exceeded, increase tot_wgts")
960	ENDIF
961	!
962	!! new weights file entry, add in extra information
963	!! a weights file represents a 2D grid of a certain shape, so we assume that the current
964	!! input data file is representative of all other files to be opened and processed with the
965	!! current weights file
966
967	!! open input data file (non-model grid)
968	CALL iom_open( sd%clname, inum, ldiof = LEN(TRIM(sd%wgtname)) > 0 )
969
970	!! get dimensions
971	id = iom_varid( inum, sd%clvar, ddims )
972
973	!! close it
974	CALL iom_close( inum )
975
976	!! now open the weights file
977
978	CALL iom_open ( sd%wgtname, inum ) ! interpolation weights
979	IF ( inum > 0 ) THEN
980
981	!! determine whether we have an east-west cyclic grid
982	!! from global attribute called "ew_wrap" in the weights file
983	!! note that if not found, iom_getatt returns -999 and cyclic with no overlap is assumed
984	!! since this is the most common forcing configuration
985
986	CALL iom_getatt(inum, 'ew_wrap', zwrap)
987	IF( zwrap >= 0 ) THEN
988	cyclical = .TRUE.
989	ELSE IF( zwrap == -999 ) THEN
990	cyclical = .TRUE.
991	zwrap = 0
992	ELSE
993	cyclical = .FALSE.
994	ENDIF
995
996	ref_wgts(nxt_wgt)%ddims(1) = ddims(1)
997	ref_wgts(nxt_wgt)%ddims(2) = ddims(2)
998	ref_wgts(nxt_wgt)%wgtname = sd%wgtname
999	ref_wgts(nxt_wgt)%overlap = zwrap
1000	ref_wgts(nxt_wgt)%cyclic = cyclical
1001	ref_wgts(nxt_wgt)%nestid = 0
1002	#if defined key_agrif
1003	ref_wgts(nxt_wgt)%nestid = Agrif_Fixed()
1004	#endif
1005	!! weights file is stored as a set of weights (wgt01->wgt04 or wgt01->wgt16)
1006	!! for each weight wgtNN there is an integer array srcNN which gives the point in
1007	!! the input data grid which is to be multiplied by the weight
1008	!! they are both arrays on the model grid so the result of the multiplication is
1009	!! added into an output array on the model grid as a running sum
1010
1011	!! two possible cases: bilinear (4 weights) or bicubic (16 weights)
1012	id = iom_varid(inum, 'src05', ldstop=.FALSE.)
1013	IF( id <= 0) THEN
1014	ref_wgts(nxt_wgt)%numwgt = 4
1015	ELSE
1016	ref_wgts(nxt_wgt)%numwgt = 16
1017	ENDIF
1018
1019	ALLOCATE( ref_wgts(nxt_wgt)%data_jpi(jpi,jpj,4) )
1020	ALLOCATE( ref_wgts(nxt_wgt)%data_jpj(jpi,jpj,4) )
1021	ALLOCATE( ref_wgts(nxt_wgt)%data_wgt(jpi,jpj,ref_wgts(nxt_wgt)%numwgt) )
1022
1023	DO jn = 1,4
1024	aname = ' '
1025	WRITE(aname,'(a3,i2.2)') 'src',jn
1026	data_tmp(:,:) = 0
1027	CALL iom_get ( inum, jpdom_data, aname, data_tmp(:,:) )
1028	data_src(:,:) = INT(data_tmp(:,:))
1029	ref_wgts(nxt_wgt)%data_jpj(:,:,jn) = 1 + (data_src(:,:)-1) / ref_wgts(nxt_wgt)%ddims(1)
1030	ref_wgts(nxt_wgt)%data_jpi(:,:,jn) = data_src(:,:) - ref_wgts(nxt_wgt)%ddims(1)*(ref_wgts(nxt_wgt)%data_jpj(:,:,jn)-1)
1031	END DO
1032
1033	DO jn = 1, ref_wgts(nxt_wgt)%numwgt
1034	aname = ' '
1035	WRITE(aname,'(a3,i2.2)') 'wgt',jn
1036	ref_wgts(nxt_wgt)%data_wgt(:,:,jn) = 0.0
1037	CALL iom_get ( inum, jpdom_data, aname, ref_wgts(nxt_wgt)%data_wgt(:,:,jn) )
1038	END DO
1039	CALL iom_close (inum)
1040
1041	! find min and max indices in grid
1042	ref_wgts(nxt_wgt)%botleft(1) = MINVAL(ref_wgts(nxt_wgt)%data_jpi(:,:,:))
1043	ref_wgts(nxt_wgt)%botleft(2) = MINVAL(ref_wgts(nxt_wgt)%data_jpj(:,:,:))
1044	ref_wgts(nxt_wgt)%topright(1) = MAXVAL(ref_wgts(nxt_wgt)%data_jpi(:,:,:))
1045	ref_wgts(nxt_wgt)%topright(2) = MAXVAL(ref_wgts(nxt_wgt)%data_jpj(:,:,:))
1046
1047	! and therefore dimensions of the input box
1048	ref_wgts(nxt_wgt)%jpiwgt = ref_wgts(nxt_wgt)%topright(1) - ref_wgts(nxt_wgt)%botleft(1) + 1
1049	ref_wgts(nxt_wgt)%jpjwgt = ref_wgts(nxt_wgt)%topright(2) - ref_wgts(nxt_wgt)%botleft(2) + 1
1050
1051	! shift indexing of source grid
1052	ref_wgts(nxt_wgt)%data_jpi(:,:,:) = ref_wgts(nxt_wgt)%data_jpi(:,:,:) - ref_wgts(nxt_wgt)%botleft(1) + 1
1053	ref_wgts(nxt_wgt)%data_jpj(:,:,:) = ref_wgts(nxt_wgt)%data_jpj(:,:,:) - ref_wgts(nxt_wgt)%botleft(2) + 1
1054
1055	! create input grid, give it a halo to allow gradient calculations
1056	! SA: +3 stencil is a patch to avoid out-of-bound computation in some configuration.
1057	! a more robust solution will be given in next release
1058	ipk = SIZE(sd%fnow, 3)
1059	ALLOCATE( ref_wgts(nxt_wgt)%fly_dta(ref_wgts(nxt_wgt)%jpiwgt+3, ref_wgts(nxt_wgt)%jpjwgt+3 ,ipk) )
1060	IF( ref_wgts(nxt_wgt)%cyclic ) ALLOCATE( ref_wgts(nxt_wgt)%col(1,ref_wgts(nxt_wgt)%jpjwgt+3,ipk) )
1061
1062	nxt_wgt = nxt_wgt + 1
1063
1064	ELSE
1065	CALL ctl_stop( ' fld_weight : unable to read the file ' )
1066	ENDIF
1067
1068	CALL wrk_dealloc( jpi,jpj, data_src ) ! integer
1069	CALL wrk_dealloc( jpi,jpj, data_tmp )
1070	!
1071	END SUBROUTINE fld_weight
1072
1073
1074	SUBROUTINE fld_interp( num, clvar, kw, kk, dta, nrec )
1075	!!---------------------------------------------------------------------
1076	!! * ROUTINE fld_interp *
1077	!!
1078	!! ** Purpose : apply weights to input gridded data to create data
1079	!! on model grid
1080	!!----------------------------------------------------------------------
1081	INTEGER , INTENT(in ) :: num ! stream number
1082	CHARACTER(LEN=*) , INTENT(in ) :: clvar ! variable name
1083	INTEGER , INTENT(in ) :: kw ! weights number
1084	INTEGER , INTENT(in ) :: kk ! vertical dimension of kk
1085	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: dta ! output field on model grid
1086	INTEGER , INTENT(in ) :: nrec ! record number to read (ie time slice)
1087	!!
1088	INTEGER, DIMENSION(3) :: rec1,recn ! temporary arrays for start and length
1089	INTEGER :: jk, jn, jm ! loop counters
1090	INTEGER :: ni, nj ! lengths
1091	INTEGER :: jpimin,jpiwid ! temporary indices
1092	INTEGER :: jpjmin,jpjwid ! temporary indices
1093	INTEGER :: jpi1,jpi2,jpj1,jpj2 ! temporary indices
1094	!!----------------------------------------------------------------------
1095	!
1096	!! for weighted interpolation we have weights at four corners of a box surrounding
1097	!! a model grid point, each weight is multiplied by a grid value (bilinear case)
1098	!! or by a grid value and gradients at the corner point (bicubic case)
1099	!! so we need to have a 4 by 4 subgrid surrounding each model point to cover both cases
1100
1101	!! sub grid from non-model input grid which encloses all grid points in this nemo process
1102	jpimin = ref_wgts(kw)%botleft(1)
1103	jpjmin = ref_wgts(kw)%botleft(2)
1104	jpiwid = ref_wgts(kw)%jpiwgt
1105	jpjwid = ref_wgts(kw)%jpjwgt
1106
1107	!! when reading in, expand this sub-grid by one halo point all the way round for calculating gradients
1108	rec1(1) = MAX( jpimin-1, 1 )
1109	rec1(2) = MAX( jpjmin-1, 1 )
1110	rec1(3) = 1
1111	recn(1) = MIN( jpiwid+2, ref_wgts(kw)%ddims(1)-rec1(1)+1 )
1112	recn(2) = MIN( jpjwid+2, ref_wgts(kw)%ddims(2)-rec1(2)+1 )
1113	recn(3) = kk
1114
1115	!! where we need to put it in the non-nemo grid fly_dta
1116	!! note that jpi1 and jpj1 only differ from 1 when jpimin and jpjmin are 1
1117	!! (ie at the extreme west or south of the whole input grid) and similarly for jpi2 and jpj2
1118	jpi1 = 2 + rec1(1) - jpimin
1119	jpj1 = 2 + rec1(2) - jpjmin
1120	jpi2 = jpi1 + recn(1) - 1
1121	jpj2 = jpj1 + recn(2) - 1
1122
1123	ref_wgts(kw)%fly_dta(:,:,:) = 0.0
1124	SELECT CASE( SIZE(ref_wgts(kw)%fly_dta(jpi1:jpi2,jpj1:jpj2,:),3) )
1125	CASE(1)
1126	CALL iom_get( num, jpdom_unknown, clvar, ref_wgts(kw)%fly_dta(jpi1:jpi2,jpj1:jpj2,1), nrec, rec1, recn)
1127	CASE DEFAULT
1128	CALL iom_get( num, jpdom_unknown, clvar, ref_wgts(kw)%fly_dta(jpi1:jpi2,jpj1:jpj2,:), nrec, rec1, recn)
1129	END SELECT
1130
1131	!! first four weights common to both bilinear and bicubic
1132	!! data_jpi, data_jpj have already been shifted to (1,1) corresponding to botleft
1133	!! note that we have to offset by 1 into fly_dta array because of halo
1134	dta(:,:,:) = 0.0
1135	DO jk = 1,4
1136	DO jn = 1, jpj
1137	DO jm = 1,jpi
1138	ni = ref_wgts(kw)%data_jpi(jm,jn,jk)
1139	nj = ref_wgts(kw)%data_jpj(jm,jn,jk)
1140	dta(jm,jn,:) = dta(jm,jn,:) + ref_wgts(kw)%data_wgt(jm,jn,jk) * ref_wgts(kw)%fly_dta(ni+1,nj+1,:)
1141	END DO
1142	END DO
1143	END DO
1144
1145	IF (ref_wgts(kw)%numwgt .EQ. 16) THEN
1146
1147	!! fix up halo points that we couldnt read from file
1148	IF( jpi1 == 2 ) THEN
1149	ref_wgts(kw)%fly_dta(jpi1-1,:,:) = ref_wgts(kw)%fly_dta(jpi1,:,:)
1150	ENDIF
1151	IF( jpi2 + jpimin - 1 == ref_wgts(kw)%ddims(1)+1 ) THEN
1152	ref_wgts(kw)%fly_dta(jpi2+1,:,:) = ref_wgts(kw)%fly_dta(jpi2,:,:)
1153	ENDIF
1154	IF( jpj1 == 2 ) THEN
1155	ref_wgts(kw)%fly_dta(:,jpj1-1,:) = ref_wgts(kw)%fly_dta(:,jpj1,:)
1156	ENDIF
1157	IF( jpj2 + jpjmin - 1 == ref_wgts(kw)%ddims(2)+1 .AND. jpj2 .lt. jpjwid+2 ) THEN
1158	ref_wgts(kw)%fly_dta(:,jpj2+1,:) = 2.0*ref_wgts(kw)%fly_dta(:,jpj2,:) - ref_wgts(kw)%fly_dta(:,jpj2-1,:)
1159	ENDIF
1160
1161	!! if data grid is cyclic we can do better on east-west edges
1162	!! but have to allow for whether first and last columns are coincident
1163	IF( ref_wgts(kw)%cyclic ) THEN
1164	rec1(2) = MAX( jpjmin-1, 1 )
1165	recn(1) = 1
1166	recn(2) = MIN( jpjwid+2, ref_wgts(kw)%ddims(2)-rec1(2)+1 )
1167	jpj1 = 2 + rec1(2) - jpjmin
1168	jpj2 = jpj1 + recn(2) - 1
1169	IF( jpi1 == 2 ) THEN
1170	rec1(1) = ref_wgts(kw)%ddims(1) - ref_wgts(kw)%overlap
1171	SELECT CASE( SIZE( ref_wgts(kw)%col(:,jpj1:jpj2,:),3) )
1172	CASE(1)
1173	CALL iom_get( num, jpdom_unknown, clvar, ref_wgts(kw)%col(:,jpj1:jpj2,1), nrec, rec1, recn)
1174	CASE DEFAULT
1175	CALL iom_get( num, jpdom_unknown, clvar, ref_wgts(kw)%col(:,jpj1:jpj2,:), nrec, rec1, recn)
1176	END SELECT
1177	ref_wgts(kw)%fly_dta(jpi1-1,jpj1:jpj2,:) = ref_wgts(kw)%col(1,jpj1:jpj2,:)
1178	ENDIF
1179	IF( jpi2 + jpimin - 1 == ref_wgts(kw)%ddims(1)+1 ) THEN
1180	rec1(1) = 1 + ref_wgts(kw)%overlap
1181	SELECT CASE( SIZE( ref_wgts(kw)%col(:,jpj1:jpj2,:),3) )
1182	CASE(1)
1183	CALL iom_get( num, jpdom_unknown, clvar, ref_wgts(kw)%col(:,jpj1:jpj2,1), nrec, rec1, recn)
1184	CASE DEFAULT
1185	CALL iom_get( num, jpdom_unknown, clvar, ref_wgts(kw)%col(:,jpj1:jpj2,:), nrec, rec1, recn)
1186	END SELECT
1187	ref_wgts(kw)%fly_dta(jpi2+1,jpj1:jpj2,:) = ref_wgts(kw)%col(1,jpj1:jpj2,:)
1188	ENDIF
1189	ENDIF
1190
1191	! gradient in the i direction
1192	DO jk = 1,4
1193	DO jn = 1, jpj
1194	DO jm = 1,jpi
1195	ni = ref_wgts(kw)%data_jpi(jm,jn,jk)
1196	nj = ref_wgts(kw)%data_jpj(jm,jn,jk)
1197	dta(jm,jn,:) = dta(jm,jn,:) + ref_wgts(kw)%data_wgt(jm,jn,jk+4) * 0.5 * &
1198	(ref_wgts(kw)%fly_dta(ni+2,nj+1,:) - ref_wgts(kw)%fly_dta(ni,nj+1,:))
1199	END DO
1200	END DO
1201	END DO
1202
1203	! gradient in the j direction
1204	DO jk = 1,4
1205	DO jn = 1, jpj
1206	DO jm = 1,jpi
1207	ni = ref_wgts(kw)%data_jpi(jm,jn,jk)
1208	nj = ref_wgts(kw)%data_jpj(jm,jn,jk)
1209	dta(jm,jn,:) = dta(jm,jn,:) + ref_wgts(kw)%data_wgt(jm,jn,jk+8) * 0.5 * &
1210	(ref_wgts(kw)%fly_dta(ni+1,nj+2,:) - ref_wgts(kw)%fly_dta(ni+1,nj,:))
1211	END DO
1212	END DO
1213	END DO
1214
1215	! gradient in the ij direction
1216	DO jk = 1,4
1217	DO jn = 1, jpj
1218	DO jm = 1,jpi
1219	ni = ref_wgts(kw)%data_jpi(jm,jn,jk)
1220	nj = ref_wgts(kw)%data_jpj(jm,jn,jk)
1221	dta(jm,jn,:) = dta(jm,jn,:) + ref_wgts(kw)%data_wgt(jm,jn,jk+12) * 0.25 * ( &
1222	(ref_wgts(kw)%fly_dta(ni+2,nj+2,:) - ref_wgts(kw)%fly_dta(ni ,nj+2,:)) - &
1223	(ref_wgts(kw)%fly_dta(ni+2,nj ,:) - ref_wgts(kw)%fly_dta(ni ,nj ,:)))
1224	END DO
1225	END DO
1226	END DO
1227	!
1228	END IF
1229	!
1230	END SUBROUTINE fld_interp
1231
1232
1233	FUNCTION ksec_week( cdday )
1234	!!---------------------------------------------------------------------
1235	!! * FUNCTION kshift_week *
1236	!!
1237	!! ** Purpose :
1238	!!---------------------------------------------------------------------
1239	CHARACTER(len=*), INTENT(in) :: cdday !3 first letters of the first day of the weekly file
1240	!!
1241	INTEGER :: ksec_week ! output variable
1242	INTEGER :: ijul !temp variable
1243	INTEGER :: ishift !temp variable
1244	CHARACTER(len=3),DIMENSION(7) :: cl_week
1245	!!----------------------------------------------------------------------
1246	cl_week = (/"sun","sat","fri","thu","wed","tue","mon"/)
1247	DO ijul = 1, 7
1248	IF( cl_week(ijul) == TRIM(cdday) ) EXIT
1249	END DO
1250	IF( ijul .GT. 7 ) CALL ctl_stop( 'ksec_week: wrong day for sdjf%cltype(6:8): '//TRIM(cdday) )
1251	!
1252	ishift = ijul * NINT(rday)
1253	!
1254	ksec_week = nsec_week + ishift
1255	ksec_week = MOD( ksec_week, 7*NINT(rday) )
1256	!
1257	END FUNCTION ksec_week
1258
1259	!!======================================================================
1260	END MODULE fldread

Note: See TracBrowser for help on using the repository browser.

Download in other formats: