New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traqsr.F90 in branches/2012/dev_r3309_LOCEAN12_Ediag/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2012/dev_r3309_LOCEAN12_Ediag/NEMOGCM/NEMO/OPA_SRC/TRA/traqsr.F90 @ 3330

Last change on this file since 3330 was 3326, checked in by gm, 12 years ago

Ediag branche: #927 add Potential Energy trend diagnostics (trdpen.F90)
  • Property svn:keywords set to Id
File size: 27.0 KB
Line 
1MODULE traqsr
2   !!======================================================================
3   !!                       ***  MODULE  traqsr  ***
4   !! Ocean physics: solar radiation penetration in the top ocean levels
5   !!======================================================================
6   !! History :  OPA  !  1990-10  (B. Blanke)  Original code
7   !!            7.0  !  1991-11  (G. Madec)
8   !!                 !  1996-01  (G. Madec)  s-coordinates
9   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
10   !!             -   !  2005-11  (G. Madec) zco, zps, sco coordinate
11   !!            3.2  !  2009-04  (G. Madec & NEMO team)
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_qsr       : trend due to the solar radiation penetration
16   !!   tra_qsr_init  : solar radiation penetration initialization
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   USE sbc_oce        ! surface boundary condition: ocean
21   USE trc_oce        ! share SMS/Ocean variables
22   USE trd_oce        ! trends: ocean variables
23   USE trdtra         ! trends manager: tracers
24   USE phycst         ! physical constants
25   USE in_out_manager ! I/O manager
26   USE prtctl         ! Print control
27   USE iom            ! I/O manager
28   USE fldread        ! read input fields
29   USE restart        ! ocean restart
30   USE lib_mpp        ! MPP library
31   USE wrk_nemo       ! Memory Allocation
32   USE timing         ! Timing
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   tra_qsr       ! routine called by step.F90 (ln_traqsr=T)
38   PUBLIC   tra_qsr_init  ! routine called by opa.F90
39
40   !                                           !!* Namelist namtra_qsr: penetrative solar radiation
41   LOGICAL , PUBLIC ::   ln_traqsr  = .TRUE.    !: light absorption (qsr) flag
42   LOGICAL , PUBLIC ::   ln_qsr_rgb = .FALSE.   !: Red-Green-Blue light absorption flag 
43   LOGICAL , PUBLIC ::   ln_qsr_2bd = .TRUE.    !: 2 band         light absorption flag
44   LOGICAL , PUBLIC ::   ln_qsr_bio = .FALSE.   !: bio-model      light absorption flag
45   INTEGER , PUBLIC ::   nn_chldta  = 0         !: use Chlorophyll data (=1) or not (=0)
46   REAL(wp), PUBLIC ::   rn_abs     = 0.58_wp   !: fraction absorbed in the very near surface (RGB & 2 bands)
47   REAL(wp), PUBLIC ::   rn_si0     = 0.35_wp   !: very near surface depth of extinction      (RGB & 2 bands)
48   REAL(wp), PUBLIC ::   rn_si1     = 23.0_wp   !: deepest depth of extinction (water type I)       (2 bands)
49   
50   INTEGER , PUBLIC ::   nksr   !: levels below which the light cannot penetrate ( depth larger than 391 m)
51
52   REAL(wp)                  ::   xsi0r, xsi1r        ! inverse of rn_si0 and rn_si1, resp.
53   REAL(wp), DIMENSION(3,61) ::   rkrgb               ! tabulated attenuation coefficients for RGB absorption
54   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_chl   ! structure of input Chl (file informations, fields read)
55
56   !! * Substitutions
57#  include "domzgr_substitute.h90"
58#  include "vectopt_loop_substitute.h90"
59   !!----------------------------------------------------------------------
60   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
61   !! $Id$
62   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
63   !!----------------------------------------------------------------------
64CONTAINS
65
66   SUBROUTINE tra_qsr( kt )
67      !!----------------------------------------------------------------------
68      !!                  ***  ROUTINE tra_qsr  ***
69      !!
70      !! ** Purpose :   Compute the temperature trend due to the solar radiation
71      !!      penetration and add it to the general temperature trend.
72      !!
73      !! ** Method  : The profile of the solar radiation within the ocean is defined
74      !!      through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs
75      !!      Considering the 2 wavebands case:
76      !!         I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) )
77      !!         The temperature trend associated with the solar radiation penetration
78      !!         is given by : zta = 1/e3t dk[ I ] / (rau0*Cp)
79      !!         At the bottom, boudary condition for the radiation is no flux :
80      !!      all heat which has not been absorbed in the above levels is put
81      !!      in the last ocean level.
82      !!         In z-coordinate case, the computation is only done down to the
83      !!      level where I(k) < 1.e-15 W/m2. In addition, the coefficients
84      !!      used for the computation are calculated one for once as they
85      !!      depends on k only.
86      !!
87      !! ** Action  : - update ta with the penetrative solar radiation trend
88      !!              - send the trend to trdtra (l_trdtra=T)
89      !!
90      !! Reference  : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
91      !!              Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516.
92      !!----------------------------------------------------------------------
93      INTEGER, INTENT(in) ::   kt     ! ocean time-step
94      !
95      INTEGER  ::   ji, jj, jk           ! dummy loop indices
96      INTEGER  ::   irgb                 ! local integers
97      REAL(wp) ::   zchl, zcoef, zfact   ! local scalars
98      REAL(wp) ::   zc0, zc1, zc2, zc3   !    -         -
99      REAL(wp) ::   zz0, zz1, z1_e3t     !    -         -
100      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
101      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea, ztrdt
102      !!----------------------------------------------------------------------
103      !
104      IF( nn_timing == 1 )  CALL timing_start('tra_qsr')
105      !
106      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        ) 
107      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
108      !
109      IF( kt == nit000 ) THEN
110         IF(lwp) WRITE(numout,*)
111         IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation'
112         IF(lwp) WRITE(numout,*) '~~~~~~~'
113         IF( .NOT.ln_traqsr )   RETURN
114      ENDIF
115
116      IF( l_trdtra ) THEN      ! Save temperature trend
117         CALL wrk_alloc( jpi, jpj, jpk, ztrdt ) 
118         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
119      ENDIF
120
121      !                                        Set before qsr tracer content field
122      !                                        ***********************************
123      IF( kt == nit000 ) THEN                     ! Set the forcing field at nit000 - 1
124         !                                        ! -----------------------------------
125         IF( ln_rstart .AND.    &                    ! Restart: read in restart file
126              & iom_varid( numror, 'qsr_hc_b', ldstop = .FALSE. ) > 0 ) THEN
127            IF(lwp) WRITE(numout,*) '          nit000-1 qsr tracer content forcing field red in the restart file'
128            zfact = 0.5e0
129            CALL iom_get( numror, jpdom_autoglo, 'qsr_hc_b', qsr_hc_b )   ! before heat content trend due to Qsr flux
130         ELSE                                           ! No restart or restart not found: Euler forward time stepping
131            zfact = 1.e0
132            qsr_hc_b(:,:,:) = 0.e0
133         ENDIF
134      ELSE                                        ! Swap of forcing field
135         !                                        ! ---------------------
136         zfact = 0.5e0
137         qsr_hc_b(:,:,:) = qsr_hc(:,:,:)
138      ENDIF
139      !                                        Compute now qsr tracer content field
140      !                                        ************************************
141      !                                           ! ============================================== !
142      IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN      !  bio-model fluxes  : all vertical coordinates  !
143         !                                        ! ============================================== !
144         DO jk = 1, jpkm1
145            qsr_hc(:,:,jk) = ro0cpr * ( etot3(:,:,jk) - etot3(:,:,jk+1) )
146         END DO
147         !                                        Add to the general trend
148         DO jk = 1, jpkm1
149            DO jj = 2, jpjm1 
150               DO ji = fs_2, fs_jpim1   ! vector opt.
151                  z1_e3t = zfact / fse3t(ji,jj,jk)
152                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
153               END DO
154            END DO
155         END DO
156         CALL iom_put( 'qsr3d', etot3 )   ! Shortwave Radiation 3D distribution
157         !                                        ! ============================================== !
158      ELSE                                        !  Ocean alone :
159         !                                        ! ============================================== !
160         !
161         !                                                ! ------------------------- !
162         IF( ln_qsr_rgb) THEN                             !  R-G-B  light penetration !
163            !                                             ! ------------------------- !
164            ! Set chlorophyl concentration
165            IF( nn_chldta == 1 .OR. lk_vvl ) THEN            !*  Variable Chlorophyll or ocean volume
166               !
167               IF( nn_chldta == 1 ) THEN                             !- Variable Chlorophyll
168                  !
169                  CALL fld_read( kt, 1, sf_chl )                         ! Read Chl data and provides it at the current time step
170                  !         
171!CDIR COLLAPSE
172!CDIR NOVERRCHK
173                  DO jj = 1, jpj                                         ! Separation in R-G-B depending of the surface Chl
174!CDIR NOVERRCHK
175                     DO ji = 1, jpi
176                        zchl = MIN( 10. , MAX( 0.03, sf_chl(1)%fnow(ji,jj,1) ) )
177                        irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
178                        zekb(ji,jj) = rkrgb(1,irgb)
179                        zekg(ji,jj) = rkrgb(2,irgb)
180                        zekr(ji,jj) = rkrgb(3,irgb)
181                     END DO
182                  END DO
183               ELSE                                                  !- Variable ocean volume but constant chrlorophyll
184                  zchl = 0.05                                           ! constant chlorophyll
185                  irgb = NINT( 41 + 20.*LOG10( zchl ) + 1.e-15 )
186                  zekb(:,:) = rkrgb(1,irgb)                             ! Separation in R-G-B depending of the chlorophyll
187                  zekg(:,:) = rkrgb(2,irgb)
188                  zekr(:,:) = rkrgb(3,irgb)
189               ENDIF
190               !
191               zcoef  = ( 1. - rn_abs ) / 3.e0                       !- equi-partition in R-G-B
192               ze0(:,:,1) = rn_abs * qsr(:,:)
193               ze1(:,:,1) =  zcoef * qsr(:,:)
194               ze2(:,:,1) =  zcoef * qsr(:,:)
195               ze3(:,:,1) =  zcoef * qsr(:,:)
196               zea(:,:,1) =          qsr(:,:)
197               !
198               DO jk = 2, nksr+1
199!CDIR NOVERRCHK
200                  DO jj = 1, jpj
201!CDIR NOVERRCHK   
202                     DO ji = 1, jpi
203                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r     )
204                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) )
205                        zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) )
206                        zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) )
207                        ze0(ji,jj,jk) = zc0
208                        ze1(ji,jj,jk) = zc1
209                        ze2(ji,jj,jk) = zc2
210                        ze3(ji,jj,jk) = zc3
211                        zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
212                     END DO
213                  END DO
214               END DO
215               !
216               DO jk = 1, nksr                                        ! compute and add qsr trend to ta
217                  qsr_hc(:,:,jk) = ro0cpr * ( zea(:,:,jk) - zea(:,:,jk+1) )
218               END DO
219               zea(:,:,nksr+1:jpk) = 0.e0     ! below 400m set to zero
220               CALL iom_put( 'qsr3d', zea )   ! Shortwave Radiation 3D distribution
221               !
222            ELSE                                                 !*  Constant Chlorophyll
223               DO jk = 1, nksr
224                  qsr_hc(:,:,jk) =  etot3(:,:,jk) * qsr(:,:)
225               END DO
226            ENDIF
227
228         ENDIF
229         !                                                ! ------------------------- !
230         IF( ln_qsr_2bd ) THEN                            !  2 band light penetration !
231            !                                             ! ------------------------- !
232            !
233            IF( lk_vvl ) THEN                                  !* variable volume
234               zz0   =        rn_abs   * ro0cpr
235               zz1   = ( 1. - rn_abs ) * ro0cpr
236               DO jk = 1, nksr                    ! solar heat absorbed at T-point in the top 400m
237                  DO jj = 1, jpj
238                     DO ji = 1, jpi
239                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
240                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
241                        qsr_hc(ji,jj,jk) = qsr(ji,jj) * ( zc0*tmask(ji,jj,jk) - zc1*tmask(ji,jj,jk+1) ) 
242                     END DO
243                  END DO
244               END DO
245            ELSE                                               !* constant volume: coef. computed one for all
246               DO jk = 1, nksr
247                  DO jj = 2, jpjm1
248                     DO ji = fs_2, fs_jpim1   ! vector opt.
249                        qsr_hc(ji,jj,jk) =  etot3(ji,jj,jk) * qsr(ji,jj)
250                     END DO
251                  END DO
252               END DO
253               !
254            ENDIF
255            !
256         ENDIF
257         !
258         !                                        Add to the general trend
259         DO jk = 1, nksr
260            DO jj = 2, jpjm1 
261               DO ji = fs_2, fs_jpim1   ! vector opt.
262                  z1_e3t = zfact / fse3t(ji,jj,jk)
263                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
264               END DO
265            END DO
266         END DO
267         !
268      ENDIF
269      !
270      IF( lrst_oce ) THEN   !                  Write in the ocean restart file
271         !                                     *******************************
272         IF(lwp) WRITE(numout,*)
273         IF(lwp) WRITE(numout,*) 'qsr tracer content forcing field written in ocean restart file ',   &
274            &                    'at it= ', kt,' date= ', ndastp
275         IF(lwp) WRITE(numout,*) '~~~~'
276         CALL iom_rstput( kt, nitrst, numrow, 'qsr_hc_b', qsr_hc )
277         !
278      ENDIF
279
280      IF( l_trdtra ) THEN     ! qsr tracers trends saved for diagnostics
281         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
282         CALL trd_tra( kt, 'TRA', jp_tem, jptra_qsr, ztrdt )
283         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt ) 
284      ENDIF
285      !                       ! print mean trends (used for debugging)
286      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' qsr  - Ta: ', mask1=tmask, clinfo3='tra-ta' )
287      !
288      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        ) 
289      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
290      !
291      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr')
292      !
293   END SUBROUTINE tra_qsr
294
295
296   SUBROUTINE tra_qsr_init
297      !!----------------------------------------------------------------------
298      !!                  ***  ROUTINE tra_qsr_init  ***
299      !!
300      !! ** Purpose :   Initialization for the penetrative solar radiation
301      !!
302      !! ** Method  :   The profile of solar radiation within the ocean is set
303      !!      from two length scale of penetration (rn_si0,rn_si1) and a ratio
304      !!      (rn_abs). These parameters are read in the namtra_qsr namelist. The
305      !!      default values correspond to clear water (type I in Jerlov'
306      !!      (1968) classification.
307      !!         called by tra_qsr at the first timestep (nit000)
308      !!
309      !! ** Action  : - initialize rn_si0, rn_si1 and rn_abs
310      !!
311      !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
312      !!----------------------------------------------------------------------
313      !
314      INTEGER  ::   ji, jj, jk     ! dummy loop indices
315      INTEGER  ::   irgb, ierror, ioptio, nqsr   ! local integer
316      REAL(wp) ::   zz0, zc0  , zc1, zcoef       ! local scalars
317      REAL(wp) ::   zz1, zc2  , zc3, zchl        !   -      -
318      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
319      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea
320      !
321      CHARACTER(len=100) ::   cn_dir   ! Root directory for location of ssr files
322      TYPE(FLD_N)        ::   sn_chl   ! informations about the chlorofyl field to be read
323      !!
324      NAMELIST/namtra_qsr/  sn_chl, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio,   &
325         &                  nn_chldta, rn_abs, rn_si0, rn_si1
326      !!----------------------------------------------------------------------
327
328      !
329      IF( nn_timing == 1 )  CALL timing_start('tra_qsr_init')
330      !
331      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        ) 
332      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
333      !
334
335      cn_dir = './'       ! directory in which the model is executed
336      ! ... default values (NB: frequency positive => hours, negative => months)
337      !            !     file       ! frequency !  variable  ! time interp !  clim   ! 'yearly' or ! weights  ! rotation   !
338      !            !     name       !  (hours)  !    name    !    (T/F)    !  (T/F)  ! 'monthly'   ! filename ! pairs      !
339      sn_chl = FLD_N( 'chlorophyll' ,    -1     ,  'CHLA'    ,  .true.     , .true.  ,   'yearly'  , ''       , ''         )
340      !
341      REWIND( numnam )            ! Read Namelist namtra_qsr : ratio and length of penetration
342      READ  ( numnam, namtra_qsr )
343      !
344      IF(lwp) THEN                ! control print
345         WRITE(numout,*)
346         WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation'
347         WRITE(numout,*) '~~~~~~~~~~~~'
348         WRITE(numout,*) '   Namelist namtra_qsr : set the parameter of penetration'
349         WRITE(numout,*) '      Light penetration (T) or not (F)         ln_traqsr  = ', ln_traqsr
350         WRITE(numout,*) '      RGB (Red-Green-Blue) light penetration   ln_qsr_rgb = ', ln_qsr_rgb
351         WRITE(numout,*) '      2 band               light penetration   ln_qsr_2bd = ', ln_qsr_2bd
352         WRITE(numout,*) '      bio-model            light penetration   ln_qsr_bio = ', ln_qsr_bio
353         WRITE(numout,*) '      RGB : Chl data (=1) or cst value (=0)    nn_chldta  = ', nn_chldta
354         WRITE(numout,*) '      RGB & 2 bands: fraction of light (rn_si1)    rn_abs = ', rn_abs
355         WRITE(numout,*) '      RGB & 2 bands: shortess depth of extinction  rn_si0 = ', rn_si0
356         WRITE(numout,*) '      2 bands: longest depth of extinction         rn_si1 = ', rn_si1
357      ENDIF
358
359      IF( ln_traqsr ) THEN     ! control consistency
360         !                     
361         IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio )   THEN
362            CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' )
363            ln_qsr_bio = .FALSE.
364         ENDIF
365         !
366         ioptio = 0                      ! Parameter control
367         IF( ln_qsr_rgb  )   ioptio = ioptio + 1
368         IF( ln_qsr_2bd  )   ioptio = ioptio + 1
369         IF( ln_qsr_bio  )   ioptio = ioptio + 1
370         !
371         IF( ioptio /= 1 ) &
372            CALL ctl_stop( '          Choose ONE type of light penetration in namelist namtra_qsr',  &
373            &              ' 2 bands, 3 RGB bands or bio-model light penetration' )
374         !
375         IF( ln_qsr_rgb .AND. nn_chldta == 0 )   nqsr =  1 
376         IF( ln_qsr_rgb .AND. nn_chldta == 1 )   nqsr =  2
377         IF( ln_qsr_2bd                      )   nqsr =  3
378         IF( ln_qsr_bio                      )   nqsr =  4
379         !
380         IF(lwp) THEN                   ! Print the choice
381            WRITE(numout,*)
382            IF( nqsr ==  1 )   WRITE(numout,*) '         R-G-B   light penetration - Constant Chlorophyll'
383            IF( nqsr ==  2 )   WRITE(numout,*) '         R-G-B   light penetration - Chl data '
384            IF( nqsr ==  3 )   WRITE(numout,*) '         2 bands light penetration'
385            IF( nqsr ==  4 )   WRITE(numout,*) '         bio-model light penetration'
386         ENDIF
387         !
388      ENDIF
389      !                          ! ===================================== !
390      IF( ln_traqsr  ) THEN      !  Initialisation of Light Penetration  ! 
391         !                       ! ===================================== !
392         !
393         xsi0r = 1.e0 / rn_si0
394         xsi1r = 1.e0 / rn_si1
395         !                                ! ---------------------------------- !
396         IF( ln_qsr_rgb ) THEN            !  Red-Green-Blue light penetration  !
397            !                             ! ---------------------------------- !
398            !
399            CALL trc_oce_rgb( rkrgb )           !* tabulated attenuation coef.
400            !
401            !                                   !* level of light extinction
402            IF(  ln_sco ) THEN   ;   nksr = jpkm1
403            ELSE                 ;   nksr = trc_oce_ext_lev( r_si2, 0.33e2 )
404            ENDIF
405
406            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m'
407            !
408            IF( nn_chldta == 1 ) THEN           !* Chl data : set sf_chl structure
409               IF(lwp) WRITE(numout,*)
410               IF(lwp) WRITE(numout,*) '        Chlorophyll read in a file'
411               ALLOCATE( sf_chl(1), STAT=ierror )
412               IF( ierror > 0 ) THEN
413                  CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' )   ;   RETURN
414               ENDIF
415               ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1)   )
416               IF( sn_chl%ln_tint )ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) )
417               !                                        ! fill sf_chl with sn_chl and control print
418               CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init',   &
419                  &                                         'Solar penetration function of read chlorophyll', 'namtra_qsr' )
420               !
421            ELSE                                !* constant Chl : compute once for all the distribution of light (etot3)
422               IF(lwp) WRITE(numout,*)
423               IF(lwp) WRITE(numout,*) '        Constant Chlorophyll concentration = 0.05'
424               IF( lk_vvl ) THEN                   ! variable volume
425                  IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
426               ELSE                                ! constant volume: computes one for all
427                  IF(lwp) WRITE(numout,*) '        fixed volume: light distribution computed one for all'
428                  !
429                  zchl = 0.05                                 ! constant chlorophyll
430                  irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
431                  zekb(:,:) = rkrgb(1,irgb)                   ! Separation in R-G-B depending of the chlorophyll
432                  zekg(:,:) = rkrgb(2,irgb)
433                  zekr(:,:) = rkrgb(3,irgb)
434                  !
435                  zcoef = ( 1. - rn_abs ) / 3.e0              ! equi-partition in R-G-B
436                  ze0(:,:,1) = rn_abs
437                  ze1(:,:,1) = zcoef
438                  ze2(:,:,1) = zcoef 
439                  ze3(:,:,1) = zcoef
440                  zea(:,:,1) = tmask(:,:,1)                   ! = ( ze0+ze1+z2+ze3 ) * tmask
441               
442                  DO jk = 2, nksr+1
443!CDIR NOVERRCHK
444                     DO jj = 1, jpj
445!CDIR NOVERRCHK   
446                        DO ji = 1, jpi
447                           zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * xsi0r     )
448                           zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * zekb(ji,jj) )
449                           zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * zekg(ji,jj) )
450                           zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * zekr(ji,jj) )
451                           ze0(ji,jj,jk) = zc0
452                           ze1(ji,jj,jk) = zc1
453                           ze2(ji,jj,jk) = zc2
454                           ze3(ji,jj,jk) = zc3
455                           zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
456                        END DO
457                     END DO
458                  END DO 
459                  !
460                  DO jk = 1, nksr
461                     etot3(:,:,jk) = ro0cpr * ( zea(:,:,jk) - zea(:,:,jk+1) ) 
462                  END DO
463                  etot3(:,:,nksr+1:jpk) = 0.e0                ! below 400m set to zero
464               ENDIF
465            ENDIF
466            !
467         ENDIF
468            !                             ! ---------------------------------- !
469         IF( ln_qsr_2bd ) THEN            !    2 bands    light penetration    !
470            !                             ! ---------------------------------- !
471            !
472            !                                ! level of light extinction
473            nksr = trc_oce_ext_lev( rn_si1, 1.e2 )
474            IF(lwp) THEN
475               WRITE(numout,*)
476            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m'
477            ENDIF
478            !
479            IF( lk_vvl ) THEN                   ! variable volume
480               IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
481            ELSE                                ! constant volume: computes one for all
482               zz0 =        rn_abs   * ro0cpr
483               zz1 = ( 1. - rn_abs ) * ro0cpr
484               DO jk = 1, nksr                    !*  solar heat absorbed at T-point computed once for all
485                  DO jj = 1, jpj                              ! top 400 meters
486                     DO ji = 1, jpi
487                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
488                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
489                        etot3(ji,jj,jk) = (  zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1)  ) 
490                     END DO
491                  END DO
492               END DO
493               etot3(:,:,nksr+1:jpk) = 0.e0                   ! below 400m set to zero
494               !
495            ENDIF
496         ENDIF
497         !                       ! ===================================== !
498      ELSE                       !        No light penetration           !                   
499         !                       ! ===================================== !
500         IF(lwp) THEN
501            WRITE(numout,*)
502            WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration'
503            WRITE(numout,*) '~~~~~~~~~~~~'
504         ENDIF
505      ENDIF
506      !
507      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        ) 
508      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
509      !
510      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr_init')
511      !
512   END SUBROUTINE tra_qsr_init
513
514   !!======================================================================
515END MODULE traqsr
Note: See TracBrowser for help on using the repository browser.