| 1 | MODULE sbcrnf |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcrnf *** |
|---|
| 4 | !! Ocean forcing: river runoff |
|---|
| 5 | !!===================================================================== |
|---|
| 6 | !! History : OPA ! 2000-11 (R. Hordoir, E. Durand) NetCDF FORMAT |
|---|
| 7 | !! NEMO 1.0 ! 2002-09 (G. Madec) F90: Free form and module |
|---|
| 8 | !! 3.0 ! 2006-07 (G. Madec) Surface module |
|---|
| 9 | !! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put |
|---|
| 10 | !! 3.3 ! 2010-10 (R. Furner, G. Madec) runoff distributed over ocean levels |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! sbc_rnf : monthly runoffs read in a NetCDF file |
|---|
| 15 | !! sbc_rnf_init : runoffs initialisation |
|---|
| 16 | !! rnf_mouth : set river mouth mask |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | USE dom_oce ! ocean space and time domain |
|---|
| 19 | USE phycst ! physical constants |
|---|
| 20 | USE sbc_oce ! surface boundary condition variables |
|---|
| 21 | USE closea ! closed seas |
|---|
| 22 | USE fldread ! read input field at current time step |
|---|
| 23 | USE in_out_manager ! I/O manager |
|---|
| 24 | USE iom ! I/O module |
|---|
| 25 | USE lib_mpp ! MPP library |
|---|
| 26 | |
|---|
| 27 | IMPLICIT NONE |
|---|
| 28 | PRIVATE |
|---|
| 29 | |
|---|
| 30 | PUBLIC sbc_rnf ! routine call in sbcmod module |
|---|
| 31 | PUBLIC sbc_rnf_div ! routine called in sshwzv module |
|---|
| 32 | PUBLIC sbc_rnf_alloc ! routine call in sbcmod module |
|---|
| 33 | |
|---|
| 34 | ! !!* namsbc_rnf namelist * |
|---|
| 35 | CHARACTER(len=100), PUBLIC :: cn_dir = './' !: Root directory for location of ssr files |
|---|
| 36 | LOGICAL , PUBLIC :: ln_rnf_depth = .false. !: depth river runoffs attribute specified in a file |
|---|
| 37 | LOGICAL , PUBLIC :: ln_rnf_tem = .false. !: temperature river runoffs attribute specified in a file |
|---|
| 38 | LOGICAL , PUBLIC :: ln_rnf_sal = .false. !: salinity river runoffs attribute specified in a file |
|---|
| 39 | LOGICAL , PUBLIC :: ln_rnf_emp = .false. !: runoffs into a file to be read or already into precipitation |
|---|
| 40 | TYPE(FLD_N) , PUBLIC :: sn_rnf !: information about the runoff file to be read |
|---|
| 41 | TYPE(FLD_N) , PUBLIC :: sn_cnf !: information about the runoff mouth file to be read |
|---|
| 42 | TYPE(FLD_N) :: sn_s_rnf !: information about the salinities of runoff file to be read |
|---|
| 43 | TYPE(FLD_N) :: sn_t_rnf !: information about the temperatures of runoff file to be read |
|---|
| 44 | TYPE(FLD_N) :: sn_dep_rnf !: information about the depth which river inflow affects |
|---|
| 45 | LOGICAL , PUBLIC :: ln_rnf_mouth = .false. !: specific treatment in mouths vicinity |
|---|
| 46 | REAL(wp) , PUBLIC :: rn_hrnf = 0._wp !: runoffs, depth over which enhanced vertical mixing is used |
|---|
| 47 | REAL(wp) , PUBLIC :: rn_avt_rnf = 0._wp !: runoffs, value of the additional vertical mixing coef. [m2/s] |
|---|
| 48 | REAL(wp) , PUBLIC :: rn_rfact = 1._wp !: multiplicative factor for runoff |
|---|
| 49 | |
|---|
| 50 | INTEGER , PUBLIC :: nkrnf = 0 !: nb of levels over which Kz is increased at river mouths |
|---|
| 51 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: rnfmsk !: river mouth mask (hori.) |
|---|
| 52 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) :: rnfmsk_z !: river mouth mask (vert.) |
|---|
| 53 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: h_rnf !: depth of runoff in m |
|---|
| 54 | INTEGER, PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: nk_rnf !: depth of runoff in model levels |
|---|
| 55 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: rnf_tsc_b, rnf_tsc !: before and now T & S runoff contents [K.m/s & PSU.m/s] |
|---|
| 56 | |
|---|
| 57 | |
|---|
| 58 | TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) :: sf_rnf ! structure: river runoff (file information, fields read) |
|---|
| 59 | TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) :: sf_s_rnf ! structure: river runoff salinity (file information, fields read) |
|---|
| 60 | TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) :: sf_t_rnf ! structure: river runoff temperature (file information, fields read) |
|---|
| 61 | |
|---|
| 62 | !! * Substitutions |
|---|
| 63 | # include "domzgr_substitute.h90" |
|---|
| 64 | !!---------------------------------------------------------------------- |
|---|
| 65 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 66 | !! $Id$ |
|---|
| 67 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 68 | !!---------------------------------------------------------------------- |
|---|
| 69 | CONTAINS |
|---|
| 70 | |
|---|
| 71 | INTEGER FUNCTION sbc_rnf_alloc() |
|---|
| 72 | !!---------------------------------------------------------------------- |
|---|
| 73 | !! *** ROUTINE sbc_rnf_alloc *** |
|---|
| 74 | !!---------------------------------------------------------------------- |
|---|
| 75 | ALLOCATE( rnfmsk(jpi,jpj) , rnfmsk_z(jpk) , & |
|---|
| 76 | & h_rnf (jpi,jpj) , nk_rnf (jpi,jpj) , & |
|---|
| 77 | & rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc ) |
|---|
| 78 | ! |
|---|
| 79 | IF( lk_mpp ) CALL mpp_sum ( sbc_rnf_alloc ) |
|---|
| 80 | IF( sbc_rnf_alloc > 0 ) CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed') |
|---|
| 81 | END FUNCTION sbc_rnf_alloc |
|---|
| 82 | |
|---|
| 83 | |
|---|
| 84 | SUBROUTINE sbc_rnf( kt ) |
|---|
| 85 | !!---------------------------------------------------------------------- |
|---|
| 86 | !! *** ROUTINE sbc_rnf *** |
|---|
| 87 | !! |
|---|
| 88 | !! ** Purpose : Introduce a climatological run off forcing |
|---|
| 89 | !! |
|---|
| 90 | !! ** Method : Set each river mouth with a monthly climatology |
|---|
| 91 | !! provided from different data. |
|---|
| 92 | !! CAUTION : upward water flux, runoff forced to be < 0 |
|---|
| 93 | !! |
|---|
| 94 | !! ** Action : runoff updated runoff field at time-step kt |
|---|
| 95 | !!---------------------------------------------------------------------- |
|---|
| 96 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 97 | ! |
|---|
| 98 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 99 | !!---------------------------------------------------------------------- |
|---|
| 100 | ! |
|---|
| 101 | IF( kt == nit000 ) CALL sbc_rnf_init ! Read namelist and allocate structures |
|---|
| 102 | |
|---|
| 103 | ! ! ---------------------------------------- ! |
|---|
| 104 | IF( kt /= nit000 ) THEN ! Swap of forcing fields ! |
|---|
| 105 | ! ! ---------------------------------------- ! |
|---|
| 106 | rnf_b (:,: ) = rnf (:,: ) ! Swap the ocean forcing fields except at nit000 |
|---|
| 107 | rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:) ! where before fields are set at the end of the routine |
|---|
| 108 | ! |
|---|
| 109 | ENDIF |
|---|
| 110 | |
|---|
| 111 | ! !-------------------! |
|---|
| 112 | IF( .NOT. ln_rnf_emp ) THEN ! Update runoff ! |
|---|
| 113 | ! !-------------------! |
|---|
| 114 | ! |
|---|
| 115 | CALL fld_read ( kt, nn_fsbc, sf_rnf ) ! Read Runoffs data and provide it at kt |
|---|
| 116 | IF( ln_rnf_tem ) CALL fld_read ( kt, nn_fsbc, sf_t_rnf ) ! idem for runoffs temperature if required |
|---|
| 117 | IF( ln_rnf_sal ) CALL fld_read ( kt, nn_fsbc, sf_s_rnf ) ! idem for runoffs salinity if required |
|---|
| 118 | ! |
|---|
| 119 | ! Runoff reduction only associated to the ORCA2_LIM configuration |
|---|
| 120 | ! when reading the NetCDF file runoff_1m_nomask.nc |
|---|
| 121 | IF( cp_cfg == 'orca' .AND. jp_cfg == 2 ) THEN |
|---|
| 122 | WHERE( 40._wp < gphit(:,:) .AND. gphit(:,:) < 65._wp ) |
|---|
| 123 | sf_rnf(1)%fnow(:,:,1) = 0.85 * sf_rnf(1)%fnow(:,:,1) |
|---|
| 124 | END WHERE |
|---|
| 125 | ENDIF |
|---|
| 126 | ! |
|---|
| 127 | IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN |
|---|
| 128 | ! |
|---|
| 129 | rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) ) ! updated runoff value at time step kt |
|---|
| 130 | ! |
|---|
| 131 | ! ! set temperature & salinity content of runoffs |
|---|
| 132 | IF( ln_rnf_tem ) THEN ! use runoffs temperature data |
|---|
| 133 | rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0 |
|---|
| 134 | WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999 ) ! if missing data value use SST as runoffs temperature |
|---|
| 135 | rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0 |
|---|
| 136 | END WHERE |
|---|
| 137 | ELSE ! use SST as runoffs temperature |
|---|
| 138 | rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0 |
|---|
| 139 | ENDIF |
|---|
| 140 | ! ! use runoffs salinity data |
|---|
| 141 | IF( ln_rnf_sal ) rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0 |
|---|
| 142 | ! ! else use S=0 for runoffs (done one for all in the init) |
|---|
| 143 | ! |
|---|
| 144 | IF( ln_rnf_tem .OR. ln_rnf_sal ) THEN ! runoffs as outflow: use ocean SST and SSS |
|---|
| 145 | WHERE( rnf(:,:) < 0._wp ) ! example baltic model when flow is out of domain |
|---|
| 146 | rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0 |
|---|
| 147 | rnf_tsc(:,:,jp_sal) = sss_m(:,:) * rnf(:,:) * r1_rau0 |
|---|
| 148 | END WHERE |
|---|
| 149 | ENDIF |
|---|
| 150 | ! |
|---|
| 151 | CALL iom_put( "runoffs", rnf ) ! output runoffs arrays |
|---|
| 152 | ENDIF |
|---|
| 153 | ! |
|---|
| 154 | ENDIF |
|---|
| 155 | ! |
|---|
| 156 | IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 ! |
|---|
| 157 | ! ! ---------------------------------------- ! |
|---|
| 158 | IF( ln_rstart .AND. & !* Restart: read in restart file |
|---|
| 159 | & iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 160 | IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields red in the restart file' |
|---|
| 161 | CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b ) ! before runoff |
|---|
| 162 | CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) ) ! before heat content of runoff |
|---|
| 163 | CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) ) ! before salinity content of runoff |
|---|
| 164 | ELSE !* no restart: set from nit000 values |
|---|
| 165 | IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields set to nit000' |
|---|
| 166 | rnf_b (:,: ) = rnf (:,: ) |
|---|
| 167 | rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:) |
|---|
| 168 | ENDIF |
|---|
| 169 | ENDIF |
|---|
| 170 | ! ! ---------------------------------------- ! |
|---|
| 171 | IF( lrst_oce ) THEN ! Write in the ocean restart file ! |
|---|
| 172 | ! ! ---------------------------------------- ! |
|---|
| 173 | IF(lwp) WRITE(numout,*) |
|---|
| 174 | IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ', & |
|---|
| 175 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 176 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 177 | CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf ) |
|---|
| 178 | CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) ) |
|---|
| 179 | CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) ) |
|---|
| 180 | ENDIF |
|---|
| 181 | ! |
|---|
| 182 | END SUBROUTINE sbc_rnf |
|---|
| 183 | |
|---|
| 184 | |
|---|
| 185 | SUBROUTINE sbc_rnf_div( phdivn ) |
|---|
| 186 | !!---------------------------------------------------------------------- |
|---|
| 187 | !! *** ROUTINE sbc_rnf *** |
|---|
| 188 | !! |
|---|
| 189 | !! ** Purpose : update the horizontal divergence with the runoff inflow |
|---|
| 190 | !! |
|---|
| 191 | !! ** Method : |
|---|
| 192 | !! CAUTION : rnf is positive (inflow) decreasing the |
|---|
| 193 | !! divergence and expressed in m/s |
|---|
| 194 | !! |
|---|
| 195 | !! ** Action : phdivn decreased by the runoff inflow |
|---|
| 196 | !!---------------------------------------------------------------------- |
|---|
| 197 | REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: phdivn ! horizontal divergence |
|---|
| 198 | !! |
|---|
| 199 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 200 | REAL(wp) :: zfact ! local scalar |
|---|
| 201 | !!---------------------------------------------------------------------- |
|---|
| 202 | ! |
|---|
| 203 | zfact = 0.5_wp |
|---|
| 204 | ! |
|---|
| 205 | IF( ln_rnf_depth ) THEN !== runoff distributed over several levels ==! |
|---|
| 206 | IF( lk_vvl ) THEN ! variable volume case |
|---|
| 207 | DO jj = 1, jpj ! update the depth over which runoffs are distributed |
|---|
| 208 | DO ji = 1, jpi |
|---|
| 209 | h_rnf(ji,jj) = 0._wp |
|---|
| 210 | DO jk = 1, nk_rnf(ji,jj) ! recalculates h_rnf to be the depth in metres |
|---|
| 211 | h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk) ! to the bottom of the relevant grid box |
|---|
| 212 | END DO |
|---|
| 213 | ! ! apply the runoff input flow |
|---|
| 214 | DO jk = 1, nk_rnf(ji,jj) |
|---|
| 215 | phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj) |
|---|
| 216 | END DO |
|---|
| 217 | END DO |
|---|
| 218 | END DO |
|---|
| 219 | ELSE ! constant volume case : just apply the runoff input flow |
|---|
| 220 | DO jj = 1, jpj |
|---|
| 221 | DO ji = 1, jpi |
|---|
| 222 | DO jk = 1, nk_rnf(ji,jj) |
|---|
| 223 | phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj) |
|---|
| 224 | END DO |
|---|
| 225 | END DO |
|---|
| 226 | END DO |
|---|
| 227 | ENDIF |
|---|
| 228 | ELSE !== runoff put only at the surface ==! |
|---|
| 229 | IF( lk_vvl ) THEN ! variable volume case |
|---|
| 230 | h_rnf(:,:) = fse3t(:,:,1) ! recalculate h_rnf to be depth of top box |
|---|
| 231 | ENDIF |
|---|
| 232 | phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rau0 / fse3t(:,:,1) |
|---|
| 233 | ENDIF |
|---|
| 234 | ! |
|---|
| 235 | END SUBROUTINE sbc_rnf_div |
|---|
| 236 | |
|---|
| 237 | |
|---|
| 238 | SUBROUTINE sbc_rnf_init |
|---|
| 239 | !!---------------------------------------------------------------------- |
|---|
| 240 | !! *** ROUTINE sbc_rnf_init *** |
|---|
| 241 | !! |
|---|
| 242 | !! ** Purpose : Initialisation of the runoffs if (ln_rnf=T) |
|---|
| 243 | !! |
|---|
| 244 | !! ** Method : - read the runoff namsbc_rnf namelist |
|---|
| 245 | !! |
|---|
| 246 | !! ** Action : - read parameters |
|---|
| 247 | !!---------------------------------------------------------------------- |
|---|
| 248 | CHARACTER(len=32) :: rn_dep_file ! runoff file name |
|---|
| 249 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 250 | INTEGER :: ierror, inum ! temporary integer |
|---|
| 251 | ! |
|---|
| 252 | NAMELIST/namsbc_rnf/ cn_dir, ln_rnf_emp, ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, & |
|---|
| 253 | & sn_rnf, sn_cnf , sn_s_rnf , sn_t_rnf , sn_dep_rnf, & |
|---|
| 254 | & ln_rnf_mouth , rn_hrnf , rn_avt_rnf, rn_rfact |
|---|
| 255 | !!---------------------------------------------------------------------- |
|---|
| 256 | ! |
|---|
| 257 | ! ! ============ |
|---|
| 258 | ! ! Namelist |
|---|
| 259 | ! ! ============ |
|---|
| 260 | ! (NB: frequency positive => hours, negative => months) |
|---|
| 261 | ! ! file ! frequency ! variable ! time intep ! clim ! 'yearly' or ! weights ! rotation ! |
|---|
| 262 | ! ! name ! (hours) ! name ! (T/F) ! (T/F) ! 'monthly' ! filename ! pairs ! |
|---|
| 263 | sn_rnf = FLD_N( 'runoffs', -1 , 'sorunoff' , .TRUE. , .true. , 'yearly' , '' , '' ) |
|---|
| 264 | sn_cnf = FLD_N( 'runoffs', 0 , 'sorunoff' , .FALSE. , .true. , 'yearly' , '' , '' ) |
|---|
| 265 | |
|---|
| 266 | sn_s_rnf = FLD_N( 'runoffs', 24. , 'rosaline' , .TRUE. , .true. , 'yearly' , '' , '' ) |
|---|
| 267 | sn_t_rnf = FLD_N( 'runoffs', 24. , 'rotemper' , .TRUE. , .true. , 'yearly' , '' , '' ) |
|---|
| 268 | sn_dep_rnf = FLD_N( 'runoffs', 0. , 'rodepth' , .FALSE. , .true. , 'yearly' , '' , '' ) |
|---|
| 269 | ! |
|---|
| 270 | REWIND ( numnam ) ! Read Namelist namsbc_rnf |
|---|
| 271 | READ ( numnam, namsbc_rnf ) |
|---|
| 272 | ! |
|---|
| 273 | ! ! Control print |
|---|
| 274 | IF(lwp) THEN |
|---|
| 275 | WRITE(numout,*) |
|---|
| 276 | WRITE(numout,*) 'sbc_rnf : runoff ' |
|---|
| 277 | WRITE(numout,*) '~~~~~~~ ' |
|---|
| 278 | WRITE(numout,*) ' Namelist namsbc_rnf' |
|---|
| 279 | WRITE(numout,*) ' runoff in a file to be read ln_rnf_emp = ', ln_rnf_emp |
|---|
| 280 | WRITE(numout,*) ' specific river mouths treatment ln_rnf_mouth = ', ln_rnf_mouth |
|---|
| 281 | WRITE(numout,*) ' river mouth additional Kz rn_avt_rnf = ', rn_avt_rnf |
|---|
| 282 | WRITE(numout,*) ' depth of river mouth additional mixing rn_hrnf = ', rn_hrnf |
|---|
| 283 | WRITE(numout,*) ' multiplicative factor for runoff rn_rfact = ', rn_rfact |
|---|
| 284 | ENDIF |
|---|
| 285 | ! |
|---|
| 286 | ! ! ================== |
|---|
| 287 | ! ! Type of runoff |
|---|
| 288 | ! ! ================== |
|---|
| 289 | ! !== allocate runoff arrays |
|---|
| 290 | IF( sbc_rnf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' ) |
|---|
| 291 | ! |
|---|
| 292 | IF( ln_rnf_emp ) THEN !== runoffs directly provided in the precipitations ==! |
|---|
| 293 | IF(lwp) WRITE(numout,*) |
|---|
| 294 | IF(lwp) WRITE(numout,*) ' runoffs directly provided in the precipitations' |
|---|
| 295 | IF( ln_rnf_depth .OR. ln_rnf_tem .OR. ln_rnf_sal ) THEN |
|---|
| 296 | CALL ctl_warn( 'runoffs already included in precipitations, so runoff (T,S, depth) attributes will not be used' ) |
|---|
| 297 | ln_rnf_depth = .FALSE. ; ln_rnf_tem = .FALSE. ; ln_rnf_sal = .FALSE. |
|---|
| 298 | ENDIF |
|---|
| 299 | ! |
|---|
| 300 | ELSE !== runoffs read in a file : set sf_rnf structure ==! |
|---|
| 301 | ! |
|---|
| 302 | ALLOCATE( sf_rnf(1), STAT=ierror ) ! Create sf_rnf structure (runoff inflow) |
|---|
| 303 | IF(lwp) WRITE(numout,*) |
|---|
| 304 | IF(lwp) WRITE(numout,*) ' runoffs inflow read in a file' |
|---|
| 305 | IF( ierror > 0 ) THEN |
|---|
| 306 | CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' ) ; RETURN |
|---|
| 307 | ENDIF |
|---|
| 308 | ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1) ) |
|---|
| 309 | IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 310 | ! ! fill sf_rnf with the namelist (sn_rnf) and control print |
|---|
| 311 | CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' ) |
|---|
| 312 | ! |
|---|
| 313 | IF( ln_rnf_tem ) THEN ! Create (if required) sf_t_rnf structure |
|---|
| 314 | IF(lwp) WRITE(numout,*) |
|---|
| 315 | IF(lwp) WRITE(numout,*) ' runoffs temperatures read in a file' |
|---|
| 316 | ALLOCATE( sf_t_rnf(1), STAT=ierror ) |
|---|
| 317 | IF( ierror > 0 ) THEN |
|---|
| 318 | CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' ) ; RETURN |
|---|
| 319 | ENDIF |
|---|
| 320 | ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1) ) |
|---|
| 321 | IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 322 | CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf' ) |
|---|
| 323 | ENDIF |
|---|
| 324 | ! |
|---|
| 325 | IF( ln_rnf_sal ) THEN ! Create (if required) sf_s_rnf and sf_t_rnf structures |
|---|
| 326 | IF(lwp) WRITE(numout,*) |
|---|
| 327 | IF(lwp) WRITE(numout,*) ' runoffs salinities read in a file' |
|---|
| 328 | ALLOCATE( sf_s_rnf(1), STAT=ierror ) |
|---|
| 329 | IF( ierror > 0 ) THEN |
|---|
| 330 | CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' ) ; RETURN |
|---|
| 331 | ENDIF |
|---|
| 332 | ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1) ) |
|---|
| 333 | IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 334 | CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf' ) |
|---|
| 335 | ENDIF |
|---|
| 336 | ! |
|---|
| 337 | IF( ln_rnf_depth ) THEN ! depth of runoffs set from a file |
|---|
| 338 | IF(lwp) WRITE(numout,*) |
|---|
| 339 | IF(lwp) WRITE(numout,*) ' runoffs depth read in a file' |
|---|
| 340 | rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname ) |
|---|
| 341 | CALL iom_open ( rn_dep_file, inum ) ! open file |
|---|
| 342 | CALL iom_get ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf ) ! read the river mouth array |
|---|
| 343 | CALL iom_close( inum ) ! close file |
|---|
| 344 | ! |
|---|
| 345 | nk_rnf(:,:) = 0 ! set the number of level over which river runoffs are applied |
|---|
| 346 | DO jj = 1, jpj |
|---|
| 347 | DO ji = 1, jpi |
|---|
| 348 | IF( h_rnf(ji,jj) > 0._wp ) THEN |
|---|
| 349 | jk = 2 |
|---|
| 350 | DO WHILE ( jk /= mbkt(ji,jj) .AND. fsdept(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1 ; END DO |
|---|
| 351 | nk_rnf(ji,jj) = jk |
|---|
| 352 | ELSEIF( h_rnf(ji,jj) == -1 ) THEN ; nk_rnf(ji,jj) = 1 |
|---|
| 353 | ELSEIF( h_rnf(ji,jj) == -999 ) THEN ; nk_rnf(ji,jj) = mbkt(ji,jj) |
|---|
| 354 | ELSEIF( h_rnf(ji,jj) /= 0 ) THEN |
|---|
| 355 | CALL ctl_stop( 'runoff depth not positive, and not -999 or -1, rnf value in file fort.999' ) |
|---|
| 356 | WRITE(999,*) 'ji, jj, rnf(ji,jj) :', ji, jj, rnf(ji,jj) |
|---|
| 357 | ENDIF |
|---|
| 358 | END DO |
|---|
| 359 | END DO |
|---|
| 360 | DO jj = 1, jpj ! set the associated depth |
|---|
| 361 | DO ji = 1, jpi |
|---|
| 362 | h_rnf(ji,jj) = 0._wp |
|---|
| 363 | DO jk = 1, nk_rnf(ji,jj) |
|---|
| 364 | h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk) |
|---|
| 365 | END DO |
|---|
| 366 | END DO |
|---|
| 367 | END DO |
|---|
| 368 | ELSE ! runoffs applied at the surface |
|---|
| 369 | nk_rnf(:,:) = 1 |
|---|
| 370 | h_rnf (:,:) = fse3t(:,:,1) |
|---|
| 371 | ENDIF |
|---|
| 372 | ! |
|---|
| 373 | ENDIF |
|---|
| 374 | ! |
|---|
| 375 | rnf(:,:) = 0._wp ! runoff initialisation |
|---|
| 376 | rnf_tsc(:,:,:) = 0._wp ! runoffs temperature & salinty contents initilisation |
|---|
| 377 | ! |
|---|
| 378 | ! ! ======================== |
|---|
| 379 | ! ! River mouth vicinity |
|---|
| 380 | ! ! ======================== |
|---|
| 381 | ! |
|---|
| 382 | IF( ln_rnf_mouth ) THEN ! Specific treatment in vicinity of river mouths : |
|---|
| 383 | ! ! - Increase Kz in surface layers ( rn_hrnf > 0 ) |
|---|
| 384 | ! ! - set to zero SSS damping (ln_ssr=T) |
|---|
| 385 | ! ! - mixed upstream-centered (ln_traadv_cen2=T) |
|---|
| 386 | ! |
|---|
| 387 | IF ( ln_rnf_depth ) CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already', & |
|---|
| 388 | & 'be spread through depth by ln_rnf_depth' ) |
|---|
| 389 | ! |
|---|
| 390 | nkrnf = 0 ! Number of level over which Kz increase |
|---|
| 391 | IF( rn_hrnf > 0._wp ) THEN |
|---|
| 392 | nkrnf = 2 |
|---|
| 393 | DO WHILE( nkrnf /= jpkm1 .AND. gdepw_0(nkrnf+1) < rn_hrnf ) ; nkrnf = nkrnf + 1 ; END DO |
|---|
| 394 | IF( ln_sco ) CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' ) |
|---|
| 395 | ENDIF |
|---|
| 396 | IF(lwp) WRITE(numout,*) |
|---|
| 397 | IF(lwp) WRITE(numout,*) ' Specific treatment used in vicinity of river mouths :' |
|---|
| 398 | IF(lwp) WRITE(numout,*) ' - Increase Kz in surface layers (if rn_hrnf > 0 )' |
|---|
| 399 | IF(lwp) WRITE(numout,*) ' by ', rn_avt_rnf,' m2/s over ', nkrnf, ' w-levels' |
|---|
| 400 | IF(lwp) WRITE(numout,*) ' - set to zero SSS damping (if ln_ssr=T)' |
|---|
| 401 | IF(lwp) WRITE(numout,*) ' - mixed upstream-centered (if ln_traadv_cen2=T)' |
|---|
| 402 | ! |
|---|
| 403 | CALL rnf_mouth ! set river mouth mask |
|---|
| 404 | ! |
|---|
| 405 | ELSE ! No treatment at river mouths |
|---|
| 406 | IF(lwp) WRITE(numout,*) |
|---|
| 407 | IF(lwp) WRITE(numout,*) ' No specific treatment at river mouths' |
|---|
| 408 | rnfmsk (:,:) = 0._wp |
|---|
| 409 | rnfmsk_z(:) = 0._wp |
|---|
| 410 | nkrnf = 0 |
|---|
| 411 | ENDIF |
|---|
| 412 | ! |
|---|
| 413 | END SUBROUTINE sbc_rnf_init |
|---|
| 414 | |
|---|
| 415 | |
|---|
| 416 | SUBROUTINE rnf_mouth |
|---|
| 417 | !!---------------------------------------------------------------------- |
|---|
| 418 | !! *** ROUTINE rnf_mouth *** |
|---|
| 419 | !! |
|---|
| 420 | !! ** Purpose : define the river mouths mask |
|---|
| 421 | !! |
|---|
| 422 | !! ** Method : read the river mouth mask (=0/1) in the river runoff |
|---|
| 423 | !! climatological file. Defined a given vertical structure. |
|---|
| 424 | !! CAUTION, the vertical structure is hard coded on the |
|---|
| 425 | !! first 5 levels. |
|---|
| 426 | !! This fields can be used to: |
|---|
| 427 | !! - set an upstream advection scheme |
|---|
| 428 | !! (ln_rnf_mouth=T and ln_traadv_cen2=T) |
|---|
| 429 | !! - increase vertical on the top nn_krnf vertical levels |
|---|
| 430 | !! at river runoff input grid point (nn_krnf>=2, see step.F90) |
|---|
| 431 | !! - set to zero SSS restoring flux at river mouth grid points |
|---|
| 432 | !! |
|---|
| 433 | !! ** Action : rnfmsk set to 1 at river runoff input, 0 elsewhere |
|---|
| 434 | !! rnfmsk_z vertical structure |
|---|
| 435 | !!---------------------------------------------------------------------- |
|---|
| 436 | INTEGER :: inum ! temporary integers |
|---|
| 437 | CHARACTER(len=140) :: cl_rnfile ! runoff file name |
|---|
| 438 | !!---------------------------------------------------------------------- |
|---|
| 439 | ! |
|---|
| 440 | IF(lwp) WRITE(numout,*) |
|---|
| 441 | IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask' |
|---|
| 442 | IF(lwp) WRITE(numout,*) '~~~~~~~~~ ' |
|---|
| 443 | ! |
|---|
| 444 | cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname ) |
|---|
| 445 | IF( .NOT. sn_cnf%ln_clim ) THEN ; WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear ! add year |
|---|
| 446 | IF( sn_cnf%cltype == 'monthly' ) WRITE(cl_rnfile, '(a,"m",i2)' ) TRIM( cl_rnfile ), nmonth ! add month |
|---|
| 447 | ENDIF |
|---|
| 448 | ! |
|---|
| 449 | ! horizontal mask (read in NetCDF file) |
|---|
| 450 | CALL iom_open ( cl_rnfile, inum ) ! open file |
|---|
| 451 | CALL iom_get ( inum, jpdom_data, sn_cnf%clvar, rnfmsk ) ! read the river mouth array |
|---|
| 452 | CALL iom_close( inum ) ! close file |
|---|
| 453 | ! |
|---|
| 454 | IF( nn_closea == 1 ) CALL clo_rnf( rnfmsk ) ! closed sea inflow set as ruver mouth |
|---|
| 455 | ! |
|---|
| 456 | rnfmsk_z(:) = 0._wp ! vertical structure |
|---|
| 457 | rnfmsk_z(1) = 1.0 |
|---|
| 458 | rnfmsk_z(2) = 1.0 ! ********** |
|---|
| 459 | rnfmsk_z(3) = 0.5 ! HARD CODED on the 5 first levels |
|---|
| 460 | rnfmsk_z(4) = 0.25 ! ********** |
|---|
| 461 | rnfmsk_z(5) = 0.125 |
|---|
| 462 | ! |
|---|
| 463 | END SUBROUTINE rnf_mouth |
|---|
| 464 | |
|---|
| 465 | !!====================================================================== |
|---|
| 466 | END MODULE sbcrnf |
|---|
