| 1 | MODULE nemogcm |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE nemogcm *** |
|---|
| 4 | !! Off-line Ocean : passive tracer evolution, dynamics read in files |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.3 ! 2010-05 (C. Ethe) Full reorganization of the off-line: phasing with the on-line |
|---|
| 7 | !! 4.0 ! 2011-01 (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation |
|---|
| 8 | !!---------------------------------------------------------------------- |
|---|
| 9 | |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | !! nemo_gcm : off-line: solve ocean tracer only |
|---|
| 12 | !! nemo_init : initialization of the nemo model |
|---|
| 13 | !! nemo_ctl : initialisation of algorithm flag |
|---|
| 14 | !! nemo_closefile : close remaining files |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | USE dom_oce ! ocean space domain variables |
|---|
| 17 | USE oce ! dynamics and tracers variables |
|---|
| 18 | USE c1d ! 1D configuration |
|---|
| 19 | USE domcfg ! domain configuration (dom_cfg routine) |
|---|
| 20 | USE domain ! domain initialization (dom_init routine) |
|---|
| 21 | USE istate ! initial state setting (istate_init routine) |
|---|
| 22 | USE eosbn2 ! equation of state (eos bn2 routine) |
|---|
| 23 | ! ! ocean physics |
|---|
| 24 | USE ldftra ! lateral diffusivity setting (ldf_tra_init routine) |
|---|
| 25 | USE ldfslp ! slopes of neutral surfaces (ldf_slp_init routine) |
|---|
| 26 | USE traqsr ! solar radiation penetration (tra_qsr_init routine) |
|---|
| 27 | USE trabbl ! bottom boundary layer (tra_bbl_init routine) |
|---|
| 28 | USE zdfini ! vertical physics: initialization |
|---|
| 29 | USE sbcmod ! surface boundary condition (sbc_init routine) |
|---|
| 30 | USE phycst ! physical constant (par_cst routine) |
|---|
| 31 | USE dtadyn ! Lecture and Interpolation of the dynamical fields |
|---|
| 32 | USE trcini ! Initilization of the passive tracers |
|---|
| 33 | USE daymod ! calendar (day routine) |
|---|
| 34 | USE trcstp ! passive tracer time-stepping (trc_stp routine) |
|---|
| 35 | USE dtadyn ! Lecture and interpolation of the dynamical fields |
|---|
| 36 | USE stpctl ! time stepping control (stp_ctl routine) |
|---|
| 37 | ! ! I/O & MPP |
|---|
| 38 | USE iom ! I/O library |
|---|
| 39 | USE in_out_manager ! I/O manager |
|---|
| 40 | USE mppini ! shared/distributed memory setting (mpp_init routine) |
|---|
| 41 | USE lib_mpp ! distributed memory computing |
|---|
| 42 | #if defined key_iomput |
|---|
| 43 | USE xios |
|---|
| 44 | #endif |
|---|
| 45 | USE prtctl ! Print control (prt_ctl_init routine) |
|---|
| 46 | USE timing ! Timing |
|---|
| 47 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 48 | |
|---|
| 49 | IMPLICIT NONE |
|---|
| 50 | PRIVATE |
|---|
| 51 | |
|---|
| 52 | PUBLIC nemo_gcm ! called by nemo.F90 |
|---|
| 53 | |
|---|
| 54 | CHARACTER (len=64) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing |
|---|
| 55 | |
|---|
| 56 | !!---------------------------------------------------------------------- |
|---|
| 57 | !! NEMO/OFF 3.3 , NEMO Consortium (2010) |
|---|
| 58 | !! $Id: nemogcm.F90 2528 2010-12-27 17:33:53Z rblod $ |
|---|
| 59 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 60 | !!---------------------------------------------------------------------- |
|---|
| 61 | CONTAINS |
|---|
| 62 | |
|---|
| 63 | SUBROUTINE nemo_gcm |
|---|
| 64 | !!---------------------------------------------------------------------- |
|---|
| 65 | !! *** ROUTINE nemo_gcm *** |
|---|
| 66 | !! |
|---|
| 67 | !! ** Purpose : nemo solves the primitive equations on an orthogonal |
|---|
| 68 | !! curvilinear mesh on the sphere. |
|---|
| 69 | !! |
|---|
| 70 | !! ** Method : - model general initialization |
|---|
| 71 | !! - launch the time-stepping (dta_dyn and trc_stp) |
|---|
| 72 | !! - finalize the run by closing files and communications |
|---|
| 73 | !! |
|---|
| 74 | !! References : Madec, Delecluse,Imbard, and Levy, 1997: internal report, IPSL. |
|---|
| 75 | !! Madec, 2008, internal report, IPSL. |
|---|
| 76 | !!---------------------------------------------------------------------- |
|---|
| 77 | INTEGER :: istp, indic ! time step index |
|---|
| 78 | !!---------------------------------------------------------------------- |
|---|
| 79 | |
|---|
| 80 | CALL nemo_init ! Initializations |
|---|
| 81 | |
|---|
| 82 | IF( lk_mpp ) CALL mpp_max( nstop ) |
|---|
| 83 | |
|---|
| 84 | ! check that all process are still there... If some process have an error, |
|---|
| 85 | ! they will never enter in step and other processes will wait until the end of the cpu time! |
|---|
| 86 | IF( lk_mpp ) CALL mpp_max( nstop ) |
|---|
| 87 | |
|---|
| 88 | ! !-----------------------! |
|---|
| 89 | ! !== time stepping ==! |
|---|
| 90 | ! !-----------------------! |
|---|
| 91 | istp = nit000 |
|---|
| 92 | ! |
|---|
| 93 | CALL iom_init ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS) |
|---|
| 94 | DO WHILE ( istp <= nitend .AND. nstop == 0 ) ! time stepping |
|---|
| 95 | ! |
|---|
| 96 | IF( istp /= nit000 ) CALL day ( istp ) ! Calendar (day was already called at nit000 in day_init) |
|---|
| 97 | CALL iom_setkt( istp - nit000 + 1 ) ! say to iom that we are at time step kstp |
|---|
| 98 | CALL dta_dyn ( istp ) ! Interpolation of the dynamical fields |
|---|
| 99 | CALL trc_stp ( istp ) ! time-stepping |
|---|
| 100 | CALL stp_ctl ( istp, indic ) ! Time loop: control and print |
|---|
| 101 | istp = istp + 1 |
|---|
| 102 | IF( lk_mpp ) CALL mpp_max( nstop ) |
|---|
| 103 | END DO |
|---|
| 104 | #if defined key_iomput |
|---|
| 105 | CALL xios_context_finalize() ! needed for XIOS+AGRIF |
|---|
| 106 | #endif |
|---|
| 107 | |
|---|
| 108 | ! !------------------------! |
|---|
| 109 | ! !== finalize the run ==! |
|---|
| 110 | ! !------------------------! |
|---|
| 111 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 112 | |
|---|
| 113 | IF( nstop /= 0 .AND. lwp ) THEN ! error print |
|---|
| 114 | WRITE(numout,cform_err) |
|---|
| 115 | WRITE(numout,*) nstop, ' error have been found' |
|---|
| 116 | ENDIF |
|---|
| 117 | ! |
|---|
| 118 | IF( nn_timing == 1 ) CALL timing_finalize |
|---|
| 119 | ! |
|---|
| 120 | CALL nemo_closefile |
|---|
| 121 | ! |
|---|
| 122 | # if defined key_iomput |
|---|
| 123 | CALL xios_finalize ! end mpp communications |
|---|
| 124 | # else |
|---|
| 125 | IF( lk_mpp ) CALL mppstop ! end mpp communications |
|---|
| 126 | # endif |
|---|
| 127 | ! |
|---|
| 128 | END SUBROUTINE nemo_gcm |
|---|
| 129 | |
|---|
| 130 | |
|---|
| 131 | SUBROUTINE nemo_init |
|---|
| 132 | !!---------------------------------------------------------------------- |
|---|
| 133 | !! *** ROUTINE nemo_init *** |
|---|
| 134 | !! |
|---|
| 135 | !! ** Purpose : initialization of the nemo model in off-line mode |
|---|
| 136 | !!---------------------------------------------------------------------- |
|---|
| 137 | INTEGER :: ji ! dummy loop indices |
|---|
| 138 | INTEGER :: ilocal_comm ! local integer |
|---|
| 139 | CHARACTER(len=80), DIMENSION(16) :: cltxt |
|---|
| 140 | !! |
|---|
| 141 | NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, & |
|---|
| 142 | & nn_isplt, nn_jsplt, nn_jctls, nn_jctle, & |
|---|
| 143 | & nn_bench, nn_timing |
|---|
| 144 | !!---------------------------------------------------------------------- |
|---|
| 145 | ! |
|---|
| 146 | cltxt = '' |
|---|
| 147 | ! |
|---|
| 148 | ! ! open Namelist file |
|---|
| 149 | CALL ctl_opn( numnam, 'namelist', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. ) |
|---|
| 150 | ! |
|---|
| 151 | READ( numnam, namctl ) ! Namelist namctl : Control prints & Benchmark |
|---|
| 152 | ! |
|---|
| 153 | ! !--------------------------------------------! |
|---|
| 154 | ! ! set communicator & select the local node ! |
|---|
| 155 | ! !--------------------------------------------! |
|---|
| 156 | #if defined key_iomput |
|---|
| 157 | CALL xios_initialize( "nemo",return_comm=ilocal_comm ) |
|---|
| 158 | narea = mynode( cltxt, numnam, nstop, ilocal_comm ) ! Nodes selection |
|---|
| 159 | #else |
|---|
| 160 | ilocal_comm = 0 |
|---|
| 161 | narea = mynode( cltxt, numnam, nstop ) ! Nodes selection (control print return in cltxt) |
|---|
| 162 | #endif |
|---|
| 163 | |
|---|
| 164 | narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 ) |
|---|
| 165 | |
|---|
| 166 | lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print |
|---|
| 167 | |
|---|
| 168 | ! If dimensions of processor grid weren't specified in the namelist file |
|---|
| 169 | ! then we calculate them here now that we have our communicator size |
|---|
| 170 | IF( (jpni < 1) .OR. (jpnj < 1) )THEN |
|---|
| 171 | #if defined key_mpp_mpi |
|---|
| 172 | CALL nemo_partition(mppsize) |
|---|
| 173 | #else |
|---|
| 174 | jpni = 1 |
|---|
| 175 | jpnj = 1 |
|---|
| 176 | jpnij = jpni*jpnj |
|---|
| 177 | #endif |
|---|
| 178 | END IF |
|---|
| 179 | |
|---|
| 180 | ! Calculate domain dimensions given calculated jpni and jpnj |
|---|
| 181 | ! This used to be done in par_oce.F90 when they were parameters rather |
|---|
| 182 | ! than variables |
|---|
| 183 | jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci ! first dim. |
|---|
| 184 | jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim. |
|---|
| 185 | jpk = jpkdta ! third dim |
|---|
| 186 | jpim1 = jpi-1 ! inner domain indices |
|---|
| 187 | jpjm1 = jpj-1 ! " " |
|---|
| 188 | jpkm1 = jpk-1 ! " " |
|---|
| 189 | jpij = jpi*jpj ! jpi x j |
|---|
| 190 | |
|---|
| 191 | |
|---|
| 192 | IF(lwp) THEN ! open listing units |
|---|
| 193 | ! |
|---|
| 194 | CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea ) |
|---|
| 195 | ! |
|---|
| 196 | WRITE(numout,*) |
|---|
| 197 | WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC' |
|---|
| 198 | WRITE(numout,*) ' NEMO team' |
|---|
| 199 | WRITE(numout,*) ' Ocean General Circulation Model' |
|---|
| 200 | WRITE(numout,*) ' version 3.5 (2012) ' |
|---|
| 201 | WRITE(numout,*) |
|---|
| 202 | WRITE(numout,*) |
|---|
| 203 | DO ji = 1, SIZE(cltxt) |
|---|
| 204 | IF( TRIM(cltxt(ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode |
|---|
| 205 | END DO |
|---|
| 206 | WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 207 | ! |
|---|
| 208 | ENDIF |
|---|
| 209 | |
|---|
| 210 | ! Now we know the dimensions of the grid and numout has been set we can |
|---|
| 211 | ! allocate arrays |
|---|
| 212 | CALL nemo_alloc() |
|---|
| 213 | |
|---|
| 214 | ! !--------------------------------! |
|---|
| 215 | ! ! Model general initialization ! |
|---|
| 216 | ! !--------------------------------! |
|---|
| 217 | |
|---|
| 218 | CALL nemo_ctl ! Control prints & Benchmark |
|---|
| 219 | |
|---|
| 220 | ! ! Domain decomposition |
|---|
| 221 | IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out |
|---|
| 222 | ELSE ; CALL mpp_init2 ! eliminate land processors |
|---|
| 223 | ENDIF |
|---|
| 224 | ! |
|---|
| 225 | IF( nn_timing == 1 ) CALL timing_init |
|---|
| 226 | ! |
|---|
| 227 | |
|---|
| 228 | ! ! General initialization |
|---|
| 229 | IF( nn_timing == 1 ) CALL timing_start( 'nemo_init') |
|---|
| 230 | ! |
|---|
| 231 | CALL phy_cst ! Physical constants |
|---|
| 232 | CALL eos_init ! Equation of state |
|---|
| 233 | CALL dom_cfg ! Domain configuration |
|---|
| 234 | CALL dom_init ! Domain |
|---|
| 235 | CALL istate_init ! ocean initial state (Dynamics and tracers) |
|---|
| 236 | |
|---|
| 237 | IF( ln_nnogather ) CALL nemo_northcomms ! Initialise the northfold neighbour lists (must be done after the masks are defined) |
|---|
| 238 | |
|---|
| 239 | IF( ln_ctl ) CALL prt_ctl_init ! Print control |
|---|
| 240 | |
|---|
| 241 | ! ! Ocean physics |
|---|
| 242 | CALL sbc_init ! Forcings : surface module |
|---|
| 243 | #if ! defined key_degrad |
|---|
| 244 | CALL ldf_tra_init ! Lateral ocean tracer physics |
|---|
| 245 | #endif |
|---|
| 246 | IF( lk_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing |
|---|
| 247 | |
|---|
| 248 | ! ! Active tracers |
|---|
| 249 | CALL tra_qsr_init ! penetrative solar radiation qsr |
|---|
| 250 | IF( lk_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme |
|---|
| 251 | |
|---|
| 252 | ! ! Passive tracers |
|---|
| 253 | CALL trc_init ! Passive tracers initialization |
|---|
| 254 | ! ! Dynamics |
|---|
| 255 | CALL dta_dyn_init ! Initialization for the dynamics |
|---|
| 256 | |
|---|
| 257 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 258 | ! |
|---|
| 259 | IF( nn_timing == 1 ) CALL timing_stop( 'nemo_init') |
|---|
| 260 | ! |
|---|
| 261 | END SUBROUTINE nemo_init |
|---|
| 262 | |
|---|
| 263 | |
|---|
| 264 | SUBROUTINE nemo_ctl |
|---|
| 265 | !!---------------------------------------------------------------------- |
|---|
| 266 | !! *** ROUTINE nemo_ctl *** |
|---|
| 267 | !! |
|---|
| 268 | !! ** Purpose : control print setting |
|---|
| 269 | !! |
|---|
| 270 | !! ** Method : - print namctl information and check some consistencies |
|---|
| 271 | !!---------------------------------------------------------------------- |
|---|
| 272 | ! |
|---|
| 273 | IF(lwp) THEN ! Parameter print |
|---|
| 274 | WRITE(numout,*) |
|---|
| 275 | WRITE(numout,*) 'nemo_flg: Control prints & Benchmark' |
|---|
| 276 | WRITE(numout,*) '~~~~~~~ ' |
|---|
| 277 | WRITE(numout,*) ' Namelist namctl' |
|---|
| 278 | WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl |
|---|
| 279 | WRITE(numout,*) ' level of print nn_print = ', nn_print |
|---|
| 280 | WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls |
|---|
| 281 | WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle |
|---|
| 282 | WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls |
|---|
| 283 | WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle |
|---|
| 284 | WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt |
|---|
| 285 | WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt |
|---|
| 286 | WRITE(numout,*) ' benchmark parameter (0/1) nn_bench = ', nn_bench |
|---|
| 287 | ENDIF |
|---|
| 288 | ! |
|---|
| 289 | nprint = nn_print ! convert DOCTOR namelist names into OLD names |
|---|
| 290 | nictls = nn_ictls |
|---|
| 291 | nictle = nn_ictle |
|---|
| 292 | njctls = nn_jctls |
|---|
| 293 | njctle = nn_jctle |
|---|
| 294 | isplt = nn_isplt |
|---|
| 295 | jsplt = nn_jsplt |
|---|
| 296 | nbench = nn_bench |
|---|
| 297 | ! ! Parameter control |
|---|
| 298 | ! |
|---|
| 299 | IF( ln_ctl ) THEN ! sub-domain area indices for the control prints |
|---|
| 300 | IF( lk_mpp ) THEN |
|---|
| 301 | isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real splitted domain |
|---|
| 302 | ELSE |
|---|
| 303 | IF( isplt == 1 .AND. jsplt == 1 ) THEN |
|---|
| 304 | CALL ctl_warn( ' - isplt & jsplt are equal to 1', & |
|---|
| 305 | & ' - the print control will be done over the whole domain' ) |
|---|
| 306 | ENDIF |
|---|
| 307 | ijsplt = isplt * jsplt ! total number of processors ijsplt |
|---|
| 308 | ENDIF |
|---|
| 309 | IF(lwp) WRITE(numout,*)' - The total number of processors over which the' |
|---|
| 310 | IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt |
|---|
| 311 | ! |
|---|
| 312 | ! ! indices used for the SUM control |
|---|
| 313 | IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area |
|---|
| 314 | lsp_area = .FALSE. |
|---|
| 315 | ELSE ! print control done over a specific area |
|---|
| 316 | lsp_area = .TRUE. |
|---|
| 317 | IF( nictls < 1 .OR. nictls > jpiglo ) THEN |
|---|
| 318 | CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' ) |
|---|
| 319 | nictls = 1 |
|---|
| 320 | ENDIF |
|---|
| 321 | IF( nictle < 1 .OR. nictle > jpiglo ) THEN |
|---|
| 322 | CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' ) |
|---|
| 323 | nictle = jpiglo |
|---|
| 324 | ENDIF |
|---|
| 325 | IF( njctls < 1 .OR. njctls > jpjglo ) THEN |
|---|
| 326 | CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' ) |
|---|
| 327 | njctls = 1 |
|---|
| 328 | ENDIF |
|---|
| 329 | IF( njctle < 1 .OR. njctle > jpjglo ) THEN |
|---|
| 330 | CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' ) |
|---|
| 331 | njctle = jpjglo |
|---|
| 332 | ENDIF |
|---|
| 333 | ENDIF |
|---|
| 334 | ENDIF |
|---|
| 335 | ! |
|---|
| 336 | IF( nbench == 1 ) THEN ! Benchmark |
|---|
| 337 | SELECT CASE ( cp_cfg ) |
|---|
| 338 | CASE ( 'gyre' ) ; CALL ctl_warn( ' The Benchmark is activated ' ) |
|---|
| 339 | CASE DEFAULT ; CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:', & |
|---|
| 340 | & ' key_gyre must be used or set nbench = 0' ) |
|---|
| 341 | END SELECT |
|---|
| 342 | ENDIF |
|---|
| 343 | ! |
|---|
| 344 | IF( lk_c1d .AND. .NOT.lk_iomput ) CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ', & |
|---|
| 345 | & 'with the IOM Input/Output manager. ' , & |
|---|
| 346 | & 'Compile with key_iomput enabled' ) |
|---|
| 347 | ! |
|---|
| 348 | IF( 1_wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ', & |
|---|
| 349 | & 'f2003 standard. ' , & |
|---|
| 350 | & 'Compile with key_nosignedzero enabled' ) |
|---|
| 351 | ! |
|---|
| 352 | END SUBROUTINE nemo_ctl |
|---|
| 353 | |
|---|
| 354 | |
|---|
| 355 | SUBROUTINE nemo_closefile |
|---|
| 356 | !!---------------------------------------------------------------------- |
|---|
| 357 | !! *** ROUTINE nemo_closefile *** |
|---|
| 358 | !! |
|---|
| 359 | !! ** Purpose : Close the files |
|---|
| 360 | !!---------------------------------------------------------------------- |
|---|
| 361 | ! |
|---|
| 362 | IF ( lk_mpp ) CALL mppsync |
|---|
| 363 | ! |
|---|
| 364 | CALL iom_close ! close all input/output files managed by iom_* |
|---|
| 365 | ! |
|---|
| 366 | IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file |
|---|
| 367 | IF( numnam /= -1 ) CLOSE( numnam ) ! oce namelist |
|---|
| 368 | IF( numout /= 6 ) CLOSE( numout ) ! standard model output file |
|---|
| 369 | numout = 6 ! redefine numout in case it is used after this point... |
|---|
| 370 | ! |
|---|
| 371 | END SUBROUTINE nemo_closefile |
|---|
| 372 | |
|---|
| 373 | |
|---|
| 374 | SUBROUTINE nemo_alloc |
|---|
| 375 | !!---------------------------------------------------------------------- |
|---|
| 376 | !! *** ROUTINE nemo_alloc *** |
|---|
| 377 | !! |
|---|
| 378 | !! ** Purpose : Allocate all the dynamic arrays of the OPA modules |
|---|
| 379 | !! |
|---|
| 380 | !! ** Method : |
|---|
| 381 | !!---------------------------------------------------------------------- |
|---|
| 382 | USE diawri, ONLY: dia_wri_alloc |
|---|
| 383 | USE dom_oce, ONLY: dom_oce_alloc |
|---|
| 384 | USE zdf_oce, ONLY: zdf_oce_alloc |
|---|
| 385 | USE ldftra_oce, ONLY: ldftra_oce_alloc |
|---|
| 386 | USE trc_oce, ONLY: trc_oce_alloc |
|---|
| 387 | ! |
|---|
| 388 | INTEGER :: ierr |
|---|
| 389 | !!---------------------------------------------------------------------- |
|---|
| 390 | ! |
|---|
| 391 | ierr = oce_alloc () ! ocean |
|---|
| 392 | ierr = ierr + dia_wri_alloc () |
|---|
| 393 | ierr = ierr + dom_oce_alloc () ! ocean domain |
|---|
| 394 | ierr = ierr + ldftra_oce_alloc() ! ocean lateral physics : tracers |
|---|
| 395 | ierr = ierr + zdf_oce_alloc () ! ocean vertical physics |
|---|
| 396 | ! |
|---|
| 397 | ierr = ierr + lib_mpp_alloc (numout) ! mpp exchanges |
|---|
| 398 | ierr = ierr + trc_oce_alloc () ! shared TRC / TRA arrays |
|---|
| 399 | ! |
|---|
| 400 | IF( lk_mpp ) CALL mpp_sum( ierr ) |
|---|
| 401 | IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' ) |
|---|
| 402 | ! |
|---|
| 403 | END SUBROUTINE nemo_alloc |
|---|
| 404 | |
|---|
| 405 | |
|---|
| 406 | SUBROUTINE nemo_partition( num_pes ) |
|---|
| 407 | !!---------------------------------------------------------------------- |
|---|
| 408 | !! *** ROUTINE nemo_partition *** |
|---|
| 409 | !! |
|---|
| 410 | !! ** Purpose : |
|---|
| 411 | !! |
|---|
| 412 | !! ** Method : |
|---|
| 413 | !!---------------------------------------------------------------------- |
|---|
| 414 | INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have |
|---|
| 415 | ! |
|---|
| 416 | INTEGER, PARAMETER :: nfactmax = 20 |
|---|
| 417 | INTEGER :: nfact ! The no. of factors returned |
|---|
| 418 | INTEGER :: ierr ! Error flag |
|---|
| 419 | INTEGER :: ji |
|---|
| 420 | INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value |
|---|
| 421 | INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors |
|---|
| 422 | !!---------------------------------------------------------------------- |
|---|
| 423 | |
|---|
| 424 | ierr = 0 |
|---|
| 425 | |
|---|
| 426 | CALL factorise( ifact, nfactmax, nfact, num_pes, ierr ) |
|---|
| 427 | |
|---|
| 428 | IF( nfact <= 1 ) THEN |
|---|
| 429 | WRITE (numout, *) 'WARNING: factorisation of number of PEs failed' |
|---|
| 430 | WRITE (numout, *) ' : using grid of ',num_pes,' x 1' |
|---|
| 431 | jpnj = 1 |
|---|
| 432 | jpni = num_pes |
|---|
| 433 | ELSE |
|---|
| 434 | ! Search through factors for the pair that are closest in value |
|---|
| 435 | mindiff = 1000000 |
|---|
| 436 | imin = 1 |
|---|
| 437 | DO ji = 1, nfact-1, 2 |
|---|
| 438 | idiff = ABS( ifact(ji) - ifact(ji+1) ) |
|---|
| 439 | IF( idiff < mindiff ) THEN |
|---|
| 440 | mindiff = idiff |
|---|
| 441 | imin = ji |
|---|
| 442 | ENDIF |
|---|
| 443 | END DO |
|---|
| 444 | jpnj = ifact(imin) |
|---|
| 445 | jpni = ifact(imin + 1) |
|---|
| 446 | ENDIF |
|---|
| 447 | ! |
|---|
| 448 | jpnij = jpni*jpnj |
|---|
| 449 | ! |
|---|
| 450 | END SUBROUTINE nemo_partition |
|---|
| 451 | |
|---|
| 452 | |
|---|
| 453 | SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr ) |
|---|
| 454 | !!---------------------------------------------------------------------- |
|---|
| 455 | !! *** ROUTINE factorise *** |
|---|
| 456 | !! |
|---|
| 457 | !! ** Purpose : return the prime factors of n. |
|---|
| 458 | !! knfax factors are returned in array kfax which is of |
|---|
| 459 | !! maximum dimension kmaxfax. |
|---|
| 460 | !! ** Method : |
|---|
| 461 | !!---------------------------------------------------------------------- |
|---|
| 462 | INTEGER , INTENT(in ) :: kn, kmaxfax |
|---|
| 463 | INTEGER , INTENT( out) :: kerr, knfax |
|---|
| 464 | INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax |
|---|
| 465 | ! |
|---|
| 466 | INTEGER :: ifac, jl, inu |
|---|
| 467 | INTEGER, PARAMETER :: ntest = 14 |
|---|
| 468 | INTEGER :: ilfax(ntest) |
|---|
| 469 | ! |
|---|
| 470 | ! lfax contains the set of allowed factors. |
|---|
| 471 | data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256, & |
|---|
| 472 | & 128, 64, 32, 16, 8, 4, 2 / |
|---|
| 473 | !!---------------------------------------------------------------------- |
|---|
| 474 | |
|---|
| 475 | ! Clear the error flag and initialise output vars |
|---|
| 476 | kerr = 0 |
|---|
| 477 | kfax = 1 |
|---|
| 478 | knfax = 0 |
|---|
| 479 | |
|---|
| 480 | ! Find the factors of n. |
|---|
| 481 | IF( kn == 1 ) GOTO 20 |
|---|
| 482 | |
|---|
| 483 | ! nu holds the unfactorised part of the number. |
|---|
| 484 | ! knfax holds the number of factors found. |
|---|
| 485 | ! l points to the allowed factor list. |
|---|
| 486 | ! ifac holds the current factor. |
|---|
| 487 | |
|---|
| 488 | inu = kn |
|---|
| 489 | knfax = 0 |
|---|
| 490 | |
|---|
| 491 | DO jl = ntest, 1, -1 |
|---|
| 492 | ! |
|---|
| 493 | ifac = ilfax(jl) |
|---|
| 494 | IF( ifac > inu ) CYCLE |
|---|
| 495 | |
|---|
| 496 | ! Test whether the factor will divide. |
|---|
| 497 | |
|---|
| 498 | IF( MOD(inu,ifac) == 0 ) THEN |
|---|
| 499 | ! |
|---|
| 500 | knfax = knfax + 1 ! Add the factor to the list |
|---|
| 501 | IF( knfax > kmaxfax ) THEN |
|---|
| 502 | kerr = 6 |
|---|
| 503 | write (*,*) 'FACTOR: insufficient space in factor array ', knfax |
|---|
| 504 | return |
|---|
| 505 | ENDIF |
|---|
| 506 | kfax(knfax) = ifac |
|---|
| 507 | ! Store the other factor that goes with this one |
|---|
| 508 | knfax = knfax + 1 |
|---|
| 509 | kfax(knfax) = inu / ifac |
|---|
| 510 | !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax) |
|---|
| 511 | ENDIF |
|---|
| 512 | ! |
|---|
| 513 | END DO |
|---|
| 514 | |
|---|
| 515 | 20 CONTINUE ! Label 20 is the exit point from the factor search loop. |
|---|
| 516 | ! |
|---|
| 517 | END SUBROUTINE factorise |
|---|
| 518 | |
|---|
| 519 | #if defined key_mpp_mpi |
|---|
| 520 | SUBROUTINE nemo_northcomms |
|---|
| 521 | !!====================================================================== |
|---|
| 522 | !! *** ROUTINE nemo_northcomms *** |
|---|
| 523 | !! nemo_northcomms : Setup for north fold exchanges with explicit peer to peer messaging |
|---|
| 524 | !!===================================================================== |
|---|
| 525 | !!---------------------------------------------------------------------- |
|---|
| 526 | !! |
|---|
| 527 | !! ** Purpose : Initialization of the northern neighbours lists. |
|---|
| 528 | !!---------------------------------------------------------------------- |
|---|
| 529 | !! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE) |
|---|
| 530 | !!---------------------------------------------------------------------- |
|---|
| 531 | |
|---|
| 532 | INTEGER :: ji, jj, jk, ij, jtyp ! dummy loop indices |
|---|
| 533 | INTEGER :: ijpj ! number of rows involved in north-fold exchange |
|---|
| 534 | INTEGER :: northcomms_alloc ! allocate return status |
|---|
| 535 | REAL(wp), ALLOCATABLE, DIMENSION ( :,: ) :: znnbrs ! workspace |
|---|
| 536 | LOGICAL, ALLOCATABLE, DIMENSION ( : ) :: lrankset ! workspace |
|---|
| 537 | |
|---|
| 538 | IF(lwp) WRITE(numout,*) |
|---|
| 539 | IF(lwp) WRITE(numout,*) 'nemo_northcomms : Initialization of the northern neighbours lists' |
|---|
| 540 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~' |
|---|
| 541 | |
|---|
| 542 | !!---------------------------------------------------------------------- |
|---|
| 543 | ALLOCATE( znnbrs(jpi,jpj), stat = northcomms_alloc ) |
|---|
| 544 | ALLOCATE( lrankset(jpnij), stat = northcomms_alloc ) |
|---|
| 545 | IF( northcomms_alloc /= 0 ) THEN |
|---|
| 546 | WRITE(numout,cform_war) |
|---|
| 547 | WRITE(numout,*) 'northcomms_alloc : failed to allocate arrays' |
|---|
| 548 | CALL ctl_stop( 'STOP', 'nemo_northcomms : unable to allocate temporary arrays' ) |
|---|
| 549 | ENDIF |
|---|
| 550 | nsndto = 0 |
|---|
| 551 | isendto = -1 |
|---|
| 552 | ijpj = 4 |
|---|
| 553 | ! |
|---|
| 554 | ! This routine has been called because ln_nnogather has been set true ( nammpp ) |
|---|
| 555 | ! However, these first few exchanges have to use the mpi_allgather method to |
|---|
| 556 | ! establish the neighbour lists to use in subsequent peer to peer exchanges. |
|---|
| 557 | ! Consequently, set l_north_nogather to be false here and set it true only after |
|---|
| 558 | ! the lists have been established. |
|---|
| 559 | ! |
|---|
| 560 | l_north_nogather = .FALSE. |
|---|
| 561 | ! |
|---|
| 562 | ! Exchange and store ranks on northern rows |
|---|
| 563 | |
|---|
| 564 | DO jtyp = 1,4 |
|---|
| 565 | |
|---|
| 566 | lrankset = .FALSE. |
|---|
| 567 | znnbrs = narea |
|---|
| 568 | SELECT CASE (jtyp) |
|---|
| 569 | CASE(1) |
|---|
| 570 | CALL lbc_lnk( znnbrs, 'T', 1. ) ! Type 1: T,W-points |
|---|
| 571 | CASE(2) |
|---|
| 572 | CALL lbc_lnk( znnbrs, 'U', 1. ) ! Type 2: U-point |
|---|
| 573 | CASE(3) |
|---|
| 574 | CALL lbc_lnk( znnbrs, 'V', 1. ) ! Type 3: V-point |
|---|
| 575 | CASE(4) |
|---|
| 576 | CALL lbc_lnk( znnbrs, 'F', 1. ) ! Type 4: F-point |
|---|
| 577 | END SELECT |
|---|
| 578 | |
|---|
| 579 | IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN |
|---|
| 580 | DO jj = nlcj-ijpj+1, nlcj |
|---|
| 581 | ij = jj - nlcj + ijpj |
|---|
| 582 | DO ji = 1,jpi |
|---|
| 583 | IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) & |
|---|
| 584 | & lrankset(INT(znnbrs(ji,jj))) = .true. |
|---|
| 585 | END DO |
|---|
| 586 | END DO |
|---|
| 587 | |
|---|
| 588 | DO jj = 1,jpnij |
|---|
| 589 | IF ( lrankset(jj) ) THEN |
|---|
| 590 | nsndto(jtyp) = nsndto(jtyp) + 1 |
|---|
| 591 | IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN |
|---|
| 592 | CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', & |
|---|
| 593 | & ' jpmaxngh will need to be increased ') |
|---|
| 594 | ENDIF |
|---|
| 595 | isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank |
|---|
| 596 | ENDIF |
|---|
| 597 | END DO |
|---|
| 598 | ENDIF |
|---|
| 599 | |
|---|
| 600 | END DO |
|---|
| 601 | |
|---|
| 602 | ! |
|---|
| 603 | ! Type 5: I-point |
|---|
| 604 | ! |
|---|
| 605 | ! ICE point exchanges may involve some averaging. The neighbours list is |
|---|
| 606 | ! built up using two exchanges to ensure that the whole stencil is covered. |
|---|
| 607 | ! lrankset should not be reset between these 'J' and 'K' point exchanges |
|---|
| 608 | |
|---|
| 609 | jtyp = 5 |
|---|
| 610 | lrankset = .FALSE. |
|---|
| 611 | znnbrs = narea |
|---|
| 612 | CALL lbc_lnk( znnbrs, 'J', 1. ) ! first ice U-V point |
|---|
| 613 | |
|---|
| 614 | IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN |
|---|
| 615 | DO jj = nlcj-ijpj+1, nlcj |
|---|
| 616 | ij = jj - nlcj + ijpj |
|---|
| 617 | DO ji = 1,jpi |
|---|
| 618 | IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) & |
|---|
| 619 | & lrankset(INT(znnbrs(ji,jj))) = .true. |
|---|
| 620 | END DO |
|---|
| 621 | END DO |
|---|
| 622 | ENDIF |
|---|
| 623 | |
|---|
| 624 | znnbrs = narea |
|---|
| 625 | CALL lbc_lnk( znnbrs, 'K', 1. ) ! second ice U-V point |
|---|
| 626 | |
|---|
| 627 | IF ( njmppt(narea) .EQ. MAXVAL( njmppt )) THEN |
|---|
| 628 | DO jj = nlcj-ijpj+1, nlcj |
|---|
| 629 | ij = jj - nlcj + ijpj |
|---|
| 630 | DO ji = 1,jpi |
|---|
| 631 | IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) & |
|---|
| 632 | & lrankset( INT(znnbrs(ji,jj))) = .true. |
|---|
| 633 | END DO |
|---|
| 634 | END DO |
|---|
| 635 | |
|---|
| 636 | DO jj = 1,jpnij |
|---|
| 637 | IF ( lrankset(jj) ) THEN |
|---|
| 638 | nsndto(jtyp) = nsndto(jtyp) + 1 |
|---|
| 639 | IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN |
|---|
| 640 | CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', & |
|---|
| 641 | & ' jpmaxngh will need to be increased ') |
|---|
| 642 | ENDIF |
|---|
| 643 | isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank |
|---|
| 644 | ENDIF |
|---|
| 645 | END DO |
|---|
| 646 | ! |
|---|
| 647 | ! For northern row areas, set l_north_nogather so that all subsequent exchanges |
|---|
| 648 | ! can use peer to peer communications at the north fold |
|---|
| 649 | ! |
|---|
| 650 | l_north_nogather = .TRUE. |
|---|
| 651 | ! |
|---|
| 652 | ENDIF |
|---|
| 653 | DEALLOCATE( znnbrs ) |
|---|
| 654 | DEALLOCATE( lrankset ) |
|---|
| 655 | |
|---|
| 656 | END SUBROUTINE nemo_northcomms |
|---|
| 657 | #else |
|---|
| 658 | SUBROUTINE nemo_northcomms ! Dummy routine |
|---|
| 659 | WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?' |
|---|
| 660 | END SUBROUTINE nemo_northcomms |
|---|
| 661 | #endif |
|---|
| 662 | !!====================================================================== |
|---|
| 663 | END MODULE nemogcm |
|---|
