New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdydta.F90 in branches/2012/dev_r3327_MERCATOR1_BDY/NEMOGCM/NEMO/OPA_SRC/BDY – NEMO

source: branches/2012/dev_r3327_MERCATOR1_BDY/NEMOGCM/NEMO/OPA_SRC/BDY/bdydta.F90 @ 3367

Last change on this file since 3367 was 3367, checked in by greffray, 12 years ago

Merge tidal packages
Merge OBC-BDY packages
Add atmospheric pressure at the open boundaries
Modification of the namelist for AMM12 configuration
  • Property svn:keywords set to Id
File size: 32.3 KB
Line 
1MODULE bdydta
2   !!======================================================================
3   !!                       ***  MODULE bdydta  ***
4   !! Open boundary data : read the data for the unstructured open boundaries.
5   !!======================================================================
6   !! History :  1.0  !  2005-01  (J. Chanut, A. Sellar)  Original code
7   !!             -   !  2007-01  (D. Storkey) Update to use IOM module
8   !!             -   !  2007-07  (D. Storkey) add bdy_dta_fla
9   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
10   !!            3.3  !  2010-09  (E.O'Dea) modifications for Shelf configurations
11   !!            3.3  !  2010-09  (D.Storkey) add ice boundary conditions
12   !!            3.4  !  2011     (D. Storkey) rewrite in preparation for OBC-BDY merge
13   !!----------------------------------------------------------------------
14#if defined key_bdy
15   !!----------------------------------------------------------------------
16   !!   'key_bdy'                     Open Boundary Conditions
17   !!----------------------------------------------------------------------
18   !!    bdy_dta        : read external data along open boundaries from file
19   !!    bdy_dta_init   : initialise arrays etc for reading of external data
20   !!----------------------------------------------------------------------
21   USE wrk_nemo        ! Memory Allocation
22   USE timing          ! Timing
23   USE oce             ! ocean dynamics and tracers
24   USE dom_oce         ! ocean space and time domain
25   USE phycst          ! physical constants
26   USE bdy_oce         ! ocean open boundary conditions 
27   USE bdytides        ! tidal forcing at boundaries
28   USE fldread         ! read input fields
29   USE iom             ! IOM library
30   USE in_out_manager  ! I/O logical units
31#if defined key_lim2
32   USE ice_2
33#endif
34   USE sbcapr
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   bdy_dta          ! routine called by step.F90 and dynspg_ts.F90
40   PUBLIC   bdy_dta_init     ! routine called by nemogcm.F90
41
42   INTEGER, ALLOCATABLE, DIMENSION(:)   ::   nb_bdy_fld        ! Number of fields to update for each boundary set.
43   INTEGER                              ::   nb_bdy_fld_sum    ! Total number of fields to update for all boundary sets.
44
45   LOGICAL,           DIMENSION(jp_bdy) ::   ln_full_vel_array ! =T => full velocities in 3D boundary conditions
46                                                               ! =F => baroclinic velocities in 3D boundary conditions
47
48   TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:), TARGET ::   bf        ! structure of input fields (file informations, fields read)
49
50   TYPE(MAP_POINTER), ALLOCATABLE, DIMENSION(:) :: nbmap_ptr   ! array of pointers to nbmap
51
52#  include "domzgr_substitute.h90"
53   !!----------------------------------------------------------------------
54   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
55   !! $Id$
56   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
57   !!----------------------------------------------------------------------
58CONTAINS
59
60      SUBROUTINE bdy_dta( kt, jit, time_offset )
61      !!----------------------------------------------------------------------
62      !!                   ***  SUBROUTINE bdy_dta  ***
63      !!                   
64      !! ** Purpose :   Update external data for open boundary conditions
65      !!
66      !! ** Method  :   Use fldread.F90
67      !!               
68      !!----------------------------------------------------------------------
69      !!
70      INTEGER, INTENT( in )           ::   kt    ! ocean time-step index
71      INTEGER, INTENT( in ), OPTIONAL ::   jit   ! subcycle time-step index (for timesplitting option)
72      INTEGER, INTENT( in ), OPTIONAL ::   time_offset  ! time offset in units of timesteps. NB. if jit
73                                                        ! is present then units = subcycle timesteps.
74                                                        ! time_offset = 0 => get data at "now" time level
75                                                        ! time_offset = -1 => get data at "before" time level
76                                                        ! time_offset = +1 => get data at "after" time level
77                                                        ! etc.
78      !!
79      INTEGER     ::  ib_bdy, jfld, jstart, jend, ib, ii, ij, ik, igrd  ! local indices
80      INTEGER,          DIMENSION(jpbgrd) ::   ilen1 
81      INTEGER, POINTER, DIMENSION(:)      ::   nblen, nblenrim  ! short cuts
82      !!
83      !!---------------------------------------------------------------------------
84      !!
85      IF( nn_timing == 1 ) CALL timing_start('bdy_dta')
86
87      ! Initialise data arrays once for all from initial conditions where required
88      !---------------------------------------------------------------------------
89      IF( kt .eq. nit000 .and. .not. PRESENT(jit) ) THEN
90
91         ! Calculate depth-mean currents
92         !-----------------------------
93         CALL wrk_alloc(jpi,jpj,pu2d,pv2d) 
94
95         pu2d(:,:) = 0.e0
96         pv2d(:,:) = 0.e0
97
98         DO ik = 1, jpkm1   !! Vertically integrated momentum trends
99             pu2d(:,:) = pu2d(:,:) + fse3u(:,:,ik) * umask(:,:,ik) * un(:,:,ik)
100             pv2d(:,:) = pv2d(:,:) + fse3v(:,:,ik) * vmask(:,:,ik) * vn(:,:,ik)
101         END DO
102         pu2d(:,:) = pu2d(:,:) * hur(:,:)
103         pv2d(:,:) = pv2d(:,:) * hvr(:,:)
104         
105         DO ib_bdy = 1, nb_bdy
106
107            nblen => idx_bdy(ib_bdy)%nblen
108            nblenrim => idx_bdy(ib_bdy)%nblenrim
109
110            IF( nn_dyn2d(ib_bdy) .gt. 0 .and. nn_dyn2d_dta(ib_bdy) .eq. 0 ) THEN
111               ilen1(:) = nblen(:)
112               igrd = 1
113               DO ib = 1, ilen1(igrd)
114                  ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
115                  ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
116                  dta_bdy(ib_bdy)%ssh(ib) = sshn(ii,ij) * tmask(ii,ij,1)         
117               END DO
118               igrd = 2
119               DO ib = 1, ilen1(igrd)
120                  ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
121                  ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
122                  dta_bdy(ib_bdy)%u2d(ib) = pu2d(ii,ij) * umask(ii,ij,1)         
123               END DO
124               igrd = 3
125               DO ib = 1, ilen1(igrd)
126                  ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
127                  ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
128                  dta_bdy(ib_bdy)%v2d(ib) = pv2d(ii,ij) * vmask(ii,ij,1)         
129               END DO
130            ENDIF
131
132            IF( nn_dyn3d(ib_bdy) .gt. 0 .and. nn_dyn3d_dta(ib_bdy) .eq. 0 ) THEN
133               ilen1(:) = nblen(:)
134               igrd = 2 
135               DO ib = 1, ilen1(igrd)
136                  DO ik = 1, jpkm1
137                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
138                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
139                     dta_bdy(ib_bdy)%u3d(ib,ik) =  ( un(ii,ij,ik) - pu2d(ii,ij) ) * umask(ii,ij,ik)         
140                  END DO
141               END DO
142               igrd = 3 
143               DO ib = 1, ilen1(igrd)
144                  DO ik = 1, jpkm1
145                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
146                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
147                     dta_bdy(ib_bdy)%v3d(ib,ik) =  ( vn(ii,ij,ik) - pv2d(ii,ij) ) * vmask(ii,ij,ik)         
148                     END DO
149               END DO
150            ENDIF
151
152            IF( nn_tra(ib_bdy) .gt. 0 .and. nn_tra_dta(ib_bdy) .eq. 0 ) THEN
153               ilen1(:) = nblen(:)
154               igrd = 1                       ! Everything is at T-points here
155               DO ib = 1, ilen1(igrd)
156                  DO ik = 1, jpkm1
157                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
158                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
159                     dta_bdy(ib_bdy)%tem(ib,ik) = tsn(ii,ij,ik,jp_tem) * tmask(ii,ij,ik)         
160                     dta_bdy(ib_bdy)%sal(ib,ik) = tsn(ii,ij,ik,jp_sal) * tmask(ii,ij,ik)         
161                  END DO
162               END DO
163            ENDIF
164
165#if defined key_lim2
166            IF( nn_ice_lim2(ib_bdy) .gt. 0 .and. nn_ice_lim2_dta(ib_bdy) .eq. 0 ) THEN
167               ilen1(:) = nblen(:)
168               igrd = 1                       ! Everything is at T-points here
169               DO ib = 1, ilen1(igrd)
170                  ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
171                  ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
172                  dta_bdy(ib_bdy)%frld(ib) = frld(ii,ij) * tmask(ii,ij,1)         
173                  dta_bdy(ib_bdy)%hicif(ib) = hicif(ii,ij) * tmask(ii,ij,1)         
174                  dta_bdy(ib_bdy)%hsnif(ib) = hsnif(ii,ij) * tmask(ii,ij,1)         
175               END DO
176            ENDIF
177#endif
178
179         ENDDO ! ib_bdy
180
181         CALL wrk_dealloc(jpi,jpj,pu2d,pv2d) 
182
183      ENDIF ! kt .eq. nit000
184
185      ! update external data from files
186      !--------------------------------
187     
188      jstart = 1
189      DO ib_bdy = 1, nb_bdy   
190         IF( nn_dta(ib_bdy) .eq. 1 ) THEN ! skip this bit if no external data required
191     
192            IF( PRESENT(jit) ) THEN
193               ! Update barotropic boundary conditions only
194               ! jit is optional argument for fld_read and tide_update
195               IF( nn_dyn2d(ib_bdy) .gt. 0 ) THEN
196                  IF( nn_dyn2d_dta(ib_bdy) .eq. 2 ) THEN ! tidal harmonic forcing ONLY: initialise arrays
197                     dta_bdy(ib_bdy)%ssh(:) = 0.0
198                     dta_bdy(ib_bdy)%u2d(:) = 0.0
199                     dta_bdy(ib_bdy)%v2d(:) = 0.0
200                  ENDIF
201                  IF (nn_tra(ib_bdy).ne.4) THEN
202                   IF (nn_dyn2d_dta(ib_bdy).eq.1.or.nn_dyn2d_dta(ib_bdy).eq.3.or.(ln_full_vel_array(ib_bdy).and.nn_dyn3d_dta(ib_bdy).eq.1)) THEN
203                     ! For the runoff case, no need to update the forcing (already done in the baroclinic part)
204                     jend = nb_bdy_fld(ib_bdy)
205                     IF ( nn_tra(ib_bdy) .GT. 0 .AND. nn_tra_dta(ib_bdy) .GE. 1 ) jend = jend - 2
206                     CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), map=nbmap_ptr(jstart:jend), jit=jit, time_offset=time_offset )
207                     IF ( nn_tra(ib_bdy) .GT. 0 .AND. nn_tra_dta(ib_bdy) .GE. 1 ) jend = jend + 2
208                     ! If full velocities in boundary data then split into barotropic and baroclinic data
209                     IF( ln_full_vel_array(ib_bdy) .and.                                             &
210                    &    ( nn_dyn2d_dta(ib_bdy) .eq. 1 .or. nn_dyn2d_dta(ib_bdy) .eq. 3 .or. nn_dyn3d_dta(ib_bdy) .eq. 1 ) ) THEN
211                        igrd = 2                      ! zonal velocity
212                        dta_bdy(ib_bdy)%u2d(:) = 0.0
213                        DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
214                           ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
215                           ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
216                           DO ik = 1, jpkm1
217                              dta_bdy(ib_bdy)%u2d(ib) = dta_bdy(ib_bdy)%u2d(ib) &
218                    &                          + fse3u(ii,ij,ik) * umask(ii,ij,ik) * dta_bdy(ib_bdy)%u3d(ib,ik)
219                           END DO
220                           dta_bdy(ib_bdy)%u2d(ib) =  dta_bdy(ib_bdy)%u2d(ib) * hur(ii,ij)
221                           DO ik = 1, jpkm1
222                              dta_bdy(ib_bdy)%u3d(ib,ik) = dta_bdy(ib_bdy)%u3d(ib,ik) - dta_bdy(ib_bdy)%u2d(ib)
223                           END DO
224                        END DO
225                        igrd = 3                      ! meridional velocity
226                        dta_bdy(ib_bdy)%v2d(:) = 0.0
227                        DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
228                           ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
229                           ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
230                           DO ik = 1, jpkm1
231                              dta_bdy(ib_bdy)%v2d(ib) = dta_bdy(ib_bdy)%v2d(ib) &
232                    &                       + fse3v(ii,ij,ik) * vmask(ii,ij,ik) * dta_bdy(ib_bdy)%v3d(ib,ik)
233                           END DO
234                           dta_bdy(ib_bdy)%v2d(ib) =  dta_bdy(ib_bdy)%v2d(ib) * hvr(ii,ij)
235                           DO ik = 1, jpkm1
236                              dta_bdy(ib_bdy)%v3d(ib,ik) = dta_bdy(ib_bdy)%v3d(ib,ik) - dta_bdy(ib_bdy)%v2d(ib)
237                           END DO
238                        END DO
239                     ENDIF                   
240                   ENDIF
241                   IF( nn_dyn2d_dta(ib_bdy) .ge. 2 ) THEN ! update tidal harmonic forcing
242                      CALL tide_update( kt=kt, idx=idx_bdy(ib_bdy), dta=dta_bdy(ib_bdy), td=tides(ib_bdy),   & 
243                      &                 jit=jit, time_offset=time_offset )
244                   ENDIF
245                  ENDIF
246               ENDIF
247            ELSE
248               IF (nn_tra(ib_bdy).eq.4) then      ! runoff condition
249                  jend = nb_bdy_fld(ib_bdy)
250                  CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), map=nbmap_ptr(jstart:jend), time_offset=time_offset )
251                  !
252                  igrd = 2                      ! zonal velocity
253                  DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
254                     ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
255                     ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
256                     dta_bdy(ib_bdy)%u2d(ib) = dta_bdy(ib_bdy)%u2d(ib) / ( e2u(ii,ij) * hu_0(ii,ij) )
257                  END DO
258                  !
259                  igrd = 3                      ! meridional velocity
260                  DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
261                     ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
262                     ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
263                     dta_bdy(ib_bdy)%v2d(ib) = dta_bdy(ib_bdy)%v2d(ib) / ( e1v(ii,ij) * hv_0(ii,ij) )
264                  END DO
265               ELSE
266                  IF( nn_dyn2d(ib_bdy) .gt. 0 .and. nn_dyn2d_dta(ib_bdy) .eq. 2 ) THEN ! tidal harmonic forcing ONLY: initialise arrays
267                     dta_bdy(ib_bdy)%ssh(:) = 0.0
268                     dta_bdy(ib_bdy)%u2d(:) = 0.0
269                     dta_bdy(ib_bdy)%v2d(:) = 0.0
270                  ENDIF
271                  IF( nb_bdy_fld(ib_bdy) .gt. 0 ) THEN ! update external data
272                     jend = nb_bdy_fld(ib_bdy)
273                     CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), map=nbmap_ptr(jstart:jend), time_offset=time_offset )
274                  ENDIF
275                  ! If full velocities in boundary data then split into barotropic and baroclinic data
276                  IF( ln_full_vel_array(ib_bdy) .and.                                             &
277                 &    ( nn_dyn2d_dta(ib_bdy) .eq. 1 .or. nn_dyn2d_dta(ib_bdy) .eq. 3 .or. nn_dyn3d_dta(ib_bdy) .eq. 1 ) ) THEN
278                     igrd = 2                      ! zonal velocity
279                     dta_bdy(ib_bdy)%u2d(:) = 0.0
280                     DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
281                        ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
282                        ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
283                        DO ik = 1, jpkm1
284                           dta_bdy(ib_bdy)%u2d(ib) = dta_bdy(ib_bdy)%u2d(ib) &
285                 &                       + fse3u(ii,ij,ik) * umask(ii,ij,ik) * dta_bdy(ib_bdy)%u3d(ib,ik)
286                        END DO
287                        dta_bdy(ib_bdy)%u2d(ib) =  dta_bdy(ib_bdy)%u2d(ib) * hur(ii,ij)
288                        DO ik = 1, jpkm1
289                           dta_bdy(ib_bdy)%u3d(ib,ik) = dta_bdy(ib_bdy)%u3d(ib,ik) - dta_bdy(ib_bdy)%u2d(ib)
290                        END DO
291                     END DO
292                     igrd = 3                      ! meridional velocity
293                     dta_bdy(ib_bdy)%v2d(:) = 0.0
294                     DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
295                        ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
296                        ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
297                        DO ik = 1, jpkm1
298                           dta_bdy(ib_bdy)%v2d(ib) = dta_bdy(ib_bdy)%v2d(ib) &
299                 &                       + fse3v(ii,ij,ik) * vmask(ii,ij,ik) * dta_bdy(ib_bdy)%v3d(ib,ik)
300                        END DO
301                        dta_bdy(ib_bdy)%v2d(ib) =  dta_bdy(ib_bdy)%v2d(ib) * hvr(ii,ij)
302                        DO ik = 1, jpkm1
303                           dta_bdy(ib_bdy)%v3d(ib,ik) = dta_bdy(ib_bdy)%v3d(ib,ik) - dta_bdy(ib_bdy)%v2d(ib)
304                        END DO
305                     END DO
306                  ENDIF
307                  IF( nn_dyn2d(ib_bdy) .gt. 0 .and. nn_dyn2d_dta(ib_bdy) .ge. 2 ) THEN ! update tidal harmonic forcing
308                     CALL tide_update( kt=kt, idx=idx_bdy(ib_bdy), dta=dta_bdy(ib_bdy), td=tides(ib_bdy), time_offset=time_offset )
309                  ENDIF
310               ENDIF
311            ENDIF
312            jstart = jend+1
313         END IF ! nn_dta(ib_bdy) = 1
314      END DO  ! ib_bdy
315
316      IF ( ln_apr_obc ) THEN
317         DO ib_bdy = 1, nb_bdy
318            IF (nn_tra(ib_bdy).NE.4)THEN
319               igrd = 1                      ! meridional velocity
320               DO ib = 1, idx_bdy(ib_bdy)%nblenrim(igrd)
321                  ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
322                  ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
323                  dta_bdy(ib_bdy)%ssh(ib) = dta_bdy(ib_bdy)%ssh(ib) + ssh_ib(ii,ij)
324               ENDDO
325            ENDIF
326         ENDDO
327      ENDIF
328
329      IF( nn_timing == 1 ) CALL timing_stop('bdy_dta')
330
331      END SUBROUTINE bdy_dta
332
333
334      SUBROUTINE bdy_dta_init
335      !!----------------------------------------------------------------------
336      !!                   ***  SUBROUTINE bdy_dta_init  ***
337      !!                   
338      !! ** Purpose :   Initialise arrays for reading of external data
339      !!                for open boundary conditions
340      !!
341      !! ** Method  :   Use fldread.F90
342      !!               
343      !!----------------------------------------------------------------------
344      USE dynspg_oce, ONLY: lk_dynspg_ts
345      !!
346      INTEGER     ::  ib_bdy, jfld, jstart, jend, ierror  ! local indices
347      !!
348      CHARACTER(len=100)                     ::   cn_dir        ! Root directory for location of data files
349      CHARACTER(len=100), DIMENSION(nb_bdy)  ::   cn_dir_array  ! Root directory for location of data files
350      LOGICAL                                ::   ln_full_vel   ! =T => full velocities in 3D boundary data
351                                                                ! =F => baroclinic velocities in 3D boundary data
352      INTEGER                                ::   ilen_global   ! Max length required for global bdy dta arrays
353      INTEGER,              DIMENSION(jpbgrd) ::  ilen0         ! size of local arrays
354      INTEGER, ALLOCATABLE, DIMENSION(:)     ::   ilen1, ilen3  ! size of 1st and 3rd dimensions of local arrays
355      INTEGER, ALLOCATABLE, DIMENSION(:)     ::   ibdy           ! bdy set for a particular jfld
356      INTEGER, ALLOCATABLE, DIMENSION(:)     ::   igrid         ! index for grid type (1,2,3 = T,U,V)
357      INTEGER, POINTER, DIMENSION(:)         ::   nblen, nblenrim  ! short cuts
358      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::   blf_i         !  array of namelist information structures
359      TYPE(FLD_N) ::   bn_tem, bn_sal, bn_u3d, bn_v3d   !
360      TYPE(FLD_N) ::   bn_ssh, bn_u2d, bn_v2d           ! informations about the fields to be read
361#if defined key_lim2
362      TYPE(FLD_N) ::   bn_frld, bn_hicif, bn_hsnif      !
363#endif
364      NAMELIST/nambdy_dta/ cn_dir, bn_tem, bn_sal, bn_u3d, bn_v3d, bn_ssh, bn_u2d, bn_v2d 
365#if defined key_lim2
366      NAMELIST/nambdy_dta/ bn_frld, bn_hicif, bn_hsnif
367#endif
368      NAMELIST/nambdy_dta/ ln_full_vel
369      !!---------------------------------------------------------------------------
370
371      IF( nn_timing == 1 ) CALL timing_start('bdy_dta_init')
372
373      IF(lwp) WRITE(numout,*)
374      IF(lwp) WRITE(numout,*) 'bdy_dta_ini : initialization of data at the open boundaries'
375      IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
376      IF(lwp) WRITE(numout,*) ''
377
378      ! Set nn_dta
379      DO ib_bdy = 1, nb_bdy
380         IF (nn_dyn2d_dta(ib_bdy).eq.1.OR.nn_dyn2d_dta(ib_bdy).eq.3) nn_dta(ib_bdy) = 1
381         IF (nn_dyn3d_dta(ib_bdy).ge.1) nn_dta(ib_bdy) = 1
382         IF (nn_tra_dta  (ib_bdy).ge.1) nn_dta(ib_bdy) = 1
383#if defined key_lim2
384         IF (nn_ice_lim2_dta(ib_bdy).eq.1) nn_dta(ib_bdy) = 1
385#endif
386         IF (lwp) THEN
387            WRITE(numout,*) 'Bdy package number ',ib_bdy
388            IF (nn_dta(ib_bdy).eq.1) THEN
389               WRITE(numout,*) 'We use external data'
390            ELSE
391               WRITE(numout,*) 'We do not use external data'
392            ENDIF
393         ENDIF
394      END DO
395
396      ! Work out upper bound of how many fields there are to read in and allocate arrays
397      ! ---------------------------------------------------------------------------
398      ALLOCATE( nb_bdy_fld(nb_bdy) )
399      nb_bdy_fld(:) = 0
400      DO ib_bdy = 1, nb_bdy         
401         IF( nn_dyn2d(ib_bdy) .gt. 0 .and. ( nn_dyn2d_dta(ib_bdy) .eq. 1 .or. nn_dyn2d_dta(ib_bdy) .eq. 3 ) ) THEN
402            nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 3
403         ENDIF
404         IF( nn_dyn3d(ib_bdy) .gt. 0 .and. nn_dyn3d_dta(ib_bdy) .eq. 1 ) THEN
405            nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 2
406         ENDIF
407         IF( nn_tra(ib_bdy) .gt. 0 .and. nn_tra_dta(ib_bdy) .eq. 1  ) THEN
408            nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 2
409         ENDIF
410#if defined key_lim2
411         IF( nn_ice_lim2(ib_bdy) .gt. 0 .and. nn_ice_lim2_dta(ib_bdy) .eq. 1  ) THEN
412            nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 3
413         ENDIF
414#endif               
415         IF(lwp) WRITE(numout,*) 'Maximum number of files to open =',nb_bdy_fld(ib_bdy)
416      ENDDO           
417
418      nb_bdy_fld_sum = SUM( nb_bdy_fld )
419
420      ALLOCATE( bf(nb_bdy_fld_sum), STAT=ierror )
421      IF( ierror > 0 ) THEN   
422         CALL ctl_stop( 'bdy_dta: unable to allocate bf structure' )   ;   RETURN 
423      ENDIF
424      ALLOCATE( blf_i(nb_bdy_fld_sum), STAT=ierror )
425      IF( ierror > 0 ) THEN   
426         CALL ctl_stop( 'bdy_dta: unable to allocate blf_i structure' )   ;   RETURN 
427      ENDIF
428      ALLOCATE( nbmap_ptr(nb_bdy_fld_sum), STAT=ierror )
429      IF( ierror > 0 ) THEN   
430         CALL ctl_stop( 'bdy_dta: unable to allocate nbmap_ptr structure' )   ;   RETURN 
431      ENDIF
432      ALLOCATE( ilen1(nb_bdy_fld_sum), ilen3(nb_bdy_fld_sum) ) 
433      ALLOCATE( ibdy(nb_bdy_fld_sum) ) 
434      ALLOCATE( igrid(nb_bdy_fld_sum) ) 
435
436      ! Read namelists
437      ! --------------
438      REWIND(numnam)
439      jfld = 0 
440      DO ib_bdy = 1, nb_bdy         
441         IF( nn_dta(ib_bdy) .eq. 1 ) THEN
442            ! set file information
443            cn_dir = './'        ! directory in which the model is executed
444            ln_full_vel = .false.
445            ! ... default values (NB: frequency positive => hours, negative => months)
446            !                    !  file       ! frequency !  variable   ! time intep !  clim   ! 'yearly' or ! weights  ! rotation  !
447            !                    !  name       ! hours !   name     !  (T/F)  !  (T/F)  !  'monthly'  ! filename ! pairs     !
448            bn_ssh     = FLD_N(  'bdy_ssh'     ,  24   , 'sossheig' , .false. , .false. ,   'yearly'  , ''       , ''        )
449            bn_u2d     = FLD_N(  'bdy_vel2d_u' ,  24   , 'vobtcrtx' , .false. , .false. ,   'yearly'  , ''       , ''        )
450            bn_v2d     = FLD_N(  'bdy_vel2d_v' ,  24   , 'vobtcrty' , .false. , .false. ,   'yearly'  , ''       , ''        )
451            bn_u3d     = FLD_N(  'bdy_vel3d_u' ,  24   , 'vozocrtx' , .false. , .false. ,   'yearly'  , ''       , ''        )
452            bn_v3d     = FLD_N(  'bdy_vel3d_v' ,  24   , 'vomecrty' , .false. , .false. ,   'yearly'  , ''       , ''        )
453            bn_tem     = FLD_N(  'bdy_tem'     ,  24   , 'votemper' , .false. , .false. ,   'yearly'  , ''       , ''        )
454            bn_sal     = FLD_N(  'bdy_sal'     ,  24   , 'vosaline' , .false. , .false. ,   'yearly'  , ''       , ''        )
455#if defined key_lim2
456            bn_frld    = FLD_N(  'bdy_frld'    ,  24   , 'ildsconc' , .false. , .false. ,   'yearly'  , ''       , ''        )
457            bn_hicif   = FLD_N(  'bdy_hicif'   ,  24   , 'iicethic' , .false. , .false. ,   'yearly'  , ''       , ''        )
458            bn_hsnif   = FLD_N(  'bdy_hsnif'   ,  24   , 'isnothic' , .false. , .false. ,   'yearly'  , ''       , ''        )
459#endif
460
461            ! Important NOT to rewind here.
462            READ( numnam, nambdy_dta )
463
464            cn_dir_array(ib_bdy) = cn_dir
465            ln_full_vel_array(ib_bdy) = ln_full_vel
466
467            nblen => idx_bdy(ib_bdy)%nblen
468            nblenrim => idx_bdy(ib_bdy)%nblenrim
469
470            ! Only read in necessary fields for this set.
471            ! Important that barotropic variables come first.
472            IF( nn_dyn2d(ib_bdy) .gt. 0 .and. ( nn_dyn2d_dta(ib_bdy) .eq. 1 .or. nn_dyn2d_dta(ib_bdy) .eq. 3 ) ) THEN
473
474               IF( nn_tra(ib_bdy) .ne. 4 ) THEN ! runoff condition : no ssh reading
475                  jfld = jfld + 1
476                  blf_i(jfld) = bn_ssh
477                  ibdy(jfld) = ib_bdy
478                  igrid(jfld) = 1
479                  ilen1(jfld) = nblen(igrid(jfld))
480                  ilen3(jfld) = 1
481               ENDIF
482
483               IF( .not. ln_full_vel_array(ib_bdy) ) THEN
484                  jfld = jfld + 1
485                  blf_i(jfld) = bn_u2d
486                  ibdy(jfld) = ib_bdy
487                  igrid(jfld) = 2
488                  ilen1(jfld) = nblen(igrid(jfld))
489                  ilen3(jfld) = 1
490
491                  jfld = jfld + 1
492                  blf_i(jfld) = bn_v2d
493                  ibdy(jfld) = ib_bdy
494                  igrid(jfld) = 3
495                  ilen1(jfld) = nblen(igrid(jfld))
496                  ilen3(jfld) = 1
497               ENDIF
498
499            ENDIF
500
501            ! baroclinic velocities
502            IF( ( nn_dyn3d(ib_bdy) .gt. 0 .and. nn_dyn3d_dta(ib_bdy) .eq. 1 ) .or. &
503           &      ( ln_full_vel_array(ib_bdy) .and. nn_dyn2d(ib_bdy) .gt. 0 .and.  &
504           &        ( nn_dyn2d_dta(ib_bdy) .eq. 1 .or. nn_dyn2d_dta(ib_bdy) .eq. 3 ) ) ) THEN
505
506               jfld = jfld + 1
507               blf_i(jfld) = bn_u3d
508               ibdy(jfld) = ib_bdy
509               igrid(jfld) = 2
510               ilen1(jfld) = nblen(igrid(jfld))
511               ilen3(jfld) = jpk
512
513               jfld = jfld + 1
514               blf_i(jfld) = bn_v3d
515               ibdy(jfld) = ib_bdy
516               igrid(jfld) = 3
517               ilen1(jfld) = nblen(igrid(jfld))
518               ilen3(jfld) = jpk
519
520            ENDIF
521
522            ! temperature and salinity
523            IF( nn_tra(ib_bdy) .gt. 0 .and. nn_tra_dta(ib_bdy) .eq. 1 ) THEN
524
525               jfld = jfld + 1
526               blf_i(jfld) = bn_tem
527               ibdy(jfld) = ib_bdy
528               igrid(jfld) = 1
529               ilen1(jfld) = nblen(igrid(jfld))
530               ilen3(jfld) = jpk
531
532               jfld = jfld + 1
533               blf_i(jfld) = bn_sal
534               ibdy(jfld) = ib_bdy
535               igrid(jfld) = 1
536               ilen1(jfld) = nblen(igrid(jfld))
537               ilen3(jfld) = jpk
538
539            ENDIF
540
541#if defined key_lim2
542            ! sea ice
543            IF( nn_ice_lim2(ib_bdy) .gt. 0 .and. nn_ice_lim2_dta(ib_bdy) .eq. 1 ) THEN
544
545               jfld = jfld + 1
546               blf_i(jfld) = bn_frld
547               ibdy(jfld) = ib_bdy
548               igrid(jfld) = 1
549               ilen1(jfld) = nblen(igrid(jfld))
550               ilen3(jfld) = 1
551
552               jfld = jfld + 1
553               blf_i(jfld) = bn_hicif
554               ibdy(jfld) = ib_bdy
555               igrid(jfld) = 1
556               ilen1(jfld) = nblen(igrid(jfld))
557               ilen3(jfld) = 1
558
559               jfld = jfld + 1
560               blf_i(jfld) = bn_hsnif
561               ibdy(jfld) = ib_bdy
562               igrid(jfld) = 1
563               ilen1(jfld) = nblen(igrid(jfld))
564               ilen3(jfld) = 1
565
566            ENDIF
567#endif
568            ! Recalculate field counts
569            !-------------------------
570            nb_bdy_fld_sum = 0
571            IF( ib_bdy .eq. 1 ) THEN
572               nb_bdy_fld(ib_bdy) = jfld
573               nb_bdy_fld_sum     = jfld             
574            ELSE
575               nb_bdy_fld(ib_bdy) = jfld - nb_bdy_fld_sum
576               nb_bdy_fld_sum = nb_bdy_fld_sum + nb_bdy_fld(ib_bdy)
577            ENDIF
578
579         ENDIF ! nn_dta .eq. 1
580      ENDDO ! ib_bdy
581
582      DO jfld = 1, nb_bdy_fld_sum
583         ALLOCATE( bf(jfld)%fnow(ilen1(jfld),1,ilen3(jfld)) )
584         IF( blf_i(jfld)%ln_tint ) ALLOCATE( bf(jfld)%fdta(ilen1(jfld),1,ilen3(jfld),2) )
585         nbmap_ptr(jfld)%ptr => idx_bdy(ibdy(jfld))%nbmap(:,igrid(jfld))
586      ENDDO
587
588      ! fill bf with blf_i and control print
589      !-------------------------------------
590      jstart = 1
591      DO ib_bdy = 1, nb_bdy
592         jend = nb_bdy_fld(ib_bdy) 
593         CALL fld_fill( bf(jstart:jend), blf_i(jstart:jend), cn_dir_array(ib_bdy), 'bdy_dta',   &
594         &              'open boundary conditions', 'nambdy_dta' )
595         jstart = jend + 1
596      ENDDO
597
598      ! Initialise local boundary data arrays
599      ! nn_xxx_dta=0 : allocate space - will be filled from initial conditions later
600      ! nn_xxx_dta=1 : point to "fnow" arrays
601      !-------------------------------------
602
603      jfld = 0
604      DO ib_bdy=1, nb_bdy
605
606         nblen => idx_bdy(ib_bdy)%nblen
607         nblenrim => idx_bdy(ib_bdy)%nblenrim
608
609         IF (nn_dyn2d(ib_bdy) .gt. 0) THEN
610            IF( nn_dyn2d_dta(ib_bdy) .eq. 0 .or. nn_dyn2d_dta(ib_bdy) .eq. 2 .or. ln_full_vel_array(ib_bdy) ) THEN
611               ilen0(1:3) = nblen(1:3)
612               ALLOCATE( dta_bdy(ib_bdy)%u2d(ilen0(2)) )
613               ALLOCATE( dta_bdy(ib_bdy)%v2d(ilen0(3)) )
614               IF (nn_dyn2d_dta(ib_bdy).eq.1.or.nn_dyn2d_dta(ib_bdy).eq.3) THEN
615                  jfld = jfld + 1
616                  dta_bdy(ib_bdy)%ssh => bf(jfld)%fnow(:,1,1)
617               ELSE
618                  ALLOCATE( dta_bdy(ib_bdy)%ssh(nblen(1)) )
619               ENDIF
620            ELSE
621               IF( nn_dyn2d(ib_bdy) .ne. jp_frs ) THEN
622                  jfld = jfld + 1
623                  dta_bdy(ib_bdy)%ssh => bf(jfld)%fnow(:,1,1)
624               ENDIF
625               jfld = jfld + 1
626               dta_bdy(ib_bdy)%u2d => bf(jfld)%fnow(:,1,1)
627               jfld = jfld + 1
628               dta_bdy(ib_bdy)%v2d => bf(jfld)%fnow(:,1,1)
629            ENDIF
630         ENDIF
631
632         IF ( nn_dyn3d(ib_bdy) .gt. 0 .and. nn_dyn3d_dta(ib_bdy) .eq. 0 ) THEN
633            ilen0(1:3) = nblen(1:3)
634            ALLOCATE( dta_bdy(ib_bdy)%u3d(ilen0(2),jpk) )
635            ALLOCATE( dta_bdy(ib_bdy)%v3d(ilen0(3),jpk) )
636         ENDIF
637         IF ( ( nn_dyn3d(ib_bdy) .gt. 0 .and. nn_dyn3d_dta(ib_bdy) .eq. 1 ).or. &
638           &  ( ln_full_vel_array(ib_bdy) .and. nn_dyn2d(ib_bdy) .gt. 0 .and.   &
639           &    ( nn_dyn2d_dta(ib_bdy) .eq. 1 .or. nn_dyn2d_dta(ib_bdy) .eq. 3 ) ) ) THEN
640            jfld = jfld + 1
641            dta_bdy(ib_bdy)%u3d => bf(jfld)%fnow(:,1,:)
642            jfld = jfld + 1
643            dta_bdy(ib_bdy)%v3d => bf(jfld)%fnow(:,1,:)
644         ENDIF
645
646         IF (nn_tra(ib_bdy) .gt. 0) THEN
647            IF( nn_tra_dta(ib_bdy) .eq. 0 ) THEN
648               ilen0(1:3) = nblen(1:3)
649               ALLOCATE( dta_bdy(ib_bdy)%tem(ilen0(1),jpk) )
650               ALLOCATE( dta_bdy(ib_bdy)%sal(ilen0(1),jpk) )
651            ELSE
652               jfld = jfld + 1
653               dta_bdy(ib_bdy)%tem => bf(jfld)%fnow(:,1,:)
654               jfld = jfld + 1
655               dta_bdy(ib_bdy)%sal => bf(jfld)%fnow(:,1,:)
656            ENDIF
657         ENDIF
658
659#if defined key_lim2
660         IF (nn_ice_lim2(ib_bdy) .gt. 0) THEN
661            IF( nn_ice_lim2_dta(ib_bdy) .eq. 0 ) THEN
662               ilen0(1:3) = nblen(1:3)
663               ALLOCATE( dta_bdy(ib_bdy)%frld(ilen0(1)) )
664               ALLOCATE( dta_bdy(ib_bdy)%hicif(ilen0(1)) )
665               ALLOCATE( dta_bdy(ib_bdy)%hsnif(ilen0(1)) )
666            ELSE
667               jfld = jfld + 1
668               dta_bdy(ib_bdy)%frld  => bf(jfld)%fnow(:,1,1)
669               jfld = jfld + 1
670               dta_bdy(ib_bdy)%hicif => bf(jfld)%fnow(:,1,1)
671               jfld = jfld + 1
672               dta_bdy(ib_bdy)%hsnif => bf(jfld)%fnow(:,1,1)
673            ENDIF
674         ENDIF
675#endif
676
677      ENDDO ! ib_bdy
678
679      IF( nn_timing == 1 ) CALL timing_stop('bdy_dta_init')
680
681      END SUBROUTINE bdy_dta_init
682
683#else
684   !!----------------------------------------------------------------------
685   !!   Dummy module                   NO Open Boundary Conditions
686   !!----------------------------------------------------------------------
687CONTAINS
688   SUBROUTINE bdy_dta( kt, jit, time_offset ) ! Empty routine
689      INTEGER, INTENT( in )           ::   kt   
690      INTEGER, INTENT( in ), OPTIONAL ::   jit   
691      INTEGER, INTENT( in ), OPTIONAL ::   time_offset
692      WRITE(*,*) 'bdy_dta: You should not have seen this print! error?', kt
693   END SUBROUTINE bdy_dta
694   SUBROUTINE bdy_dta_init()                  ! Empty routine
695      WRITE(*,*) 'bdy_dta_init: You should not have seen this print! error?'
696   END SUBROUTINE bdy_dta_init
697#endif
698
699   !!==============================================================================
700END MODULE bdydta
Note: See TracBrowser for help on using the repository browser.