New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_eiv.F90 in branches/2012/dev_MERGE_2012/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2012/dev_MERGE_2012/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_eiv.F90 @ 3787

Last change on this file since 3787 was 3787, checked in by gm, 11 years ago

dev_MERGE_2012: #1049 & #1053 : bug corrections in traadv_eiv.F90 (AR5 diag) and in traadv_ubs.F90 (UBS scheme), resp.
  • Property svn:keywords set to Id
File size: 10.3 KB
Line 
1MODULE traadv_eiv
2   !!======================================================================
3   !!                    ***  MODULE  traadv_eiv  ***
4   !! Ocean tracers:  advection trend - eddy induced velocity
5   !!======================================================================
6   !! History :  1.0  !  2005-11 (G. Madec)  Original code, from traldf and zdf _iso
7   !!            3.3  !  2010-05 (C. Ethe, G. Madec)  merge TRC-TRA
8   !!----------------------------------------------------------------------
9#if defined key_traldf_eiv   ||   defined key_esopa
10   !!----------------------------------------------------------------------
11   !!   'key_traldf_eiv'                  rotation of the lateral mixing tensor
12   !!----------------------------------------------------------------------
13   !!   tra_ldf_iso : update the tracer trend with the horizontal component
14   !!                 of iso neutral laplacian operator or horizontal
15   !!                 laplacian operator in s-coordinate
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers variables
18   USE dom_oce         ! ocean space and time domain variables
19   USE ldftra_oce      ! ocean active tracers: lateral physics
20   USE ldfslp          ! iso-neutral slopes
21   USE in_out_manager  ! I/O manager
22   USE iom
23   USE trc_oce         ! share passive tracers/Ocean variables
24# if defined key_diaeiv
25   USE phycst          ! physical constants
26   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
27   USE diaar5, ONLY:   lk_diaar5
28# endif 
29   USE wrk_nemo        ! Memory Allocation
30   USE timing          ! Timing
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   tra_adv_eiv   ! routine called by step.F90
36
37   !! * Substitutions
38#  include "domzgr_substitute.h90"
39#  include "ldftra_substitute.h90"
40#  include "ldfeiv_substitute.h90"
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE tra_adv_eiv( kt, kit000, pun, pvn, pwn, cdtype )
50      !!----------------------------------------------------------------------
51      !!                  ***  ROUTINE tra_adv_eiv  ***
52      !!
53      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
54      !!      trend and add it to the general trend of tracer equation.
55      !!
56      !! ** Method  :   The eddy induced advection is computed from the slope
57      !!      of iso-neutral surfaces computed in routine ldf_slp as follows:
58      !!         zu_eiv =  1/(e2u e3u)   dk[ aeiu e2u mi(wslpi) ]
59      !!         zv_eiv =  1/(e1v e3v)   dk[ aeiv e1v mj(wslpj)
60      !!         zw_eiv = -1/(e1t e2t) { di[ aeiu e2u mi(wslpi) ]
61      !!                               + dj[ aeiv e1v mj(wslpj) ] }
62      !!      add the eiv component to the model velocity:
63      !!         p.n = p.n + z._eiv
64      !!
65      !! ** Action  : - add to p.n the eiv component
66      !!----------------------------------------------------------------------
67      INTEGER                         , INTENT(in   ) ::   kt       ! ocean time-step index
68      INTEGER                         , INTENT(in   ) ::   kit000   ! first time step index
69      CHARACTER(len=3)                , INTENT(in   ) ::   cdtype   ! =TRA or TRC (tracer indicator)
70      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pun      ! in : 3 ocean velocity components
71      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pvn      ! out: 3 ocean velocity components
72      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pwn      ! increased by the eiv
73      !!
74      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
75      REAL(wp) ::   zuwk, zuwk1, zuwi, zuwi1   ! local scalars
76      REAL(wp) ::   zvwk, zvwk1, zvwj, zvwj1   !   -      -
77# if defined key_diaeiv 
78      REAL(wp) ::   zztmp                      ! local scalar
79# endif 
80      REAL(wp), POINTER, DIMENSION(:,:) :: zu_eiv, zv_eiv, zw_eiv, z2d
81      !!----------------------------------------------------------------------
82      !
83      IF( nn_timing == 1 )  CALL timing_start( 'tra_adv_eiv')
84      !
85# if defined key_diaeiv 
86      CALL wrk_alloc( jpi, jpj, zu_eiv, zv_eiv, zw_eiv, z2d )
87# else
88      CALL wrk_alloc( jpi, jpj, zu_eiv, zv_eiv, zw_eiv )
89# endif
90
91      IF( kt == kit000 )  THEN
92         IF(lwp) WRITE(numout,*)
93         IF(lwp) WRITE(numout,*) 'tra_adv_eiv : eddy induced advection on ', cdtype,' :'
94         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   add to velocity fields the eiv component'
95# if defined key_diaeiv 
96         IF( cdtype == 'TRA') THEN
97            u_eiv(:,:,:) = 0.e0
98            v_eiv(:,:,:) = 0.e0
99            w_eiv(:,:,:) = 0.e0
100         END IF
101# endif
102      ENDIF
103
104      zu_eiv(:,:) = 0.e0   ;   zv_eiv(:,:) = 0.e0   ;    zw_eiv(:,:) = 0.e0 
105     
106                                                    ! =================
107      DO jk = 1, jpkm1                              !  Horizontal slab
108         !                                          ! =================
109         DO jj = 1, jpjm1
110            DO ji = 1, fs_jpim1   ! vector opt.
111               zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj,jk  ) ) * fsaeiu(ji,jj,jk  ) * umask(ji,jj,jk  )
112               zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj,jk+1) ) * fsaeiu(ji,jj,jk+1) * umask(ji,jj,jk+1)
113               zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji,jj+1,jk  ) ) * fsaeiv(ji,jj,jk  ) * vmask(ji,jj,jk  )
114               zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji,jj+1,jk+1) ) * fsaeiv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
115
116               zu_eiv(ji,jj) = 0.5 * umask(ji,jj,jk) * ( zuwk - zuwk1 ) 
117               zv_eiv(ji,jj) = 0.5 * vmask(ji,jj,jk) * ( zvwk - zvwk1 ) 
118   
119               pun(ji,jj,jk) = pun(ji,jj,jk) + e2u(ji,jj) * zu_eiv(ji,jj)
120               pvn(ji,jj,jk) = pvn(ji,jj,jk) + e1v(ji,jj) * zv_eiv(ji,jj)
121            END DO
122         END DO
123# if defined key_diaeiv 
124         IF( cdtype == 'TRA') THEN
125            u_eiv(:,:,jk) = zu_eiv(:,:) / fse3u(:,:,jk)
126            v_eiv(:,:,jk) = zv_eiv(:,:) / fse3v(:,:,jk)
127         END IF
128# endif
129         IF( jk >=2 ) THEN                             ! jk=1 zw_eiv=0, not computed
130            DO jj = 2, jpjm1
131               DO ji = fs_2, fs_jpim1   ! vector opt.
132# if defined key_traldf_c2d || defined key_traldf_c3d
133                  zuwi  = ( wslpi(ji,jj,jk)+wslpi(ji-1,jj,jk) ) * fsaeiu(ji-1,jj,jk) * e2u(ji-1,jj) * umask(ji-1,jj,jk)
134                  zuwi1 = ( wslpi(ji,jj,jk)+wslpi(ji+1,jj,jk) ) * fsaeiu(ji  ,jj,jk) * e2u(ji  ,jj) * umask(ji  ,jj,jk)
135                  zvwj  = ( wslpj(ji,jj,jk)+wslpj(ji,jj-1,jk) ) * fsaeiv(ji,jj-1,jk) * e1v(ji,jj-1) * vmask(ji,jj-1,jk)
136                  zvwj1 = ( wslpj(ji,jj,jk)+wslpj(ji,jj+1,jk) ) * fsaeiv(ji,jj  ,jk) * e1v(ji  ,jj) * vmask(ji  ,jj,jk)
137 
138                  zw_eiv(ji,jj) = - 0.5 * tmask(ji,jj,jk) * ( zuwi1 - zuwi + zvwj1 - zvwj ) 
139# else
140                  zuwi  = ( wslpi(ji,jj,jk) + wslpi(ji-1,jj,jk) ) * e2u(ji-1,jj) * umask(ji-1,jj,jk)
141                  zuwi1 = ( wslpi(ji,jj,jk) + wslpi(ji+1,jj,jk) ) * e2u(ji  ,jj) * umask(ji  ,jj,jk)
142                  zvwj  = ( wslpj(ji,jj,jk) + wslpj(ji,jj-1,jk) ) * e1v(ji,jj-1) * vmask(ji,jj-1,jk)
143                  zvwj1 = ( wslpj(ji,jj,jk) + wslpj(ji,jj+1,jk) ) * e1v(ji  ,jj) * vmask(ji  ,jj,jk)
144
145                  zw_eiv(ji,jj) = - 0.5 * tmask(ji,jj,jk) * fsaeiw(ji,jj,jk) * ( zuwi1 - zuwi + zvwj1 - zvwj )
146# endif
147                  pwn(ji,jj,jk) = pwn(ji,jj,jk) + zw_eiv(ji,jj)
148               END DO
149            END DO
150# if defined key_diaeiv 
151            IF( cdtype == 'TRA')  w_eiv(:,:,jk) = zw_eiv(:,:) / ( e1t(:,:) * e2t(:,:) )
152# endif
153         ENDIF
154         !                                          ! =================
155      END DO                                        !    End of slab 
156      !                                             ! =================
157
158# if defined key_diaeiv 
159      IF( cdtype == 'TRA') THEN
160         CALL iom_put( "uoce_eiv", u_eiv )    ! i-eiv current
161         CALL iom_put( "voce_eiv", v_eiv )    ! j-eiv current
162         CALL iom_put( "woce_eiv", w_eiv )    ! vert. eiv current
163         IF( lk_diaar5 ) THEN
164            zztmp = 0.5 * rau0 * rcp 
165            z2d(:,:) = 0.e0 
166            DO jk = 1, jpkm1
167               DO jj = 2, jpjm1
168                  DO ji = fs_2, fs_jpim1   ! vector opt.
169                     z2d(ji,jj) = z2d(ji,jj) + zztmp * u_eiv(ji,jj,jk) &
170                       &         * (tsn(ji,jj,jk,jp_tem)+tsn(ji+1,jj,jk,jp_tem)) * e2u(ji,jj) * fse3u(ji,jj,jk) 
171                  END DO
172               END DO
173            END DO
174            CALL lbc_lnk( z2d, 'U', -1. )
175            CALL iom_put( "ueiv_heattr", z2d )                  ! heat transport in i-direction
176            z2d(:,:) = 0.e0 
177            DO jk = 1, jpkm1
178               DO jj = 2, jpjm1
179                  DO ji = fs_2, fs_jpim1   ! vector opt.
180                     z2d(ji,jj) = z2d(ji,jj) + zztmp * v_eiv(ji,jj,jk) &
181                     &           * (tsn(ji,jj,jk,jp_tem)+tsn(ji,jj+1,jk,jp_tem)) * e1v(ji,jj) * fse3v(ji,jj,jk) 
182                  END DO
183               END DO
184            END DO
185            CALL lbc_lnk( z2d, 'V', -1. )
186            CALL iom_put( "veiv_heattr", z2d )                  !  heat transport in i-direction
187         ENDIF
188    END IF
189# endif 
190      !
191# if defined key_diaeiv 
192      CALL wrk_dealloc( jpi, jpj, zu_eiv, zv_eiv, zw_eiv, z2d )
193# else
194      CALL wrk_dealloc( jpi, jpj, zu_eiv, zv_eiv, zw_eiv )
195# endif
196      !
197      IF( nn_timing == 1 )  CALL timing_stop( 'tra_adv_eiv')
198      !
199    END SUBROUTINE tra_adv_eiv
200
201#else
202   !!----------------------------------------------------------------------
203   !!   Dummy module :             No rotation of the lateral mixing tensor
204   !!----------------------------------------------------------------------
205CONTAINS
206   SUBROUTINE tra_adv_eiv( kt, kit000, pun, pvn, pwn, cdtype )              ! Empty routine
207      INTEGER  ::   kt   
208      INTEGER  ::   kit000   
209      CHARACTER(len=3) ::   cdtype
210      REAL, DIMENSION(:,:,:) ::   pun, pvn, pwn
211      WRITE(*,*) 'tra_adv_eiv: You should not have seen this print! error?', kt, cdtype, pun(1,1,1), pvn(1,1,1), pwn(1,1,1)
212   END SUBROUTINE tra_adv_eiv
213#endif
214
215   !!==============================================================================
216END MODULE traadv_eiv
Note: See TracBrowser for help on using the repository browser.