New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in branches/2012/dev_r3327_MERCATOR1_BDY/NEMOGCM/NEMO/OPA_SRC – NEMO

Context Navigation

source: branches/2012/dev_r3327_MERCATOR1_BDY/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 3367

Last change on this file since 3367 was 3367, checked in by greffray, 12 years ago
Merge tidal packages Merge OBC-BDY packages Add atmospheric pressure at the open boundaries Modification of the namelist for AMM12 configuration
Property svn:keywords set to `Id`
File size: 36.0 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) LIM sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!! 3.4 ! 2011-11 (C. Harris) decomposition changes for running with CICE
31	!!----------------------------------------------------------------------
32
33	!!----------------------------------------------------------------------
34	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
35	!! nemo_init : initialization of the NEMO system
36	!! nemo_ctl : initialisation of the contol print
37	!! nemo_closefile : close remaining open files
38	!! nemo_alloc : dynamical allocation
39	!! nemo_partition : calculate MPP domain decomposition
40	!! factorise : calculate the factors of the no. of MPI processes
41	!!----------------------------------------------------------------------
42	USE step_oce ! module used in the ocean time stepping module
43	USE sbc_oce ! surface boundary condition: ocean
44	USE cla ! cross land advection (tra_cla routine)
45	USE domcfg ! domain configuration (dom_cfg routine)
46	USE mppini ! shared/distributed memory setting (mpp_init routine)
47	USE domain ! domain initialization (dom_init routine)
48	USE tideini ! tidal components initialization (tide_ini routine)
49	USE obcini ! open boundary cond. initialization (obc_ini routine)
50	USE bdyini ! open boundary cond. initialization (bdy_init routine)
51	USE bdydta ! open boundary cond. initialization (bdy_dta_init routine)
52	USE bdytides ! open boundary cond. initialization (bdytide_init routine)
53	USE istate ! initial state setting (istate_init routine)
54	USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine)
55	USE ldftra ! lateral diffusivity setting (ldftra_init routine)
56	USE zdfini ! vertical physics setting (zdf_init routine)
57	USE phycst ! physical constant (par_cst routine)
58	USE trdmod ! momentum/tracers trends (trd_mod_init routine)
59	USE asmtrj ! writing out state trajectory
60	USE diaptr ! poleward transports (dia_ptr_init routine)
61	USE diadct ! sections transports (dia_dct_init routine)
62	USE diaobs ! Observation diagnostics (dia_obs_init routine)
63	USE step ! NEMO time-stepping (stp routine)
64	#if defined key_oasis3
65	USE cpl_oasis3 ! OASIS3 coupling
66	#elif defined key_oasis4
67	USE cpl_oasis4 ! OASIS4 coupling (not working)
68	#endif
69	USE c1d ! 1D configuration
70	USE step_c1d ! Time stepping loop for the 1D configuration
71	#if defined key_top
72	USE trcini ! passive tracer initialisation
73	#endif
74	USE lib_mpp ! distributed memory computing
75	#if defined key_iomput
76	USE mod_ioclient
77	#endif
78
79	IMPLICIT NONE
80	PRIVATE
81
82	PUBLIC nemo_gcm ! called by model.F90
83	PUBLIC nemo_init ! needed by AGRIF
84
85	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
86
87	!!----------------------------------------------------------------------
88	!! NEMO/OPA 4.0 , NEMO Consortium (2011)
89	!! $Id$
90	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
91	!!----------------------------------------------------------------------
92	CONTAINS
93
94	SUBROUTINE nemo_gcm
95	!!----------------------------------------------------------------------
96	!! * ROUTINE nemo_gcm *
97	!!
98	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
99	!! curvilinear mesh on the sphere.
100	!!
101	!! ** Method : - model general initialization
102	!! - launch the time-stepping (stp routine)
103	!! - finalize the run by closing files and communications
104	!!
105	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
106	!! Madec, 2008, internal report, IPSL.
107	!!----------------------------------------------------------------------
108	INTEGER :: istp ! time step index
109	!!----------------------------------------------------------------------
110	!
111	#if defined key_agrif
112	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
113	#endif
114
115	! !-----------------------!
116	CALL nemo_init !== Initialisations ==!
117	! !-----------------------!
118	#if defined key_agrif
119	CALL Agrif_Declare_Var ! AGRIF: set the meshes
120	# if defined key_top
121	CALL Agrif_Declare_Var_Top ! AGRIF: set the meshes
122	# endif
123	#endif
124	! check that all process are still there... If some process have an error,
125	! they will never enter in step and other processes will wait until the end of the cpu time!
126	IF( lk_mpp ) CALL mpp_max( nstop )
127
128	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
129
130	! !-----------------------!
131	! !== time stepping ==!
132	! !-----------------------!
133	istp = nit000
134	#if defined key_c1d
135	DO WHILE ( istp <= nitend .AND. nstop == 0 )
136	CALL stp_c1d( istp )
137	istp = istp + 1
138	END DO
139	#else
140	IF( lk_asminc ) THEN
141	IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 ) ! Output background fields
142	IF( ln_trjwri ) CALL asm_trj_wri( nit000 - 1 ) ! Output trajectory fields
143	IF( ln_asmdin ) THEN ! Direct initialization
144	IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 ) ! Tracers
145	IF( ln_dyninc ) THEN
146	CALL dyn_asm_inc( nit000 - 1 ) ! Dynamics
147	IF ( ln_asmdin ) CALL ssh_wzv ( nit000 - 1 ) ! update vertical velocity
148	ENDIF
149	IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 ) ! SSH
150	ENDIF
151	ENDIF
152
153	DO WHILE ( istp <= nitend .AND. nstop == 0 )
154	#if defined key_agrif
155	CALL Agrif_Step( stp ) ! AGRIF: time stepping
156	#else
157	CALL stp( istp ) ! standard time stepping
158	#endif
159	istp = istp + 1
160	IF( lk_mpp ) CALL mpp_max( nstop )
161	END DO
162	#endif
163
164	IF( lk_diaobs ) CALL dia_obs_wri
165
166	! !------------------------!
167	! !== finalize the run ==!
168	! !------------------------!
169	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
170	!
171	IF( nstop /= 0 .AND. lwp ) THEN ! error print
172	WRITE(numout,cform_err)
173	WRITE(numout,*) nstop, ' error have been found'
174	ENDIF
175	!
176	#if defined key_agrif
177	CALL Agrif_ParentGrid_To_ChildGrid()
178	IF( lk_diaobs ) CALL dia_obs_wri
179	IF( nn_timing == 1 ) CALL timing_finalize
180	CALL Agrif_ChildGrid_To_ParentGrid()
181	#endif
182	IF( nn_timing == 1 ) CALL timing_finalize
183	!
184	CALL nemo_closefile
185	#if defined key_oasis3 \|\| defined key_oasis4
186	CALL cpl_prism_finalize ! end coupling and mpp communications with OASIS
187	#else
188	IF( lk_mpp ) CALL mppstop ! end mpp communications
189	#endif
190	!
191	END SUBROUTINE nemo_gcm
192
193
194	SUBROUTINE nemo_init
195	!!----------------------------------------------------------------------
196	!! * ROUTINE nemo_init *
197	!!
198	!! ** Purpose : initialization of the NEMO GCM
199	!!----------------------------------------------------------------------
200	INTEGER :: ji ! dummy loop indices
201	INTEGER :: ilocal_comm ! local integer
202	CHARACTER(len=80), DIMENSION(16) :: cltxt
203	!!
204	NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, &
205	& nn_isplt, nn_jsplt, nn_jctls, nn_jctle, &
206	& nn_bench, nn_timing
207	!!----------------------------------------------------------------------
208	!
209	cltxt = ''
210	!
211	! ! open Namelist file
212	CALL ctl_opn( numnam, 'namelist', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
213	!
214	READ( numnam, namctl ) ! Namelist namctl : Control prints & Benchmark
215	!
216	! !--------------------------------------------!
217	! ! set communicator & select the local node !
218	! !--------------------------------------------!
219	#if defined key_iomput
220	IF( Agrif_Root() ) THEN
221	# if defined key_oasis3 \|\| defined key_oasis4
222	CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis
223	# endif
224	CALL init_ioclient( ilocal_comm ) ! exchange io_server nemo local communicator with the io_server
225	ENDIF
226	narea = mynode( cltxt, numnam, nstop, ilocal_comm ) ! Nodes selection
227	#else
228	# if defined key_oasis3 \|\| defined key_oasis4
229	IF( Agrif_Root() ) THEN
230	CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis
231	ENDIF
232	narea = mynode( cltxt, numnam, nstop, ilocal_comm ) ! Nodes selection (control print return in cltxt)
233	# else
234	ilocal_comm = 0
235	narea = mynode( cltxt, numnam, nstop ) ! Nodes selection (control print return in cltxt)
236	# endif
237	#endif
238	narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 )
239
240	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
241
242	! If dimensions of processor grid weren't specified in the namelist file
243	! then we calculate them here now that we have our communicator size
244	IF( (jpni < 1) .OR. (jpnj < 1) )THEN
245	#if defined key_mpp_mpi
246	IF( Agrif_Root() ) CALL nemo_partition(mppsize)
247	#else
248	jpni = 1
249	jpnj = 1
250	jpnij = jpni*jpnj
251	#endif
252	END IF
253
254	! Calculate domain dimensions given calculated jpni and jpnj
255	! This used to be done in par_oce.F90 when they were parameters rather
256	! than variables
257	IF( Agrif_Root() ) THEN
258	jpi = ( jpiglo-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
259	#if defined key_nemocice_decomp
260	jpj = ( jpjglo+1-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
261	#else
262	jpj = ( jpjglo-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
263	#endif
264	jpk = jpkdta ! third dim
265	jpim1 = jpi-1 ! inner domain indices
266	jpjm1 = jpj-1 ! " "
267	jpkm1 = jpk-1 ! " "
268	jpij = jpi*jpj ! jpi x j
269	ENDIF
270
271	IF(lwp) THEN ! open listing units
272	!
273	CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
274	!
275	WRITE(numout,*)
276	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
277	WRITE(numout,*) ' NEMO team'
278	WRITE(numout,*) ' Ocean General Circulation Model'
279	WRITE(numout,*) ' version 3.4 (2011) '
280	WRITE(numout,*)
281	WRITE(numout,*)
282	DO ji = 1, SIZE(cltxt)
283	IF( TRIM(cltxt(ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode
284	END DO
285	WRITE(numout,cform_aaa) ! Flag AAAAAAA
286	!
287	ENDIF
288
289	! Now we know the dimensions of the grid and numout has been set we can
290	! allocate arrays
291	CALL nemo_alloc()
292
293	! !-------------------------------!
294	! ! NEMO general initialization !
295	! !-------------------------------!
296
297	CALL nemo_ctl ! Control prints & Benchmark
298
299	! ! Domain decomposition
300	IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out
301	ELSE ; CALL mpp_init2 ! eliminate land processors
302	ENDIF
303	!
304	IF( nn_timing == 1 ) CALL timing_init
305	!
306	! ! General initialization
307	CALL phy_cst ! Physical constants
308	CALL eos_init ! Equation of state
309	CALL dom_cfg ! Domain configuration
310	CALL dom_init ! Domain
311
312	IF( ln_nnogather ) CALL nemo_northcomms ! Initialise the northfold neighbour lists (must be done after the masks are defined)
313
314	IF( ln_ctl ) CALL prt_ctl_init ! Print control
315
316	IF( lk_obc ) CALL obc_init ! Open boundaries
317
318	CALL istate_init ! ocean initial state (Dynamics and tracers)
319
320	CALL tide_init( nit000 ) ! Initialisation of the tidal harmonics
321
322	IF( lk_bdy ) CALL bdy_init ! Open boundaries initialisation
323	IF( lk_bdy ) CALL bdy_dta_init ! Open boundaries initialisation of external data arrays
324	IF( lk_bdy ) CALL bdytide_init ! Open boundaries initialisation of tidal harmonic forcing
325
326	CALL flush(numout)
327	CALL dyn_nept_init ! simplified form of Neptune effect
328	CALL flush(numout)
329
330	! ! Ocean physics
331	CALL sbc_init ! Forcings : surface module
332	! ! Vertical physics
333	CALL zdf_init ! namelist read
334	CALL zdf_bfr_init ! bottom friction
335	IF( lk_zdfric ) CALL zdf_ric_init ! Richardson number dependent Kz
336	IF( lk_zdftke ) CALL zdf_tke_init ! TKE closure scheme
337	IF( lk_zdfgls ) CALL zdf_gls_init ! GLS closure scheme
338	IF( lk_zdfkpp ) CALL zdf_kpp_init ! KPP closure scheme
339	IF( lk_zdftmx ) CALL zdf_tmx_init ! tidal vertical mixing
340	IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) &
341	& CALL zdf_ddm_init ! double diffusive mixing
342	! ! Lateral physics
343	CALL ldf_tra_init ! Lateral ocean tracer physics
344	CALL ldf_dyn_init ! Lateral ocean momentum physics
345	IF( lk_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
346
347	! ! Active tracers
348	CALL tra_qsr_init ! penetrative solar radiation qsr
349	CALL tra_bbc_init ! bottom heat flux
350	IF( lk_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
351	IF( ln_tradmp ) CALL tra_dmp_init ! internal damping trends
352	CALL tra_adv_init ! horizontal & vertical advection
353	CALL tra_ldf_init ! lateral mixing
354	CALL tra_zdf_init ! vertical mixing and after tracer fields
355
356	! ! Dynamics
357	CALL dyn_adv_init ! advection (vector or flux form)
358	CALL dyn_vor_init ! vorticity term including Coriolis
359	CALL dyn_ldf_init ! lateral mixing
360	CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure
361	CALL dyn_zdf_init ! vertical diffusion
362	CALL dyn_spg_init ! surface pressure gradient
363
364	! ! Misc. options
365	IF( nn_cla == 1 ) CALL cla_init ! Cross Land Advection
366
367	#if defined key_top
368	! ! Passive tracers
369	CALL trc_init
370	#endif
371	! ! Diagnostics
372	IF( lk_floats ) CALL flo_init ! drifting Floats
373	CALL iom_init ! iom_put initialization
374	IF( lk_diaar5 ) CALL dia_ar5_init ! ar5 diag
375	CALL dia_ptr_init ! Poleward TRansports initialization
376	IF( lk_diadct ) CALL dia_dct_init ! Sections tranports
377	CALL dia_hsb_init ! heat content, salt content and volume budgets
378	CALL trd_mod_init ! Mixed-layer/Vorticity/Integral constraints trends
379	IF( lk_diaobs ) THEN ! Observation & model comparison
380	CALL dia_obs_init ! Initialize observational data
381	CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
382	ENDIF
383	! ! Assimilation increments
384	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
385	IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
386	!
387	END SUBROUTINE nemo_init
388
389
390	SUBROUTINE nemo_ctl
391	!!----------------------------------------------------------------------
392	!! * ROUTINE nemo_ctl *
393	!!
394	!! ** Purpose : control print setting
395	!!
396	!! ** Method : - print namctl information and check some consistencies
397	!!----------------------------------------------------------------------
398	!
399	IF(lwp) THEN ! control print
400	WRITE(numout,*)
401	WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
402	WRITE(numout,*) '~~~~~~~ '
403	WRITE(numout,*) ' Namelist namctl'
404	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
405	WRITE(numout,*) ' level of print nn_print = ', nn_print
406	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
407	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
408	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
409	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
410	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
411	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
412	WRITE(numout,*) ' benchmark parameter (0/1) nn_bench = ', nn_bench
413	ENDIF
414	!
415	nprint = nn_print ! convert DOCTOR namelist names into OLD names
416	nictls = nn_ictls
417	nictle = nn_ictle
418	njctls = nn_jctls
419	njctle = nn_jctle
420	isplt = nn_isplt
421	jsplt = nn_jsplt
422	nbench = nn_bench
423	! ! Parameter control
424	!
425	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
426	IF( lk_mpp .AND. jpnij > 1 ) THEN
427	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
428	ELSE
429	IF( isplt == 1 .AND. jsplt == 1 ) THEN
430	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
431	& ' - the print control will be done over the whole domain' )
432	ENDIF
433	ijsplt = isplt * jsplt ! total number of processors ijsplt
434	ENDIF
435	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
436	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
437	!
438	! ! indices used for the SUM control
439	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
440	lsp_area = .FALSE.
441	ELSE ! print control done over a specific area
442	lsp_area = .TRUE.
443	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
444	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
445	nictls = 1
446	ENDIF
447	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
448	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
449	nictle = jpiglo
450	ENDIF
451	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
452	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
453	njctls = 1
454	ENDIF
455	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
456	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
457	njctle = jpjglo
458	ENDIF
459	ENDIF
460	ENDIF
461	!
462	IF( nbench == 1 ) THEN ! Benchmark
463	SELECT CASE ( cp_cfg )
464	CASE ( 'gyre' ) ; CALL ctl_warn( ' The Benchmark is activated ' )
465	CASE DEFAULT ; CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:', &
466	& ' key_gyre must be used or set nbench = 0' )
467	END SELECT
468	ENDIF
469	!
470	IF( lk_c1d .AND. .NOT.lk_iomput ) CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ', &
471	& 'with the IOM Input/Output manager. ' , &
472	& 'Compile with key_iomput enabled' )
473	!
474	END SUBROUTINE nemo_ctl
475
476
477	SUBROUTINE nemo_closefile
478	!!----------------------------------------------------------------------
479	!! * ROUTINE nemo_closefile *
480	!!
481	!! ** Purpose : Close the files
482	!!----------------------------------------------------------------------
483	!
484	IF( lk_mpp ) CALL mppsync
485	!
486	CALL iom_close ! close all input/output files managed by iom_*
487	!
488	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
489	IF( numsol /= -1 ) CLOSE( numsol ) ! solver file
490	IF( numnam /= -1 ) CLOSE( numnam ) ! oce namelist
491	IF( numnam_ice /= -1 ) CLOSE( numnam_ice ) ! ice namelist
492	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
493	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
494	IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports
495	IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports
496	IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports
497
498	!
499	numout = 6 ! redefine numout in case it is used after this point...
500	!
501	END SUBROUTINE nemo_closefile
502
503
504	SUBROUTINE nemo_alloc
505	!!----------------------------------------------------------------------
506	!! * ROUTINE nemo_alloc *
507	!!
508	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
509	!!
510	!! ** Method :
511	!!----------------------------------------------------------------------
512	USE diawri , ONLY: dia_wri_alloc
513	USE dom_oce , ONLY: dom_oce_alloc
514	USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
515	USE ldftra_oce, ONLY: ldftra_oce_alloc
516	USE trc_oce , ONLY: trc_oce_alloc
517	!
518	INTEGER :: ierr
519	!!----------------------------------------------------------------------
520	!
521	ierr = oce_alloc () ! ocean
522	ierr = ierr + dia_wri_alloc ()
523	ierr = ierr + dom_oce_alloc () ! ocean domain
524	ierr = ierr + ldfdyn_oce_alloc() ! ocean lateral physics : dynamics
525	ierr = ierr + ldftra_oce_alloc() ! ocean lateral physics : tracers
526	ierr = ierr + zdf_oce_alloc () ! ocean vertical physics
527	!
528	ierr = ierr + lib_mpp_alloc (numout) ! mpp exchanges
529	ierr = ierr + trc_oce_alloc () ! shared TRC / TRA arrays
530	!
531	IF( lk_mpp ) CALL mpp_sum( ierr )
532	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
533	!
534	END SUBROUTINE nemo_alloc
535
536
537	SUBROUTINE nemo_partition( num_pes )
538	!!----------------------------------------------------------------------
539	!! * ROUTINE nemo_partition *
540	!!
541	!! ** Purpose :
542	!!
543	!! ** Method :
544	!!----------------------------------------------------------------------
545	INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
546	!
547	INTEGER, PARAMETER :: nfactmax = 20
548	INTEGER :: nfact ! The no. of factors returned
549	INTEGER :: ierr ! Error flag
550	INTEGER :: ji
551	INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
552	INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
553	!!----------------------------------------------------------------------
554
555	ierr = 0
556
557	CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
558
559	IF( nfact <= 1 ) THEN
560	WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
561	WRITE (numout, *) ' : using grid of ',num_pes,' x 1'
562	jpnj = 1
563	jpni = num_pes
564	ELSE
565	! Search through factors for the pair that are closest in value
566	mindiff = 1000000
567	imin = 1
568	DO ji = 1, nfact-1, 2
569	idiff = ABS( ifact(ji) - ifact(ji+1) )
570	IF( idiff < mindiff ) THEN
571	mindiff = idiff
572	imin = ji
573	ENDIF
574	END DO
575	jpnj = ifact(imin)
576	jpni = ifact(imin + 1)
577	ENDIF
578	!
579	jpnij = jpni*jpnj
580	!
581	END SUBROUTINE nemo_partition
582
583
584	SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
585	!!----------------------------------------------------------------------
586	!! * ROUTINE factorise *
587	!!
588	!! ** Purpose : return the prime factors of n.
589	!! knfax factors are returned in array kfax which is of
590	!! maximum dimension kmaxfax.
591	!! ** Method :
592	!!----------------------------------------------------------------------
593	INTEGER , INTENT(in ) :: kn, kmaxfax
594	INTEGER , INTENT( out) :: kerr, knfax
595	INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax
596	!
597	INTEGER :: ifac, jl, inu
598	INTEGER, PARAMETER :: ntest = 14
599	INTEGER :: ilfax(ntest)
600
601	! lfax contains the set of allowed factors.
602	data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256, &
603	& 128, 64, 32, 16, 8, 4, 2 /
604	!!----------------------------------------------------------------------
605
606	! Clear the error flag and initialise output vars
607	kerr = 0
608	kfax = 1
609	knfax = 0
610
611	! Find the factors of n.
612	IF( kn == 1 ) GOTO 20
613
614	! nu holds the unfactorised part of the number.
615	! knfax holds the number of factors found.
616	! l points to the allowed factor list.
617	! ifac holds the current factor.
618
619	inu = kn
620	knfax = 0
621
622	DO jl = ntest, 1, -1
623	!
624	ifac = ilfax(jl)
625	IF( ifac > inu ) CYCLE
626
627	! Test whether the factor will divide.
628
629	IF( MOD(inu,ifac) == 0 ) THEN
630	!
631	knfax = knfax + 1 ! Add the factor to the list
632	IF( knfax > kmaxfax ) THEN
633	kerr = 6
634	write (,) 'FACTOR: insufficient space in factor array ', knfax
635	return
636	ENDIF
637	kfax(knfax) = ifac
638	! Store the other factor that goes with this one
639	knfax = knfax + 1
640	kfax(knfax) = inu / ifac
641	!WRITE (,) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
642	ENDIF
643	!
644	END DO
645
646	20 CONTINUE ! Label 20 is the exit point from the factor search loop.
647	!
648	END SUBROUTINE factorise
649
650	#if defined key_mpp_mpi
651	SUBROUTINE nemo_northcomms
652	!!======================================================================
653	!! * ROUTINE nemo_northcomms *
654	!! nemo_northcomms : Setup for north fold exchanges with explicit peer to peer messaging
655	!!=====================================================================
656	!!----------------------------------------------------------------------
657	!!
658	!! ** Purpose : Initialization of the northern neighbours lists.
659	!!----------------------------------------------------------------------
660	!! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE)
661	!!----------------------------------------------------------------------
662
663	INTEGER :: ji, jj, jk, ij, jtyp ! dummy loop indices
664	INTEGER :: ijpj ! number of rows involved in north-fold exchange
665	INTEGER :: northcomms_alloc ! allocate return status
666	REAL(wp), ALLOCATABLE, DIMENSION ( :,: ) :: znnbrs ! workspace
667	LOGICAL, ALLOCATABLE, DIMENSION ( : ) :: lrankset ! workspace
668
669	IF(lwp) WRITE(numout,*)
670	IF(lwp) WRITE(numout,*) 'nemo_northcomms : Initialization of the northern neighbours lists'
671	IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
672
673	!!----------------------------------------------------------------------
674	ALLOCATE( znnbrs(jpi,jpj), stat = northcomms_alloc )
675	ALLOCATE( lrankset(jpnij), stat = northcomms_alloc )
676	IF( northcomms_alloc /= 0 ) THEN
677	WRITE(numout,cform_war)
678	WRITE(numout,*) 'northcomms_alloc : failed to allocate arrays'
679	CALL ctl_stop( 'STOP', 'nemo_northcomms : unable to allocate temporary arrays' )
680	ENDIF
681	nsndto = 0
682	isendto = -1
683	ijpj = 4
684	!
685	! This routine has been called because ln_nnogather has been set true ( nammpp )
686	! However, these first few exchanges have to use the mpi_allgather method to
687	! establish the neighbour lists to use in subsequent peer to peer exchanges.
688	! Consequently, set l_north_nogather to be false here and set it true only after
689	! the lists have been established.
690	!
691	l_north_nogather = .FALSE.
692	!
693	! Exchange and store ranks on northern rows
694
695	DO jtyp = 1,4
696
697	lrankset = .FALSE.
698	znnbrs = narea
699	SELECT CASE (jtyp)
700	CASE(1)
701	CALL lbc_lnk( znnbrs, 'T', 1. ) ! Type 1: T,W-points
702	CASE(2)
703	CALL lbc_lnk( znnbrs, 'U', 1. ) ! Type 2: U-point
704	CASE(3)
705	CALL lbc_lnk( znnbrs, 'V', 1. ) ! Type 3: V-point
706	CASE(4)
707	CALL lbc_lnk( znnbrs, 'F', 1. ) ! Type 4: F-point
708	END SELECT
709
710	IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
711	DO jj = nlcj-ijpj+1, nlcj
712	ij = jj - nlcj + ijpj
713	DO ji = 1,jpi
714	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
715	& lrankset(INT(znnbrs(ji,jj))) = .true.
716	END DO
717	END DO
718
719	DO jj = 1,jpnij
720	IF ( lrankset(jj) ) THEN
721	nsndto(jtyp) = nsndto(jtyp) + 1
722	IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
723	CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
724	& ' jpmaxngh will need to be increased ')
725	ENDIF
726	isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank
727	ENDIF
728	END DO
729	ENDIF
730
731	END DO
732
733	!
734	! Type 5: I-point
735	!
736	! ICE point exchanges may involve some averaging. The neighbours list is
737	! built up using two exchanges to ensure that the whole stencil is covered.
738	! lrankset should not be reset between these 'J' and 'K' point exchanges
739
740	jtyp = 5
741	lrankset = .FALSE.
742	znnbrs = narea
743	CALL lbc_lnk( znnbrs, 'J', 1. ) ! first ice U-V point
744
745	IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
746	DO jj = nlcj-ijpj+1, nlcj
747	ij = jj - nlcj + ijpj
748	DO ji = 1,jpi
749	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
750	& lrankset(INT(znnbrs(ji,jj))) = .true.
751	END DO
752	END DO
753	ENDIF
754
755	znnbrs = narea
756	CALL lbc_lnk( znnbrs, 'K', 1. ) ! second ice U-V point
757
758	IF ( njmppt(narea) .EQ. MAXVAL( njmppt )) THEN
759	DO jj = nlcj-ijpj+1, nlcj
760	ij = jj - nlcj + ijpj
761	DO ji = 1,jpi
762	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
763	& lrankset( INT(znnbrs(ji,jj))) = .true.
764	END DO
765	END DO
766
767	DO jj = 1,jpnij
768	IF ( lrankset(jj) ) THEN
769	nsndto(jtyp) = nsndto(jtyp) + 1
770	IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
771	CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
772	& ' jpmaxngh will need to be increased ')
773	ENDIF
774	isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank
775	ENDIF
776	END DO
777	!
778	! For northern row areas, set l_north_nogather so that all subsequent exchanges
779	! can use peer to peer communications at the north fold
780	!
781	l_north_nogather = .TRUE.
782	!
783	ENDIF
784	DEALLOCATE( znnbrs )
785	DEALLOCATE( lrankset )
786
787	END SUBROUTINE nemo_northcomms
788	#else
789	SUBROUTINE nemo_northcomms ! Dummy routine
790	WRITE(,) 'nemo_northcomms: You should not have seen this print! error?'
791	END SUBROUTINE nemo_northcomms
792	#endif
793	!!======================================================================
794	END MODULE nemogcm

Note: See TracBrowser for help on using the repository browser.

Download in other formats: