New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

sbcmod.F90 in branches/2012/dev_r3322_NOCS09_SAS/NEMOGCM/NEMO/SAS_SRC – NEMO

Context Navigation

source: branches/2012/dev_r3322_NOCS09_SAS/NEMOGCM/NEMO/SAS_SRC/sbcmod.F90 @ 3334

Last change on this file since 3334 was 3334, checked in by sga, 12 years ago

NEMO 2012 development branch dev_r3322_NOCS09_SAS: add some lines from rst_opn in order to allow correct ice restart creation;

and a little bit of light dusting.

File size: 20.4 KB

Line
1	MODULE sbcmod
2	!!======================================================================
3	!! * MODULE sbcmod *
4	!! Surface module : provide to the ocean its surface boundary condition
5	!!======================================================================
6	!! History : 3.0 ! 2006-07 (G. Madec) Original code
7	!! 3.1 ! 2008-08 (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8	!! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps
9	!! 3.3 ! 2010-10 (S. Masson) add diurnal cycle
10	!! 3.3 ! 2010-09 (D. Storkey) add ice boundary conditions (BDY)
11	!! - ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step
12	!! - ! 2010-10 (J. Chanut, C. Bricaud, G. Madec) add the surface pressure forcing
13	!! 3.4 ! 2011-11 (C. Harris) CICE added as an option
14	!!----------------------------------------------------------------------
15
16	!!----------------------------------------------------------------------
17	!! sbc_init : read namsbc namelist
18	!! sbc : surface ocean momentum, heat and freshwater boundary conditions
19	!!----------------------------------------------------------------------
20	USE oce ! ocean dynamics and tracers
21	USE dom_oce ! ocean space and time domain
22	USE phycst ! physical constants
23	USE sbc_oce ! Surface boundary condition: ocean fields
24	USE sbc_ice ! Surface boundary condition: ice fields
25	USE sbcdcy ! surface boundary condition: diurnal cycle
26	USE sbcssm ! surface boundary condition: sea-surface mean variables
27	USE sbcapr ! surface boundary condition: atmospheric pressure
28	USE sbcana ! surface boundary condition: analytical formulation
29	USE sbcflx ! surface boundary condition: flux formulation
30	USE sbcblk_clio ! surface boundary condition: bulk formulation : CLIO
31	USE sbcblk_core ! surface boundary condition: bulk formulation : CORE
32	USE sbcblk_mfs ! surface boundary condition: bulk formulation : MFS
33	USE sbcice_if ! surface boundary condition: ice-if sea-ice model
34	USE sbcice_lim ! surface boundary condition: LIM 3.0 sea-ice model
35	USE sbcice_lim_2 ! surface boundary condition: LIM 2.0 sea-ice model
36	USE sbcice_cice ! surface boundary condition: CICE sea-ice model
37	USE sbccpl ! surface boundary condition: coupled florulation
38	USE cpl_oasis3, ONLY:lk_cpl ! are we in coupled mode?
39	USE sbcssr ! surface boundary condition: sea surface restoring
40	USE sbcrnf ! surface boundary condition: runoffs
41	USE sbcfwb ! surface boundary condition: freshwater budget
42	USE closea ! closed sea
43
44	USE prtctl ! Print control (prt_ctl routine)
45	USE restart ! ocean restart
46	USE iom ! IOM library
47	USE in_out_manager ! I/O manager
48	USE lib_mpp ! MPP library
49	USE timing ! Timing
50	USE sbcwave ! Wave module
51	USE sbcsas
52
53	IMPLICIT NONE
54	PRIVATE
55
56	PUBLIC sbc ! routine called by step.F90
57	PUBLIC sbc_init ! routine called by opa.F90
58
59	INTEGER :: nsbc ! type of surface boundary condition (deduced from namsbc informations)
60
61	!! * Substitutions
62	# include "domzgr_substitute.h90"
63	!!----------------------------------------------------------------------
64	!! NEMO/OPA 4.0 , NEMO-consortium (2011)
65	!! $Id: sbcmod.F90 3294 2012-01-28 16:44:18Z rblod $
66	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
67	!!----------------------------------------------------------------------
68	CONTAINS
69
70	SUBROUTINE sbc_init
71	!!---------------------------------------------------------------------
72	!! * ROUTINE sbc_init *
73	!!
74	!! ** Purpose : Initialisation of the ocean surface boundary computation
75	!!
76	!! ** Method : Read the namsbc namelist and set derived parameters
77	!!
78	!! ** Action : - read namsbc parameters
79	!! - nsbc: type of sbc
80	!!----------------------------------------------------------------------
81	INTEGER :: icpt ! local integer
82	!!
83	NAMELIST/namsbc/ nn_fsbc , ln_ana , ln_flx , ln_blk_clio, ln_blk_core, ln_cpl, &
84	& ln_blk_mfs, ln_apr_dyn, nn_ice , ln_dm2dc, ln_rnf, ln_ssr , nn_fwb, ln_cdgw
85	!!----------------------------------------------------------------------
86
87	IF(lwp) THEN
88	WRITE(numout,*)
89	WRITE(numout,*) 'sbc_init : surface boundary condition setting'
90	WRITE(numout,*) '~~~~~~~~ '
91	ENDIF
92
93	REWIND( numnam ) ! Read Namelist namsbc
94	READ ( numnam, namsbc )
95
96	! ! overwrite namelist parameter using CPP key information
97	IF( Agrif_Root() ) THEN ! AGRIF zoom
98	IF( lk_lim2 ) nn_ice = 2
99	IF( lk_lim3 ) nn_ice = 3
100	IF( lk_cice ) nn_ice = 4
101	ENDIF
102	IF( cp_cfg == 'gyre' ) THEN ! GYRE configuration
103	ln_ana = .TRUE.
104	nn_ice = 0
105	ENDIF
106	IF( ln_cpl ) THEN
107	IF( lwp ) WRITE(numout,*) 'Coupled mode not sensible with StandAlone Surface scheme'
108	ln_cpl = .FALSE.
109	ENDIF
110	IF( ln_apr_dyn ) THEN
111	IF( lwp ) WRITE(numout,*) 'No atmospheric gradient needed with StandAlone Surface scheme'
112	ln_apr_dyn = .FALSE.
113	ENDIF
114	IF( ln_dm2dc ) THEN
115	IF( lwp ) WRITE(numout,*) 'No diurnal cycle needed with StandAlone Surface scheme'
116	ln_dm2dc = .FALSE.
117	ENDIF
118	IF( ln_rnf ) THEN
119	IF( lwp ) WRITE(numout,*) 'No runoff needed with StandAlone Surface scheme'
120	ln_rnf = .FALSE.
121	ENDIF
122	IF( ln_ssr ) THEN
123	IF( lwp ) WRITE(numout,*) 'No surface relaxation needed with StandAlone Surface scheme'
124	ln_ssr = .FALSE.
125	ENDIF
126	IF( nn_fwb > 0 ) THEN
127	IF( lwp ) WRITE(numout,*) 'No freshwater budget adjustment needed with StandAlone Surface scheme'
128	nn_fwb = 0
129	ENDIF
130	IF( nn_closea > 0 ) THEN
131	IF( lwp ) WRITE(numout,*) 'No closed seas adjustment needed with StandAlone Surface scheme'
132	nn_closea = 0
133	ENDIF
134
135	IF(lwp) THEN ! Control print
136	WRITE(numout,*) ' Namelist namsbc (partly overwritten with CPP key setting)'
137	WRITE(numout,*) ' frequency update of sbc (and ice) nn_fsbc = ', nn_fsbc
138	WRITE(numout,*) ' Type of sbc : '
139	WRITE(numout,*) ' analytical formulation ln_ana = ', ln_ana
140	WRITE(numout,*) ' flux formulation ln_flx = ', ln_flx
141	WRITE(numout,*) ' CLIO bulk formulation ln_blk_clio = ', ln_blk_clio
142	WRITE(numout,*) ' CORE bulk formulation ln_blk_core = ', ln_blk_core
143	WRITE(numout,*) ' MFS bulk formulation ln_blk_mfs = ', ln_blk_mfs
144	WRITE(numout,*) ' coupled formulation (T if key_sbc_cpl) ln_cpl = ', ln_cpl
145	WRITE(numout,*) ' Misc. options of sbc : '
146	WRITE(numout,*) ' Patm gradient added in ocean & ice Eqs. ln_apr_dyn = ', ln_apr_dyn
147	WRITE(numout,*) ' ice management in the sbc (=0/1/2/3) nn_ice = ', nn_ice
148	WRITE(numout,*) ' daily mean to diurnal cycle qsr ln_dm2dc = ', ln_dm2dc
149	WRITE(numout,*) ' runoff / runoff mouths ln_rnf = ', ln_rnf
150	WRITE(numout,*) ' Sea Surface Restoring on SST and/or SSS ln_ssr = ', ln_ssr
151	WRITE(numout,*) ' FreshWater Budget control (=0/1/2) nn_fwb = ', nn_fwb
152	WRITE(numout,*) ' closed sea (=0/1) (set in namdom) nn_closea = ', nn_closea
153	ENDIF
154
155	! ! allocate sbc arrays
156	IF( sbc_oce_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_oce arrays' )
157
158	! ! Checks:
159	IF( .NOT. ln_rnf ) THEN ! no specific treatment in vicinity of river mouths
160	ln_rnf_mouth = .false.
161	IF( sbc_rnf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_rnf arrays' )
162	nkrnf = 0
163	rnf (:,:) = 0.e0
164	rnfmsk (:,:) = 0.e0
165	rnfmsk_z(:) = 0.e0
166	ENDIF
167	IF( nn_ice == 0 ) fr_i(:,:) = 0.e0 ! no ice in the domain, ice fraction is always zero
168
169	! ! restartability
170	IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 ) &
171	& CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' )
172	!
173	IF( ( nn_ice == 2 .OR. nn_ice ==3 ) .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. lk_cpl ) ) &
174	& CALL ctl_stop( 'LIM sea-ice model requires a bulk formulation or coupled configuration' )
175	IF( nn_ice == 4 .AND. .NOT.( ln_blk_core .OR. lk_cpl ) ) &
176	& CALL ctl_stop( 'CICE sea-ice model requires ln_blk_core or lk_cpl' )
177	IF( nn_ice == 4 .AND. ( .NOT. ( cp_cfg == 'orca' ) .OR. lk_agrif ) ) &
178	& CALL ctl_stop( 'CICE sea-ice model currently only available in a global ORCA configuration without AGRIF' )
179
180	!drag coefficient read from wave model definable only with mfs bulk formulae and core
181	IF(ln_cdgw .AND. .NOT.(ln_blk_mfs .OR. ln_blk_core) ) &
182	& CALL ctl_stop( 'drag coefficient read from wave model definable only with mfs bulk formulae and core')
183
184	! ! Choice of the Surface Boudary Condition (set nsbc)
185	icpt = 0
186	IF( ln_ana ) THEN ; nsbc = 1 ; icpt = icpt + 1 ; ENDIF ! analytical formulation
187	IF( ln_flx ) THEN ; nsbc = 2 ; icpt = icpt + 1 ; ENDIF ! flux formulation
188	IF( ln_blk_clio ) THEN ; nsbc = 3 ; icpt = icpt + 1 ; ENDIF ! CLIO bulk formulation
189	IF( ln_blk_core ) THEN ; nsbc = 4 ; icpt = icpt + 1 ; ENDIF ! CORE bulk formulation
190	IF( ln_blk_mfs ) THEN ; nsbc = 6 ; icpt = icpt + 1 ; ENDIF ! MFS bulk formulation
191	IF( ln_cpl ) THEN ; nsbc = 5 ; icpt = icpt + 1 ; ENDIF ! Coupled formulation
192	IF( cp_cfg == 'gyre') THEN ; nsbc = 0 ; ENDIF ! GYRE analytical formulation
193	IF( lk_esopa ) nsbc = -1 ! esopa test, ALL formulations
194	!
195	IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN
196	WRITE(numout,*)
197	WRITE(numout,*) ' E R R O R in setting the sbc, one and only one namelist/CPP key option '
198	WRITE(numout,*) ' must be choosen. You choose ', icpt, ' option(s)'
199	WRITE(numout,*) ' We stop'
200	nstop = nstop + 1
201	ENDIF
202	IF(lwp) THEN
203	WRITE(numout,*)
204	IF( nsbc == -1 ) WRITE(numout,*) ' ESOPA test All surface boundary conditions'
205	IF( nsbc == 0 ) WRITE(numout,*) ' GYRE analytical formulation'
206	IF( nsbc == 1 ) WRITE(numout,*) ' analytical formulation'
207	IF( nsbc == 2 ) WRITE(numout,*) ' flux formulation'
208	IF( nsbc == 3 ) WRITE(numout,*) ' CLIO bulk formulation'
209	IF( nsbc == 4 ) WRITE(numout,*) ' CORE bulk formulation'
210	IF( nsbc == 5 ) WRITE(numout,*) ' coupled formulation'
211	IF( nsbc == 6 ) WRITE(numout,*) ' MFS Bulk formulation'
212	ENDIF
213
214	IF( nn_ice == 4 ) CALL cice_sbc_init (nsbc)
215	!
216	END SUBROUTINE sbc_init
217
218
219	SUBROUTINE sbc( kt )
220	!!---------------------------------------------------------------------
221	!! * ROUTINE sbc *
222	!!
223	!! ** Purpose : provide at each time-step the ocean surface boundary
224	!! condition (momentum, heat and freshwater fluxes)
225	!!
226	!! ** Method : blah blah to be written ?????????
227	!! CAUTION : never mask the surface stress field (tke sbc)
228	!!
229	!! ** Action : - set the ocean surface boundary condition at before and now
230	!! time step, i.e.
231	!! utau_b, vtau_b, qns_b, qsr_b, emp_n, emps_b, qrp_b, erp_b
232	!! utau , vtau , qns , qsr , emp , emps , qrp , erp
233	!! - updte the ice fraction : fr_i
234	!!----------------------------------------------------------------------
235	INTEGER, INTENT(in) :: kt ! ocean time step
236	!!---------------------------------------------------------------------
237	!
238	IF( nn_timing == 1 ) CALL timing_start('sbc')
239	!
240	! ! ---------------------------------------- !
241	IF( kt /= nit000 ) THEN ! Swap of forcing fields !
242	! ! ---------------------------------------- !
243	utau_b(:,:) = utau(:,:) ! Swap the ocean forcing fields
244	vtau_b(:,:) = vtau(:,:) ! (except at nit000 where before fields
245	qns_b (:,:) = qns (:,:) ! are set at the end of the routine)
246	! The 3D heat content due to qsr forcing is treated in traqsr
247	! qsr_b (:,:) = qsr (:,:)
248	emp_b (:,:) = emp (:,:)
249	emps_b(:,:) = emps(:,:)
250	ENDIF
251	! ! ---------------------------------------- !
252	! ! forcing field computation !
253	! ! ---------------------------------------- !
254
255	CALL iom_setkt( kt + nn_fsbc - 1 ) ! in sbc, iom_put is called every nn_fsbc time step
256	!
257	CALL sbc_sas( kt ) ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
258	! ! averaged over nf_sbc time-step
259
260	IF (ln_cdgw) CALL sbc_wave( kt )
261	!== sbc formulation ==!
262
263	SELECT CASE( nsbc ) ! Compute ocean surface boundary condition
264	! ! (i.e. utau,vtau, qns, qsr, emp, emps)
265	CASE( 0 ) ; CALL sbc_gyre ( kt ) ! analytical formulation : GYRE configuration
266	CASE( 1 ) ; CALL sbc_ana ( kt ) ! analytical formulation : uniform sbc
267	CASE( 2 ) ; CALL sbc_flx ( kt ) ! flux formulation
268	CASE( 3 ) ; CALL sbc_blk_clio( kt ) ! bulk formulation : CLIO for the ocean
269	CASE( 4 ) ; CALL sbc_blk_core( kt ) ! bulk formulation : CORE for the ocean
270	CASE( 5 ) ; CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! coupled formulation
271	CASE( 6 ) ; CALL sbc_blk_mfs ( kt ) ! bulk formulation : MFS for the ocean
272	CASE( -1 )
273	CALL sbc_ana ( kt ) ! ESOPA, test ALL the formulations
274	CALL sbc_gyre ( kt ) !
275	CALL sbc_flx ( kt ) !
276	CALL sbc_blk_clio( kt ) !
277	CALL sbc_blk_core( kt ) !
278	CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) !
279	END SELECT
280
281	! !== Misc. Options ==!
282
283	SELECT CASE( nn_ice ) ! Update heat and freshwater fluxes over sea-ice areas
284	CASE( 1 ) ; CALL sbc_ice_if ( kt ) ! Ice-cover climatology ("Ice-if" model)
285	!
286	CASE( 2 ) ; CALL sbc_ice_lim_2( kt, nsbc ) ! LIM-2 ice model
287	!
288	CASE( 3 ) ; CALL sbc_ice_lim ( kt, nsbc ) ! LIM-3 ice model
289	!
290	CASE( 4 ) ; CALL sbc_ice_cice ( kt, nsbc ) ! CICE ice model
291	END SELECT
292
293	!RBbug do not understand why see ticket 667
294	CALL lbc_lnk( emp, 'T', 1. )
295	!
296	IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 !
297	! ! ---------------------------------------- !
298	IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields set to nit000'
299	utau_b(:,:) = utau(:,:)
300	vtau_b(:,:) = vtau(:,:)
301	qns_b (:,:) = qns (:,:)
302	! qsr_b (:,:) = qsr (:,:)
303	emp_b (:,:) = emp (:,:)
304	emps_b(:,:) = emps(:,:)
305	ENDIF
306	! ! ---------------------------------------- !
307	! ! Outputs and control print !
308	! ! ---------------------------------------- !
309	IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
310	CALL iom_put( "empmr" , emp - rnf ) ! upward water flux
311	CALL iom_put( "empsmr", emps - rnf ) ! c/d water flux
312	CALL iom_put( "qt" , qns + qsr ) ! total heat flux
313	CALL iom_put( "qns" , qns ) ! solar heat flux
314	CALL iom_put( "qsr" , qsr ) ! solar heat flux
315	IF( nn_ice > 0 ) CALL iom_put( "ice_cover", fr_i ) ! ice fraction
316	ENDIF
317	!
318	CALL iom_setkt( kt ) ! iom_put outside of sbc is called at every time step
319	!
320	CALL iom_put( "utau", utau ) ! i-wind stress (stress can be updated at
321	CALL iom_put( "vtau", vtau ) ! j-wind stress each time step in sea-ice)
322	CALL iom_put( "taum", taum ) ! wind stress module
323	CALL iom_put( "wspd", wndm ) ! wind speed module
324	!
325	IF(ln_ctl) THEN ! print mean trends (used for debugging)
326	CALL prt_ctl(tab2d_1=fr_i , clinfo1=' fr_i - : ', mask1=tmask, ovlap=1 )
327	CALL prt_ctl(tab2d_1=(emp-rnf) , clinfo1=' emp-rnf - : ', mask1=tmask, ovlap=1 )
328	CALL prt_ctl(tab2d_1=(emps-rnf) , clinfo1=' emps-rnf - : ', mask1=tmask, ovlap=1 )
329	CALL prt_ctl(tab2d_1=qns , clinfo1=' qns - : ', mask1=tmask, ovlap=1 )
330	CALL prt_ctl(tab2d_1=qsr , clinfo1=' qsr - : ', mask1=tmask, ovlap=1 )
331	CALL prt_ctl(tab3d_1=tmask , clinfo1=' tmask - : ', mask1=tmask, ovlap=1, kdim=jpk )
332	CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst - : ', mask1=tmask, ovlap=1, kdim=1 )
333	CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss - : ', mask1=tmask, ovlap=1, kdim=1 )
334	CALL prt_ctl(tab2d_1=utau , clinfo1=' utau - : ', mask1=umask, &
335	& tab2d_2=vtau , clinfo2=' vtau - : ', mask2=vmask, ovlap=1 )
336	ENDIF
337
338	IF( kt == nitend ) CALL sbc_final ! Close down surface module if necessary
339	!
340	IF( nn_timing == 1 ) CALL timing_stop('sbc')
341	!
342	END SUBROUTINE sbc
343
344	SUBROUTINE sbc_final
345	!!---------------------------------------------------------------------
346	!! * ROUTINE sbc_final *
347	!!---------------------------------------------------------------------
348
349	!-----------------------------------------------------------------
350	! Finalize CICE (if used)
351	!-----------------------------------------------------------------
352
353	IF( nn_ice == 4 ) CALL cice_sbc_final
354	!
355	END SUBROUTINE sbc_final
356
357	!!======================================================================
358	END MODULE sbcmod

Note: See TracBrowser for help on using the repository browser.

Download in other formats: