[1418] | 1 | MODULE zdftmx |
---|
| 2 | !!======================================================================== |
---|
| 3 | !! *** MODULE zdftmx *** |
---|
| 4 | !! Ocean physics: vertical tidal mixing coefficient |
---|
| 5 | !!======================================================================== |
---|
| 6 | !! History : 1.0 ! 2004-04 (L. Bessieres, G. Madec) Original code |
---|
| 7 | !! - ! 2006-08 (A. Koch-Larrouy) Indonesian strait |
---|
[2528] | 8 | !! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase |
---|
[1418] | 9 | !!---------------------------------------------------------------------- |
---|
[2715] | 10 | #if defined key_zdftmx || defined key_esopa |
---|
[1418] | 11 | !!---------------------------------------------------------------------- |
---|
| 12 | !! 'key_zdftmx' Tidal vertical mixing |
---|
| 13 | !!---------------------------------------------------------------------- |
---|
[3625] | 14 | !! zdf_tmx : global momentum & tracer Kz with tidal induced Kz |
---|
| 15 | !! tmx_itf : Indonesian momentum & tracer Kz with tidal induced Kz |
---|
[1418] | 16 | !!---------------------------------------------------------------------- |
---|
[3625] | 17 | USE oce ! ocean dynamics and tracers variables |
---|
| 18 | USE dom_oce ! ocean space and time domain variables |
---|
| 19 | USE zdf_oce ! ocean vertical physics variables |
---|
| 20 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
| 21 | USE eosbn2 ! ocean equation of state |
---|
| 22 | USE phycst ! physical constants |
---|
| 23 | USE prtctl ! Print control |
---|
| 24 | USE in_out_manager ! I/O manager |
---|
| 25 | USE iom ! I/O Manager |
---|
| 26 | USE lib_mpp ! MPP library |
---|
| 27 | USE wrk_nemo ! work arrays |
---|
| 28 | USE timing ! Timing |
---|
| 29 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
---|
[1418] | 30 | |
---|
| 31 | IMPLICIT NONE |
---|
| 32 | PRIVATE |
---|
| 33 | |
---|
[2528] | 34 | PUBLIC zdf_tmx ! called in step module |
---|
| 35 | PUBLIC zdf_tmx_init ! called in opa module |
---|
[2715] | 36 | PUBLIC zdf_tmx_alloc ! called in nemogcm module |
---|
[1418] | 37 | |
---|
| 38 | LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .TRUE. !: tidal mixing flag |
---|
| 39 | |
---|
[1601] | 40 | ! !!* Namelist namzdf_tmx : tidal mixing * |
---|
[1518] | 41 | REAL(wp) :: rn_htmx = 500. ! vertical decay scale for turbulence (meters) |
---|
| 42 | REAL(wp) :: rn_n2min = 1.e-8 ! threshold of the Brunt-Vaisala frequency (s-1) |
---|
| 43 | REAL(wp) :: rn_tfe = 1./3. ! tidal dissipation efficiency (St Laurent et al. 2002) |
---|
| 44 | REAL(wp) :: rn_me = 0.2 ! mixing efficiency (Osborn 1980) |
---|
| 45 | LOGICAL :: ln_tmx_itf = .TRUE. ! Indonesian Through Flow (ITF): Koch-Larrouy et al. (2007) parameterization |
---|
| 46 | REAL(wp) :: rn_tfe_itf = 1. ! ITF tidal dissipation efficiency (St Laurent et al. 2002) |
---|
[1418] | 47 | |
---|
[2715] | 48 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: en_tmx ! energy available for tidal mixing (W/m2) |
---|
| 49 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: mask_itf ! mask to use over Indonesian area |
---|
| 50 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: az_tmx ! coefficient used to evaluate the tidal induced Kz |
---|
[1418] | 51 | |
---|
| 52 | !! * Substitutions |
---|
| 53 | # include "domzgr_substitute.h90" |
---|
| 54 | # include "vectopt_loop_substitute.h90" |
---|
| 55 | !!---------------------------------------------------------------------- |
---|
[2715] | 56 | !! NEMO/OPA 4.0 , NEMO Consortium (2011) |
---|
[2528] | 57 | !! $Id$ |
---|
[2715] | 58 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
[1418] | 59 | !!---------------------------------------------------------------------- |
---|
| 60 | CONTAINS |
---|
| 61 | |
---|
[2715] | 62 | INTEGER FUNCTION zdf_tmx_alloc() |
---|
| 63 | !!---------------------------------------------------------------------- |
---|
| 64 | !! *** FUNCTION zdf_tmx_alloc *** |
---|
| 65 | !!---------------------------------------------------------------------- |
---|
| 66 | ALLOCATE(en_tmx(jpi,jpj), mask_itf(jpi,jpj), az_tmx(jpi,jpj,jpk), STAT=zdf_tmx_alloc ) |
---|
| 67 | ! |
---|
| 68 | IF( lk_mpp ) CALL mpp_sum ( zdf_tmx_alloc ) |
---|
| 69 | IF( zdf_tmx_alloc /= 0 ) CALL ctl_warn('zdf_tmx_alloc: failed to allocate arrays') |
---|
| 70 | END FUNCTION zdf_tmx_alloc |
---|
| 71 | |
---|
| 72 | |
---|
[1418] | 73 | SUBROUTINE zdf_tmx( kt ) |
---|
| 74 | !!---------------------------------------------------------------------- |
---|
| 75 | !! *** ROUTINE zdf_tmx *** |
---|
| 76 | !! |
---|
| 77 | !! ** Purpose : add to the vertical mixing coefficients the effect of |
---|
[1496] | 78 | !! tidal mixing (Simmons et al 2004). |
---|
[1418] | 79 | !! |
---|
| 80 | !! ** Method : - tidal-induced vertical mixing is given by: |
---|
[1496] | 81 | !! Kz_tides = az_tmx / max( rn_n2min, N^2 ) |
---|
| 82 | !! where az_tmx is a coefficient that specified the 3D space |
---|
| 83 | !! distribution of the faction of tidal energy taht is used |
---|
| 84 | !! for mixing. Its expression is set in zdf_tmx_init routine, |
---|
| 85 | !! following Simmons et al. 2004. |
---|
| 86 | !! NB: a specific bounding procedure is performed on av_tide |
---|
| 87 | !! so that the input tidal energy is actually almost used. The |
---|
| 88 | !! basic maximum value is 60 cm2/s, but values of 300 cm2/s |
---|
| 89 | !! can be reached in area where bottom stratification is too |
---|
| 90 | !! weak. |
---|
[1418] | 91 | !! |
---|
[1496] | 92 | !! - update av_tide in the Indonesian Through Flow area |
---|
| 93 | !! following Koch-Larrouy et al. (2007) parameterisation |
---|
| 94 | !! (see tmx_itf routine). |
---|
[1418] | 95 | !! |
---|
[1496] | 96 | !! - update the model vertical eddy viscosity and diffusivity: |
---|
| 97 | !! avt = avt + av_tides |
---|
[1527] | 98 | !! avm = avm + av_tides |
---|
[1496] | 99 | !! avmu = avmu + mi(av_tides) |
---|
| 100 | !! avmv = avmv + mj(av_tides) |
---|
| 101 | !! |
---|
[1527] | 102 | !! ** Action : avt, avm, avmu, avmv increased by tidal mixing |
---|
[1496] | 103 | !! |
---|
[1418] | 104 | !! References : Simmons et al. 2004, Ocean Modelling, 6, 3-4, 245-263. |
---|
[1496] | 105 | !! Koch-Larrouy et al. 2007, GRL. |
---|
[1418] | 106 | !!---------------------------------------------------------------------- |
---|
[1601] | 107 | USE oce, zav_tide => ua ! use ua as workspace |
---|
[1546] | 108 | !! |
---|
[1418] | 109 | INTEGER, INTENT(in) :: kt ! ocean time-step |
---|
| 110 | !! |
---|
| 111 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
| 112 | REAL(wp) :: ztpc ! scalar workspace |
---|
[3294] | 113 | REAL(wp), POINTER, DIMENSION(:,:) :: zkz |
---|
[1418] | 114 | !!---------------------------------------------------------------------- |
---|
[3294] | 115 | ! |
---|
| 116 | IF( nn_timing == 1 ) CALL timing_start('zdf_tmx') |
---|
| 117 | ! |
---|
| 118 | CALL wrk_alloc( jpi,jpj, zkz ) |
---|
[1418] | 119 | |
---|
[1546] | 120 | ! ! ----------------------- ! |
---|
| 121 | ! ! Standard tidal mixing ! (compute zav_tide) |
---|
| 122 | ! ! ----------------------- ! |
---|
[1496] | 123 | ! !* First estimation (with n2 bound by rn_n2min) bounded by 60 cm2/s |
---|
[1546] | 124 | zav_tide(:,:,:) = MIN( 60.e-4, az_tmx(:,:,:) / MAX( rn_n2min, rn2(:,:,:) ) ) |
---|
[1418] | 125 | |
---|
[1496] | 126 | zkz(:,:) = 0.e0 !* Associated potential energy consummed over the whole water column |
---|
[1418] | 127 | DO jk = 2, jpkm1 |
---|
[1546] | 128 | zkz(:,:) = zkz(:,:) + fse3w(:,:,jk) * MAX( 0.e0, rn2(:,:,jk) ) * rau0 * zav_tide(:,:,jk)* tmask(:,:,jk) |
---|
[1418] | 129 | END DO |
---|
| 130 | |
---|
[1496] | 131 | DO jj = 1, jpj !* Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx |
---|
[1418] | 132 | DO ji = 1, jpi |
---|
| 133 | IF( zkz(ji,jj) /= 0.e0 ) zkz(ji,jj) = en_tmx(ji,jj) / zkz(ji,jj) |
---|
| 134 | END DO |
---|
| 135 | END DO |
---|
| 136 | |
---|
[1546] | 137 | DO jk = 2, jpkm1 !* Mutiply by zkz to recover en_tmx, BUT bound by 30/6 ==> zav_tide bound by 300 cm2/s |
---|
| 138 | zav_tide(:,:,jk) = zav_tide(:,:,jk) * MIN( zkz(:,:), 30./6. ) !kz max = 300 cm2/s |
---|
[1418] | 139 | END DO |
---|
| 140 | |
---|
[1546] | 141 | IF( kt == nit000 ) THEN !* check at first time-step: diagnose the energy consumed by zav_tide |
---|
[1418] | 142 | ztpc = 0.e0 |
---|
| 143 | DO jk= 1, jpk |
---|
| 144 | DO jj= 1, jpj |
---|
| 145 | DO ji= 1, jpi |
---|
[1496] | 146 | ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) & |
---|
[1546] | 147 | & * MAX( 0.e0, rn2(ji,jj,jk) ) * zav_tide(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
---|
[1418] | 148 | END DO |
---|
| 149 | END DO |
---|
| 150 | END DO |
---|
[1495] | 151 | ztpc= rau0 / ( rn_tfe * rn_me ) * ztpc |
---|
[1418] | 152 | IF(lwp) WRITE(numout,*) |
---|
[1496] | 153 | IF(lwp) WRITE(numout,*) ' N Total power consumption by av_tide : ztpc = ', ztpc * 1.e-12 ,'TW' |
---|
[1418] | 154 | ENDIF |
---|
[1495] | 155 | |
---|
[1546] | 156 | ! ! ----------------------- ! |
---|
| 157 | ! ! ITF tidal mixing ! (update zav_tide) |
---|
| 158 | ! ! ----------------------- ! |
---|
| 159 | IF( ln_tmx_itf ) CALL tmx_itf( kt, zav_tide ) |
---|
[1418] | 160 | |
---|
[1546] | 161 | ! ! ----------------------- ! |
---|
| 162 | ! ! Update mixing coefs ! |
---|
| 163 | ! ! ----------------------- ! |
---|
[1495] | 164 | DO jk = 2, jpkm1 !* update momentum & tracer diffusivity with tidal mixing |
---|
[1546] | 165 | avt(:,:,jk) = avt(:,:,jk) + zav_tide(:,:,jk) |
---|
| 166 | avm(:,:,jk) = avm(:,:,jk) + zav_tide(:,:,jk) |
---|
[1418] | 167 | DO jj = 2, jpjm1 |
---|
| 168 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
[1546] | 169 | avmu(ji,jj,jk) = avmu(ji,jj,jk) + 0.5 * ( zav_tide(ji,jj,jk) + zav_tide(ji+1,jj ,jk) ) * umask(ji,jj,jk) |
---|
| 170 | avmv(ji,jj,jk) = avmv(ji,jj,jk) + 0.5 * ( zav_tide(ji,jj,jk) + zav_tide(ji ,jj+1,jk) ) * vmask(ji,jj,jk) |
---|
[1418] | 171 | END DO |
---|
| 172 | END DO |
---|
| 173 | END DO |
---|
[1496] | 174 | CALL lbc_lnk( avmu, 'U', 1. ) ; CALL lbc_lnk( avmv, 'V', 1. ) ! lateral boundary condition |
---|
[1418] | 175 | |
---|
[1546] | 176 | ! !* output tidal mixing coefficient |
---|
| 177 | CALL iom_put( "av_tide", zav_tide ) |
---|
| 178 | |
---|
| 179 | IF(ln_ctl) CALL prt_ctl(tab3d_1=zav_tide , clinfo1=' tmx - av_tide: ', tab3d_2=avt, clinfo2=' avt: ', ovlap=1, kdim=jpk) |
---|
[1418] | 180 | ! |
---|
[3294] | 181 | CALL wrk_dealloc( jpi,jpj, zkz ) |
---|
[2715] | 182 | ! |
---|
[3294] | 183 | IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx') |
---|
| 184 | ! |
---|
[1418] | 185 | END SUBROUTINE zdf_tmx |
---|
| 186 | |
---|
| 187 | |
---|
[1546] | 188 | SUBROUTINE tmx_itf( kt, pav ) |
---|
[1418] | 189 | !!---------------------------------------------------------------------- |
---|
| 190 | !! *** ROUTINE tmx_itf *** |
---|
| 191 | !! |
---|
[1496] | 192 | !! ** Purpose : modify the vertical eddy diffusivity coefficients |
---|
[1546] | 193 | !! (pav) in the Indonesian Through Flow area (ITF). |
---|
[1418] | 194 | !! |
---|
[1496] | 195 | !! ** Method : - Following Koch-Larrouy et al. (2007), in the ITF defined |
---|
| 196 | !! by msk_itf (read in a file, see tmx_init), the tidal |
---|
| 197 | !! mixing coefficient is computed with : |
---|
| 198 | !! * q=1 (i.e. all the tidal energy remains trapped in |
---|
| 199 | !! the area and thus is used for mixing) |
---|
| 200 | !! * the vertical distribution of the tifal energy is a |
---|
| 201 | !! proportional to N above the thermocline (d(N^2)/dz > 0) |
---|
| 202 | !! and to N^2 below the thermocline (d(N^2)/dz < 0) |
---|
[1418] | 203 | !! |
---|
[1496] | 204 | !! ** Action : av_tide updated in the ITF area (msk_itf) |
---|
[1418] | 205 | !! |
---|
| 206 | !! References : Koch-Larrouy et al. 2007, GRL |
---|
| 207 | !!---------------------------------------------------------------------- |
---|
[1546] | 208 | INTEGER , INTENT(in ) :: kt ! ocean time-step |
---|
| 209 | REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) :: pav ! Tidal mixing coef. |
---|
[1418] | 210 | !! |
---|
[1495] | 211 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
| 212 | REAL(wp) :: zcoef, ztpc ! temporary scalar |
---|
[3294] | 213 | REAL(wp), DIMENSION(:,:) , POINTER :: zkz ! 2D workspace |
---|
| 214 | REAL(wp), DIMENSION(:,:) , POINTER :: zsum1 , zsum2 , zsum ! - - |
---|
| 215 | REAL(wp), DIMENSION(:,:,:), POINTER :: zempba_3d_1, zempba_3d_2 ! 3D workspace |
---|
| 216 | REAL(wp), DIMENSION(:,:,:), POINTER :: zempba_3d , zdn2dz ! - - |
---|
| 217 | REAL(wp), DIMENSION(:,:,:), POINTER :: zavt_itf ! - - |
---|
[1418] | 218 | !!---------------------------------------------------------------------- |
---|
[2715] | 219 | ! |
---|
[3294] | 220 | IF( nn_timing == 1 ) CALL timing_start('tmx_itf') |
---|
| 221 | ! |
---|
| 222 | CALL wrk_alloc( jpi,jpj, zkz, zsum1 , zsum2 , zsum ) |
---|
| 223 | CALL wrk_alloc( jpi,jpj,jpk, zempba_3d_1, zempba_3d_2, zempba_3d, zdn2dz, zavt_itf ) |
---|
| 224 | |
---|
[1418] | 225 | ! ! compute the form function using N2 at each time step |
---|
[1518] | 226 | zempba_3d_1(:,:,jpk) = 0.e0 |
---|
| 227 | zempba_3d_2(:,:,jpk) = 0.e0 |
---|
| 228 | DO jk = 1, jpkm1 |
---|
| 229 | zdn2dz (:,:,jk) = rn2(:,:,jk) - rn2(:,:,jk+1) ! Vertical profile of dN2/dz |
---|
[1495] | 230 | !CDIR NOVERRCHK |
---|
[1518] | 231 | zempba_3d_1(:,:,jk) = SQRT( MAX( 0.e0, rn2(:,:,jk) ) ) ! - - of N |
---|
| 232 | zempba_3d_2(:,:,jk) = MAX( 0.e0, rn2(:,:,jk) ) ! - - of N^2 |
---|
[1418] | 233 | END DO |
---|
[1518] | 234 | ! |
---|
| 235 | zsum (:,:) = 0.e0 |
---|
| 236 | zsum1(:,:) = 0.e0 |
---|
| 237 | zsum2(:,:) = 0.e0 |
---|
[1418] | 238 | DO jk= 2, jpk |
---|
[1518] | 239 | zsum1(:,:) = zsum1(:,:) + zempba_3d_1(:,:,jk) * fse3w(:,:,jk) |
---|
| 240 | zsum2(:,:) = zsum2(:,:) + zempba_3d_2(:,:,jk) * fse3w(:,:,jk) |
---|
[1418] | 241 | END DO |
---|
| 242 | DO jj = 1, jpj |
---|
[1518] | 243 | DO ji = 1, jpi |
---|
| 244 | IF( zsum1(ji,jj) /= 0.e0 ) zsum1(ji,jj) = 1.e0 / zsum1(ji,jj) |
---|
| 245 | IF( zsum2(ji,jj) /= 0.e0 ) zsum2(ji,jj) = 1.e0 / zsum2(ji,jj) |
---|
| 246 | END DO |
---|
[1418] | 247 | END DO |
---|
| 248 | |
---|
| 249 | DO jk= 1, jpk |
---|
| 250 | DO jj = 1, jpj |
---|
| 251 | DO ji = 1, jpi |
---|
[1518] | 252 | zcoef = 0.5 - SIGN( 0.5, zdn2dz(ji,jj,jk) ) ! =0 if dN2/dz > 0, =1 otherwise |
---|
| 253 | ztpc = zempba_3d_1(ji,jj,jk) * zsum1(ji,jj) * zcoef & |
---|
| 254 | & + zempba_3d_2(ji,jj,jk) * zsum2(ji,jj) * ( 1. - zcoef ) |
---|
| 255 | ! |
---|
| 256 | zempba_3d(ji,jj,jk) = ztpc |
---|
| 257 | zsum (ji,jj) = zsum(ji,jj) + ztpc * fse3w(ji,jj,jk) |
---|
[1418] | 258 | END DO |
---|
| 259 | END DO |
---|
| 260 | END DO |
---|
| 261 | DO jj = 1, jpj |
---|
| 262 | DO ji = 1, jpi |
---|
[1518] | 263 | IF( zsum(ji,jj) > 0.e0 ) zsum(ji,jj) = 1.e0 / zsum(ji,jj) |
---|
[1418] | 264 | END DO |
---|
| 265 | END DO |
---|
| 266 | |
---|
[1495] | 267 | ! ! first estimation bounded by 10 cm2/s (with n2 bounded by rn_n2min) |
---|
| 268 | zcoef = rn_tfe_itf / ( rn_tfe * rau0 ) |
---|
[1518] | 269 | DO jk = 1, jpk |
---|
| 270 | zavt_itf(:,:,jk) = MIN( 10.e-4, zcoef * en_tmx(:,:) * zsum(:,:) * zempba_3d(:,:,jk) & |
---|
| 271 | & / MAX( rn_n2min, rn2(:,:,jk) ) * tmask(:,:,jk) ) |
---|
[1495] | 272 | END DO |
---|
[1418] | 273 | |
---|
| 274 | zkz(:,:) = 0.e0 ! Associated potential energy consummed over the whole water column |
---|
| 275 | DO jk = 2, jpkm1 |
---|
[1495] | 276 | zkz(:,:) = zkz(:,:) + fse3w(:,:,jk) * MAX( 0.e0, rn2(:,:,jk) ) * rau0 * zavt_itf(:,:,jk) * tmask(:,:,jk) |
---|
[1418] | 277 | END DO |
---|
| 278 | |
---|
| 279 | DO jj = 1, jpj ! Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx |
---|
| 280 | DO ji = 1, jpi |
---|
| 281 | IF( zkz(ji,jj) /= 0.e0 ) zkz(ji,jj) = en_tmx(ji,jj) * rn_tfe_itf / rn_tfe / zkz(ji,jj) |
---|
| 282 | END DO |
---|
| 283 | END DO |
---|
| 284 | |
---|
[1495] | 285 | DO jk = 2, jpkm1 ! Mutiply by zkz to recover en_tmx, BUT bound by 30/6 ==> zavt_itf bound by 300 cm2/s |
---|
| 286 | zavt_itf(:,:,jk) = zavt_itf(:,:,jk) * MIN( zkz(:,:), 120./10. ) ! kz max = 120 cm2/s |
---|
[1418] | 287 | END DO |
---|
| 288 | |
---|
[1495] | 289 | IF( kt == nit000 ) THEN ! diagnose the nergy consumed by zavt_itf |
---|
[1418] | 290 | ztpc = 0.e0 |
---|
| 291 | DO jk= 1, jpk |
---|
| 292 | DO jj= 1, jpj |
---|
| 293 | DO ji= 1, jpi |
---|
[1495] | 294 | ztpc = ztpc + e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk) * MAX( 0.e0, rn2(ji,jj,jk) ) & |
---|
| 295 | & * zavt_itf(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
---|
[1418] | 296 | END DO |
---|
| 297 | END DO |
---|
| 298 | END DO |
---|
[1495] | 299 | ztpc= rau0 * ztpc / ( rn_me * rn_tfe_itf ) |
---|
| 300 | IF(lwp) WRITE(numout,*) ' N Total power consumption by zavt_itf: ztpc = ', ztpc * 1.e-12 ,'TW' |
---|
[1418] | 301 | ENDIF |
---|
| 302 | |
---|
[1546] | 303 | ! ! Update pav with the ITF mixing coefficient |
---|
[1418] | 304 | DO jk = 2, jpkm1 |
---|
[1546] | 305 | pav(:,:,jk) = pav (:,:,jk) * ( 1.e0 - mask_itf(:,:) ) & |
---|
| 306 | & + zavt_itf(:,:,jk) * mask_itf(:,:) |
---|
[1418] | 307 | END DO |
---|
| 308 | ! |
---|
[3294] | 309 | CALL wrk_dealloc( jpi,jpj, zkz, zsum1 , zsum2 , zsum ) |
---|
| 310 | CALL wrk_dealloc( jpi,jpj,jpk, zempba_3d_1, zempba_3d_2, zempba_3d, zdn2dz, zavt_itf ) |
---|
[2715] | 311 | ! |
---|
[3294] | 312 | IF( nn_timing == 1 ) CALL timing_stop('tmx_itf') |
---|
| 313 | ! |
---|
[1418] | 314 | END SUBROUTINE tmx_itf |
---|
| 315 | |
---|
| 316 | |
---|
| 317 | SUBROUTINE zdf_tmx_init |
---|
| 318 | !!---------------------------------------------------------------------- |
---|
| 319 | !! *** ROUTINE zdf_tmx_init *** |
---|
| 320 | !! |
---|
| 321 | !! ** Purpose : Initialization of the vertical tidal mixing, Reading |
---|
[1496] | 322 | !! of M2 and K1 tidal energy in nc files |
---|
[1418] | 323 | !! |
---|
[1496] | 324 | !! ** Method : - Read the namtmx namelist and check the parameters |
---|
| 325 | !! |
---|
| 326 | !! - Read the input data in NetCDF files : |
---|
| 327 | !! M2 and K1 tidal energy. The total tidal energy, en_tmx, |
---|
| 328 | !! is the sum of M2, K1 and S2 energy where S2 is assumed |
---|
| 329 | !! to be: S2=(1/2)^2 * M2 |
---|
| 330 | !! mask_itf, a mask array that determine where substituing |
---|
| 331 | !! the standard Simmons et al. (2005) formulation with the |
---|
| 332 | !! one of Koch_Larrouy et al. (2007). |
---|
| 333 | !! |
---|
[1418] | 334 | !! - Compute az_tmx, a 3D coefficient that allows to compute |
---|
[1496] | 335 | !! the standard tidal-induced vertical mixing as follows: |
---|
| 336 | !! Kz_tides = az_tmx / max( rn_n2min, N^2 ) |
---|
| 337 | !! with az_tmx a bottom intensified coefficient is given by: |
---|
| 338 | !! az_tmx(z) = en_tmx / ( rau0 * rn_htmx ) * EXP( -(H-z)/rn_htmx ) |
---|
| 339 | !! / ( 1. - EXP( - H /rn_htmx ) ) |
---|
| 340 | !! where rn_htmx the characteristic length scale of the bottom |
---|
| 341 | !! intensification, en_tmx the tidal energy, and H the ocean depth |
---|
[1418] | 342 | !! |
---|
| 343 | !! ** input : - Namlist namtmx |
---|
[1496] | 344 | !! - NetCDF file : M2_ORCA2.nc, K1_ORCA2.nc, and mask_itf.nc |
---|
[1418] | 345 | !! |
---|
| 346 | !! ** Action : - Increase by 1 the nstop flag is setting problem encounter |
---|
| 347 | !! - defined az_tmx used to compute tidal-induced mixing |
---|
[1496] | 348 | !! |
---|
| 349 | !! References : Simmons et al. 2004, Ocean Modelling, 6, 3-4, 245-263. |
---|
| 350 | !! Koch-Larrouy et al. 2007, GRL. |
---|
[1418] | 351 | !!---------------------------------------------------------------------- |
---|
[2715] | 352 | USE oce , zav_tide => ua ! ua used as workspace |
---|
[1546] | 353 | !! |
---|
[2715] | 354 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
| 355 | INTEGER :: inum ! local integer |
---|
| 356 | REAL(wp) :: ztpc, ze_z ! local scalars |
---|
[3294] | 357 | REAL(wp), DIMENSION(:,:) , POINTER :: zem2, zek1 ! read M2 and K1 tidal energy |
---|
| 358 | REAL(wp), DIMENSION(:,:) , POINTER :: zkz ! total M2, K1 and S2 tidal energy |
---|
| 359 | REAL(wp), DIMENSION(:,:) , POINTER :: zfact ! used for vertical structure function |
---|
| 360 | REAL(wp), DIMENSION(:,:) , POINTER :: zhdep ! Ocean depth |
---|
| 361 | REAL(wp), DIMENSION(:,:,:), POINTER :: zpc ! power consumption |
---|
[1496] | 362 | !! |
---|
[1601] | 363 | NAMELIST/namzdf_tmx/ rn_htmx, rn_n2min, rn_tfe, rn_me, ln_tmx_itf, rn_tfe_itf |
---|
[1418] | 364 | !!---------------------------------------------------------------------- |
---|
[3294] | 365 | ! |
---|
| 366 | IF( nn_timing == 1 ) CALL timing_start('zdf_tmx_init') |
---|
| 367 | ! |
---|
| 368 | CALL wrk_alloc( jpi,jpj, zem2, zek1, zkz, zfact, zhdep ) |
---|
| 369 | CALL wrk_alloc( jpi,jpj,jpk, zpc ) |
---|
| 370 | |
---|
[1601] | 371 | REWIND( numnam ) ! Read Namelist namtmx : Tidal Mixing |
---|
| 372 | READ ( numnam, namzdf_tmx ) |
---|
[1537] | 373 | |
---|
| 374 | IF(lwp) THEN ! Control print |
---|
[1418] | 375 | WRITE(numout,*) |
---|
| 376 | WRITE(numout,*) 'zdf_tmx_init : tidal mixing' |
---|
| 377 | WRITE(numout,*) '~~~~~~~~~~~~' |
---|
[1601] | 378 | WRITE(numout,*) ' Namelist namzdf_tmx : set tidal mixing parameters' |
---|
[1537] | 379 | WRITE(numout,*) ' Vertical decay scale for turbulence = ', rn_htmx |
---|
| 380 | WRITE(numout,*) ' Brunt-Vaisala frequency threshold = ', rn_n2min |
---|
| 381 | WRITE(numout,*) ' Tidal dissipation efficiency = ', rn_tfe |
---|
| 382 | WRITE(numout,*) ' Mixing efficiency = ', rn_me |
---|
| 383 | WRITE(numout,*) ' ITF specific parameterisation = ', ln_tmx_itf |
---|
| 384 | WRITE(numout,*) ' ITF tidal dissipation efficiency = ', rn_tfe_itf |
---|
[1418] | 385 | ENDIF |
---|
| 386 | |
---|
[2715] | 387 | ! ! allocate tmx arrays |
---|
| 388 | IF( zdf_tmx_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'zdf_tmx_init : unable to allocate tmx arrays' ) |
---|
| 389 | |
---|
[1537] | 390 | IF( ln_tmx_itf ) THEN ! read the Indonesian Through Flow mask |
---|
[1518] | 391 | CALL iom_open('mask_itf',inum) |
---|
| 392 | CALL iom_get (inum, jpdom_data, 'tmaskitf',mask_itf,1) ! |
---|
| 393 | CALL iom_close(inum) |
---|
| 394 | ENDIF |
---|
[1418] | 395 | |
---|
| 396 | ! read M2 tidal energy flux : W/m2 ( zem2 < 0 ) |
---|
| 397 | CALL iom_open('M2rowdrg',inum) |
---|
| 398 | CALL iom_get (inum, jpdom_data, 'field',zem2,1) ! |
---|
| 399 | CALL iom_close(inum) |
---|
| 400 | |
---|
| 401 | ! read K1 tidal energy flux : W/m2 ( zek1 < 0 ) |
---|
| 402 | CALL iom_open('K1rowdrg',inum) |
---|
| 403 | CALL iom_get (inum, jpdom_data, 'field',zek1,1) ! |
---|
| 404 | CALL iom_close(inum) |
---|
| 405 | |
---|
| 406 | ! Total tidal energy ( M2, S2 and K1 with S2=(1/2)^2 * M2 ) |
---|
| 407 | ! only the energy available for mixing is taken into account, |
---|
| 408 | ! (mixing efficiency tidal dissipation efficiency) |
---|
| 409 | en_tmx(:,:) = - rn_tfe * rn_me * ( zem2(:,:) * 1.25 + zek1(:,:) ) * tmask(:,:,1) |
---|
| 410 | |
---|
[1496] | 411 | ! Vertical structure (az_tmx) |
---|
| 412 | DO jj = 1, jpj ! part independent of the level |
---|
[1418] | 413 | DO ji = 1, jpi |
---|
[2528] | 414 | zhdep(ji,jj) = fsdepw(ji,jj,mbkt(ji,jj)+1) ! depth of the ocean |
---|
[1418] | 415 | zfact(ji,jj) = rau0 * rn_htmx * ( 1. - EXP( -zhdep(ji,jj) / rn_htmx ) ) |
---|
| 416 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = en_tmx(ji,jj) / zfact(ji,jj) |
---|
| 417 | END DO |
---|
| 418 | END DO |
---|
| 419 | DO jk= 1, jpk ! complete with the level-dependent part |
---|
| 420 | DO jj = 1, jpj |
---|
| 421 | DO ji = 1, jpi |
---|
| 422 | az_tmx(ji,jj,jk) = zfact(ji,jj) * EXP( -( zhdep(ji,jj)-fsdepw(ji,jj,jk) ) / rn_htmx ) * tmask(ji,jj,jk) |
---|
| 423 | END DO |
---|
| 424 | END DO |
---|
| 425 | END DO |
---|
| 426 | |
---|
| 427 | IF( nprint == 1 .AND. lwp ) THEN |
---|
| 428 | ! Control print |
---|
| 429 | ! Total power consumption due to vertical mixing |
---|
[1546] | 430 | ! zpc = rau0 * 1/rn_me * rn2 * zav_tide |
---|
| 431 | zav_tide(:,:,:) = 0.e0 |
---|
[1418] | 432 | DO jk = 2, jpkm1 |
---|
[1546] | 433 | zav_tide(:,:,jk) = az_tmx(:,:,jk) / MAX( rn_n2min, rn2(:,:,jk) ) |
---|
[1418] | 434 | END DO |
---|
| 435 | |
---|
| 436 | ztpc = 0.e0 |
---|
[1546] | 437 | zpc(:,:,:) = MAX(rn_n2min,rn2(:,:,:)) * zav_tide(:,:,:) |
---|
[1418] | 438 | DO jk= 2, jpkm1 |
---|
| 439 | DO jj = 1, jpj |
---|
| 440 | DO ji = 1, jpi |
---|
| 441 | ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) * zpc(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
---|
| 442 | END DO |
---|
| 443 | END DO |
---|
| 444 | END DO |
---|
| 445 | ztpc= rau0 * 1/(rn_tfe * rn_me) * ztpc |
---|
| 446 | |
---|
| 447 | WRITE(numout,*) |
---|
| 448 | WRITE(numout,*) ' Total power consumption of the tidally driven part of Kz : ztpc = ', ztpc * 1.e-12 ,'TW' |
---|
| 449 | |
---|
| 450 | |
---|
| 451 | ! control print 2 |
---|
[1546] | 452 | zav_tide(:,:,:) = MIN( zav_tide(:,:,:), 60.e-4 ) |
---|
[1418] | 453 | zkz(:,:) = 0.e0 |
---|
| 454 | DO jk = 2, jpkm1 |
---|
| 455 | DO jj = 1, jpj |
---|
| 456 | DO ji = 1, jpi |
---|
[1546] | 457 | zkz(ji,jj) = zkz(ji,jj) + fse3w(ji,jj,jk) * MAX( 0.e0, rn2(ji,jj,jk) ) * rau0 * zav_tide(ji,jj,jk)* tmask(ji,jj,jk) |
---|
[1418] | 458 | END DO |
---|
| 459 | END DO |
---|
| 460 | END DO |
---|
| 461 | ! Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz |
---|
| 462 | DO jj = 1, jpj |
---|
| 463 | DO ji = 1, jpi |
---|
| 464 | IF( zkz(ji,jj) /= 0.e0 ) THEN |
---|
| 465 | zkz(ji,jj) = en_tmx(ji,jj) / zkz(ji,jj) |
---|
| 466 | ENDIF |
---|
| 467 | END DO |
---|
| 468 | END DO |
---|
| 469 | ztpc = 1.e50 |
---|
| 470 | DO jj = 1, jpj |
---|
| 471 | DO ji = 1, jpi |
---|
| 472 | IF( zkz(ji,jj) /= 0.e0 ) THEN |
---|
| 473 | ztpc = Min( zkz(ji,jj), ztpc) |
---|
| 474 | ENDIF |
---|
| 475 | END DO |
---|
| 476 | END DO |
---|
| 477 | WRITE(numout,*) ' Min de zkz ', ztpc, ' Max = ', maxval(zkz(:,:) ) |
---|
| 478 | |
---|
| 479 | DO jk = 2, jpkm1 |
---|
[1546] | 480 | zav_tide(:,:,jk) = zav_tide(:,:,jk) * MIN( zkz(:,:), 30./6. ) !kz max = 300 cm2/s |
---|
[1418] | 481 | END DO |
---|
| 482 | ztpc = 0.e0 |
---|
[1546] | 483 | zpc(:,:,:) = Max(0.e0,rn2(:,:,:)) * zav_tide(:,:,:) |
---|
[1418] | 484 | DO jk= 1, jpk |
---|
| 485 | DO jj = 1, jpj |
---|
| 486 | DO ji = 1, jpi |
---|
| 487 | ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) * zpc(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
---|
| 488 | END DO |
---|
| 489 | END DO |
---|
| 490 | END DO |
---|
| 491 | ztpc= rau0 * 1/(rn_tfe * rn_me) * ztpc |
---|
| 492 | WRITE(numout,*) ' 2 Total power consumption of the tidally driven part of Kz : ztpc = ', ztpc * 1.e-12 ,'TW' |
---|
| 493 | |
---|
| 494 | DO jk = 1, jpk |
---|
[1546] | 495 | ze_z = SUM( e1t(:,:) * e2t(:,:) * zav_tide(:,:,jk) * tmask_i(:,:) ) & |
---|
[1418] | 496 | & / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * tmask (:,:,jk) * tmask_i(:,:) ) ) |
---|
| 497 | ztpc = 1.E50 |
---|
| 498 | DO jj = 1, jpj |
---|
| 499 | DO ji = 1, jpi |
---|
[1546] | 500 | IF( zav_tide(ji,jj,jk) /= 0.e0 ) ztpc =Min( ztpc, zav_tide(ji,jj,jk) ) |
---|
[1418] | 501 | END DO |
---|
| 502 | END DO |
---|
| 503 | WRITE(numout,*) ' N2 min - jk= ', jk,' ', ze_z * 1.e4,' cm2/s min= ',ztpc*1.e4, & |
---|
[1546] | 504 | & 'max= ', MAXVAL(zav_tide(:,:,jk) )*1.e4, ' cm2/s' |
---|
[1418] | 505 | END DO |
---|
| 506 | |
---|
| 507 | WRITE(numout,*) ' e_tide : ', SUM( e1t*e2t*en_tmx ) / ( rn_tfe * rn_me ) * 1.e-12, 'TW' |
---|
| 508 | WRITE(numout,*) |
---|
| 509 | WRITE(numout,*) ' Initial profile of tidal vertical mixing' |
---|
| 510 | DO jk = 1, jpk |
---|
| 511 | DO jj = 1,jpj |
---|
| 512 | DO ji = 1,jpi |
---|
| 513 | zkz(ji,jj) = az_tmx(ji,jj,jk) /MAX( rn_n2min, rn2(ji,jj,jk) ) |
---|
| 514 | END DO |
---|
| 515 | END DO |
---|
| 516 | ze_z = SUM( e1t(:,:) * e2t(:,:) * zkz(:,:) * tmask_i(:,:) ) & |
---|
| 517 | & / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * tmask (:,:,jk) * tmask_i(:,:) ) ) |
---|
| 518 | WRITE(numout,*) ' jk= ', jk,' ', ze_z * 1.e4,' cm2/s' |
---|
| 519 | END DO |
---|
| 520 | DO jk = 1, jpk |
---|
| 521 | zkz(:,:) = az_tmx(:,:,jk) /rn_n2min |
---|
| 522 | ze_z = SUM( e1t(:,:) * e2t(:,:) * zkz(:,:) * tmask_i(:,:) ) & |
---|
| 523 | & / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * tmask (:,:,jk) * tmask_i(:,:) ) ) |
---|
| 524 | WRITE(numout,*) |
---|
| 525 | WRITE(numout,*) ' N2 min - jk= ', jk,' ', ze_z * 1.e4,' cm2/s min= ',MINVAL(zkz)*1.e4, & |
---|
| 526 | & 'max= ', MAXVAL(zkz)*1.e4, ' cm2/s' |
---|
| 527 | END DO |
---|
| 528 | ! |
---|
| 529 | ENDIF |
---|
[2528] | 530 | ! |
---|
[3294] | 531 | CALL wrk_dealloc( jpi,jpj, zem2, zek1, zkz, zfact, zhdep ) |
---|
| 532 | CALL wrk_dealloc( jpi,jpj,jpk, zpc ) |
---|
[2715] | 533 | ! |
---|
[3294] | 534 | IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx_init') |
---|
| 535 | ! |
---|
[1418] | 536 | END SUBROUTINE zdf_tmx_init |
---|
| 537 | |
---|
| 538 | #else |
---|
| 539 | !!---------------------------------------------------------------------- |
---|
| 540 | !! Default option Dummy module NO Tidal MiXing |
---|
| 541 | !!---------------------------------------------------------------------- |
---|
| 542 | LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .FALSE. !: tidal mixing flag |
---|
| 543 | CONTAINS |
---|
[2528] | 544 | SUBROUTINE zdf_tmx_init ! Dummy routine |
---|
| 545 | WRITE(*,*) 'zdf_tmx: You should not have seen this print! error?' |
---|
| 546 | END SUBROUTINE zdf_tmx_init |
---|
| 547 | SUBROUTINE zdf_tmx( kt ) ! Dummy routine |
---|
[1418] | 548 | WRITE(*,*) 'zdf_tmx: You should not have seen this print! error?', kt |
---|
| 549 | END SUBROUTINE zdf_tmx |
---|
| 550 | #endif |
---|
| 551 | |
---|
| 552 | !!====================================================================== |
---|
| 553 | END MODULE zdftmx |
---|