New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcadv.F90 in branches/2012/dev_r3309_LOCEAN12_Ediag/NEMOGCM/NEMO/TOP_SRC/TRP – NEMO

source: branches/2012/dev_r3309_LOCEAN12_Ediag/NEMOGCM/NEMO/TOP_SRC/TRP/trcadv.F90 @ 3318

Last change on this file since 3318 was 3318, checked in by gm, 12 years ago

Ediag branche: #927 split TRA/DYN trd computation
  • Property svn:keywords set to Id
File size: 10.6 KB
Line 
1MODULE trcadv
2   !!==============================================================================
3   !!                       ***  MODULE  trcadv  ***
4   !! Ocean passive tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  05-11  (G. Madec)  Original code
7   !!            3.0  !  10-06  (C. Ethe)   Adapted to passive tracers
8   !!----------------------------------------------------------------------
9#if defined key_top
10   !!----------------------------------------------------------------------
11   !!   'key_top'                                                TOP models
12   !!----------------------------------------------------------------------
13   !!   trc_adv      : compute ocean tracer advection trend
14   !!   trc_adv_ctl  : control the different options of advection scheme
15   !!----------------------------------------------------------------------
16   USE oce_trc         ! ocean dynamics and active tracers
17   USE trc             ! ocean passive tracers variables
18   USE trcnam_trp      ! passive tracers transport namelist variables
19   USE traadv_cen2     ! 2nd order centered scheme (tra_adv_cen2   routine)
20   USE traadv_tvd      ! TVD      scheme           (tra_adv_tvd    routine)
21   USE traadv_muscl    ! MUSCL    scheme           (tra_adv_muscl  routine)
22   USE traadv_muscl2   ! MUSCL2   scheme           (tra_adv_muscl2 routine)
23   USE traadv_ubs      ! UBS      scheme           (tra_adv_ubs    routine)
24   USE traadv_qck      ! QUICKEST scheme           (tra_adv_qck    routine)
25   USE traadv_eiv      ! eddy induced velocity     (tra_adv_eiv    routine)
26   USE ldftra_oce      ! lateral diffusion coefficient on tracers
27   USE prtctl_trc      ! Print control
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   trc_adv          ! routine called by step module
33   PUBLIC   trc_adv_alloc    ! routine called by nemogcm module
34
35   INTEGER ::   nadv   ! choice of the type of advection scheme
36   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:) ::   r2dt  ! vertical profile time-step, = 2 rdttra
37   !                                                    ! except at nitrrc000 (=rdttra) if neuler=0
38
39   !! * Substitutions
40#  include "domzgr_substitute.h90"
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
44   !! $Id$
45   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   INTEGER FUNCTION trc_adv_alloc()
50      !!----------------------------------------------------------------------
51      !!                  ***  FUNDCTION trc_adv_alloc  ***
52      !!----------------------------------------------------------------------
53      ALLOCATE( r2dt(jpk), STAT=trc_adv_alloc )
54      IF( trc_adv_alloc /= 0 ) CALL ctl_warn('trc_adv_alloc : failed to allocate array.')
55   END FUNCTION trc_adv_alloc
56
57
58   SUBROUTINE trc_adv( kt )
59      !!----------------------------------------------------------------------
60      !!                  ***  ROUTINE trc_adv  ***
61      !!
62      !! ** Purpose :   compute the ocean tracer advection trend.
63      !!
64      !! ** Method  : - Update the tracer with the advection term following nadv
65      !!----------------------------------------------------------------------
66      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
67      !
68      INTEGER ::   jk 
69      CHARACTER (len=22) ::   charout
70      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zun, zvn, zwn  ! effective velocity
71      !!----------------------------------------------------------------------
72      !
73      IF( nn_timing == 1 )  CALL timing_start('trc_adv')
74      !
75      CALL wrk_alloc( jpi, jpj, jpk, zun, zvn, zwn )
76      !
77
78      IF( kt == nittrc000 )   CALL trc_adv_ctl          ! initialisation & control of options
79
80#if ! defined key_pisces
81      IF( neuler == 0 .AND. kt == nittrc000 ) THEN     ! at nittrc000
82         r2dt(:) =  rdttrc(:)           ! = rdttrc (restarting with Euler time stepping)
83      ELSEIF( kt <= nittrc000 + 1 ) THEN          ! at nittrc000 or nittrc000+1
84         r2dt(:) = 2. * rdttrc(:)       ! = 2 rdttrc (leapfrog)
85      ENDIF
86#else
87      r2dt(:) =  rdttrc(:)              ! = rdttrc (for PISCES use Euler time stepping)
88#endif
89
90      !                                                   ! effective transport
91      DO jk = 1, jpkm1
92         !                                                ! eulerian transport only
93         zun(:,:,jk) = e2u  (:,:) * fse3u(:,:,jk) * un(:,:,jk)
94         zvn(:,:,jk) = e1v  (:,:) * fse3v(:,:,jk) * vn(:,:,jk)
95         zwn(:,:,jk) = e1e2t(:,:)                 * wn(:,:,jk)
96         !
97      END DO
98      zwn(:,:,jpk) = 0.e0                                 ! no transport trough the bottom
99
100      IF( lk_traldf_eiv .AND. .NOT. ln_traldf_grif )   &  ! add the eiv transport (if necessary)
101         &              CALL tra_adv_eiv( kt, nittrc000, zun, zvn, zwn, 'TRC' )
102      !
103      SELECT CASE ( nadv )                            !==  compute advection trend and add it to general trend  ==!
104      CASE ( 1 )   ;    CALL tra_adv_cen2  ( kt, nittrc000, 'TRC',       zun, zvn, zwn, trb, trn, tra, jptra )   !  2nd order centered
105      CASE ( 2 )   ;    CALL tra_adv_tvd   ( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )   !  TVD
106      CASE ( 3 )   ;    CALL tra_adv_muscl ( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb,      tra, jptra )   !  MUSCL
107      CASE ( 4 )   ;    CALL tra_adv_muscl2( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )   !  MUSCL2
108      CASE ( 5 )   ;    CALL tra_adv_ubs   ( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )   !  UBS
109      CASE ( 6 )   ;    CALL tra_adv_qck   ( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )   !  QUICKEST
110      !
111      CASE (-1 )                                      !==  esopa: test all possibility with control print  ==!
112         CALL tra_adv_cen2  ( kt, nittrc000, 'TRC',       zun, zvn, zwn, trb, trn, tra, jptra )         
113         WRITE(charout, FMT="('adv1')")  ; CALL prt_ctl_trc_info(charout)
114                                           CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
115         CALL tra_adv_tvd   ( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )         
116         WRITE(charout, FMT="('adv2')")  ; CALL prt_ctl_trc_info(charout)
117                                           CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
118         CALL tra_adv_muscl ( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb,      tra, jptra )         
119         WRITE(charout, FMT="('adv3')")  ; CALL prt_ctl_trc_info(charout)
120                                           CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
121         CALL tra_adv_muscl2( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )         
122         WRITE(charout, FMT="('adv4')")  ; CALL prt_ctl_trc_info(charout)
123                                           CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
124         CALL tra_adv_ubs   ( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )         
125         WRITE(charout, FMT="('adv5')")  ; CALL prt_ctl_trc_info(charout)
126                                           CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
127         CALL tra_adv_qck   ( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )         
128         WRITE(charout, FMT="('adv6')")  ; CALL prt_ctl_trc_info(charout)
129                                           CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
130         !
131      END SELECT
132
133      !                                              ! print mean trends (used for debugging)
134      IF( ln_ctl )   THEN
135         WRITE(charout, FMT="('adv ')")  ;  CALL prt_ctl_trc_info(charout)
136                                            CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
137      END IF
138      !
139      CALL wrk_dealloc( jpi, jpj, jpk, zun, zvn, zwn )
140      !
141      IF( nn_timing == 1 )  CALL timing_stop('trc_adv')
142      !
143   END SUBROUTINE trc_adv
144
145
146   SUBROUTINE trc_adv_ctl
147      !!---------------------------------------------------------------------
148      !!                  ***  ROUTINE trc_adv_ctl  ***
149      !!               
150      !! ** Purpose : Control the consistency between namelist options for
151      !!              passive tracer advection schemes and set nadv
152      !!----------------------------------------------------------------------
153      INTEGER ::   ioptio
154      !!----------------------------------------------------------------------
155
156      ioptio = 0                      ! Parameter control
157      IF( ln_trcadv_cen2   )   ioptio = ioptio + 1
158      IF( ln_trcadv_tvd    )   ioptio = ioptio + 1
159      IF( ln_trcadv_muscl  )   ioptio = ioptio + 1
160      IF( ln_trcadv_muscl2 )   ioptio = ioptio + 1
161      IF( ln_trcadv_ubs    )   ioptio = ioptio + 1
162      IF( ln_trcadv_qck    )   ioptio = ioptio + 1
163      IF( lk_esopa         )   ioptio =          1
164
165      IF( ioptio /= 1 )   CALL ctl_stop( 'Choose ONE advection scheme in namelist namtrc_adv' )
166
167      !                              ! Set nadv
168      IF( ln_trcadv_cen2   )   nadv =  1
169      IF( ln_trcadv_tvd    )   nadv =  2
170      IF( ln_trcadv_muscl  )   nadv =  3
171      IF( ln_trcadv_muscl2 )   nadv =  4
172      IF( ln_trcadv_ubs    )   nadv =  5
173      IF( ln_trcadv_qck    )   nadv =  6
174      IF( lk_esopa         )   nadv = -1
175
176      IF(lwp) THEN                   ! Print the choice
177         WRITE(numout,*)
178         IF( nadv ==  1 )   WRITE(numout,*) '         2nd order scheme is used'
179         IF( nadv ==  2 )   WRITE(numout,*) '         TVD       scheme is used'
180         IF( nadv ==  3 )   WRITE(numout,*) '         MUSCL     scheme is used'
181         IF( nadv ==  4 )   WRITE(numout,*) '         MUSCL2    scheme is used'
182         IF( nadv ==  5 )   WRITE(numout,*) '         UBS       scheme is used'
183         IF( nadv ==  6 )   WRITE(numout,*) '         QUICKEST  scheme is used'
184         IF( nadv == -1 )   WRITE(numout,*) '         esopa test: use all advection scheme'
185      ENDIF
186      !
187   END SUBROUTINE trc_adv_ctl
188   
189#else
190   !!----------------------------------------------------------------------
191   !!   Default option                                         Empty module
192   !!----------------------------------------------------------------------
193CONTAINS
194   SUBROUTINE trc_adv( kt )
195      INTEGER, INTENT(in) :: kt
196      WRITE(*,*) 'trc_adv: You should not have seen this print! error?', kt
197   END SUBROUTINE trc_adv
198#endif
199
200  !!======================================================================
201END MODULE trcadv
Note: See TracBrowser for help on using the repository browser.