New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in branches/2012/dev_LOCEAN_UKMO_CMCC_INGV_2012/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2012/dev_LOCEAN_UKMO_CMCC_INGV_2012/NEMOGCM/NEMO/OPA_SRC/SBC/sbcssm.F90 @ 3666

Last change on this file since 3666 was 3653, checked in by cetlod, 11 years ago

commit the changes from LOCEAN & UKMO merge, see ticket #1021
  • Property svn:keywords set to Id
File size: 9.5 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_ssm        : calculate sea surface mean currents, temperature, 
12   !!                    and salinity over nn_fsbc time-step
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and tracers
15   USE dom_oce         ! ocean space and time domain
16   USE sbc_oce         ! Surface boundary condition: ocean fields
17   USE sbc_oce         ! surface boundary condition: ocean fields
18   USE sbcapr          ! surface boundary condition: atmospheric pressure
19   USE prtctl          ! Print control                    (prt_ctl routine)
20   USE iom
21   USE in_out_manager  ! I/O manager
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   sbc_ssm    ! routine called by step.F90
27   
28   !! * Substitutions
29#  include "domzgr_substitute.h90"
30   !!----------------------------------------------------------------------
31   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
32   !! $Id$
33   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
34   !!----------------------------------------------------------------------
35CONTAINS
36
37   SUBROUTINE sbc_ssm( kt )
38      !!---------------------------------------------------------------------
39      !!                     ***  ROUTINE sbc_oce  ***
40      !!                     
41      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
42      !!                condition computation
43      !!               
44      !! ** Method  :   compute mean surface velocity (2 components at U and
45      !!      V-points) [m/s], temperature [Celcius] and salinity [psu] over
46      !!      the periode (kt - nn_fsbc) to kt
47      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
48      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
49      !!---------------------------------------------------------------------
50      INTEGER, INTENT(in) ::   kt   ! ocean time step
51      !
52      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
53      !!---------------------------------------------------------------------
54      !                                                   ! ---------------------------------------- !
55      IF( nn_fsbc == 1 ) THEN                             !      Instantaneous surface fields        !
56         !                                                ! ---------------------------------------- !
57         IF( kt == nit000 ) THEN
58            IF(lwp) WRITE(numout,*)
59            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields, nn_fsbc=1 : instantaneous values'
60            IF(lwp) WRITE(numout,*) '~~~~~~~ '
61         ENDIF
62         !
63         ssu_m(:,:) = ub(:,:,1)
64         ssv_m(:,:) = vb(:,:,1)
65         sst_m(:,:) = tsn(:,:,1,jp_tem)
66         sss_m(:,:) = tsn(:,:,1,jp_sal)
67         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
68         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
69         ELSE                    ;   ssh_m(:,:) = sshn(:,:)
70         ENDIF
71
72         !
73      ELSE
74         !                                                ! ---------------------------------------- !
75         IF( kt == nit000) THEN                           !       Initialisation: 1st time-step      !
76            !                                             ! ---------------------------------------- !
77            IF(lwp) WRITE(numout,*)
78            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields'
79            !
80            IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
81               CALL iom_get( numror               , 'nn_fsbc', zf_sbc )   ! sbc frequency of previous run
82               CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m  )   ! sea surface mean velocity    (T-point)
83               CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m  )   !   "         "    velocity    (V-point)
84               CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m  )   !   "         "    temperature (T-point)
85               CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m  )   !   "         "    salinity    (T-point)
86               CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m  )   !   "         "    height      (T-point)
87               !
88               IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
89                  IF(lwp) WRITE(numout,*) '~~~~~~~   restart with a change in the frequency of mean ',   &
90                     &                    'from ', zf_sbc, ' to ', nn_fsbc
91                  zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc
92                  ssu_m(:,:) = zcoef * ssu_m(:,:)
93                  ssv_m(:,:) = zcoef * ssv_m(:,:)
94                  sst_m(:,:) = zcoef * sst_m(:,:)
95                  sss_m(:,:) = zcoef * sss_m(:,:)
96                  ssh_m(:,:) = zcoef * ssh_m(:,:)
97               ELSE
98                  IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields read in the ocean restart file'
99               ENDIF
100            ELSE
101               IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields initialised to instantaneous values'
102               zcoef = REAL( nn_fsbc - 1, wp )
103               ssu_m(:,:) = zcoef * ub(:,:,1)
104               ssv_m(:,:) = zcoef * vb(:,:,1)
105               sst_m(:,:) = zcoef * tsn(:,:,1,jp_tem)
106               sss_m(:,:) = zcoef * tsn(:,:,1,jp_sal)
107               !                          ! removed inverse barometer ssh when Patm forcing is used
108               IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
109               ELSE                    ;   ssh_m(:,:) = zcoef *   sshn(:,:)
110               ENDIF
111
112            ENDIF
113            !                                             ! ---------------------------------------- !
114         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
115            !                                             ! ---------------------------------------- !
116            ssu_m(:,:) = 0.e0      ! reset to zero ocean mean sbc fields
117            ssv_m(:,:) = 0.e0
118            sst_m(:,:) = 0.e0
119            sss_m(:,:) = 0.e0
120            ssh_m(:,:) = 0.e0
121         ENDIF
122         !                                                ! ---------------------------------------- !
123         !                                                !        Cumulate at each time step        !
124         !                                                ! ---------------------------------------- !
125         ssu_m(:,:) = ssu_m(:,:) + ub(:,:,1)
126         ssv_m(:,:) = ssv_m(:,:) + vb(:,:,1)
127         sst_m(:,:) = sst_m(:,:) + tsn(:,:,1,jp_tem)
128         sss_m(:,:) = sss_m(:,:) + tsn(:,:,1,jp_sal)
129         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
130         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 *  ( ssh_ib(:,:) + ssh_ibb(:,:) )
131         ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
132         ENDIF
133
134         !                                                ! ---------------------------------------- !
135         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
136            !                                             ! ---------------------------------------- !
137            zcoef = 1. / REAL( nn_fsbc, wp )
138            sst_m(:,:) = sst_m(:,:) * zcoef           ! mean SST             [Celcius]
139            sss_m(:,:) = sss_m(:,:) * zcoef           ! mean SSS             [psu]
140            ssu_m(:,:) = ssu_m(:,:) * zcoef           ! mean suface current  [m/s]
141            ssv_m(:,:) = ssv_m(:,:) * zcoef           !
142            ssh_m(:,:) = ssh_m(:,:) * zcoef           ! mean SSH             [m]
143            !
144         ENDIF
145         !                                                ! ---------------------------------------- !
146         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
147            !                                             ! ---------------------------------------- !
148            IF(lwp) WRITE(numout,*)
149            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
150               &                    'at it= ', kt,' date= ', ndastp
151            IF(lwp) WRITE(numout,*) '~~~~~~~'
152            zf_sbc = REAL( nn_fsbc, wp )
153            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc )    ! sbc frequency
154            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m  )    ! sea surface mean fields
155            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m  )
156            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m  )
157            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m  )
158            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m  )
159            !
160         ENDIF
161         !
162      ENDIF
163      !
164   END SUBROUTINE sbc_ssm
165
166   !!======================================================================
167END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.