[2496] | 1 | MODULE nemogcm |
---|
[2442] | 2 | !!====================================================================== |
---|
[2496] | 3 | !! *** MODULE nemogcm *** |
---|
| 4 | !! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice) |
---|
[2442] | 5 | !!====================================================================== |
---|
[1593] | 6 | !! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code |
---|
| 7 | !! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec) |
---|
| 8 | !! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar, |
---|
[2104] | 9 | !! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1 |
---|
[1593] | 10 | !! - ! 1992-06 (L.Terray) coupling implementation |
---|
| 11 | !! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice |
---|
| 12 | !! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar, |
---|
[2104] | 13 | !! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0 |
---|
[1593] | 14 | !! 8.1 ! 1997-06 (M. Imbard, G. Madec) |
---|
| 15 | !! 8.2 ! 1999-11 (M. Imbard, H. Goosse) LIM sea-ice model |
---|
| 16 | !! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP |
---|
| 17 | !! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER) |
---|
| 18 | !! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules |
---|
| 19 | !! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces |
---|
| 20 | !! - ! 2004-08 (C. Talandier) New trends organization |
---|
| 21 | !! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility |
---|
| 22 | !! - ! 2005-11 (V. Garnier) Surface pressure gradient organization |
---|
| 23 | !! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation |
---|
| 24 | !! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization |
---|
| 25 | !! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY) |
---|
| 26 | !! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp |
---|
[2236] | 27 | !! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface |
---|
| 28 | !! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase |
---|
[3294] | 29 | !! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation |
---|
| 30 | !! 3.4 ! 2011-11 (C. Harris) decomposition changes for running with CICE |
---|
[1593] | 31 | !!---------------------------------------------------------------------- |
---|
[3] | 32 | |
---|
| 33 | !!---------------------------------------------------------------------- |
---|
[2496] | 34 | !! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice |
---|
| 35 | !! nemo_init : initialization of the NEMO system |
---|
| 36 | !! nemo_ctl : initialisation of the contol print |
---|
| 37 | !! nemo_closefile : close remaining open files |
---|
[2715] | 38 | !! nemo_alloc : dynamical allocation |
---|
| 39 | !! nemo_partition : calculate MPP domain decomposition |
---|
| 40 | !! factorise : calculate the factors of the no. of MPI processes |
---|
[3] | 41 | !!---------------------------------------------------------------------- |
---|
[2382] | 42 | USE step_oce ! module used in the ocean time stepping module |
---|
[888] | 43 | USE sbc_oce ! surface boundary condition: ocean |
---|
[2392] | 44 | USE cla ! cross land advection (tra_cla routine) |
---|
[3] | 45 | USE domcfg ! domain configuration (dom_cfg routine) |
---|
| 46 | USE mppini ! shared/distributed memory setting (mpp_init routine) |
---|
| 47 | USE domain ! domain initialization (dom_init routine) |
---|
[3625] | 48 | #if defined key_nemocice_decomp |
---|
| 49 | USE ice_domain_size, only: nx_global, ny_global |
---|
| 50 | #endif |
---|
[3651] | 51 | USE tideini ! tidal components initialization (tide_ini routine) |
---|
[3] | 52 | USE obcini ! open boundary cond. initialization (obc_ini routine) |
---|
[3294] | 53 | USE bdyini ! open boundary cond. initialization (bdy_init routine) |
---|
| 54 | USE bdydta ! open boundary cond. initialization (bdy_dta_init routine) |
---|
[3651] | 55 | USE bdytides ! open boundary cond. initialization (bdytide_init routine) |
---|
[3] | 56 | USE istate ! initial state setting (istate_init routine) |
---|
| 57 | USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine) |
---|
| 58 | USE ldftra ! lateral diffusivity setting (ldftra_init routine) |
---|
[2392] | 59 | USE zdfini ! vertical physics setting (zdf_init routine) |
---|
[3] | 60 | USE phycst ! physical constant (par_cst routine) |
---|
[2236] | 61 | USE trdmod ! momentum/tracers trends (trd_mod_init routine) |
---|
| 62 | USE asmtrj ! writing out state trajectory |
---|
| 63 | USE diaptr ! poleward transports (dia_ptr_init routine) |
---|
[3294] | 64 | USE diadct ! sections transports (dia_dct_init routine) |
---|
[2236] | 65 | USE diaobs ! Observation diagnostics (dia_obs_init routine) |
---|
[2496] | 66 | USE step ! NEMO time-stepping (stp routine) |
---|
[3609] | 67 | USE icbini ! handle bergs, initialisation |
---|
| 68 | USE icbstp ! handle bergs, calving, themodynamics and transport |
---|
[532] | 69 | #if defined key_oasis3 |
---|
[1359] | 70 | USE cpl_oasis3 ! OASIS3 coupling |
---|
[599] | 71 | #elif defined key_oasis4 |
---|
[1359] | 72 | USE cpl_oasis4 ! OASIS4 coupling (not working) |
---|
[532] | 73 | #endif |
---|
[900] | 74 | USE c1d ! 1D configuration |
---|
| 75 | USE step_c1d ! Time stepping loop for the 1D configuration |
---|
[1594] | 76 | #if defined key_top |
---|
[1593] | 77 | USE trcini ! passive tracer initialisation |
---|
[1594] | 78 | #endif |
---|
[1593] | 79 | USE lib_mpp ! distributed memory computing |
---|
[1412] | 80 | #if defined key_iomput |
---|
| 81 | USE mod_ioclient |
---|
[1359] | 82 | #endif |
---|
[3651] | 83 | USE sbctide, ONLY: lk_tide |
---|
[268] | 84 | |
---|
[3651] | 85 | |
---|
[2715] | 86 | IMPLICIT NONE |
---|
[3] | 87 | PRIVATE |
---|
| 88 | |
---|
[2496] | 89 | PUBLIC nemo_gcm ! called by model.F90 |
---|
| 90 | PUBLIC nemo_init ! needed by AGRIF |
---|
[467] | 91 | |
---|
[2498] | 92 | CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing |
---|
[1593] | 93 | |
---|
[3] | 94 | !!---------------------------------------------------------------------- |
---|
[2715] | 95 | !! NEMO/OPA 4.0 , NEMO Consortium (2011) |
---|
[2392] | 96 | !! $Id$ |
---|
[2329] | 97 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
[3] | 98 | !!---------------------------------------------------------------------- |
---|
| 99 | CONTAINS |
---|
| 100 | |
---|
[2496] | 101 | SUBROUTINE nemo_gcm |
---|
[3] | 102 | !!---------------------------------------------------------------------- |
---|
[2496] | 103 | !! *** ROUTINE nemo_gcm *** |
---|
[3] | 104 | !! |
---|
[2496] | 105 | !! ** Purpose : NEMO solves the primitive equations on an orthogonal |
---|
[1593] | 106 | !! curvilinear mesh on the sphere. |
---|
[3] | 107 | !! |
---|
| 108 | !! ** Method : - model general initialization |
---|
| 109 | !! - launch the time-stepping (stp routine) |
---|
[1593] | 110 | !! - finalize the run by closing files and communications |
---|
[3] | 111 | !! |
---|
[2715] | 112 | !! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL. |
---|
[1593] | 113 | !! Madec, 2008, internal report, IPSL. |
---|
[3] | 114 | !!---------------------------------------------------------------------- |
---|
| 115 | INTEGER :: istp ! time step index |
---|
[389] | 116 | !!---------------------------------------------------------------------- |
---|
[2382] | 117 | ! |
---|
[392] | 118 | #if defined key_agrif |
---|
[1593] | 119 | CALL Agrif_Init_Grids() ! AGRIF: set the meshes |
---|
[389] | 120 | #endif |
---|
| 121 | |
---|
[1593] | 122 | ! !-----------------------! |
---|
[2496] | 123 | CALL nemo_init !== Initialisations ==! |
---|
[1593] | 124 | ! !-----------------------! |
---|
[2715] | 125 | #if defined key_agrif |
---|
[3680] | 126 | CALL Agrif_Declare_Var_dom ! AGRIF: set the meshes for DOM |
---|
| 127 | CALL Agrif_Declare_Var ! " " " " " DYN/TRA |
---|
[2715] | 128 | # if defined key_top |
---|
[3680] | 129 | CALL Agrif_Declare_Var_top ! " " " " " TOP |
---|
[2715] | 130 | # endif |
---|
[3680] | 131 | # if defined key_lim2 |
---|
| 132 | CALL Agrif_Declare_Var_lim2 ! " " " " " LIM |
---|
| 133 | # endif |
---|
[2715] | 134 | #endif |
---|
[682] | 135 | ! check that all process are still there... If some process have an error, |
---|
| 136 | ! they will never enter in step and other processes will wait until the end of the cpu time! |
---|
[900] | 137 | IF( lk_mpp ) CALL mpp_max( nstop ) |
---|
[682] | 138 | |
---|
[1593] | 139 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
---|
| 140 | |
---|
| 141 | ! !-----------------------! |
---|
| 142 | ! !== time stepping ==! |
---|
| 143 | ! !-----------------------! |
---|
[900] | 144 | istp = nit000 |
---|
[2236] | 145 | #if defined key_c1d |
---|
[389] | 146 | DO WHILE ( istp <= nitend .AND. nstop == 0 ) |
---|
[900] | 147 | CALL stp_c1d( istp ) |
---|
[389] | 148 | istp = istp + 1 |
---|
| 149 | END DO |
---|
[2236] | 150 | #else |
---|
| 151 | IF( lk_asminc ) THEN |
---|
| 152 | IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 ) ! Output background fields |
---|
| 153 | IF( ln_trjwri ) CALL asm_trj_wri( nit000 - 1 ) ! Output trajectory fields |
---|
| 154 | IF( ln_asmdin ) THEN ! Direct initialization |
---|
| 155 | IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 ) ! Tracers |
---|
| 156 | IF( ln_dyninc ) THEN |
---|
| 157 | CALL dyn_asm_inc( nit000 - 1 ) ! Dynamics |
---|
| 158 | IF ( ln_asmdin ) CALL ssh_wzv ( nit000 - 1 ) ! update vertical velocity |
---|
| 159 | ENDIF |
---|
| 160 | IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 ) ! SSH |
---|
| 161 | ENDIF |
---|
| 162 | ENDIF |
---|
| 163 | |
---|
[389] | 164 | DO WHILE ( istp <= nitend .AND. nstop == 0 ) |
---|
[392] | 165 | #if defined key_agrif |
---|
[1593] | 166 | CALL Agrif_Step( stp ) ! AGRIF: time stepping |
---|
[389] | 167 | #else |
---|
[1593] | 168 | CALL stp( istp ) ! standard time stepping |
---|
[389] | 169 | #endif |
---|
| 170 | istp = istp + 1 |
---|
[900] | 171 | IF( lk_mpp ) CALL mpp_max( nstop ) |
---|
[389] | 172 | END DO |
---|
[2236] | 173 | #endif |
---|
| 174 | |
---|
[3609] | 175 | IF( lk_diaobs ) CALL dia_obs_wri |
---|
| 176 | ! |
---|
| 177 | IF( ln_icebergs ) CALL icb_end( nitend ) |
---|
[1593] | 178 | |
---|
| 179 | ! !------------------------! |
---|
| 180 | ! !== finalize the run ==! |
---|
| 181 | ! !------------------------! |
---|
| 182 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
---|
| 183 | ! |
---|
| 184 | IF( nstop /= 0 .AND. lwp ) THEN ! error print |
---|
[682] | 185 | WRITE(numout,cform_err) |
---|
| 186 | WRITE(numout,*) nstop, ' error have been found' |
---|
[389] | 187 | ENDIF |
---|
[1593] | 188 | ! |
---|
[3294] | 189 | #if defined key_agrif |
---|
| 190 | CALL Agrif_ParentGrid_To_ChildGrid() |
---|
| 191 | IF( lk_diaobs ) CALL dia_obs_wri |
---|
| 192 | IF( nn_timing == 1 ) CALL timing_finalize |
---|
| 193 | CALL Agrif_ChildGrid_To_ParentGrid() |
---|
| 194 | #endif |
---|
| 195 | IF( nn_timing == 1 ) CALL timing_finalize |
---|
| 196 | ! |
---|
[2496] | 197 | CALL nemo_closefile |
---|
[532] | 198 | #if defined key_oasis3 || defined key_oasis4 |
---|
[1976] | 199 | CALL cpl_prism_finalize ! end coupling and mpp communications with OASIS |
---|
[532] | 200 | #else |
---|
[1593] | 201 | IF( lk_mpp ) CALL mppstop ! end mpp communications |
---|
[532] | 202 | #endif |
---|
[900] | 203 | ! |
---|
[2496] | 204 | END SUBROUTINE nemo_gcm |
---|
[389] | 205 | |
---|
| 206 | |
---|
[2496] | 207 | SUBROUTINE nemo_init |
---|
[389] | 208 | !!---------------------------------------------------------------------- |
---|
[2496] | 209 | !! *** ROUTINE nemo_init *** |
---|
[389] | 210 | !! |
---|
[2496] | 211 | !! ** Purpose : initialization of the NEMO GCM |
---|
[389] | 212 | !!---------------------------------------------------------------------- |
---|
[2715] | 213 | INTEGER :: ji ! dummy loop indices |
---|
| 214 | INTEGER :: ilocal_comm ! local integer |
---|
| 215 | CHARACTER(len=80), DIMENSION(16) :: cltxt |
---|
[1593] | 216 | !! |
---|
[1601] | 217 | NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, & |
---|
[3294] | 218 | & nn_isplt, nn_jsplt, nn_jctls, nn_jctle, & |
---|
| 219 | & nn_bench, nn_timing |
---|
[3] | 220 | !!---------------------------------------------------------------------- |
---|
[1593] | 221 | ! |
---|
[2496] | 222 | cltxt = '' |
---|
| 223 | ! |
---|
[1593] | 224 | ! ! open Namelist file |
---|
[1581] | 225 | CALL ctl_opn( numnam, 'namelist', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. ) |
---|
[1593] | 226 | ! |
---|
| 227 | READ( numnam, namctl ) ! Namelist namctl : Control prints & Benchmark |
---|
| 228 | ! |
---|
| 229 | ! !--------------------------------------------! |
---|
| 230 | ! ! set communicator & select the local node ! |
---|
| 231 | ! !--------------------------------------------! |
---|
[1412] | 232 | #if defined key_iomput |
---|
[2200] | 233 | IF( Agrif_Root() ) THEN |
---|
[1412] | 234 | # if defined key_oasis3 || defined key_oasis4 |
---|
[2715] | 235 | CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis |
---|
[1412] | 236 | # endif |
---|
[2715] | 237 | CALL init_ioclient( ilocal_comm ) ! exchange io_server nemo local communicator with the io_server |
---|
[2200] | 238 | ENDIF |
---|
[2715] | 239 | narea = mynode( cltxt, numnam, nstop, ilocal_comm ) ! Nodes selection |
---|
[532] | 240 | #else |
---|
[1412] | 241 | # if defined key_oasis3 || defined key_oasis4 |
---|
[2236] | 242 | IF( Agrif_Root() ) THEN |
---|
[2715] | 243 | CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis |
---|
[2236] | 244 | ENDIF |
---|
[2715] | 245 | narea = mynode( cltxt, numnam, nstop, ilocal_comm ) ! Nodes selection (control print return in cltxt) |
---|
[1412] | 246 | # else |
---|
[2082] | 247 | ilocal_comm = 0 |
---|
[2715] | 248 | narea = mynode( cltxt, numnam, nstop ) ! Nodes selection (control print return in cltxt) |
---|
[1412] | 249 | # endif |
---|
[532] | 250 | #endif |
---|
[2715] | 251 | narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 ) |
---|
[3] | 252 | |
---|
[2715] | 253 | lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print |
---|
[1579] | 254 | |
---|
[2715] | 255 | ! If dimensions of processor grid weren't specified in the namelist file |
---|
| 256 | ! then we calculate them here now that we have our communicator size |
---|
| 257 | IF( (jpni < 1) .OR. (jpnj < 1) )THEN |
---|
| 258 | #if defined key_mpp_mpi |
---|
| 259 | IF( Agrif_Root() ) CALL nemo_partition(mppsize) |
---|
| 260 | #else |
---|
| 261 | jpni = 1 |
---|
| 262 | jpnj = 1 |
---|
| 263 | jpnij = jpni*jpnj |
---|
| 264 | #endif |
---|
| 265 | END IF |
---|
| 266 | |
---|
| 267 | ! Calculate domain dimensions given calculated jpni and jpnj |
---|
| 268 | ! This used to be done in par_oce.F90 when they were parameters rather |
---|
| 269 | ! than variables |
---|
| 270 | IF( Agrif_Root() ) THEN |
---|
[3294] | 271 | #if defined key_nemocice_decomp |
---|
[3625] | 272 | jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci ! first dim. |
---|
| 273 | jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim. |
---|
[3294] | 274 | #else |
---|
[3625] | 275 | jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci ! first dim. |
---|
[2715] | 276 | jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim. |
---|
[3294] | 277 | #endif |
---|
[2715] | 278 | jpk = jpkdta ! third dim |
---|
| 279 | jpim1 = jpi-1 ! inner domain indices |
---|
| 280 | jpjm1 = jpj-1 ! " " |
---|
| 281 | jpkm1 = jpk-1 ! " " |
---|
| 282 | jpij = jpi*jpj ! jpi x j |
---|
| 283 | ENDIF |
---|
| 284 | |
---|
[1593] | 285 | IF(lwp) THEN ! open listing units |
---|
| 286 | ! |
---|
[1581] | 287 | CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea ) |
---|
[1593] | 288 | ! |
---|
[1579] | 289 | WRITE(numout,*) |
---|
[3294] | 290 | WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC' |
---|
[1593] | 291 | WRITE(numout,*) ' NEMO team' |
---|
[1579] | 292 | WRITE(numout,*) ' Ocean General Circulation Model' |
---|
[3294] | 293 | WRITE(numout,*) ' version 3.4 (2011) ' |
---|
[1579] | 294 | WRITE(numout,*) |
---|
| 295 | WRITE(numout,*) |
---|
[1593] | 296 | DO ji = 1, SIZE(cltxt) |
---|
| 297 | IF( TRIM(cltxt(ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode |
---|
[1579] | 298 | END DO |
---|
[1593] | 299 | WRITE(numout,cform_aaa) ! Flag AAAAAAA |
---|
| 300 | ! |
---|
[473] | 301 | ENDIF |
---|
[2715] | 302 | |
---|
| 303 | ! Now we know the dimensions of the grid and numout has been set we can |
---|
| 304 | ! allocate arrays |
---|
| 305 | CALL nemo_alloc() |
---|
| 306 | |
---|
[2496] | 307 | ! !-------------------------------! |
---|
| 308 | ! ! NEMO general initialization ! |
---|
| 309 | ! !-------------------------------! |
---|
[473] | 310 | |
---|
[2496] | 311 | CALL nemo_ctl ! Control prints & Benchmark |
---|
[531] | 312 | |
---|
[2082] | 313 | ! ! Domain decomposition |
---|
[1593] | 314 | IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out |
---|
| 315 | ELSE ; CALL mpp_init2 ! eliminate land processors |
---|
[3] | 316 | ENDIF |
---|
[2382] | 317 | ! |
---|
[3294] | 318 | IF( nn_timing == 1 ) CALL timing_init |
---|
| 319 | ! |
---|
[2082] | 320 | ! ! General initialization |
---|
[2027] | 321 | CALL phy_cst ! Physical constants |
---|
| 322 | CALL eos_init ! Equation of state |
---|
| 323 | CALL dom_cfg ! Domain configuration |
---|
| 324 | CALL dom_init ! Domain |
---|
[413] | 325 | |
---|
[3294] | 326 | IF( ln_nnogather ) CALL nemo_northcomms ! Initialise the northfold neighbour lists (must be done after the masks are defined) |
---|
| 327 | |
---|
[2027] | 328 | IF( ln_ctl ) CALL prt_ctl_init ! Print control |
---|
| 329 | |
---|
| 330 | IF( lk_obc ) CALL obc_init ! Open boundaries |
---|
[3651] | 331 | |
---|
| 332 | CALL istate_init ! ocean initial state (Dynamics and tracers) |
---|
| 333 | |
---|
| 334 | IF( lk_tide ) CALL tide_init( nit000 ) ! Initialisation of the tidal harmonics |
---|
| 335 | |
---|
[3294] | 336 | IF( lk_bdy ) CALL bdy_init ! Open boundaries initialisation |
---|
| 337 | IF( lk_bdy ) CALL bdy_dta_init ! Open boundaries initialisation of external data arrays |
---|
[3651] | 338 | IF( lk_bdy ) CALL bdytide_init ! Open boundaries initialisation of tidal harmonic forcing |
---|
[2027] | 339 | |
---|
[3294] | 340 | CALL dyn_nept_init ! simplified form of Neptune effect |
---|
| 341 | |
---|
[3] | 342 | ! ! Ocean physics |
---|
[2104] | 343 | CALL sbc_init ! Forcings : surface module |
---|
[2082] | 344 | ! ! Vertical physics |
---|
| 345 | CALL zdf_init ! namelist read |
---|
| 346 | CALL zdf_bfr_init ! bottom friction |
---|
| 347 | IF( lk_zdfric ) CALL zdf_ric_init ! Richardson number dependent Kz |
---|
[2329] | 348 | IF( lk_zdftke ) CALL zdf_tke_init ! TKE closure scheme |
---|
| 349 | IF( lk_zdfgls ) CALL zdf_gls_init ! GLS closure scheme |
---|
| 350 | IF( lk_zdfkpp ) CALL zdf_kpp_init ! KPP closure scheme |
---|
[2082] | 351 | IF( lk_zdftmx ) CALL zdf_tmx_init ! tidal vertical mixing |
---|
[2027] | 352 | IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) & |
---|
[2082] | 353 | & CALL zdf_ddm_init ! double diffusive mixing |
---|
| 354 | ! ! Lateral physics |
---|
| 355 | CALL ldf_tra_init ! Lateral ocean tracer physics |
---|
| 356 | CALL ldf_dyn_init ! Lateral ocean momentum physics |
---|
[2392] | 357 | IF( lk_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing |
---|
[2082] | 358 | |
---|
[2027] | 359 | ! ! Active tracers |
---|
| 360 | CALL tra_qsr_init ! penetrative solar radiation qsr |
---|
[2325] | 361 | CALL tra_bbc_init ! bottom heat flux |
---|
[2027] | 362 | IF( lk_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme |
---|
[3294] | 363 | IF( ln_tradmp ) CALL tra_dmp_init ! internal damping trends |
---|
[2027] | 364 | CALL tra_adv_init ! horizontal & vertical advection |
---|
| 365 | CALL tra_ldf_init ! lateral mixing |
---|
| 366 | CALL tra_zdf_init ! vertical mixing and after tracer fields |
---|
| 367 | |
---|
| 368 | ! ! Dynamics |
---|
| 369 | CALL dyn_adv_init ! advection (vector or flux form) |
---|
[2104] | 370 | CALL dyn_vor_init ! vorticity term including Coriolis |
---|
[2027] | 371 | CALL dyn_ldf_init ! lateral mixing |
---|
[2104] | 372 | CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure |
---|
[2027] | 373 | CALL dyn_zdf_init ! vertical diffusion |
---|
| 374 | CALL dyn_spg_init ! surface pressure gradient |
---|
[2392] | 375 | |
---|
| 376 | ! ! Misc. options |
---|
| 377 | IF( nn_cla == 1 ) CALL cla_init ! Cross Land Advection |
---|
[3609] | 378 | CALL icb_init( rdt, nit000) ! initialise icebergs instance |
---|
[2392] | 379 | |
---|
[1594] | 380 | #if defined key_top |
---|
[2027] | 381 | ! ! Passive tracers |
---|
[2082] | 382 | CALL trc_init |
---|
[1594] | 383 | #endif |
---|
[2382] | 384 | ! ! Diagnostics |
---|
[3294] | 385 | IF( lk_floats ) CALL flo_init ! drifting Floats |
---|
[2027] | 386 | CALL iom_init ! iom_put initialization |
---|
[2392] | 387 | IF( lk_diaar5 ) CALL dia_ar5_init ! ar5 diag |
---|
[2027] | 388 | CALL dia_ptr_init ! Poleward TRansports initialization |
---|
[3294] | 389 | IF( lk_diadct ) CALL dia_dct_init ! Sections tranports |
---|
[2148] | 390 | CALL dia_hsb_init ! heat content, salt content and volume budgets |
---|
[2027] | 391 | CALL trd_mod_init ! Mixed-layer/Vorticity/Integral constraints trends |
---|
[2392] | 392 | IF( lk_diaobs ) THEN ! Observation & model comparison |
---|
[2382] | 393 | CALL dia_obs_init ! Initialize observational data |
---|
| 394 | CALL dia_obs( nit000 - 1 ) ! Observation operator for restart |
---|
[2236] | 395 | ENDIF |
---|
[2382] | 396 | ! ! Assimilation increments |
---|
[2392] | 397 | IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments |
---|
[2382] | 398 | IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler |
---|
[1593] | 399 | ! |
---|
[2496] | 400 | END SUBROUTINE nemo_init |
---|
[467] | 401 | |
---|
| 402 | |
---|
[2496] | 403 | SUBROUTINE nemo_ctl |
---|
[467] | 404 | !!---------------------------------------------------------------------- |
---|
[2496] | 405 | !! *** ROUTINE nemo_ctl *** |
---|
[467] | 406 | !! |
---|
[2442] | 407 | !! ** Purpose : control print setting |
---|
[467] | 408 | !! |
---|
[2442] | 409 | !! ** Method : - print namctl information and check some consistencies |
---|
[467] | 410 | !!---------------------------------------------------------------------- |
---|
[2442] | 411 | ! |
---|
[2496] | 412 | IF(lwp) THEN ! control print |
---|
[531] | 413 | WRITE(numout,*) |
---|
[2496] | 414 | WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark' |
---|
[531] | 415 | WRITE(numout,*) '~~~~~~~ ' |
---|
[1593] | 416 | WRITE(numout,*) ' Namelist namctl' |
---|
[1601] | 417 | WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl |
---|
| 418 | WRITE(numout,*) ' level of print nn_print = ', nn_print |
---|
| 419 | WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls |
---|
| 420 | WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle |
---|
| 421 | WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls |
---|
| 422 | WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle |
---|
| 423 | WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt |
---|
| 424 | WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt |
---|
| 425 | WRITE(numout,*) ' benchmark parameter (0/1) nn_bench = ', nn_bench |
---|
[3610] | 426 | WRITE(numout,*) ' timing activated (0/1) nn_timing = ', nn_timing |
---|
[531] | 427 | ENDIF |
---|
[2442] | 428 | ! |
---|
[1601] | 429 | nprint = nn_print ! convert DOCTOR namelist names into OLD names |
---|
| 430 | nictls = nn_ictls |
---|
| 431 | nictle = nn_ictle |
---|
| 432 | njctls = nn_jctls |
---|
| 433 | njctle = nn_jctle |
---|
| 434 | isplt = nn_isplt |
---|
| 435 | jsplt = nn_jsplt |
---|
| 436 | nbench = nn_bench |
---|
[2442] | 437 | ! ! Parameter control |
---|
[1593] | 438 | ! |
---|
| 439 | IF( ln_ctl ) THEN ! sub-domain area indices for the control prints |
---|
[3294] | 440 | IF( lk_mpp .AND. jpnij > 1 ) THEN |
---|
[2496] | 441 | isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain |
---|
[531] | 442 | ELSE |
---|
| 443 | IF( isplt == 1 .AND. jsplt == 1 ) THEN |
---|
[1593] | 444 | CALL ctl_warn( ' - isplt & jsplt are equal to 1', & |
---|
| 445 | & ' - the print control will be done over the whole domain' ) |
---|
[531] | 446 | ENDIF |
---|
[1593] | 447 | ijsplt = isplt * jsplt ! total number of processors ijsplt |
---|
[531] | 448 | ENDIF |
---|
| 449 | IF(lwp) WRITE(numout,*)' - The total number of processors over which the' |
---|
| 450 | IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt |
---|
[1593] | 451 | ! |
---|
| 452 | ! ! indices used for the SUM control |
---|
| 453 | IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area |
---|
| 454 | lsp_area = .FALSE. |
---|
| 455 | ELSE ! print control done over a specific area |
---|
[531] | 456 | lsp_area = .TRUE. |
---|
| 457 | IF( nictls < 1 .OR. nictls > jpiglo ) THEN |
---|
| 458 | CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' ) |
---|
| 459 | nictls = 1 |
---|
| 460 | ENDIF |
---|
| 461 | IF( nictle < 1 .OR. nictle > jpiglo ) THEN |
---|
| 462 | CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' ) |
---|
| 463 | nictle = jpiglo |
---|
| 464 | ENDIF |
---|
| 465 | IF( njctls < 1 .OR. njctls > jpjglo ) THEN |
---|
| 466 | CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' ) |
---|
| 467 | njctls = 1 |
---|
| 468 | ENDIF |
---|
| 469 | IF( njctle < 1 .OR. njctle > jpjglo ) THEN |
---|
| 470 | CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' ) |
---|
| 471 | njctle = jpjglo |
---|
| 472 | ENDIF |
---|
[1593] | 473 | ENDIF |
---|
| 474 | ENDIF |
---|
[2442] | 475 | ! |
---|
| 476 | IF( nbench == 1 ) THEN ! Benchmark |
---|
[531] | 477 | SELECT CASE ( cp_cfg ) |
---|
[1593] | 478 | CASE ( 'gyre' ) ; CALL ctl_warn( ' The Benchmark is activated ' ) |
---|
| 479 | CASE DEFAULT ; CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:', & |
---|
| 480 | & ' key_gyre must be used or set nbench = 0' ) |
---|
[531] | 481 | END SELECT |
---|
| 482 | ENDIF |
---|
[1593] | 483 | ! |
---|
[2496] | 484 | IF( lk_c1d .AND. .NOT.lk_iomput ) CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ', & |
---|
| 485 | & 'with the IOM Input/Output manager. ' , & |
---|
[2442] | 486 | & 'Compile with key_iomput enabled' ) |
---|
[2409] | 487 | ! |
---|
[2496] | 488 | END SUBROUTINE nemo_ctl |
---|
[467] | 489 | |
---|
| 490 | |
---|
[2496] | 491 | SUBROUTINE nemo_closefile |
---|
[467] | 492 | !!---------------------------------------------------------------------- |
---|
[2496] | 493 | !! *** ROUTINE nemo_closefile *** |
---|
[467] | 494 | !! |
---|
| 495 | !! ** Purpose : Close the files |
---|
| 496 | !!---------------------------------------------------------------------- |
---|
[1593] | 497 | ! |
---|
| 498 | IF( lk_mpp ) CALL mppsync |
---|
| 499 | ! |
---|
[1685] | 500 | CALL iom_close ! close all input/output files managed by iom_* |
---|
[1593] | 501 | ! |
---|
[3294] | 502 | IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file |
---|
| 503 | IF( numsol /= -1 ) CLOSE( numsol ) ! solver file |
---|
| 504 | IF( numnam /= -1 ) CLOSE( numnam ) ! oce namelist |
---|
| 505 | IF( numnam_ice /= -1 ) CLOSE( numnam_ice ) ! ice namelist |
---|
| 506 | IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution) |
---|
| 507 | IF( numout /= 6 ) CLOSE( numout ) ! standard model output file |
---|
| 508 | IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports |
---|
| 509 | IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports |
---|
| 510 | IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports |
---|
| 511 | |
---|
[1593] | 512 | ! |
---|
[2442] | 513 | numout = 6 ! redefine numout in case it is used after this point... |
---|
| 514 | ! |
---|
[2496] | 515 | END SUBROUTINE nemo_closefile |
---|
[467] | 516 | |
---|
[2715] | 517 | |
---|
| 518 | SUBROUTINE nemo_alloc |
---|
| 519 | !!---------------------------------------------------------------------- |
---|
| 520 | !! *** ROUTINE nemo_alloc *** |
---|
| 521 | !! |
---|
| 522 | !! ** Purpose : Allocate all the dynamic arrays of the OPA modules |
---|
| 523 | !! |
---|
| 524 | !! ** Method : |
---|
| 525 | !!---------------------------------------------------------------------- |
---|
| 526 | USE diawri , ONLY: dia_wri_alloc |
---|
| 527 | USE dom_oce , ONLY: dom_oce_alloc |
---|
| 528 | USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc |
---|
| 529 | USE ldftra_oce, ONLY: ldftra_oce_alloc |
---|
| 530 | USE trc_oce , ONLY: trc_oce_alloc |
---|
[3680] | 531 | #if defined key_diadct |
---|
| 532 | USE diadct , ONLY: diadct_alloc |
---|
| 533 | #endif |
---|
[2715] | 534 | ! |
---|
| 535 | INTEGER :: ierr |
---|
| 536 | !!---------------------------------------------------------------------- |
---|
| 537 | ! |
---|
| 538 | ierr = oce_alloc () ! ocean |
---|
| 539 | ierr = ierr + dia_wri_alloc () |
---|
| 540 | ierr = ierr + dom_oce_alloc () ! ocean domain |
---|
| 541 | ierr = ierr + ldfdyn_oce_alloc() ! ocean lateral physics : dynamics |
---|
| 542 | ierr = ierr + ldftra_oce_alloc() ! ocean lateral physics : tracers |
---|
| 543 | ierr = ierr + zdf_oce_alloc () ! ocean vertical physics |
---|
| 544 | ! |
---|
| 545 | ierr = ierr + lib_mpp_alloc (numout) ! mpp exchanges |
---|
| 546 | ierr = ierr + trc_oce_alloc () ! shared TRC / TRA arrays |
---|
| 547 | ! |
---|
[3680] | 548 | #if defined key_diadct |
---|
| 549 | ierr = ierr + diadct_alloc () ! |
---|
| 550 | #endif |
---|
| 551 | ! |
---|
[2715] | 552 | IF( lk_mpp ) CALL mpp_sum( ierr ) |
---|
| 553 | IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' ) |
---|
| 554 | ! |
---|
| 555 | END SUBROUTINE nemo_alloc |
---|
| 556 | |
---|
| 557 | |
---|
| 558 | SUBROUTINE nemo_partition( num_pes ) |
---|
| 559 | !!---------------------------------------------------------------------- |
---|
| 560 | !! *** ROUTINE nemo_partition *** |
---|
| 561 | !! |
---|
| 562 | !! ** Purpose : |
---|
| 563 | !! |
---|
| 564 | !! ** Method : |
---|
| 565 | !!---------------------------------------------------------------------- |
---|
| 566 | INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have |
---|
| 567 | ! |
---|
| 568 | INTEGER, PARAMETER :: nfactmax = 20 |
---|
| 569 | INTEGER :: nfact ! The no. of factors returned |
---|
| 570 | INTEGER :: ierr ! Error flag |
---|
| 571 | INTEGER :: ji |
---|
| 572 | INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value |
---|
| 573 | INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors |
---|
| 574 | !!---------------------------------------------------------------------- |
---|
| 575 | |
---|
| 576 | ierr = 0 |
---|
| 577 | |
---|
| 578 | CALL factorise( ifact, nfactmax, nfact, num_pes, ierr ) |
---|
| 579 | |
---|
| 580 | IF( nfact <= 1 ) THEN |
---|
| 581 | WRITE (numout, *) 'WARNING: factorisation of number of PEs failed' |
---|
| 582 | WRITE (numout, *) ' : using grid of ',num_pes,' x 1' |
---|
| 583 | jpnj = 1 |
---|
| 584 | jpni = num_pes |
---|
| 585 | ELSE |
---|
| 586 | ! Search through factors for the pair that are closest in value |
---|
| 587 | mindiff = 1000000 |
---|
| 588 | imin = 1 |
---|
| 589 | DO ji = 1, nfact-1, 2 |
---|
| 590 | idiff = ABS( ifact(ji) - ifact(ji+1) ) |
---|
| 591 | IF( idiff < mindiff ) THEN |
---|
| 592 | mindiff = idiff |
---|
| 593 | imin = ji |
---|
| 594 | ENDIF |
---|
| 595 | END DO |
---|
| 596 | jpnj = ifact(imin) |
---|
| 597 | jpni = ifact(imin + 1) |
---|
| 598 | ENDIF |
---|
| 599 | ! |
---|
| 600 | jpnij = jpni*jpnj |
---|
| 601 | ! |
---|
| 602 | END SUBROUTINE nemo_partition |
---|
| 603 | |
---|
| 604 | |
---|
| 605 | SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr ) |
---|
| 606 | !!---------------------------------------------------------------------- |
---|
| 607 | !! *** ROUTINE factorise *** |
---|
| 608 | !! |
---|
| 609 | !! ** Purpose : return the prime factors of n. |
---|
| 610 | !! knfax factors are returned in array kfax which is of |
---|
| 611 | !! maximum dimension kmaxfax. |
---|
| 612 | !! ** Method : |
---|
| 613 | !!---------------------------------------------------------------------- |
---|
| 614 | INTEGER , INTENT(in ) :: kn, kmaxfax |
---|
| 615 | INTEGER , INTENT( out) :: kerr, knfax |
---|
| 616 | INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax |
---|
| 617 | ! |
---|
| 618 | INTEGER :: ifac, jl, inu |
---|
| 619 | INTEGER, PARAMETER :: ntest = 14 |
---|
| 620 | INTEGER :: ilfax(ntest) |
---|
| 621 | |
---|
| 622 | ! lfax contains the set of allowed factors. |
---|
| 623 | data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256, & |
---|
| 624 | & 128, 64, 32, 16, 8, 4, 2 / |
---|
| 625 | !!---------------------------------------------------------------------- |
---|
| 626 | |
---|
| 627 | ! Clear the error flag and initialise output vars |
---|
| 628 | kerr = 0 |
---|
| 629 | kfax = 1 |
---|
| 630 | knfax = 0 |
---|
| 631 | |
---|
| 632 | ! Find the factors of n. |
---|
| 633 | IF( kn == 1 ) GOTO 20 |
---|
| 634 | |
---|
| 635 | ! nu holds the unfactorised part of the number. |
---|
| 636 | ! knfax holds the number of factors found. |
---|
| 637 | ! l points to the allowed factor list. |
---|
| 638 | ! ifac holds the current factor. |
---|
| 639 | |
---|
| 640 | inu = kn |
---|
| 641 | knfax = 0 |
---|
| 642 | |
---|
| 643 | DO jl = ntest, 1, -1 |
---|
| 644 | ! |
---|
| 645 | ifac = ilfax(jl) |
---|
| 646 | IF( ifac > inu ) CYCLE |
---|
| 647 | |
---|
| 648 | ! Test whether the factor will divide. |
---|
| 649 | |
---|
| 650 | IF( MOD(inu,ifac) == 0 ) THEN |
---|
| 651 | ! |
---|
| 652 | knfax = knfax + 1 ! Add the factor to the list |
---|
| 653 | IF( knfax > kmaxfax ) THEN |
---|
| 654 | kerr = 6 |
---|
| 655 | write (*,*) 'FACTOR: insufficient space in factor array ', knfax |
---|
| 656 | return |
---|
| 657 | ENDIF |
---|
| 658 | kfax(knfax) = ifac |
---|
| 659 | ! Store the other factor that goes with this one |
---|
| 660 | knfax = knfax + 1 |
---|
| 661 | kfax(knfax) = inu / ifac |
---|
| 662 | !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax) |
---|
| 663 | ENDIF |
---|
| 664 | ! |
---|
| 665 | END DO |
---|
| 666 | |
---|
| 667 | 20 CONTINUE ! Label 20 is the exit point from the factor search loop. |
---|
| 668 | ! |
---|
| 669 | END SUBROUTINE factorise |
---|
| 670 | |
---|
[3294] | 671 | #if defined key_mpp_mpi |
---|
| 672 | SUBROUTINE nemo_northcomms |
---|
| 673 | !!====================================================================== |
---|
| 674 | !! *** ROUTINE nemo_northcomms *** |
---|
| 675 | !! nemo_northcomms : Setup for north fold exchanges with explicit peer to peer messaging |
---|
| 676 | !!===================================================================== |
---|
| 677 | !!---------------------------------------------------------------------- |
---|
| 678 | !! |
---|
| 679 | !! ** Purpose : Initialization of the northern neighbours lists. |
---|
| 680 | !!---------------------------------------------------------------------- |
---|
| 681 | !! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE) |
---|
| 682 | !!---------------------------------------------------------------------- |
---|
| 683 | |
---|
| 684 | INTEGER :: ji, jj, jk, ij, jtyp ! dummy loop indices |
---|
| 685 | INTEGER :: ijpj ! number of rows involved in north-fold exchange |
---|
| 686 | INTEGER :: northcomms_alloc ! allocate return status |
---|
| 687 | REAL(wp), ALLOCATABLE, DIMENSION ( :,: ) :: znnbrs ! workspace |
---|
| 688 | LOGICAL, ALLOCATABLE, DIMENSION ( : ) :: lrankset ! workspace |
---|
| 689 | |
---|
| 690 | IF(lwp) WRITE(numout,*) |
---|
| 691 | IF(lwp) WRITE(numout,*) 'nemo_northcomms : Initialization of the northern neighbours lists' |
---|
| 692 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~' |
---|
| 693 | |
---|
| 694 | !!---------------------------------------------------------------------- |
---|
| 695 | ALLOCATE( znnbrs(jpi,jpj), stat = northcomms_alloc ) |
---|
| 696 | ALLOCATE( lrankset(jpnij), stat = northcomms_alloc ) |
---|
| 697 | IF( northcomms_alloc /= 0 ) THEN |
---|
| 698 | WRITE(numout,cform_war) |
---|
| 699 | WRITE(numout,*) 'northcomms_alloc : failed to allocate arrays' |
---|
| 700 | CALL ctl_stop( 'STOP', 'nemo_northcomms : unable to allocate temporary arrays' ) |
---|
| 701 | ENDIF |
---|
| 702 | nsndto = 0 |
---|
| 703 | isendto = -1 |
---|
| 704 | ijpj = 4 |
---|
| 705 | ! |
---|
| 706 | ! This routine has been called because ln_nnogather has been set true ( nammpp ) |
---|
| 707 | ! However, these first few exchanges have to use the mpi_allgather method to |
---|
| 708 | ! establish the neighbour lists to use in subsequent peer to peer exchanges. |
---|
| 709 | ! Consequently, set l_north_nogather to be false here and set it true only after |
---|
| 710 | ! the lists have been established. |
---|
| 711 | ! |
---|
| 712 | l_north_nogather = .FALSE. |
---|
| 713 | ! |
---|
| 714 | ! Exchange and store ranks on northern rows |
---|
| 715 | |
---|
| 716 | DO jtyp = 1,4 |
---|
| 717 | |
---|
| 718 | lrankset = .FALSE. |
---|
| 719 | znnbrs = narea |
---|
| 720 | SELECT CASE (jtyp) |
---|
| 721 | CASE(1) |
---|
| 722 | CALL lbc_lnk( znnbrs, 'T', 1. ) ! Type 1: T,W-points |
---|
| 723 | CASE(2) |
---|
| 724 | CALL lbc_lnk( znnbrs, 'U', 1. ) ! Type 2: U-point |
---|
| 725 | CASE(3) |
---|
| 726 | CALL lbc_lnk( znnbrs, 'V', 1. ) ! Type 3: V-point |
---|
| 727 | CASE(4) |
---|
| 728 | CALL lbc_lnk( znnbrs, 'F', 1. ) ! Type 4: F-point |
---|
| 729 | END SELECT |
---|
| 730 | |
---|
| 731 | IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN |
---|
| 732 | DO jj = nlcj-ijpj+1, nlcj |
---|
| 733 | ij = jj - nlcj + ijpj |
---|
| 734 | DO ji = 1,jpi |
---|
| 735 | IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) & |
---|
| 736 | & lrankset(INT(znnbrs(ji,jj))) = .true. |
---|
| 737 | END DO |
---|
| 738 | END DO |
---|
| 739 | |
---|
| 740 | DO jj = 1,jpnij |
---|
| 741 | IF ( lrankset(jj) ) THEN |
---|
| 742 | nsndto(jtyp) = nsndto(jtyp) + 1 |
---|
| 743 | IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN |
---|
| 744 | CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', & |
---|
| 745 | & ' jpmaxngh will need to be increased ') |
---|
| 746 | ENDIF |
---|
| 747 | isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank |
---|
| 748 | ENDIF |
---|
| 749 | END DO |
---|
| 750 | ENDIF |
---|
| 751 | |
---|
| 752 | END DO |
---|
| 753 | |
---|
| 754 | ! |
---|
| 755 | ! Type 5: I-point |
---|
| 756 | ! |
---|
| 757 | ! ICE point exchanges may involve some averaging. The neighbours list is |
---|
| 758 | ! built up using two exchanges to ensure that the whole stencil is covered. |
---|
| 759 | ! lrankset should not be reset between these 'J' and 'K' point exchanges |
---|
| 760 | |
---|
| 761 | jtyp = 5 |
---|
| 762 | lrankset = .FALSE. |
---|
| 763 | znnbrs = narea |
---|
| 764 | CALL lbc_lnk( znnbrs, 'J', 1. ) ! first ice U-V point |
---|
| 765 | |
---|
| 766 | IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN |
---|
| 767 | DO jj = nlcj-ijpj+1, nlcj |
---|
| 768 | ij = jj - nlcj + ijpj |
---|
| 769 | DO ji = 1,jpi |
---|
| 770 | IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) & |
---|
| 771 | & lrankset(INT(znnbrs(ji,jj))) = .true. |
---|
| 772 | END DO |
---|
| 773 | END DO |
---|
| 774 | ENDIF |
---|
| 775 | |
---|
| 776 | znnbrs = narea |
---|
| 777 | CALL lbc_lnk( znnbrs, 'K', 1. ) ! second ice U-V point |
---|
| 778 | |
---|
| 779 | IF ( njmppt(narea) .EQ. MAXVAL( njmppt )) THEN |
---|
| 780 | DO jj = nlcj-ijpj+1, nlcj |
---|
| 781 | ij = jj - nlcj + ijpj |
---|
| 782 | DO ji = 1,jpi |
---|
| 783 | IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) & |
---|
| 784 | & lrankset( INT(znnbrs(ji,jj))) = .true. |
---|
| 785 | END DO |
---|
| 786 | END DO |
---|
| 787 | |
---|
| 788 | DO jj = 1,jpnij |
---|
| 789 | IF ( lrankset(jj) ) THEN |
---|
| 790 | nsndto(jtyp) = nsndto(jtyp) + 1 |
---|
| 791 | IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN |
---|
| 792 | CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', & |
---|
| 793 | & ' jpmaxngh will need to be increased ') |
---|
| 794 | ENDIF |
---|
| 795 | isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank |
---|
| 796 | ENDIF |
---|
| 797 | END DO |
---|
| 798 | ! |
---|
| 799 | ! For northern row areas, set l_north_nogather so that all subsequent exchanges |
---|
| 800 | ! can use peer to peer communications at the north fold |
---|
| 801 | ! |
---|
| 802 | l_north_nogather = .TRUE. |
---|
| 803 | ! |
---|
| 804 | ENDIF |
---|
| 805 | DEALLOCATE( znnbrs ) |
---|
| 806 | DEALLOCATE( lrankset ) |
---|
| 807 | |
---|
| 808 | END SUBROUTINE nemo_northcomms |
---|
| 809 | #else |
---|
| 810 | SUBROUTINE nemo_northcomms ! Dummy routine |
---|
| 811 | WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?' |
---|
| 812 | END SUBROUTINE nemo_northcomms |
---|
| 813 | #endif |
---|
[3] | 814 | !!====================================================================== |
---|
[2496] | 815 | END MODULE nemogcm |
---|