New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
step.F90 in branches/2012/dev_MERGE_2012/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/2012/dev_MERGE_2012/NEMOGCM/NEMO/OPA_SRC/step.F90 @ 3680

Last change on this file since 3680 was 3680, checked in by rblod, 11 years ago

First commit of the final branch for 2012 (future nemo_3_5), see ticket #1028
  • Property svn:keywords set to Id
File size: 16.5 KB
Line 
1MODULE step
2   !!======================================================================
3   !!                       ***  MODULE step  ***
4   !! Time-stepping    : manager of the ocean, tracer and ice time stepping
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (G. Madec)  Original code
7   !!             -   !  1991-11  (G. Madec)
8   !!             -   !  1992-06  (M. Imbard)  add a first output record
9   !!             -   !  1996-04  (G. Madec)  introduction of dynspg
10   !!             -   !  1996-04  (M.A. Foujols)  introduction of passive tracer
11   !!            8.0  !  1997-06  (G. Madec)  new architecture of call
12   !!            8.2  !  1997-06  (G. Madec, M. Imbard, G. Roullet)  free surface
13   !!             -   !  1999-02  (G. Madec, N. Grima)  hpg implicit
14   !!             -   !  2000-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
15   !!   NEMO     1.0  !  2002-06  (G. Madec)  free form, suppress macro-tasking
16   !!             -   !  2004-08  (C. Talandier) New trends organization
17   !!             -   !  2005-01  (C. Ethe) Add the KPP closure scheme
18   !!             -   !  2005-11  (G. Madec)  Reorganisation of tra and dyn calls
19   !!             -   !  2006-01  (L. Debreu, C. Mazauric)  Agrif implementation
20   !!             -   !  2006-07  (S. Masson)  restart using iom
21   !!            3.2  !  2009-02  (G. Madec, R. Benshila)  reintroduicing z*-coordinate
22   !!             -   !  2009-06  (S. Masson, G. Madec)  TKE restart compatible with key_cpl
23   !!            3.3  !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
24   !!             -   !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
25   !!            3.4  !  2011-04  (G. Madec, C. Ethe) Merge of dtatem and dtasal
26   !!----------------------------------------------------------------------
27
28   !!----------------------------------------------------------------------
29   !!   stp             : OPA system time-stepping
30   !!----------------------------------------------------------------------
31   USE step_oce         ! time stepping definition modules
32#if defined key_top
33   USE trcstp           ! passive tracer time-stepping      (trc_stp routine)
34#endif
35#if defined key_agrif
36   USE agrif_opa_sponge ! Momemtum and tracers sponges
37#endif
38   USE restart          ! restart
39
40   IMPLICIT NONE
41   PRIVATE
42
43   PUBLIC   stp   ! called by opa.F90
44
45   !! * Substitutions
46#  include "domzgr_substitute.h90"
47#  include "zdfddm_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
50   !! $Id$
51   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55#if defined key_agrif
56   SUBROUTINE stp( )
57      INTEGER             ::   kstp   ! ocean time-step index
58#else
59   SUBROUTINE stp( kstp )
60      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
61#endif
62      !!----------------------------------------------------------------------
63      !!                     ***  ROUTINE stp  ***
64      !!                     
65      !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.)
66      !!              - Time stepping of LIM (dynamic and thermodynamic eqs.)
67      !!              - Tme stepping  of TRC (passive tracer eqs.)
68      !!
69      !! ** Method  : -1- Update forcings and data 
70      !!              -2- Update ocean physics
71      !!              -3- Compute the t and s trends
72      !!              -4- Update t and s
73      !!              -5- Compute the momentum trends
74      !!              -6- Update the horizontal velocity
75      !!              -7- Compute the diagnostics variables (rd,N2, div,cur,w)
76      !!              -8- Outputs and diagnostics
77      !!----------------------------------------------------------------------
78      INTEGER ::   jk       ! dummy loop indice
79      INTEGER ::   indic    ! error indicator if < 0
80      !! ---------------------------------------------------------------------
81
82#if defined key_agrif
83      kstp = nit000 + Agrif_Nb_Step()
84!      IF ( Agrif_Root() .and. lwp) Write(*,*) '---'
85!      IF (lwp) Write(*,*) 'Grid Number',Agrif_Fixed(),' time step ',kstp
86# if defined key_iomput
87      IF( Agrif_Nbstepint() == 0 )   CALL iom_swap
88# endif   
89#endif   
90                             indic = 0                ! reset to no error condition
91      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
92                             CALL iom_setkt( kstp )   ! say to iom that we are at time step kstp
93
94      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
95      ! Update data, open boundaries, surface boundary condition (including sea-ice)
96      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
97                         CALL sbc    ( kstp )         ! Sea Boundary Condition (including sea-ice)
98      IF( lk_tide.AND.(kstp /= nit000 ))   CALL tide_init ( kstp )
99      IF( lk_tide    )   CALL sbc_tide( kstp )
100      IF( lk_obc     )   CALL obc_dta( kstp )         ! update dynamic and tracer data at open boundaries
101      IF( lk_obc     )   CALL obc_rad( kstp )         ! compute phase velocities at open boundaries
102      IF( lk_bdy     )   CALL bdy_dta( kstp, time_offset=+1 ) ! update dynamic and tracer data at open boundaries
103
104      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
105      !  Ocean dynamics : ssh, wn, hdiv, rot                                 !
106      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
107                         CALL ssh_wzv( kstp )         ! after ssh & vertical velocity
108
109      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
110      ! Ocean physics update                (ua, va, tsa used as workspace)
111      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
112                         CALL bn2( tsb, rn2b )        ! before Brunt-Vaisala frequency
113                         CALL bn2( tsn, rn2  )        ! now    Brunt-Vaisala frequency
114      !
115      !  VERTICAL PHYSICS   
116                         CALL zdf_bfr( kstp )         ! bottom friction
117                         
118      !                                               ! Vertical eddy viscosity and diffusivity coefficients
119      IF( lk_zdfric  )   CALL zdf_ric( kstp )            ! Richardson number dependent Kz
120      IF( lk_zdftke  )   CALL zdf_tke( kstp )            ! TKE closure scheme for Kz
121      IF( lk_zdfgls  )   CALL zdf_gls( kstp )            ! GLS closure scheme for Kz
122      IF( lk_zdfkpp  )   CALL zdf_kpp( kstp )            ! KPP closure scheme for Kz
123      IF( lk_zdfcst  )   THEN                            ! Constant Kz (reset avt, avm[uv] to the background value)
124         avt (:,:,:) = rn_avt0 * tmask(:,:,:)
125         avmu(:,:,:) = rn_avm0 * umask(:,:,:)
126         avmv(:,:,:) = rn_avm0 * vmask(:,:,:)
127      ENDIF
128      IF( ln_rnf_mouth ) THEN                         ! increase diffusivity at rivers mouths
129         DO jk = 2, nkrnf   ;   avt(:,:,jk) = avt(:,:,jk) + 2.e0 * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk)   ;   END DO
130      ENDIF
131      IF( ln_zdfevd  )   CALL zdf_evd( kstp )         ! enhanced vertical eddy diffusivity
132
133      IF( lk_zdftmx  )   CALL zdf_tmx( kstp )         ! tidal vertical mixing
134
135      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
136         &               CALL zdf_ddm( kstp )         ! double diffusive mixing
137         
138                         CALL zdf_mxl( kstp )         ! mixed layer depth
139
140                                                      ! write TKE or GLS information in the restart file
141      IF( lrst_oce .AND. lk_zdftke )   CALL tke_rst( kstp, 'WRITE' )
142      IF( lrst_oce .AND. lk_zdfgls )   CALL gls_rst( kstp, 'WRITE' )
143      !
144      !  LATERAL  PHYSICS
145      !
146      IF( lk_ldfslp ) THEN                            ! slope of lateral mixing
147                         CALL eos( tsb, rhd )                ! before in situ density
148         IF( ln_zps )    CALL zps_hde( kstp, jpts, tsb, gtsu, gtsv,  &    ! Partial steps: before horizontal gradient
149            &                                      rhd, gru , grv  )      ! of t, s, rd at the last ocean level
150         IF( ln_traldf_grif ) THEN                           ! before slope for Griffies operator
151                         CALL ldf_slp_grif( kstp )
152         ELSE
153                         CALL ldf_slp( kstp, rhd, rn2b )     ! before slope for Madec operator
154         ENDIF
155      ENDIF
156#if defined key_traldf_c2d
157      IF( lk_traldf_eiv )   CALL ldf_eiv( kstp )      ! eddy induced velocity coefficient
158#endif
159#if defined key_traldf_c3d && key_traldf_smag
160                          CALL ldf_tra_smag( kstp )      ! eddy induced velocity coefficient
161#  endif
162#if defined key_dynldf_c3d && key_dynldf_smag
163                          CALL ldf_dyn_smag( kstp )      ! eddy induced velocity coefficient
164#  endif
165
166
167      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
168      ! diagnostics and outputs             (ua, va, tsa used as workspace)
169      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
170      IF( lk_floats  )   CALL flo_stp( kstp )         ! drifting Floats
171      IF( lk_diahth  )   CALL dia_hth( kstp )         ! Thermocline depth (20 degres isotherm depth)
172      IF( lk_diafwb  )   CALL dia_fwb( kstp )         ! Fresh water budget diagnostics
173      IF( ln_diaptr  )   CALL dia_ptr( kstp )         ! Poleward TRansports diagnostics
174      IF( lk_diadct  )   CALL dia_dct( kstp )         ! Transports
175      IF( lk_diaar5  )   CALL dia_ar5( kstp )         ! ar5 diag
176      IF( lk_diaharm )   CALL dia_harm( kstp )        ! Tidal harmonic analysis
177                         CALL dia_wri( kstp )         ! ocean model: outputs
178
179#if defined key_top
180      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
181      ! Passive Tracer Model
182      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
183                         CALL trc_stp( kstp )         ! time-stepping
184#endif
185
186      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
187      ! Active tracers                              (ua, va used as workspace)
188      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
189                             tsa(:,:,:,:) = 0.e0            ! set tracer trends to zero
190
191      IF(  ln_asmiau .AND. &
192         & ln_trainc     )   CALL tra_asm_inc( kstp )       ! apply tracer assimilation increment
193                             CALL tra_sbc    ( kstp )       ! surface boundary condition
194      IF( ln_traqsr      )   CALL tra_qsr    ( kstp )       ! penetrative solar radiation qsr
195      IF( ln_trabbc      )   CALL tra_bbc    ( kstp )       ! bottom heat flux
196      IF( lk_trabbl      )   CALL tra_bbl    ( kstp )       ! advective (and/or diffusive) bottom boundary layer scheme
197      IF( ln_tradmp      )   CALL tra_dmp    ( kstp )       ! internal damping trends
198      IF( lk_bdy         )   CALL bdy_tra_dmp( kstp )       ! bdy damping trends
199                             CALL tra_adv    ( kstp )       ! horizontal & vertical advection
200      IF( lk_zdfkpp      )   CALL tra_kpp    ( kstp )       ! KPP non-local tracer fluxes
201                             CALL tra_ldf    ( kstp )       ! lateral mixing
202#if defined key_agrif
203      IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_tra          ! tracers sponge
204#endif
205                             CALL tra_zdf    ( kstp )       ! vertical mixing and after tracer fields
206
207      IF( ln_dynhpg_imp  ) THEN                             ! semi-implicit hpg (time stepping then eos)
208         IF( ln_zdfnpc   )   CALL tra_npc( kstp )                ! update after fields by non-penetrative convection
209                             CALL tra_nxt( kstp )                ! tracer fields at next time step
210                             CALL eos    ( tsa, rhd, rhop )      ! Time-filtered in situ density for hpg computation
211         IF( ln_zps      )   CALL zps_hde( kstp, jpts, tsa, gtsu, gtsv,  &    ! zps: time filtered hor. derivative
212            &                                          rhd, gru , grv  )      ! of t, s, rd at the last ocean level
213         
214      ELSE                                                  ! centered hpg  (eos then time stepping)
215                             CALL eos    ( tsn, rhd, rhop )      ! now in situ density for hpg computation
216         IF( ln_zps      )   CALL zps_hde( kstp, jpts, tsn, gtsu, gtsv,  &    ! zps: now hor. derivative
217            &                                          rhd, gru , grv  )      ! of t, s, rd at the last ocean level
218         IF( ln_zdfnpc   )   CALL tra_npc( kstp )                ! update after fields by non-penetrative convection
219                             CALL tra_nxt( kstp )                ! tracer fields at next time step
220      ENDIF 
221
222      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
223      ! Dynamics                                    (tsa used as workspace)
224      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
225                               ua(:,:,:) = 0.e0             ! set dynamics trends to zero
226                               va(:,:,:) = 0.e0
227
228      IF(  ln_asmiau .AND. &
229         & ln_dyninc       )   CALL dyn_asm_inc( kstp )     ! apply dynamics assimilation increment
230      IF( ln_neptsimp )        CALL dyn_nept_cor( kstp )    ! subtract Neptune velocities (simplified)
231      IF( lk_bdy           )   CALL bdy_dyn3d_dmp(kstp )    ! bdy damping trends
232                               CALL dyn_adv( kstp )         ! advection (vector or flux form)
233                               CALL dyn_vor( kstp )         ! vorticity term including Coriolis
234                               CALL dyn_ldf( kstp )         ! lateral mixing
235      IF( ln_neptsimp )        CALL dyn_nept_cor( kstp )    ! add Neptune velocities (simplified)
236#if defined key_agrif
237      IF(.NOT. Agrif_Root())   CALL Agrif_Sponge_dyn        ! momemtum sponge
238#endif
239                               CALL dyn_hpg( kstp )         ! horizontal gradient of Hydrostatic pressure
240                               CALL dyn_bfr( kstp )         ! bottom friction   
241                               CALL dyn_zdf( kstp )         ! vertical diffusion
242                               CALL dyn_spg( kstp, indic )  ! surface pressure gradient
243                               CALL dyn_nxt( kstp )         ! lateral velocity at next time step
244
245                               CALL ssh_nxt( kstp )         ! sea surface height at next time step
246
247      IF( ln_diahsb        )   CALL dia_hsb( kstp )         ! - ML - global conservation diagnostics
248      IF( lk_diaobs  )         CALL dia_obs( kstp )         ! obs-minus-model (assimilation) diagnostics (call after dynamics update)
249
250      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
251      ! Control and restarts
252      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
253                               CALL stp_ctl( kstp, indic )
254      IF( indic < 0        )   THEN
255                               CALL ctl_stop( 'step: indic < 0' )
256                               CALL dia_wri_state( 'output.abort', kstp )
257      ENDIF
258      IF( kstp == nit000   )   CALL iom_close( numror )     ! close input  ocean restart file
259      IF( lrst_oce         )   CALL rst_write    ( kstp )   ! write output ocean restart file
260      IF( lk_obc           )   CALL obc_rst_write( kstp )   ! write open boundary restart file
261
262      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
263      ! Trends                              (ua, va, tsa used as workspace)
264      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
265      IF( nstop == 0 ) THEN                         
266         IF( lk_trddyn     )   CALL trd_dwr( kstp )         ! trends: dynamics
267         IF( lk_trdtra     )   CALL trd_twr( kstp )         ! trends: active tracers
268         IF( lk_trdmld     )   CALL trd_mld( kstp )         ! trends: Mixed-layer
269         IF( lk_trdvor     )   CALL trd_vor( kstp )         ! trends: vorticity budget
270      ENDIF
271
272      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
273      ! Coupled mode
274      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
275      IF( lk_cpl           )   CALL sbc_cpl_snd( kstp )     ! coupled mode : field exchanges
276      !
277      IF( nn_timing == 1 .AND.  kstp == nit000  )   CALL timing_reset
278      !
279   END SUBROUTINE stp
280
281   !!======================================================================
282END MODULE step
Note: See TracBrowser for help on using the repository browser.