New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in branches/2012/dev_MERGE_2012/NEMOGCM/NEMO/SAS_SRC – NEMO

Context Navigation

source: branches/2012/dev_MERGE_2012/NEMOGCM/NEMO/SAS_SRC/nemogcm.F90 @ 3769

Last change on this file since 3769 was 3769, checked in by smasson, 11 years ago
dev_MERGE_2012: xios+agrif+oasis compliant
File size: 28.1 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) LIM sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!! 3.4 ! 2011-11 (C. Harris) decomposition changes for running with CICE
31	!!----------------------------------------------------------------------
32
33	!!----------------------------------------------------------------------
34	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
35	!! nemo_init : initialization of the NEMO system
36	!! nemo_ctl : initialisation of the contol print
37	!! nemo_closefile : close remaining open files
38	!! nemo_alloc : dynamical allocation
39	!! nemo_partition : calculate MPP domain decomposition
40	!! factorise : calculate the factors of the no. of MPI processes
41	!!----------------------------------------------------------------------
42	USE step_oce ! module used in the ocean time stepping module
43	USE sbc_oce ! surface boundary condition: ocean
44	USE cla ! cross land advection (tra_cla routine)
45	USE domcfg ! domain configuration (dom_cfg routine)
46	USE daymod ! calendar
47	USE mppini ! shared/distributed memory setting (mpp_init routine)
48	USE domain ! domain initialization (dom_init routine)
49	USE phycst ! physical constant (par_cst routine)
50	USE step ! NEMO time-stepping (stp routine)
51	USE lib_mpp ! distributed memory computing
52	#if defined key_iomput
53	USE xios
54	#endif
55	USE sbcssm
56
57	IMPLICIT NONE
58	PRIVATE
59
60	PUBLIC nemo_gcm ! called by model.F90
61	PUBLIC nemo_init ! needed by AGRIF
62
63	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
64
65	!!----------------------------------------------------------------------
66	!! NEMO/OPA 4.0 , NEMO Consortium (2011)
67	!! $Id: nemogcm.F90 3294 2012-01-28 16:44:18Z rblod $
68	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
69	!!----------------------------------------------------------------------
70	CONTAINS
71
72	SUBROUTINE nemo_gcm
73	!!----------------------------------------------------------------------
74	!! * ROUTINE nemo_gcm *
75	!!
76	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
77	!! curvilinear mesh on the sphere.
78	!!
79	!! ** Method : - model general initialization
80	!! - launch the time-stepping (stp routine)
81	!! - finalize the run by closing files and communications
82	!!
83	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
84	!! Madec, 2008, internal report, IPSL.
85	!!----------------------------------------------------------------------
86	INTEGER :: istp ! time step index
87	!!----------------------------------------------------------------------
88	!
89	#if defined key_agrif
90	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
91	#endif
92
93	! !-----------------------!
94	CALL nemo_init !== Initialisations ==!
95	! !-----------------------!
96	#if defined key_agrif
97	CALL Agrif_Declare_Var ! AGRIF: set the meshes
98	#endif
99	! check that all process are still there... If some process have an error,
100	! they will never enter in step and other processes will wait until the end of the cpu time!
101	IF( lk_mpp ) CALL mpp_max( nstop )
102
103	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
104
105	! !-----------------------!
106	! !== time stepping ==!
107	! !-----------------------!
108	istp = nit000
109
110	DO WHILE ( istp <= nitend .AND. nstop == 0 )
111	#if defined key_agrif
112	CALL Agrif_Step( stp ) ! AGRIF: time stepping
113	#else
114	CALL stp( istp ) ! standard time stepping
115	#endif
116	istp = istp + 1
117	IF( lk_mpp ) CALL mpp_max( nstop )
118	END DO
119	! !------------------------!
120	! !== finalize the run ==!
121	! !------------------------!
122	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
123	!
124	IF( nstop /= 0 .AND. lwp ) THEN ! error print
125	WRITE(numout,cform_err)
126	WRITE(numout,*) nstop, ' error have been found'
127	ENDIF
128	!
129	#if defined key_agrif
130	CALL Agrif_ParentGrid_To_ChildGrid()
131	IF( nn_timing == 1 ) CALL timing_finalize
132	CALL Agrif_ChildGrid_To_ParentGrid()
133	#endif
134	IF( nn_timing == 1 ) CALL timing_finalize
135	!
136	CALL nemo_closefile
137	#if defined key_iomput
138	CALL xios_finalize ! end mpp communications with xios
139	#else
140	IF( lk_mpp ) CALL mppstop ! end mpp communications
141	#endif
142	!
143	END SUBROUTINE nemo_gcm
144
145
146	SUBROUTINE nemo_init
147	!!----------------------------------------------------------------------
148	!! * ROUTINE nemo_init *
149	!!
150	!! ** Purpose : initialization of the NEMO GCM
151	!!----------------------------------------------------------------------
152	INTEGER :: ji ! dummy loop indices
153	INTEGER :: ilocal_comm ! local integer
154	CHARACTER(len=80), DIMENSION(16) :: cltxt
155	!!
156	NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, &
157	& nn_isplt, nn_jsplt, nn_jctls, nn_jctle, &
158	& nn_bench, nn_timing
159	!!----------------------------------------------------------------------
160	!
161	cltxt = ''
162	!
163	! ! open Namelist file
164	CALL ctl_opn( numnam, 'namelist', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
165	!
166	READ( numnam, namctl ) ! Namelist namctl : Control prints & Benchmark
167	!
168	! !--------------------------------------------!
169	! ! set communicator & select the local node !
170	! !--------------------------------------------!
171	#if defined key_iomput
172	IF( Agrif_Root() ) THEN
173	CALL xios_initialize( "nemo",return_comm=ilocal_comm )
174	ENDIF
175	narea = mynode( cltxt, numnam, nstop, ilocal_comm ) ! Nodes selection
176	#else
177	ilocal_comm = 0
178	narea = mynode( cltxt, numnam, nstop ) ! Nodes selection (control print return in cltxt)
179	#endif
180	narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 )
181
182	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
183
184	! If dimensions of processor grid weren't specified in the namelist file
185	! then we calculate them here now that we have our communicator size
186	IF( (jpni < 1) .OR. (jpnj < 1) )THEN
187	#if defined key_mpp_mpi
188	IF( Agrif_Root() ) CALL nemo_partition(mppsize)
189	#else
190	jpni = 1
191	jpnj = 1
192	jpnij = jpni*jpnj
193	#endif
194	END IF
195
196	! Calculate domain dimensions given calculated jpni and jpnj
197	! This used to be done in par_oce.F90 when they were parameters rather
198	! than variables
199	IF( Agrif_Root() ) THEN
200	jpi = ( jpiglo-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
201	#if defined key_nemocice_decomp
202	jpj = ( jpjglo+1-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
203	#else
204	jpj = ( jpjglo-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
205	#endif
206	jpk = jpkdta ! third dim
207	jpim1 = jpi-1 ! inner domain indices
208	jpjm1 = jpj-1 ! " "
209	jpkm1 = jpk-1 ! " "
210	jpij = jpi*jpj ! jpi x j
211	ENDIF
212
213	IF(lwp) THEN ! open listing units
214	!
215	CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
216	!
217	WRITE(numout,*)
218	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
219	WRITE(numout,*) ' NEMO team'
220	WRITE(numout,*) ' Ocean General Circulation Model'
221	WRITE(numout,*) ' version 3.4 (2011) '
222	WRITE(numout,*) ' StandAlone Surface version (SAS) '
223	WRITE(numout,*)
224	WRITE(numout,*)
225	DO ji = 1, SIZE(cltxt)
226	IF( TRIM(cltxt(ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode
227	END DO
228	WRITE(numout,cform_aaa) ! Flag AAAAAAA
229	!
230	ENDIF
231
232	! Now we know the dimensions of the grid and numout has been set we can
233	! allocate arrays
234	CALL nemo_alloc()
235
236	! !-------------------------------!
237	! ! NEMO general initialization !
238	! !-------------------------------!
239
240	CALL nemo_ctl ! Control prints & Benchmark
241
242	! ! Domain decomposition
243	IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out
244	ELSE ; CALL mpp_init2 ! eliminate land processors
245	ENDIF
246	!
247	IF( nn_timing == 1 ) CALL timing_init
248	!
249	! ! General initialization
250	CALL phy_cst ! Physical constants
251	CALL eos_init ! Equation of state
252	CALL dom_cfg ! Domain configuration
253	CALL dom_init ! Domain
254
255	IF( ln_nnogather ) CALL nemo_northcomms ! Initialise the northfold neighbour lists (must be done after the masks are defined)
256
257	IF( ln_ctl ) CALL prt_ctl_init ! Print control
258	CALL flush(numout)
259
260	CALL day_init ! model calendar (using both namelist and restart infos)
261
262	CALL sbc_init ! Forcings : surface module
263
264	IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
265	!
266	END SUBROUTINE nemo_init
267
268
269	SUBROUTINE nemo_ctl
270	!!----------------------------------------------------------------------
271	!! * ROUTINE nemo_ctl *
272	!!
273	!! ** Purpose : control print setting
274	!!
275	!! ** Method : - print namctl information and check some consistencies
276	!!----------------------------------------------------------------------
277	!
278	IF(lwp) THEN ! control print
279	WRITE(numout,*)
280	WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
281	WRITE(numout,*) '~~~~~~~ '
282	WRITE(numout,*) ' Namelist namctl'
283	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
284	WRITE(numout,*) ' level of print nn_print = ', nn_print
285	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
286	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
287	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
288	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
289	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
290	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
291	WRITE(numout,*) ' benchmark parameter (0/1) nn_bench = ', nn_bench
292	ENDIF
293	!
294	nprint = nn_print ! convert DOCTOR namelist names into OLD names
295	nictls = nn_ictls
296	nictle = nn_ictle
297	njctls = nn_jctls
298	njctle = nn_jctle
299	isplt = nn_isplt
300	jsplt = nn_jsplt
301	nbench = nn_bench
302	! ! Parameter control
303	!
304	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
305	IF( lk_mpp .AND. jpnij > 1 ) THEN
306	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
307	ELSE
308	IF( isplt == 1 .AND. jsplt == 1 ) THEN
309	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
310	& ' - the print control will be done over the whole domain' )
311	ENDIF
312	ijsplt = isplt * jsplt ! total number of processors ijsplt
313	ENDIF
314	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
315	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
316	!
317	! ! indices used for the SUM control
318	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
319	lsp_area = .FALSE.
320	ELSE ! print control done over a specific area
321	lsp_area = .TRUE.
322	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
323	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
324	nictls = 1
325	ENDIF
326	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
327	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
328	nictle = jpiglo
329	ENDIF
330	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
331	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
332	njctls = 1
333	ENDIF
334	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
335	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
336	njctle = jpjglo
337	ENDIF
338	ENDIF
339	ENDIF
340	!
341	IF( nbench == 1 ) THEN ! Benchmark
342	SELECT CASE ( cp_cfg )
343	CASE ( 'gyre' ) ; CALL ctl_warn( ' The Benchmark is activated ' )
344	CASE DEFAULT ; CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:', &
345	& ' key_gyre must be used or set nbench = 0' )
346	END SELECT
347	ENDIF
348	!
349	END SUBROUTINE nemo_ctl
350
351
352	SUBROUTINE nemo_closefile
353	!!----------------------------------------------------------------------
354	!! * ROUTINE nemo_closefile *
355	!!
356	!! ** Purpose : Close the files
357	!!----------------------------------------------------------------------
358	!
359	IF( lk_mpp ) CALL mppsync
360	!
361	CALL iom_close ! close all input/output files managed by iom_*
362	!
363	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
364	IF( numnam /= -1 ) CLOSE( numnam ) ! oce namelist
365	IF( numnam_ice /= -1 ) CLOSE( numnam_ice ) ! ice namelist
366	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
367	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
368	!
369	numout = 6 ! redefine numout in case it is used after this point...
370	!
371	END SUBROUTINE nemo_closefile
372
373
374	SUBROUTINE nemo_alloc
375	!!----------------------------------------------------------------------
376	!! * ROUTINE nemo_alloc *
377	!!
378	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
379	!!
380	!! ** Method :
381	!!----------------------------------------------------------------------
382	USE diawri , ONLY: dia_wri_alloc
383	USE dom_oce , ONLY: dom_oce_alloc
384	!
385	INTEGER :: ierr
386	!!----------------------------------------------------------------------
387	!
388	ierr = dia_wri_alloc ()
389	ierr = ierr + dom_oce_alloc () ! ocean domain
390	ierr = ierr + lib_mpp_alloc (numout) ! mpp exchanges
391	!
392	IF( lk_mpp ) CALL mpp_sum( ierr )
393	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
394	!
395	END SUBROUTINE nemo_alloc
396
397
398	SUBROUTINE nemo_partition( num_pes )
399	!!----------------------------------------------------------------------
400	!! * ROUTINE nemo_partition *
401	!!
402	!! ** Purpose :
403	!!
404	!! ** Method :
405	!!----------------------------------------------------------------------
406	INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
407	!
408	INTEGER, PARAMETER :: nfactmax = 20
409	INTEGER :: nfact ! The no. of factors returned
410	INTEGER :: ierr ! Error flag
411	INTEGER :: ji
412	INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
413	INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
414	!!----------------------------------------------------------------------
415
416	ierr = 0
417
418	CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
419
420	IF( nfact <= 1 ) THEN
421	WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
422	WRITE (numout, *) ' : using grid of ',num_pes,' x 1'
423	jpnj = 1
424	jpni = num_pes
425	ELSE
426	! Search through factors for the pair that are closest in value
427	mindiff = 1000000
428	imin = 1
429	DO ji = 1, nfact-1, 2
430	idiff = ABS( ifact(ji) - ifact(ji+1) )
431	IF( idiff < mindiff ) THEN
432	mindiff = idiff
433	imin = ji
434	ENDIF
435	END DO
436	jpnj = ifact(imin)
437	jpni = ifact(imin + 1)
438	ENDIF
439	!
440	jpnij = jpni*jpnj
441	!
442	END SUBROUTINE nemo_partition
443
444
445	SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
446	!!----------------------------------------------------------------------
447	!! * ROUTINE factorise *
448	!!
449	!! ** Purpose : return the prime factors of n.
450	!! knfax factors are returned in array kfax which is of
451	!! maximum dimension kmaxfax.
452	!! ** Method :
453	!!----------------------------------------------------------------------
454	INTEGER , INTENT(in ) :: kn, kmaxfax
455	INTEGER , INTENT( out) :: kerr, knfax
456	INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax
457	!
458	INTEGER :: ifac, jl, inu
459	INTEGER, PARAMETER :: ntest = 14
460	INTEGER :: ilfax(ntest)
461
462	! lfax contains the set of allowed factors.
463	data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256, &
464	& 128, 64, 32, 16, 8, 4, 2 /
465	!!----------------------------------------------------------------------
466
467	! Clear the error flag and initialise output vars
468	kerr = 0
469	kfax = 1
470	knfax = 0
471
472	! Find the factors of n.
473	IF( kn == 1 ) GOTO 20
474
475	! nu holds the unfactorised part of the number.
476	! knfax holds the number of factors found.
477	! l points to the allowed factor list.
478	! ifac holds the current factor.
479
480	inu = kn
481	knfax = 0
482
483	DO jl = ntest, 1, -1
484	!
485	ifac = ilfax(jl)
486	IF( ifac > inu ) CYCLE
487
488	! Test whether the factor will divide.
489
490	IF( MOD(inu,ifac) == 0 ) THEN
491	!
492	knfax = knfax + 1 ! Add the factor to the list
493	IF( knfax > kmaxfax ) THEN
494	kerr = 6
495	write (,) 'FACTOR: insufficient space in factor array ', knfax
496	return
497	ENDIF
498	kfax(knfax) = ifac
499	! Store the other factor that goes with this one
500	knfax = knfax + 1
501	kfax(knfax) = inu / ifac
502	!WRITE (,) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
503	ENDIF
504	!
505	END DO
506
507	20 CONTINUE ! Label 20 is the exit point from the factor search loop.
508	!
509	END SUBROUTINE factorise
510
511	#if defined key_mpp_mpi
512	SUBROUTINE nemo_northcomms
513	!!======================================================================
514	!! * ROUTINE nemo_northcomms *
515	!! nemo_northcomms : Setup for north fold exchanges with explicit peer to peer messaging
516	!!=====================================================================
517	!!----------------------------------------------------------------------
518	!!
519	!! ** Purpose : Initialization of the northern neighbours lists.
520	!!----------------------------------------------------------------------
521	!! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE)
522	!!----------------------------------------------------------------------
523
524	INTEGER :: ji, jj, jk, ij, jtyp ! dummy loop indices
525	INTEGER :: ijpj ! number of rows involved in north-fold exchange
526	INTEGER :: northcomms_alloc ! allocate return status
527	REAL(wp), ALLOCATABLE, DIMENSION ( :,: ) :: znnbrs ! workspace
528	LOGICAL, ALLOCATABLE, DIMENSION ( : ) :: lrankset ! workspace
529
530	IF(lwp) WRITE(numout,*)
531	IF(lwp) WRITE(numout,*) 'nemo_northcomms : Initialization of the northern neighbours lists'
532	IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
533
534	!!----------------------------------------------------------------------
535	ALLOCATE( znnbrs(jpi,jpj), stat = northcomms_alloc )
536	ALLOCATE( lrankset(jpnij), stat = northcomms_alloc )
537	IF( northcomms_alloc /= 0 ) THEN
538	WRITE(numout,cform_war)
539	WRITE(numout,*) 'northcomms_alloc : failed to allocate arrays'
540	CALL ctl_stop( 'STOP', 'nemo_northcomms : unable to allocate temporary arrays' )
541	ENDIF
542	nsndto = 0
543	isendto = -1
544	ijpj = 4
545	!
546	! This routine has been called because ln_nnogather has been set true ( nammpp )
547	! However, these first few exchanges have to use the mpi_allgather method to
548	! establish the neighbour lists to use in subsequent peer to peer exchanges.
549	! Consequently, set l_north_nogather to be false here and set it true only after
550	! the lists have been established.
551	!
552	l_north_nogather = .FALSE.
553	!
554	! Exchange and store ranks on northern rows
555
556	DO jtyp = 1,4
557
558	lrankset = .FALSE.
559	znnbrs = narea
560	SELECT CASE (jtyp)
561	CASE(1)
562	CALL lbc_lnk( znnbrs, 'T', 1. ) ! Type 1: T,W-points
563	CASE(2)
564	CALL lbc_lnk( znnbrs, 'U', 1. ) ! Type 2: U-point
565	CASE(3)
566	CALL lbc_lnk( znnbrs, 'V', 1. ) ! Type 3: V-point
567	CASE(4)
568	CALL lbc_lnk( znnbrs, 'F', 1. ) ! Type 4: F-point
569	END SELECT
570
571	IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
572	DO jj = nlcj-ijpj+1, nlcj
573	ij = jj - nlcj + ijpj
574	DO ji = 1,jpi
575	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
576	& lrankset(INT(znnbrs(ji,jj))) = .true.
577	END DO
578	END DO
579
580	DO jj = 1,jpnij
581	IF ( lrankset(jj) ) THEN
582	nsndto(jtyp) = nsndto(jtyp) + 1
583	IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
584	CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
585	& ' jpmaxngh will need to be increased ')
586	ENDIF
587	isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank
588	ENDIF
589	END DO
590	ENDIF
591
592	END DO
593
594	!
595	! Type 5: I-point
596	!
597	! ICE point exchanges may involve some averaging. The neighbours list is
598	! built up using two exchanges to ensure that the whole stencil is covered.
599	! lrankset should not be reset between these 'J' and 'K' point exchanges
600
601	jtyp = 5
602	lrankset = .FALSE.
603	znnbrs = narea
604	CALL lbc_lnk( znnbrs, 'J', 1. ) ! first ice U-V point
605
606	IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
607	DO jj = nlcj-ijpj+1, nlcj
608	ij = jj - nlcj + ijpj
609	DO ji = 1,jpi
610	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
611	& lrankset(INT(znnbrs(ji,jj))) = .true.
612	END DO
613	END DO
614	ENDIF
615
616	znnbrs = narea
617	CALL lbc_lnk( znnbrs, 'K', 1. ) ! second ice U-V point
618
619	IF ( njmppt(narea) .EQ. MAXVAL( njmppt )) THEN
620	DO jj = nlcj-ijpj+1, nlcj
621	ij = jj - nlcj + ijpj
622	DO ji = 1,jpi
623	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
624	& lrankset( INT(znnbrs(ji,jj))) = .true.
625	END DO
626	END DO
627
628	DO jj = 1,jpnij
629	IF ( lrankset(jj) ) THEN
630	nsndto(jtyp) = nsndto(jtyp) + 1
631	IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
632	CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
633	& ' jpmaxngh will need to be increased ')
634	ENDIF
635	isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank
636	ENDIF
637	END DO
638	!
639	! For northern row areas, set l_north_nogather so that all subsequent exchanges
640	! can use peer to peer communications at the north fold
641	!
642	l_north_nogather = .TRUE.
643	!
644	ENDIF
645	DEALLOCATE( znnbrs )
646	DEALLOCATE( lrankset )
647
648	END SUBROUTINE nemo_northcomms
649	#else
650	SUBROUTINE nemo_northcomms ! Dummy routine
651	WRITE(,) 'nemo_northcomms: You should not have seen this print! error?'
652	END SUBROUTINE nemo_northcomms
653	#endif
654	!!======================================================================
655	END MODULE nemogcm

Note: See TracBrowser for help on using the repository browser.

Download in other formats: