New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdytra.F90 in branches/2012/dev_r3327_MERCATOR1_BDY/NEMOGCM/NEMO/OPA_SRC/BDY – NEMO

source: branches/2012/dev_r3327_MERCATOR1_BDY/NEMOGCM/NEMO/OPA_SRC/BDY/bdytra.F90 @ 3367

Last change on this file since 3367 was 3367, checked in by greffray, 12 years ago

Merge tidal packages
Merge OBC-BDY packages
Add atmospheric pressure at the open boundaries
Modification of the namelist for AMM12 configuration
  • Property svn:keywords set to Id
File size: 13.0 KB
Line 
1MODULE bdytra
2   !!======================================================================
3   !!                       ***  MODULE  bdytra  ***
4   !! Ocean tracers:   Apply boundary conditions for tracers
5   !!======================================================================
6   !! History :  1.0  !  2005-01  (J. Chanut, A. Sellar)  Original code
7   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
8   !!            3.4  !  2011     (D. Storkey) rewrite in preparation for OBC-BDY merge
9   !!----------------------------------------------------------------------
10#if defined key_bdy
11   !!----------------------------------------------------------------------
12   !!   'key_bdy'                     Unstructured Open Boundary Conditions
13   !!----------------------------------------------------------------------
14   !!   bdy_tra            : Apply open boundary conditions to T and S
15   !!   bdy_tra_frs        : Apply Flow Relaxation Scheme
16   !!----------------------------------------------------------------------
17   USE timing          ! Timing
18   USE oce             ! ocean dynamics and tracers variables
19   USE dom_oce         ! ocean space and time domain variables
20   USE bdy_oce         ! ocean open boundary conditions
21   USE bdydta, ONLY:   bf
22   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
23   USE in_out_manager  ! I/O manager
24   USE phycst
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC bdy_tra      ! routine called in tranxt.F90
30   PUBLIC bdy_tra_dmp  ! routine called in tranxt.F90
31
32   !!----------------------------------------------------------------------
33   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
34   !! $Id$
35   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
36   !!----------------------------------------------------------------------
37CONTAINS
38
39   SUBROUTINE bdy_tra( kt )
40      !!----------------------------------------------------------------------
41      !!                  ***  SUBROUTINE bdy_tra  ***
42      !!
43      !! ** Purpose : - Apply open boundary conditions for temperature and salinity
44      !!
45      !!----------------------------------------------------------------------
46      INTEGER, INTENT( in ) :: kt     ! Main time step counter
47      !!
48      INTEGER               :: ib_bdy ! Loop index
49
50      DO ib_bdy=1, nb_bdy
51
52         SELECT CASE( nn_tra(ib_bdy) )
53         CASE(jp_none)
54            CYCLE
55         CASE(jp_frs)
56            CALL bdy_tra_frs( idx_bdy(ib_bdy), dta_bdy(ib_bdy), kt )
57         CASE(2)
58            CALL bdy_tra_spe( idx_bdy(ib_bdy), dta_bdy(ib_bdy), kt )
59         CASE(3)
60            CALL bdy_tra_nmn( idx_bdy(ib_bdy), dta_bdy(ib_bdy), kt )
61         CASE(4)
62            CALL bdy_tra_rnf( idx_bdy(ib_bdy), dta_bdy(ib_bdy), kt )
63         CASE DEFAULT
64            CALL ctl_stop( 'bdy_tra : unrecognised option for open boundaries for T and S' )
65         END SELECT
66      ENDDO
67
68   END SUBROUTINE bdy_tra
69
70   SUBROUTINE bdy_tra_frs( idx, dta, kt )
71      !!----------------------------------------------------------------------
72      !!                 ***  SUBROUTINE bdy_tra_frs  ***
73      !!                   
74      !! ** Purpose : Apply the Flow Relaxation Scheme for tracers at open boundaries.
75      !!
76      !! Reference : Engedahl H., 1995, Tellus, 365-382.
77      !!----------------------------------------------------------------------
78      INTEGER,         INTENT(in) ::   kt
79      TYPE(OBC_INDEX), INTENT(in) ::   idx  ! OBC indices
80      TYPE(OBC_DATA),  INTENT(in) ::   dta  ! OBC external data
81      !!
82      REAL(wp) ::   zwgt           ! boundary weight
83      INTEGER  ::   ib, ik, igrd   ! dummy loop indices
84      INTEGER  ::   ii, ij         ! 2D addresses
85      !!----------------------------------------------------------------------
86      !
87      IF( nn_timing == 1 ) CALL timing_start('bdy_tra_frs')
88      !
89      igrd = 1                       ! Everything is at T-points here
90      DO ib = 1, idx%nblen(igrd)
91         DO ik = 1, jpkm1
92            ii = idx%nbi(ib,igrd)
93            ij = idx%nbj(ib,igrd)
94            zwgt = idx%nbw(ib,igrd)
95            tsa(ii,ij,ik,jp_tem) = ( tsa(ii,ij,ik,jp_tem) + zwgt * ( dta%tem(ib,ik) - tsa(ii,ij,ik,jp_tem) ) ) * tmask(ii,ij,ik)         
96            tsa(ii,ij,ik,jp_sal) = ( tsa(ii,ij,ik,jp_sal) + zwgt * ( dta%sal(ib,ik) - tsa(ii,ij,ik,jp_sal) ) ) * tmask(ii,ij,ik)
97         END DO
98      END DO 
99      !
100      CALL lbc_lnk( tsa(:,:,:,jp_tem), 'T', 1. )   ; CALL lbc_lnk( tsa(:,:,:,jp_sal), 'T', 1. )    ! Boundary points should be updated
101      !
102      IF( kt .eq. nit000 ) CLOSE( unit = 102 )
103      !
104      IF( nn_timing == 1 ) CALL timing_stop('bdy_tra_frs')
105      !
106   END SUBROUTINE bdy_tra_frs
107 
108   SUBROUTINE bdy_tra_spe( idx, dta, kt )
109      !!----------------------------------------------------------------------
110      !!                 ***  SUBROUTINE bdy_tra_frs  ***
111      !!                   
112      !! ** Purpose : Apply a specified value for tracers at open boundaries.
113      !!
114      !!----------------------------------------------------------------------
115      INTEGER,         INTENT(in) ::   kt
116      TYPE(OBC_INDEX), INTENT(in) ::   idx  ! OBC indices
117      TYPE(OBC_DATA),  INTENT(in) ::   dta  ! OBC external data
118      !!
119      REAL(wp) ::   zwgt           ! boundary weight
120      INTEGER  ::   ib, ik, igrd   ! dummy loop indices
121      INTEGER  ::   ii, ij         ! 2D addresses
122      !!----------------------------------------------------------------------
123      !
124      IF( nn_timing == 1 ) CALL timing_start('bdy_tra_spe')
125      !
126      igrd = 1                       ! Everything is at T-points here
127      DO ib = 1, idx%nblenrim(igrd)
128         ii = idx%nbi(ib,igrd)
129         ij = idx%nbj(ib,igrd)
130         DO ik = 1, jpkm1
131            tsa(ii,ij,ik,jp_tem) = dta%tem(ib,ik) * tmask(ii,ij,ik)
132            tsa(ii,ij,ik,jp_sal) = dta%sal(ib,ik) * tmask(ii,ij,ik)
133         END DO
134      END DO
135      !
136      CALL lbc_lnk( tsa(:,:,:,jp_tem), 'T', 1. )   ; CALL lbc_lnk( tsa(:,:,:,jp_sal), 'T', 1. )    ! Boundary points should be updated
137      !
138      IF( kt .eq. nit000 ) CLOSE( unit = 102 )
139      !
140      IF( nn_timing == 1 ) CALL timing_stop('bdy_tra_spe')
141      !
142   END SUBROUTINE bdy_tra_spe
143
144   SUBROUTINE bdy_tra_nmn( idx, dta, kt )
145      !!----------------------------------------------------------------------
146      !!                 ***  SUBROUTINE bdy_tra_nmn  ***
147      !!                   
148      !! ** Purpose : Duplicate the value for tracers at open boundaries.
149      !!
150      !!----------------------------------------------------------------------
151      INTEGER,         INTENT(in) ::   kt
152      TYPE(OBC_INDEX), INTENT(in) ::   idx  ! OBC indices
153      TYPE(OBC_DATA),  INTENT(in) ::   dta  ! OBC external data
154      !!
155      REAL(wp) ::   zwgt           ! boundary weight
156      INTEGER  ::   ib, ik, igrd   ! dummy loop indices
157      INTEGER  ::   ii, ij,zcoef, zcoef1,zcoef2, ip, jp   ! 2D addresses
158      !!----------------------------------------------------------------------
159      !
160      IF( nn_timing == 1 ) CALL timing_start('bdy_tra_nmn')
161      !
162      igrd = 1                       ! Everything is at T-points here
163      DO ib = 1, idx%nblenrim(igrd)
164         ii = idx%nbi(ib,igrd)
165         ij = idx%nbj(ib,igrd)
166         DO ik = 1, jpkm1
167            ! search the sense of the gradient
168            zcoef1 = bdytmask(ii-1,ij  ) +  bdytmask(ii+1,ij  )
169            zcoef2 = bdytmask(ii  ,ij-1) +  bdytmask(ii  ,ij+1)
170            IF ( zcoef1+zcoef2 == 0) THEN
171               ! corner
172               zcoef = tmask(ii-1,ij,ik) + tmask(ii+1,ij,ik) +  tmask(ii,ij-1,ik) +  tmask(ii,ij+1,ik)
173               tsa(ii,ij,ik,jp_tem) = tsa(ii-1,ij  ,ik,jp_tem) * tmask(ii-1,ij  ,ik) + &
174                 &                    tsa(ii+1,ij  ,ik,jp_tem) * tmask(ii+1,ij  ,ik) + &
175                 &                    tsa(ii  ,ij-1,ik,jp_tem) * tmask(ii  ,ij-1,ik) + &
176                 &                    tsa(ii  ,ij+1,ik,jp_tem) * tmask(ii  ,ij+1,ik)
177               tsa(ii,ij,ik,jp_tem) = ( tsa(ii,ij,ik,jp_tem) / MAX( 1, zcoef) ) * tmask(ii,ij,ik)
178               tsa(ii,ij,ik,jp_sal) = tsa(ii-1,ij  ,ik,jp_sal) * tmask(ii-1,ij  ,ik) + &
179                 &                    tsa(ii+1,ij  ,ik,jp_sal) * tmask(ii+1,ij  ,ik) + &
180                 &                    tsa(ii  ,ij-1,ik,jp_sal) * tmask(ii  ,ij-1,ik) + &
181                 &                    tsa(ii  ,ij+1,ik,jp_sal) * tmask(ii  ,ij+1,ik)
182               tsa(ii,ij,ik,jp_sal) = ( tsa(ii,ij,ik,jp_sal) / MAX( 1, zcoef) ) * tmask(ii,ij,ik)
183            ELSE
184               ip = bdytmask(ii+1,ij  ) - bdytmask(ii-1,ij  )
185               jp = bdytmask(ii  ,ij+1) - bdytmask(ii  ,ij-1)
186               tsa(ii,ij,ik,jp_tem) = tsa(ii+ip,ij+jp,ik,jp_tem) * tmask(ii+ip,ij+jp,ik)
187               tsa(ii,ij,ik,jp_sal) = tsa(ii+ip,ij+jp,ik,jp_sal) * tmask(ii+ip,ij+jp,ik)
188            ENDIF
189         END DO
190      END DO
191      !
192      CALL lbc_lnk( tsa(:,:,:,jp_tem), 'T', 1. )   ; CALL lbc_lnk( tsa(:,:,:,jp_sal), 'T', 1. )    ! Boundary points should be updated
193      !
194      IF( kt .eq. nit000 ) CLOSE( unit = 102 )
195      !
196      IF( nn_timing == 1 ) CALL timing_stop('bdy_tra_nmn')
197      !
198   END SUBROUTINE bdy_tra_nmn
199
200   SUBROUTINE bdy_tra_rnf( idx, dta, kt )
201      !!----------------------------------------------------------------------
202      !!                 ***  SUBROUTINE bdy_tra_rnf  ***
203      !!                   
204      !! ** Purpose : Apply the runoff values for tracers at open boundaries:
205      !!                  - specified to 0.1 PSU for the salinity
206      !!                  - duplicate the value for the temperature
207      !!
208      !!----------------------------------------------------------------------
209      INTEGER,         INTENT(in) ::   kt
210      TYPE(OBC_INDEX), INTENT(in) ::   idx  ! OBC indices
211      TYPE(OBC_DATA),  INTENT(in) ::   dta  ! OBC external data
212      !!
213      REAL(wp) ::   zwgt           ! boundary weight
214      INTEGER  ::   ib, ik, igrd   ! dummy loop indices
215      INTEGER  ::   ii, ij, ip, jp ! 2D addresses
216      !!----------------------------------------------------------------------
217      !
218      IF( nn_timing == 1 ) CALL timing_start('bdy_tra_rnf')
219      !
220      igrd = 1                       ! Everything is at T-points here
221      DO ib = 1, idx%nblenrim(igrd)
222         ii = idx%nbi(ib,igrd)
223         ij = idx%nbj(ib,igrd)
224         DO ik = 1, jpkm1
225            ip = bdytmask(ii+1,ij  ) - bdytmask(ii-1,ij  )
226            jp = bdytmask(ii  ,ij+1) - bdytmask(ii  ,ij-1)
227            tsa(ii,ij,ik,jp_tem) = tsa(ii+ip,ij+jp,ik,jp_tem) * tmask(ii,ij,ik)
228            tsa(ii,ij,ik,jp_sal) =                        0.1 * tmask(ii,ij,ik)
229         END DO
230      END DO
231      !
232      CALL lbc_lnk( tsa(:,:,:,jp_tem), 'T', 1. )   ; CALL lbc_lnk( tsa(:,:,:,jp_sal), 'T', 1. )    ! Boundary points should be updated
233      !
234      IF( kt .eq. nit000 ) CLOSE( unit = 102 )
235      !
236      IF( nn_timing == 1 ) CALL timing_stop('bdy_tra_rnf')
237      !
238   END SUBROUTINE bdy_tra_rnf
239
240   SUBROUTINE bdy_tra_dmp( kt )
241      !!----------------------------------------------------------------------
242      !!                 ***  SUBROUTINE bdy_tra_dmp  ***
243      !!                   
244      !! ** Purpose : Apply damping for tracers at open boundaries.
245      !!
246      !!----------------------------------------------------------------------
247      INTEGER,         INTENT(in) ::   kt
248      !!
249      REAL(wp) ::   zwgt           ! boundary weight
250      REAL(wp) ::   zta, zsa, ztime
251      INTEGER  ::   ib, ik, igrd   ! dummy loop indices
252      INTEGER  ::   ii, ij         ! 2D addresses
253      INTEGER  ::   ib_bdy         ! Loop index
254      !!----------------------------------------------------------------------
255      !
256      IF( nn_timing == 1 ) CALL timing_start('bdy_tra_dmp')
257      !
258      DO ib_bdy=1, nb_bdy
259         IF ( ln_tra_dmp(ib_bdy) ) THEN
260            igrd = 1                       ! Everything is at T-points here
261            DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
262               ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
263               ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
264               zwgt = idx_bdy(ib_bdy)%nbw(ib,igrd) / ( rn_time_dmp(ib_bdy) * rday )
265               DO ik = 1, jpkm1
266                  tsa(ii,ij,ik,jp_tem) = ( tsa(ii,ij,ik,jp_tem) + zwgt * ( dta_bdy(ib_bdy)%tem(ib,ik) - tsb(ii,ij,ik,jp_tem) ) ) * tmask(ii,ij,ik)
267                  tsa(ii,ij,ik,jp_sal) = ( tsa(ii,ij,ik,jp_sal) + zwgt * ( dta_bdy(ib_bdy)%sal(ib,ik) - tsb(ii,ij,ik,jp_sal) ) ) * tmask(ii,ij,ik)
268               END DO
269            END DO
270         ENDIF
271      ENDDO
272      !
273      CALL lbc_lnk( tsa(:,:,:,jp_tem), 'T', 1. )  ;  CALL lbc_lnk( tsa(:,:,:,jp_sal), 'T', 1. )    ! Boundary points should be updated
274      !
275      IF( nn_timing == 1 ) CALL timing_stop('bdy_tra_dmp')
276      !
277   END SUBROUTINE bdy_tra_dmp
278 
279#else
280   !!----------------------------------------------------------------------
281   !!   Dummy module                   NO Unstruct Open Boundary Conditions
282   !!----------------------------------------------------------------------
283CONTAINS
284   SUBROUTINE bdy_tra(kt)      ! Empty routine
285      WRITE(*,*) 'bdy_tra: You should not have seen this print! error?', kt
286   END SUBROUTINE bdy_tra
287#endif
288
289   !!======================================================================
290END MODULE bdytra
Note: See TracBrowser for help on using the repository browser.