New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in branches/2012/dev_r3309_LOCEAN12_Ediag/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2012/dev_r3309_LOCEAN12_Ediag/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 3318

Last change on this file since 3318 was 3318, checked in by gm, 12 years ago

Ediag branche: #927 split TRA/DYN trd computation
  • Property svn:keywords set to Id
File size: 52.7 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!----------------------------------------------------------------------
19
20   !!----------------------------------------------------------------------
21   !!   dyn_hpg      : update the momentum trend with the now horizontal
22   !!                  gradient of the hydrostatic pressure
23   !!   dyn_hpg_init : initialisation and control of options
24   !!       hpg_zco  : z-coordinate scheme
25   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
26   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
27   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
28   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
29   !!----------------------------------------------------------------------
30   USE oce             ! ocean dynamics and tracers
31   USE dom_oce         ! ocean space and time domain
32   USE phycst          ! physical constants
33   USE trd_oce         ! trends: ocean variables
34   USE trddyn          ! trend manager: dynamics
35   USE in_out_manager  ! I/O manager
36   USE prtctl          ! Print control
37   USE lbclnk          ! lateral boundary condition
38   USE lib_mpp         ! MPP library
39   USE wrk_nemo        ! Memory Allocation
40   USE timing          ! Timing
41
42   IMPLICIT NONE
43   PRIVATE
44
45   PUBLIC   dyn_hpg        ! routine called by step module
46   PUBLIC   dyn_hpg_init   ! routine called by opa module
47
48   !                                              !!* Namelist namdyn_hpg : hydrostatic pressure gradient
49   LOGICAL , PUBLIC ::   ln_hpg_zco    = .TRUE.    !: z-coordinate - full steps
50   LOGICAL , PUBLIC ::   ln_hpg_zps    = .FALSE.   !: z-coordinate - partial steps (interpolation)
51   LOGICAL , PUBLIC ::   ln_hpg_sco    = .FALSE.   !: s-coordinate (standard jacobian formulation)
52   LOGICAL , PUBLIC ::   ln_hpg_djc    = .FALSE.   !: s-coordinate (Density Jacobian with Cubic polynomial)
53   LOGICAL , PUBLIC ::   ln_hpg_prj    = .FALSE.   !: s-coordinate (Pressure Jacobian scheme)
54   LOGICAL , PUBLIC ::   ln_dynhpg_imp = .FALSE.   !: semi-implicite hpg flag
55
56   INTEGER  ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags)
57
58   !! * Substitutions
59#  include "domzgr_substitute.h90"
60#  include "vectopt_loop_substitute.h90"
61   !!----------------------------------------------------------------------
62   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
63   !! $Id$
64   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE dyn_hpg( kt )
69      !!---------------------------------------------------------------------
70      !!                  ***  ROUTINE dyn_hpg  ***
71      !!
72      !! ** Method  :   Call the hydrostatic pressure gradient routine
73      !!              using the scheme defined in the namelist
74      !!   
75      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
76      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
77      !!----------------------------------------------------------------------
78      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
79      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
80      !!----------------------------------------------------------------------
81      !
82      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
83      !
84      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
85         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
86         ztrdu(:,:,:) = ua(:,:,:) 
87         ztrdv(:,:,:) = va(:,:,:) 
88      ENDIF     
89      !
90      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
91      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
92      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
93      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
94      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
95      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
96      END SELECT
97      !
98      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
99         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
100         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
101         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
102         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
103      ENDIF         
104      !
105      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
106         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
107      !
108      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
109      !
110   END SUBROUTINE dyn_hpg
111
112
113   SUBROUTINE dyn_hpg_init
114      !!----------------------------------------------------------------------
115      !!                 ***  ROUTINE dyn_hpg_init  ***
116      !!
117      !! ** Purpose :   initializations for the hydrostatic pressure gradient
118      !!              computation and consistency control
119      !!
120      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
121      !!      with the type of vertical coordinate used (zco, zps, sco)
122      !!----------------------------------------------------------------------
123      INTEGER ::   ioptio = 0      ! temporary integer
124      !!
125      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
126         &                 ln_hpg_djc, ln_hpg_prj, ln_dynhpg_imp
127      !!----------------------------------------------------------------------
128      !
129      REWIND( numnam )               ! Read Namelist namdyn_hpg
130      READ  ( numnam, namdyn_hpg )
131      !
132      IF(lwp) THEN                   ! Control print
133         WRITE(numout,*)
134         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
135         WRITE(numout,*) '~~~~~~~~~~~~'
136         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
137         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
138         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
139         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
140         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
141         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
142         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
143      ENDIF
144      !
145      IF( ln_hpg_djc )   &
146         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
147                           & currently disabled (bugs under investigation). Please select &
148                           & either  ln_hpg_sco or  ln_hpg_prj instead')
149      !
150      IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj) )   &
151         &   CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
152                           & the standard jacobian formulation hpg_sco or &
153                           & the pressure jacobian formulation hpg_prj')
154      !
155      !                               ! Set nhpg from ln_hpg_... flags
156      IF( ln_hpg_zco )   nhpg = 0
157      IF( ln_hpg_zps )   nhpg = 1
158      IF( ln_hpg_sco )   nhpg = 2
159      IF( ln_hpg_djc )   nhpg = 3
160      IF( ln_hpg_prj )   nhpg = 4
161      !
162      !                               ! Consistency check
163      ioptio = 0 
164      IF( ln_hpg_zco )   ioptio = ioptio + 1
165      IF( ln_hpg_zps )   ioptio = ioptio + 1
166      IF( ln_hpg_sco )   ioptio = ioptio + 1
167      IF( ln_hpg_djc )   ioptio = ioptio + 1
168      IF( ln_hpg_prj )   ioptio = ioptio + 1
169      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
170      !
171   END SUBROUTINE dyn_hpg_init
172
173
174   SUBROUTINE hpg_zco( kt )
175      !!---------------------------------------------------------------------
176      !!                  ***  ROUTINE hpg_zco  ***
177      !!
178      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
179      !!      The now hydrostatic pressure gradient at a given level, jk,
180      !!      is computed by taking the vertical integral of the in-situ
181      !!      density gradient along the model level from the suface to that
182      !!      level:    zhpi = grav .....
183      !!                zhpj = grav .....
184      !!      add it to the general momentum trend (ua,va).
185      !!            ua = ua - 1/e1u * zhpi
186      !!            va = va - 1/e2v * zhpj
187      !!
188      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
189      !!----------------------------------------------------------------------
190      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
191      !!
192      INTEGER  ::   ji, jj, jk       ! dummy loop indices
193      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
194      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj 
195      !!----------------------------------------------------------------------
196      ! 
197      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
198      !
199      IF( kt == nit000 ) THEN
200         IF(lwp) WRITE(numout,*)
201         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
202         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
203      ENDIF
204     
205      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
206
207      ! Surface value
208      DO jj = 2, jpjm1
209         DO ji = fs_2, fs_jpim1   ! vector opt.
210            zcoef1 = zcoef0 * fse3w(ji,jj,1)
211            ! hydrostatic pressure gradient
212            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
213            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
214            ! add to the general momentum trend
215            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
216            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
217         END DO
218      END DO
219
220      !
221      ! interior value (2=<jk=<jpkm1)
222      DO jk = 2, jpkm1
223         DO jj = 2, jpjm1
224            DO ji = fs_2, fs_jpim1   ! vector opt.
225               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
226               ! hydrostatic pressure gradient
227               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
228                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
229                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
230
231               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
232                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
233                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
234               ! add to the general momentum trend
235               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
236               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
237            END DO
238         END DO
239      END DO
240      !
241      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
242      !
243   END SUBROUTINE hpg_zco
244
245
246   SUBROUTINE hpg_zps( kt )
247      !!---------------------------------------------------------------------
248      !!                 ***  ROUTINE hpg_zps  ***
249      !!                   
250      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
251      !!
252      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
253      !!----------------------------------------------------------------------
254      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
255      !!
256      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
257      INTEGER  ::   iku, ikv                         ! temporary integers
258      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
259      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj 
260      !!----------------------------------------------------------------------
261      !
262      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
263      !
264      IF( kt == nit000 ) THEN
265         IF(lwp) WRITE(numout,*)
266         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
267         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
268      ENDIF
269
270
271      ! Local constant initialization
272      zcoef0 = - grav * 0.5_wp
273
274      !  Surface value (also valid in partial step case)
275      DO jj = 2, jpjm1
276         DO ji = fs_2, fs_jpim1   ! vector opt.
277            zcoef1 = zcoef0 * fse3w(ji,jj,1)
278            ! hydrostatic pressure gradient
279            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
280            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
281            ! add to the general momentum trend
282            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
283            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
284         END DO
285      END DO
286
287
288      ! interior value (2=<jk=<jpkm1)
289      DO jk = 2, jpkm1
290         DO jj = 2, jpjm1
291            DO ji = fs_2, fs_jpim1   ! vector opt.
292               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
293               ! hydrostatic pressure gradient
294               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
295                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
296                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
297
298               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
299                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
300                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
301               ! add to the general momentum trend
302               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
303               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
304            END DO
305         END DO
306      END DO
307
308
309      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
310# if defined key_vectopt_loop
311         jj = 1
312         DO ji = jpi+2, jpij-jpi-1   ! vector opt. (forced unrolling)
313# else
314      DO jj = 2, jpjm1
315         DO ji = 2, jpim1
316# endif
317            iku = mbku(ji,jj)
318            ikv = mbkv(ji,jj)
319            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
320            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
321            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
322               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
323               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
324                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
325               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
326            ENDIF
327            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
328               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
329               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
330                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
331               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
332            ENDIF
333# if ! defined key_vectopt_loop
334         END DO
335# endif
336      END DO
337      !
338      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
339      !
340   END SUBROUTINE hpg_zps
341
342
343   SUBROUTINE hpg_sco( kt )
344      !!---------------------------------------------------------------------
345      !!                  ***  ROUTINE hpg_sco  ***
346      !!
347      !! ** Method  :   s-coordinate case. Jacobian scheme.
348      !!      The now hydrostatic pressure gradient at a given level, jk,
349      !!      is computed by taking the vertical integral of the in-situ
350      !!      density gradient along the model level from the suface to that
351      !!      level. s-coordinates (ln_sco): a corrective term is added
352      !!      to the horizontal pressure gradient :
353      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
354      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
355      !!      add it to the general momentum trend (ua,va).
356      !!         ua = ua - 1/e1u * zhpi
357      !!         va = va - 1/e2v * zhpj
358      !!
359      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
360      !!----------------------------------------------------------------------
361      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
362      !!
363      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
364      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
365      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj 
366      !!----------------------------------------------------------------------
367      !
368      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
369      !
370      IF( kt == nit000 ) THEN
371         IF(lwp) WRITE(numout,*)
372         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
373         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
374      ENDIF
375
376      ! Local constant initialization
377      zcoef0 = - grav * 0.5_wp
378      ! To use density and not density anomaly
379      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
380      ELSE                 ;     znad = 0._wp         ! Fixed volume
381      ENDIF
382
383      ! Surface value
384      DO jj = 2, jpjm1
385         DO ji = fs_2, fs_jpim1   ! vector opt.   
386            ! hydrostatic pressure gradient along s-surfaces
387            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
388               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
389            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
390               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
391            ! s-coordinate pressure gradient correction
392            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
393               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
394            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
395               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
396            ! add to the general momentum trend
397            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
398            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
399         END DO 
400      END DO   
401           
402      ! interior value (2=<jk=<jpkm1)
403      DO jk = 2, jpkm1                                 
404         DO jj = 2, jpjm1     
405            DO ji = fs_2, fs_jpim1   ! vector opt.     
406               ! hydrostatic pressure gradient along s-surfaces
407               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   & 
408                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   & 
409                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
410               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
411                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
412                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
413               ! s-coordinate pressure gradient correction
414               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
415                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
416               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
417                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
418               ! add to the general momentum trend
419               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
420               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
421            END DO
422         END DO
423      END DO
424      !
425      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
426      !
427   END SUBROUTINE hpg_sco
428
429
430   SUBROUTINE hpg_djc( kt )
431      !!---------------------------------------------------------------------
432      !!                  ***  ROUTINE hpg_djc  ***
433      !!
434      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
435      !!
436      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
437      !!----------------------------------------------------------------------
438      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
439      !!
440      INTEGER  ::   ji, jj, jk          ! dummy loop indices
441      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
442      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
443      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
444      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj 
445      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
446      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
447      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
448      !!----------------------------------------------------------------------
449      !
450      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   ) 
451      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow ) 
452      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        ) 
453      !
454
455      IF( kt == nit000 ) THEN
456         IF(lwp) WRITE(numout,*)
457         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
458         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
459      ENDIF
460
461      ! Local constant initialization
462      zcoef0 = - grav * 0.5_wp
463      z1_10  = 1._wp / 10._wp
464      z1_12  = 1._wp / 12._wp
465
466      !----------------------------------------------------------------------------------------
467      !  compute and store in provisional arrays elementary vertical and horizontal differences
468      !----------------------------------------------------------------------------------------
469
470!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
471
472      DO jk = 2, jpkm1
473         DO jj = 2, jpjm1
474            DO ji = fs_2, fs_jpim1   ! vector opt.
475               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
476               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
477               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
478               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
479               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
480               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
481            END DO
482         END DO
483      END DO
484
485      !-------------------------------------------------------------------------
486      ! compute harmonic averages using eq. 5.18
487      !-------------------------------------------------------------------------
488      zep = 1.e-15
489
490!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
491!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
492
493      DO jk = 2, jpkm1
494         DO jj = 2, jpjm1
495            DO ji = fs_2, fs_jpim1   ! vector opt.
496               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
497
498               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
499               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
500 
501               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
502               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
503
504               IF( cffw > zep) THEN
505                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
506                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
507               ELSE
508                  drhow(ji,jj,jk) = 0._wp
509               ENDIF
510
511               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
512                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
513
514               IF( cffu > zep ) THEN
515                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
516                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
517               ELSE
518                  drhou(ji,jj,jk ) = 0._wp
519               ENDIF
520
521               IF( cffx > zep ) THEN
522                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
523                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
524               ELSE
525                  dzu(ji,jj,jk) = 0._wp
526               ENDIF
527
528               IF( cffv > zep ) THEN
529                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
530                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
531               ELSE
532                  drhov(ji,jj,jk) = 0._wp
533               ENDIF
534
535               IF( cffy > zep ) THEN
536                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
537                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
538               ELSE
539                  dzv(ji,jj,jk) = 0._wp
540               ENDIF
541
542            END DO
543         END DO
544      END DO
545
546      !----------------------------------------------------------------------------------
547      ! apply boundary conditions at top and bottom using 5.36-5.37
548      !----------------------------------------------------------------------------------
549      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
550      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
551      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
552
553      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
554      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
555      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
556
557
558      !--------------------------------------------------------------
559      ! Upper half of top-most grid box, compute and store
560      !-------------------------------------------------------------
561
562!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
563!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
564
565      DO jj = 2, jpjm1
566         DO ji = fs_2, fs_jpim1   ! vector opt.
567            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )               &
568               &                   * (  rhd(ji,jj,1)                                    &
569               &                     + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
570               &                              * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
571               &                              / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  ) 
572         END DO
573      END DO
574
575!!bug gm    : here also, simplification is possible
576!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
577
578      DO jk = 2, jpkm1
579         DO jj = 2, jpjm1
580            DO ji = fs_2, fs_jpim1   ! vector opt.
581
582               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
583                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
584                  &            - grav * z1_10 * (                                                                     &
585                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
586                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
587                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
588                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
589                  &                             )
590
591               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
592                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
593                  &            - grav* z1_10 * (                                                                      &
594                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
595                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
596                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
597                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
598                  &                            )
599
600               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
601                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
602                  &            - grav* z1_10 * (                                                                      &
603                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
604                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
605                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
606                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
607                  &                            )
608
609            END DO
610         END DO
611      END DO
612      CALL lbc_lnk(rho_k,'W',1.)
613      CALL lbc_lnk(rho_i,'U',1.)
614      CALL lbc_lnk(rho_j,'V',1.)
615
616
617      ! ---------------
618      !  Surface value
619      ! ---------------
620      DO jj = 2, jpjm1
621         DO ji = fs_2, fs_jpim1   ! vector opt.
622            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
623            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
624            ! add to the general momentum trend
625            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
626            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
627         END DO
628      END DO
629
630      ! ----------------
631      !  interior value   (2=<jk=<jpkm1)
632      ! ----------------
633      DO jk = 2, jpkm1
634         DO jj = 2, jpjm1 
635            DO ji = fs_2, fs_jpim1   ! vector opt.
636               ! hydrostatic pressure gradient along s-surfaces
637               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
638                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
639                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
640               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
641                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
642                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
643               ! add to the general momentum trend
644               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
645               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
646            END DO
647         END DO
648      END DO
649      !
650      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   ) 
651      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow ) 
652      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        ) 
653      !
654   END SUBROUTINE hpg_djc
655
656
657   SUBROUTINE hpg_prj( kt )
658      !!---------------------------------------------------------------------
659      !!                  ***  ROUTINE hpg_prj  ***
660      !!
661      !! ** Method  :   s-coordinate case.
662      !!      A Pressure-Jacobian horizontal pressure gradient method
663      !!      based on the constrained cubic-spline interpolation for
664      !!      all vertical coordinate systems
665      !!
666      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
667      !!----------------------------------------------------------------------
668      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
669      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
670      !!
671      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
672      REAL(wp) ::   zcoef0, znad                    ! temporary scalars
673      !!
674      !! The local variables for the correction term
675      INTEGER  :: jk1, jis, jid, jjs, jjd
676      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
677      REAL(wp) :: zrhdt1 
678      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
679      INTEGER  :: zbhitwe, zbhitns
680      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdeptht, zrhh 
681      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
682      !!----------------------------------------------------------------------
683      !
684      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp ) 
685      CALL wrk_alloc( jpi,jpj,jpk, zdeptht, zrhh ) 
686      !
687      IF( kt == nit000 ) THEN
688         IF(lwp) WRITE(numout,*)
689         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
690         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
691      ENDIF
692
693      !!----------------------------------------------------------------------
694      ! Local constant initialization
695      zcoef0 = - grav 
696      znad = 0.0_wp
697      IF( lk_vvl ) znad = 1._wp
698
699      ! Clean 3-D work arrays
700      zhpi(:,:,:) = 0._wp
701      zrhh(:,:,:) = rhd(:,:,:)
702     
703      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
704      DO jj = 1, jpj
705        DO ji = 1, jpi   
706          jk = mbathy(ji,jj)
707          IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
708          ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
709          ELSE IF(jk < jpkm1) THEN
710             DO jkk = jk+1, jpk
711                zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk),   fsde3w(ji,jj,jkk-1), &
712                                         fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
713             END DO
714          ENDIF
715        END DO
716      END DO
717
718      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdeptht(:,:,:)"
719      DO jj = 1, jpj
720        DO ji = 1, jpi
721          zdeptht(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1)
722          zdeptht(ji,jj,1) = zdeptht(ji,jj,1) - sshn(ji,jj) * znad
723          DO jk = 2, jpk
724             zdeptht(ji,jj,jk) = zdeptht(ji,jj,jk-1) + fse3w(ji,jj,jk)
725          END DO
726        END DO
727      END DO
728
729      DO jk = 1, jpkm1
730        DO jj = 1, jpj
731          DO ji = 1, jpi
732            fsp(ji,jj,jk) = zrhh(ji,jj,jk)
733            xsp(ji,jj,jk) = zdeptht(ji,jj,jk)
734          END DO
735        END DO
736      END DO
737
738      ! Construct the vertical density profile with the
739      ! constrained cubic spline interpolation
740      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
741      CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)     
742
743      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
744      DO jj = 2, jpj
745        DO ji = 2, jpi 
746          zrhdt1 = zrhh(ji,jj,1) - interp3(zdeptht(ji,jj,1),asp(ji,jj,1), &
747                                         bsp(ji,jj,1),   csp(ji,jj,1), &
748                                         dsp(ji,jj,1) ) * 0.5_wp * zdeptht(ji,jj,1)
749          zrhdt1 = MAX(zrhdt1, 1000._wp - rau0)        ! no lighter than fresh water
750
751          ! assuming linear profile across the top half surface layer
752          zhpi(ji,jj,1) =  0.5_wp * fse3w(ji,jj,1) * zrhdt1 
753        END DO
754      END DO
755
756      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
757      DO jk = 2, jpkm1                                 
758        DO jj = 2, jpj     
759          DO ji = 2, jpi
760            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                          &
761                             integ2(zdeptht(ji,jj,jk-1), zdeptht(ji,jj,jk),&
762                                    asp(ji,jj,jk-1),    bsp(ji,jj,jk-1), &
763                                    csp(ji,jj,jk-1),    dsp(ji,jj,jk-1))
764          END DO
765        END DO
766      END DO
767
768      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
769      DO jj = 2, jpjm1     
770        DO ji = 2, jpim1 
771          zu(ji,jj,1) = - ( fse3u(ji,jj,1) - sshu_n(ji,jj) * znad)
772          zv(ji,jj,1) = - ( fse3v(ji,jj,1) - sshv_n(ji,jj) * znad)
773        END DO
774      END DO
775
776      DO jk = 2, jpkm1                                 
777        DO jj = 2, jpjm1     
778          DO ji = 2, jpim1 
779            zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
780            zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
781          END DO
782        END DO
783      END DO
784               
785      DO jk = 1, jpkm1                                 
786        DO jj = 2, jpjm1     
787          DO ji = 2, jpim1 
788            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
789            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
790          END DO
791        END DO
792      END DO
793
794      DO jk = 1, jpkm1                                 
795        DO jj = 2, jpjm1     
796          DO ji = 2, jpim1 
797            zpwes = 0._wp; zpwed = 0._wp
798            zpnss = 0._wp; zpnsd = 0._wp
799            zuijk = zu(ji,jj,jk)
800            zvijk = zv(ji,jj,jk)
801
802            !!!!!     for u equation
803            IF( jk <= mbku(ji,jj) ) THEN
804               IF( -zdeptht(ji+1,jj,mbku(ji,jj)) >= -zdeptht(ji,jj,mbku(ji,jj)) ) THEN
805                 jis = ji + 1; jid = ji
806               ELSE
807                 jis = ji;     jid = ji +1
808               ENDIF
809
810               ! integrate the pressure on the shallow side
811               jk1 = jk 
812               zbhitwe = 0
813               DO WHILE ( -zdeptht(jis,jj,jk1) > zuijk )
814                 IF( jk1 == mbku(ji,jj) ) THEN
815                   zbhitwe = 1
816                   EXIT
817                 ENDIF
818                 zdeps = MIN(zdeptht(jis,jj,jk1+1), -zuijk)
819                 zpwes = zpwes +                                    & 
820                      integ2(zdeptht(jis,jj,jk1), zdeps,            &
821                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
822                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
823                 jk1 = jk1 + 1
824               END DO
825           
826               IF(zbhitwe == 1) THEN
827                 zuijk = -zdeptht(jis,jj,jk1)
828               ENDIF
829
830               ! integrate the pressure on the deep side
831               jk1 = jk 
832               zbhitwe = 0
833               DO WHILE ( -zdeptht(jid,jj,jk1) < zuijk )
834                 IF( jk1 == 1 ) THEN
835                   zbhitwe = 1
836                   EXIT
837                 ENDIF
838                 zdeps = MAX(zdeptht(jid,jj,jk1-1), -zuijk)
839                 zpwed = zpwed +                                        & 
840                        integ2(zdeps,              zdeptht(jid,jj,jk1), &
841                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
842                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
843                 jk1 = jk1 - 1
844               END DO
845           
846               IF( zbhitwe == 1 ) THEN
847                 zdeps = zdeptht(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
848                 zrhdt1 = zrhh(jid,jj,1) - interp3(zdeptht(jid,jj,1), asp(jid,jj,1), &
849                                                 bsp(jid,jj,1),    csp(jid,jj,1), &
850                                                 dsp(jid,jj,1)) * zdeps
851                 zrhdt1 = MAX(zrhdt1, 1000._wp - rau0)        ! no lighter than fresh water
852                 zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
853               ENDIF
854
855               ! update the momentum trends in u direction
856
857               zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
858               IF( lk_vvl ) THEN
859                 zdpdx2 = zcoef0 / e1u(ji,jj) * & 
860                         ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) ) 
861                ELSE
862                 zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed) 
863               ENDIF
864
865               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
866               &           umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
867            ENDIF
868 
869            !!!!!     for v equation
870            IF( jk <= mbkv(ji,jj) ) THEN
871               IF( -zdeptht(ji,jj+1,mbkv(ji,jj)) >= -zdeptht(ji,jj,mbkv(ji,jj)) ) THEN
872                 jjs = jj + 1; jjd = jj
873               ELSE
874                 jjs = jj    ; jjd = jj + 1
875               ENDIF
876
877               ! integrate the pressure on the shallow side
878               jk1 = jk 
879               zbhitns = 0
880               DO WHILE ( -zdeptht(ji,jjs,jk1) > zvijk )
881                 IF( jk1 == mbkv(ji,jj) ) THEN
882                   zbhitns = 1
883                   EXIT
884                 ENDIF
885                 zdeps = MIN(zdeptht(ji,jjs,jk1+1), -zvijk)
886                 zpnss = zpnss +                                      & 
887                        integ2(zdeptht(ji,jjs,jk1), zdeps,            &
888                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
889                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
890                 jk1 = jk1 + 1
891               END DO
892           
893               IF(zbhitns == 1) THEN
894                 zvijk = -zdeptht(ji,jjs,jk1)
895               ENDIF
896
897               ! integrate the pressure on the deep side
898               jk1 = jk 
899               zbhitns = 0
900               DO WHILE ( -zdeptht(ji,jjd,jk1) < zvijk )
901                 IF( jk1 == 1 ) THEN
902                   zbhitns = 1
903                   EXIT
904                 ENDIF
905                 zdeps = MAX(zdeptht(ji,jjd,jk1-1), -zvijk)
906                 zpnsd = zpnsd +                                        & 
907                        integ2(zdeps,              zdeptht(ji,jjd,jk1), &
908                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
909                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
910                 jk1 = jk1 - 1
911               END DO
912           
913               IF( zbhitns == 1 ) THEN
914                 zdeps = zdeptht(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
915                 zrhdt1 = zrhh(ji,jjd,1) - interp3(zdeptht(ji,jjd,1), asp(ji,jjd,1), &
916                                                 bsp(ji,jjd,1),    csp(ji,jjd,1), &
917                                                 dsp(ji,jjd,1) ) * zdeps
918                 zrhdt1 = MAX(zrhdt1, 1000._wp - rau0)        ! no lighter than fresh water
919                 zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
920               ENDIF
921
922               ! update the momentum trends in v direction
923
924               zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
925               IF( lk_vvl ) THEN
926                   zdpdy2 = zcoef0 / e2v(ji,jj) * &
927                           ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) ) 
928               ELSE
929                   zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd ) 
930               ENDIF
931
932               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
933               &              vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
934            ENDIF
935
936                   
937           END DO
938        END DO
939      END DO
940      !
941      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp ) 
942      CALL wrk_dealloc( jpi,jpj,jpk, zdeptht, zrhh ) 
943      !
944   END SUBROUTINE hpg_prj
945
946   SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
947      !!----------------------------------------------------------------------
948      !!                 ***  ROUTINE cspline  ***
949      !!       
950      !! ** Purpose :   constrained cubic spline interpolation
951      !!         
952      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
953      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
954      !!
955      !!----------------------------------------------------------------------
956      IMPLICIT NONE
957      REAL(wp), DIMENSION(:,:,:), INTENT(in)  :: fsp, xsp           ! value and coordinate
958      REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
959                                                                    ! the interpoated function
960      INTEGER, INTENT(in) :: polynomial_type                        ! 1: cubic spline
961                                                                    ! 2: Linear
962
963      ! Local Variables     
964      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
965      INTEGER  ::   jpi, jpj, jpkm1
966      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
967      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
968      REAL(wp) ::   zdf(size(fsp,3))
969      !!----------------------------------------------------------------------
970
971      jpi   = size(fsp,1)
972      jpj   = size(fsp,2)
973      jpkm1 = size(fsp,3) - 1
974
975     
976      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
977         DO ji = 1, jpi
978            DO jj = 1, jpj
979           !!Fritsch&Butland's method, 1984 (preferred, but more computation)             
980           !    DO jk = 2, jpkm1-1
981           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1) 
982           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk) 
983           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
984           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
985           !
986           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
987           !     
988           !       IF(zdf1 * zdf2 <= 0._wp) THEN
989           !           zdf(jk) = 0._wp
990           !       ELSE
991           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
992           !       ENDIF
993           !    END DO
994           
995           !!Simply geometric average
996               DO jk = 2, jpkm1-1
997                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
998                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
999           
1000                  IF(zdf1 * zdf2 <= 0._wp) THEN
1001                     zdf(jk) = 0._wp
1002                  ELSE
1003                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1004                  ENDIF
1005               END DO
1006           
1007               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1008                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) ) -  0.5_wp * zdf(2)
1009               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1010                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1011                          & 0.5_wp * zdf(jpkm1 - 1)
1012   
1013               DO jk = 1, jpkm1 - 1
1014                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk) 
1015                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1016                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1017                 zddf1  = -2._wp * ztmp1 + ztmp2 
1018                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1019                 zddf2  =  2._wp * ztmp1 - ztmp2 
1020     
1021                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1022                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1023                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - & 
1024                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1025                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1026                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1027                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1028                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1029                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1030               END DO
1031            END DO
1032         END DO
1033 
1034      ELSE IF (polynomial_type == 2) THEN     ! Linear
1035         DO ji = 1, jpi
1036            DO jj = 1, jpj
1037               DO jk = 1, jpkm1-1
1038                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk) 
1039                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1040   
1041                  dsp(ji,jj,jk) = 0._wp
1042                  csp(ji,jj,jk) = 0._wp
1043                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1044                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1045               END DO
1046            END DO
1047         END DO
1048
1049      ELSE
1050           CALL ctl_stop( 'invalid polynomial type in cspline' )
1051      ENDIF
1052
1053     
1054   END SUBROUTINE cspline
1055
1056
1057   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f) 
1058      !!----------------------------------------------------------------------
1059      !!                 ***  ROUTINE interp1  ***
1060      !!       
1061      !! ** Purpose :   1-d linear interpolation
1062      !!         
1063      !! ** Method  : 
1064      !!                interpolation is straight forward
1065      !!                extrapolation is also permitted (no value limit)
1066      !!
1067      !!----------------------------------------------------------------------
1068      IMPLICIT NONE
1069      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr   
1070      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1071      REAL(wp)             ::  zdeltx
1072      !!----------------------------------------------------------------------
1073
1074      zdeltx = xr - xl
1075      IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1076        f = 0.5_wp * (fl + fr)
1077      ELSE
1078        f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1079      ENDIF
1080     
1081   END FUNCTION interp1
1082
1083   FUNCTION interp2(x, a, b, c, d)  RESULT(f) 
1084      !!----------------------------------------------------------------------
1085      !!                 ***  ROUTINE interp1  ***
1086      !!       
1087      !! ** Purpose :   1-d constrained cubic spline interpolation
1088      !!         
1089      !! ** Method  :  cubic spline interpolation
1090      !!
1091      !!----------------------------------------------------------------------
1092      IMPLICIT NONE
1093      REAL(wp), INTENT(in) ::  x, a, b, c, d   
1094      REAL(wp)             ::  f ! value from the interpolation
1095      !!----------------------------------------------------------------------
1096
1097      f = a + x* ( b + x * ( c + d * x ) ) 
1098
1099   END FUNCTION interp2
1100
1101
1102   FUNCTION interp3(x, a, b, c, d)  RESULT(f) 
1103      !!----------------------------------------------------------------------
1104      !!                 ***  ROUTINE interp1  ***
1105      !!       
1106      !! ** Purpose :   Calculate the first order of deriavtive of
1107      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1108      !!         
1109      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1110      !!
1111      !!----------------------------------------------------------------------
1112      IMPLICIT NONE
1113      REAL(wp), INTENT(in) ::  x, a, b, c, d   
1114      REAL(wp)             ::  f ! value from the interpolation
1115      !!----------------------------------------------------------------------
1116
1117      f = b + x * ( 2._wp * c + 3._wp * d * x)
1118
1119   END FUNCTION interp3
1120
1121   
1122   FUNCTION integ2(xl, xr, a, b, c, d)  RESULT(f) 
1123      !!----------------------------------------------------------------------
1124      !!                 ***  ROUTINE interp1  ***
1125      !!       
1126      !! ** Purpose :   1-d constrained cubic spline integration
1127      !!         
1128      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1129      !!
1130      !!----------------------------------------------------------------------
1131      IMPLICIT NONE
1132      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d   
1133      REAL(wp)             ::  za1, za2, za3     
1134      REAL(wp)             ::  f                   ! integration result
1135      !!----------------------------------------------------------------------
1136
1137      za1 = 0.5_wp * b 
1138      za2 = c / 3.0_wp 
1139      za3 = 0.25_wp * d 
1140
1141      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1142         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1143
1144   END FUNCTION integ2
1145
1146
1147   !!======================================================================
1148END MODULE dynhpg
Note: See TracBrowser for help on using the repository browser.