source: branches/2012/dev_r3322_NOCS09_SAS/NEMOGCM/NEMO/SAS_SRC/sbcmod.F90 @ 3331

Last change on this file since 3331 was 3331, checked in by sga, 9 years ago

NEMO 2012 development branch dev_r3322_NOCS09_SAS
Code changes made for compilation and running of Stand Alone? Surface scheme (tinkering still required)

File size: 20.6 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   sbc_init       : read namsbc namelist
18   !!   sbc            : surface ocean momentum, heat and freshwater boundary conditions
19   !!----------------------------------------------------------------------
20   USE oce              ! ocean dynamics and tracers
21   USE dom_oce          ! ocean space and time domain
22   USE phycst           ! physical constants
23   USE sbc_oce          ! Surface boundary condition: ocean fields
24   USE sbc_ice          ! Surface boundary condition: ice fields
25   USE sbcdcy           ! surface boundary condition: diurnal cycle
26   USE sbcssm           ! surface boundary condition: sea-surface mean variables
27   USE sbcapr           ! surface boundary condition: atmospheric pressure
28   USE sbcana           ! surface boundary condition: analytical formulation
29   USE sbcflx           ! surface boundary condition: flux formulation
30   USE sbcblk_clio      ! surface boundary condition: bulk formulation : CLIO
31   USE sbcblk_core      ! surface boundary condition: bulk formulation : CORE
32   USE sbcblk_mfs       ! surface boundary condition: bulk formulation : MFS
33   USE sbcice_if        ! surface boundary condition: ice-if sea-ice model
34   USE sbcice_lim       ! surface boundary condition: LIM 3.0 sea-ice model
35   USE sbcice_lim_2     ! surface boundary condition: LIM 2.0 sea-ice model
36   USE sbcice_cice      ! surface boundary condition: CICE    sea-ice model
37   USE sbccpl           ! surface boundary condition: coupled florulation
38   USE cpl_oasis3, ONLY:lk_cpl      ! are we in coupled mode?
39   USE sbcssr           ! surface boundary condition: sea surface restoring
40   USE sbcrnf           ! surface boundary condition: runoffs
41   USE sbcfwb           ! surface boundary condition: freshwater budget
42   USE closea           ! closed sea
43   USE bdy_par          ! for lk_bdy
44   USE bdyice_lim2      ! unstructured open boundary data  (bdy_ice_lim_2 routine)
45
46   USE prtctl           ! Print control                    (prt_ctl routine)
47   USE restart          ! ocean restart
48   USE iom              ! IOM library
49   USE in_out_manager   ! I/O manager
50   USE lib_mpp          ! MPP library
51   USE timing           ! Timing
52   USE sbcwave          ! Wave module
53   USE sbcsas
54
55   IMPLICIT NONE
56   PRIVATE
57
58   PUBLIC   sbc        ! routine called by step.F90
59   PUBLIC   sbc_init   ! routine called by opa.F90
60   
61   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
62     
63   !! * Substitutions
64#  include "domzgr_substitute.h90"
65   !!----------------------------------------------------------------------
66   !! NEMO/OPA 4.0 , NEMO-consortium (2011)
67   !! $Id: sbcmod.F90 3294 2012-01-28 16:44:18Z rblod $
68   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
69   !!----------------------------------------------------------------------
70CONTAINS
71
72   SUBROUTINE sbc_init
73      !!---------------------------------------------------------------------
74      !!                    ***  ROUTINE sbc_init ***
75      !!
76      !! ** Purpose :   Initialisation of the ocean surface boundary computation
77      !!
78      !! ** Method  :   Read the namsbc namelist and set derived parameters
79      !!
80      !! ** Action  : - read namsbc parameters
81      !!              - nsbc: type of sbc
82      !!----------------------------------------------------------------------
83      INTEGER ::   icpt   ! local integer
84      !!
85      NAMELIST/namsbc/ nn_fsbc   , ln_ana , ln_flx  , ln_blk_clio, ln_blk_core, ln_cpl,   &
86         &             ln_blk_mfs, ln_apr_dyn, nn_ice , ln_dm2dc, ln_rnf, ln_ssr     , nn_fwb, ln_cdgw
87      !!----------------------------------------------------------------------
88
89      IF(lwp) THEN
90         WRITE(numout,*)
91         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
92         WRITE(numout,*) '~~~~~~~~ '
93      ENDIF
94
95      REWIND( numnam )           ! Read Namelist namsbc
96      READ  ( numnam, namsbc )
97
98      !                          ! overwrite namelist parameter using CPP key information
99      IF( Agrif_Root() ) THEN                ! AGRIF zoom
100        IF( lk_lim2 )   nn_ice      = 2
101        IF( lk_lim3 )   nn_ice      = 3
102        IF( lk_cice )   nn_ice      = 4
103      ENDIF
104      IF( cp_cfg == 'gyre' ) THEN            ! GYRE configuration
105          ln_ana      = .TRUE.   
106          nn_ice      =   0
107      ENDIF
108      IF( lwp ) THEN
109         IF( ln_cpl ) THEN
110            WRITE(numout,*) 'Coupled mode not sensible with StandAlone Surface scheme'
111            ln_cpl = .FALSE.
112         ENDIF
113         IF( ln_apr_dyn ) THEN
114            WRITE(numout,*) 'No atmospheric gradient needed with StandAlone Surface scheme'
115            ln_apr_dyn = .FALSE.
116         ENDIF
117         IF( ln_dm2dc ) THEN
118            WRITE(numout,*) 'No diurnal cycle needed with StandAlone Surface scheme'
119            ln_dm2dc = .FALSE.
120         ENDIF
121         IF( ln_rnf ) THEN
122            WRITE(numout,*) 'No runoff needed with StandAlone Surface scheme'
123            ln_rnf = .FALSE.
124         ENDIF
125         IF( ln_ssr ) THEN
126            WRITE(numout,*) 'No surface relaxation needed with StandAlone Surface scheme'
127            ln_ssr = .FALSE.
128         ENDIF
129         IF( nn_fwb > 0 ) THEN
130            WRITE(numout,*) 'No freshwater budget adjustment needed with StandAlone Surface scheme'
131            nn_fwb = 0
132         ENDIF
133         IF( nn_closea > 0 ) THEN
134            WRITE(numout,*) 'No closed seas adjustment needed with StandAlone Surface scheme'
135            nn_closea = 0
136         ENDIF
137      ENDIF
138     
139      IF(lwp) THEN               ! Control print
140         WRITE(numout,*) '        Namelist namsbc (partly overwritten with CPP key setting)'
141         WRITE(numout,*) '           frequency update of sbc (and ice)             nn_fsbc     = ', nn_fsbc
142         WRITE(numout,*) '           Type of sbc : '
143         WRITE(numout,*) '              analytical formulation                     ln_ana      = ', ln_ana
144         WRITE(numout,*) '              flux       formulation                     ln_flx      = ', ln_flx
145         WRITE(numout,*) '              CLIO bulk  formulation                     ln_blk_clio = ', ln_blk_clio
146         WRITE(numout,*) '              CORE bulk  formulation                     ln_blk_core = ', ln_blk_core
147         WRITE(numout,*) '              MFS  bulk  formulation                     ln_blk_mfs  = ', ln_blk_mfs
148         WRITE(numout,*) '              coupled    formulation (T if key_sbc_cpl)  ln_cpl      = ', ln_cpl
149         WRITE(numout,*) '           Misc. options of sbc : '
150         WRITE(numout,*) '              Patm gradient added in ocean & ice Eqs.    ln_apr_dyn  = ', ln_apr_dyn
151         WRITE(numout,*) '              ice management in the sbc (=0/1/2/3)       nn_ice      = ', nn_ice 
152         WRITE(numout,*) '              daily mean to diurnal cycle qsr            ln_dm2dc    = ', ln_dm2dc 
153         WRITE(numout,*) '              runoff / runoff mouths                     ln_rnf      = ', ln_rnf
154         WRITE(numout,*) '              Sea Surface Restoring on SST and/or SSS    ln_ssr      = ', ln_ssr
155         WRITE(numout,*) '              FreshWater Budget control  (=0/1/2)        nn_fwb      = ', nn_fwb
156         WRITE(numout,*) '              closed sea (=0/1) (set in namdom)          nn_closea   = ', nn_closea
157      ENDIF
158
159      !                              ! allocate sbc arrays
160      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_oce arrays' )
161
162      !                          ! Checks:
163      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
164         ln_rnf_mouth  = .false.                     
165         IF( sbc_rnf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_rnf arrays' )
166         nkrnf         = 0
167         rnf     (:,:) = 0.e0
168         rnfmsk  (:,:) = 0.e0
169         rnfmsk_z(:)   = 0.e0
170      ENDIF
171      IF( nn_ice == 0  )   fr_i(:,:) = 0.e0        ! no ice in the domain, ice fraction is always zero
172
173      !                                            ! restartability   
174      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
175         &  CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' )
176      !
177      IF( ( nn_ice == 2 .OR. nn_ice ==3 ) .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. lk_cpl ) )   &
178         &   CALL ctl_stop( 'LIM sea-ice model requires a bulk formulation or coupled configuration' )
179      IF( nn_ice == 4 .AND. .NOT.( ln_blk_core .OR. lk_cpl ) )   &
180         &   CALL ctl_stop( 'CICE sea-ice model requires ln_blk_core or lk_cpl' )
181      IF( nn_ice == 4 .AND. ( .NOT. ( cp_cfg == 'orca' ) .OR. lk_agrif ) )   &
182         &   CALL ctl_stop( 'CICE sea-ice model currently only available in a global ORCA configuration without AGRIF' )
183     
184       !drag coefficient read from wave model definable only with mfs bulk formulae and core
185       IF(ln_cdgw .AND. .NOT.(ln_blk_mfs .OR. ln_blk_core) )              &
186          &   CALL ctl_stop( 'drag coefficient read from wave model definable only with mfs bulk formulae and core')
187     
188      !                          ! Choice of the Surface Boudary Condition (set nsbc)
189      icpt = 0
190      IF( ln_ana          ) THEN   ;   nsbc =  1   ; icpt = icpt + 1   ;   ENDIF       ! analytical      formulation
191      IF( ln_flx          ) THEN   ;   nsbc =  2   ; icpt = icpt + 1   ;   ENDIF       ! flux            formulation
192      IF( ln_blk_clio     ) THEN   ;   nsbc =  3   ; icpt = icpt + 1   ;   ENDIF       ! CLIO bulk       formulation
193      IF( ln_blk_core     ) THEN   ;   nsbc =  4   ; icpt = icpt + 1   ;   ENDIF       ! CORE bulk       formulation
194      IF( ln_blk_mfs      ) THEN   ;   nsbc =  6   ; icpt = icpt + 1   ;   ENDIF       ! MFS  bulk       formulation
195      IF( ln_cpl          ) THEN   ;   nsbc =  5   ; icpt = icpt + 1   ;   ENDIF       ! Coupled         formulation
196      IF( cp_cfg == 'gyre') THEN   ;   nsbc =  0                       ;   ENDIF       ! GYRE analytical formulation
197      IF( lk_esopa        )            nsbc = -1                                       ! esopa test, ALL formulations
198      !
199      IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN
200         WRITE(numout,*)
201         WRITE(numout,*) '           E R R O R in setting the sbc, one and only one namelist/CPP key option '
202         WRITE(numout,*) '                     must be choosen. You choose ', icpt, ' option(s)'
203         WRITE(numout,*) '                     We stop'
204         nstop = nstop + 1
205      ENDIF
206      IF(lwp) THEN
207         WRITE(numout,*)
208         IF( nsbc == -1 )   WRITE(numout,*) '              ESOPA test All surface boundary conditions'
209         IF( nsbc ==  0 )   WRITE(numout,*) '              GYRE analytical formulation'
210         IF( nsbc ==  1 )   WRITE(numout,*) '              analytical formulation'
211         IF( nsbc ==  2 )   WRITE(numout,*) '              flux formulation'
212         IF( nsbc ==  3 )   WRITE(numout,*) '              CLIO bulk formulation'
213         IF( nsbc ==  4 )   WRITE(numout,*) '              CORE bulk formulation'
214         IF( nsbc ==  5 )   WRITE(numout,*) '              coupled formulation'
215         IF( nsbc ==  6 )   WRITE(numout,*) '              MFS Bulk formulation'
216      ENDIF
217
218      IF( nn_ice == 4 )   CALL cice_sbc_init (nsbc)
219      !
220   END SUBROUTINE sbc_init
221
222
223   SUBROUTINE sbc( kt )
224      !!---------------------------------------------------------------------
225      !!                    ***  ROUTINE sbc  ***
226      !!             
227      !! ** Purpose :   provide at each time-step the ocean surface boundary
228      !!                condition (momentum, heat and freshwater fluxes)
229      !!
230      !! ** Method  :   blah blah  to be written ?????????
231      !!                CAUTION : never mask the surface stress field (tke sbc)
232      !!
233      !! ** Action  : - set the ocean surface boundary condition at before and now
234      !!                time step, i.e. 
235      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, emps_b, qrp_b, erp_b
236      !!                utau  , vtau  , qns  , qsr  , emp  , emps  , qrp  , erp
237      !!              - updte the ice fraction : fr_i
238      !!----------------------------------------------------------------------
239      INTEGER, INTENT(in) ::   kt       ! ocean time step
240      !!---------------------------------------------------------------------
241      !
242      IF( nn_timing == 1 )  CALL timing_start('sbc')
243      !
244      !                                            ! ---------------------------------------- !
245      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
246         !                                         ! ---------------------------------------- !
247         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
248         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
249         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
250         ! The 3D heat content due to qsr forcing is treated in traqsr
251         ! qsr_b (:,:) = qsr (:,:)
252         emp_b (:,:) = emp (:,:)
253         emps_b(:,:) = emps(:,:)
254      ENDIF
255      !                                            ! ---------------------------------------- !
256      !                                            !        forcing field computation         !
257      !                                            ! ---------------------------------------- !
258
259      CALL iom_setkt( kt + nn_fsbc - 1 )                 ! in sbc, iom_put is called every nn_fsbc time step
260      !
261      CALL sbc_sas( kt )                                 ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
262      !                                                  ! averaged over nf_sbc time-step
263
264      IF (ln_cdgw) CALL sbc_wave( kt )
265                                                   !==  sbc formulation  ==!
266                                                           
267      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
268      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, emps)
269      CASE(  0 )   ;   CALL sbc_gyre    ( kt )                    ! analytical formulation : GYRE configuration
270      CASE(  1 )   ;   CALL sbc_ana     ( kt )                    ! analytical formulation : uniform sbc
271      CASE(  2 )   ;   CALL sbc_flx     ( kt )                    ! flux formulation
272      CASE(  3 )   ;   CALL sbc_blk_clio( kt )                    ! bulk formulation : CLIO for the ocean
273      CASE(  4 )   ;   CALL sbc_blk_core( kt )                    ! bulk formulation : CORE for the ocean
274      CASE(  5 )   ;   CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! coupled formulation
275      CASE(  6 )   ;   CALL sbc_blk_mfs ( kt )                    ! bulk formulation : MFS for the ocean
276      CASE( -1 )                               
277                       CALL sbc_ana     ( kt )                    ! ESOPA, test ALL the formulations
278                       CALL sbc_gyre    ( kt )                    !
279                       CALL sbc_flx     ( kt )                    !
280                       CALL sbc_blk_clio( kt )                    !
281                       CALL sbc_blk_core( kt )                    !
282                       CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   !
283      END SELECT
284
285      !                                            !==  Misc. Options  ==!
286     
287      SELECT CASE( nn_ice )                                     ! Update heat and freshwater fluxes over sea-ice areas
288      CASE(  1 )   ;       CALL sbc_ice_if   ( kt )                  ! Ice-cover climatology ("Ice-if" model)
289         !                                                     
290      CASE(  2 )   ;       CALL sbc_ice_lim_2( kt, nsbc )            ! LIM-2 ice model
291         IF( lk_bdy )      CALL bdy_ice_lim_2( kt )                  ! BDY boundary condition
292         !                                                     
293      CASE(  3 )   ;       CALL sbc_ice_lim  ( kt, nsbc )            ! LIM-3 ice model
294         !
295      CASE(  4 )   ;       CALL sbc_ice_cice ( kt, nsbc )            ! CICE ice model
296      END SELECT                                             
297
298!RBbug do not understand why see ticket 667
299      CALL lbc_lnk( emp, 'T', 1. )
300      !
301      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
302         !                                             ! ---------------------------------------- !
303         IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
304         utau_b(:,:) = utau(:,:) 
305         vtau_b(:,:) = vtau(:,:)
306         qns_b (:,:) = qns (:,:)
307         ! qsr_b (:,:) = qsr (:,:)
308         emp_b (:,:) = emp (:,:)
309         emps_b(:,:) = emps(:,:)
310      ENDIF
311      !                                                ! ---------------------------------------- !
312      !                                                !        Outputs and control print         !
313      !                                                ! ---------------------------------------- !
314      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
315         CALL iom_put( "empmr" , emp  - rnf )                   ! upward water flux
316         CALL iom_put( "empsmr", emps - rnf )                   ! c/d water flux
317         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
318         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
319         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
320         IF( nn_ice > 0 )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
321      ENDIF
322      !
323      CALL iom_setkt( kt )           ! iom_put outside of sbc is called at every time step
324      !
325      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at
326      CALL iom_put( "vtau", vtau )   ! j-wind stress    each time step in sea-ice)
327      CALL iom_put( "taum", taum )   ! wind stress module
328      CALL iom_put( "wspd", wndm )   ! wind speed  module
329      !
330      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
331         CALL prt_ctl(tab2d_1=fr_i             , clinfo1=' fr_i     - : ', mask1=tmask, ovlap=1 )
332         CALL prt_ctl(tab2d_1=(emp-rnf)        , clinfo1=' emp-rnf  - : ', mask1=tmask, ovlap=1 )
333         CALL prt_ctl(tab2d_1=(emps-rnf)       , clinfo1=' emps-rnf - : ', mask1=tmask, ovlap=1 )
334         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask, ovlap=1 )
335         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask, ovlap=1 )
336         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, ovlap=1, kdim=jpk )
337         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, ovlap=1, kdim=1   )
338         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, ovlap=1, kdim=1   )
339         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
340            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask, ovlap=1 )
341      ENDIF
342
343      IF( kt == nitend )   CALL sbc_final         ! Close down surface module if necessary
344      !
345      IF( nn_timing == 1 )  CALL timing_stop('sbc')
346      !
347   END SUBROUTINE sbc
348
349   SUBROUTINE sbc_final
350      !!---------------------------------------------------------------------
351      !!                    ***  ROUTINE sbc_final  ***
352      !!---------------------------------------------------------------------
353
354      !-----------------------------------------------------------------
355      ! Finalize CICE (if used)
356      !-----------------------------------------------------------------
357
358      IF( nn_ice == 4 )   CALL cice_sbc_final
359      !
360   END SUBROUTINE sbc_final
361
362   !!======================================================================
363END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.