New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limvar.F90 in branches/2012/dev_r3385_NOCS04_HAMF/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2012/dev_r3385_NOCS04_HAMF/NEMOGCM/NEMO/LIM_SRC_3/limvar.F90 @ 3517

Last change on this file since 3517 was 3517, checked in by gm, 12 years ago

gm: Branch: dev_r3385_NOCS04_HAMF; #665. update sbccpl ; change LIM3 from equivalent salt flux to salt flux and mass flux
  • Property svn:keywords set to Id
File size: 21.7 KB
Line 
1MODULE limvar
2   !!======================================================================
3   !!                       ***  MODULE limvar ***
4   !!                 Different sets of ice model variables
5   !!                   how to switch from one to another
6   !!
7   !!                 There are three sets of variables
8   !!                 VGLO : global variables of the model
9   !!                        - v_i (jpi,jpj,jpl)
10   !!                        - v_s (jpi,jpj,jpl)
11   !!                        - a_i (jpi,jpj,jpl)
12   !!                        - t_s (jpi,jpj,jpl)
13   !!                        - e_i (jpi,jpj,nlay_i,jpl)
14   !!                        - smv_i(jpi,jpj,jpl)
15   !!                        - oa_i (jpi,jpj,jpl)
16   !!                 VEQV : equivalent variables sometimes used in the model
17   !!                        - ht_i(jpi,jpj,jpl)
18   !!                        - ht_s(jpi,jpj,jpl)
19   !!                        - t_i (jpi,jpj,nlay_i,jpl)
20   !!                        ...
21   !!                 VAGG : aggregate variables, averaged/summed over all
22   !!                        thickness categories
23   !!                        - vt_i(jpi,jpj)
24   !!                        - vt_s(jpi,jpj)
25   !!                        - at_i(jpi,jpj)
26   !!                        - et_s(jpi,jpj)  !total snow heat content
27   !!                        - et_i(jpi,jpj)  !total ice thermal content
28   !!                        - smt_i(jpi,jpj) !mean ice salinity
29   !!                        - ot_i(jpi,jpj)  !average ice age
30   !!======================================================================
31   !! History :   -   ! 2006-01 (M. Vancoppenolle) Original code
32   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
33   !!----------------------------------------------------------------------
34#if defined key_lim3
35   !!----------------------------------------------------------------------
36   !!   'key_lim3'                                      LIM3 sea-ice model
37   !!----------------------------------------------------------------------
38   !!   lim_var_agg       :
39   !!   lim_var_glo2eqv   :
40   !!   lim_var_eqv2glo   :
41   !!   lim_var_salprof   :
42   !!   lim_var_salprof1d :
43   !!   lim_var_bv        :
44   !!----------------------------------------------------------------------
45   USE par_oce          ! ocean parameters
46   USE phycst           ! physical constants (ocean directory)
47   USE sbc_oce          ! Surface boundary condition: ocean fields
48   USE ice              ! LIM variables
49   USE par_ice          ! LIM parameters
50   USE dom_ice          ! LIM domain
51   USE thd_ice          ! LIM thermodynamics
52   USE in_out_manager   ! I/O manager
53   USE lib_mpp          ! MPP library
54   USE wrk_nemo         ! work arrays
55
56   IMPLICIT NONE
57   PRIVATE
58
59   PUBLIC   lim_var_agg          !
60   PUBLIC   lim_var_glo2eqv      !
61   PUBLIC   lim_var_eqv2glo      !
62   PUBLIC   lim_var_salprof      !
63   PUBLIC   lim_var_bv           !
64   PUBLIC   lim_var_salprof1d    !
65
66   REAL(wp) ::   eps20 = 1.e-20_wp   ! module constants
67   REAL(wp) ::   eps16 = 1.e-16_wp   !    -       -
68   REAL(wp) ::   eps13 = 1.e-13_wp   !    -       -
69   REAL(wp) ::   eps10 = 1.e-10_wp   !    -       -
70   REAL(wp) ::   eps06 = 1.e-06_wp   !    -       -
71   REAL(wp) ::   zzero = 0.e0        !    -       -
72   REAL(wp) ::   zone  = 1.e0        !    -       -
73
74   !!----------------------------------------------------------------------
75   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
76   !! $Id$
77   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
78   !!----------------------------------------------------------------------
79CONTAINS
80
81   SUBROUTINE lim_var_agg( kn )
82      !!------------------------------------------------------------------
83      !!                ***  ROUTINE lim_var_agg  ***
84      !!
85      !! ** Purpose :   aggregates ice-thickness-category variables to all-ice variables
86      !!              i.e. it turns VGLO into VAGG
87      !! ** Method  :
88      !!
89      !! ** Arguments : n = 1, at_i vt_i only
90      !!                n = 2 everything
91      !!
92      !! note : you could add an argument when you need only at_i, vt_i
93      !!        and when you need everything
94      !!------------------------------------------------------------------
95      INTEGER, INTENT( in ) ::   kn     ! =1 at_i & vt only ; = what is needed
96      !
97      INTEGER  ::   ji, jj, jk, jl   ! dummy loop indices
98      REAL(wp) ::   zinda
99      !!------------------------------------------------------------------
100
101      !--------------------
102      ! Compute variables
103      !--------------------
104      vt_i (:,:) = 0._wp
105      vt_s (:,:) = 0._wp
106      at_i (:,:) = 0._wp
107      ato_i(:,:) = 1._wp
108      !
109      DO jl = 1, jpl
110         DO jj = 1, jpj
111            DO ji = 1, jpi
112               !
113               vt_i(ji,jj) = vt_i(ji,jj) + v_i(ji,jj,jl) ! ice volume
114               vt_s(ji,jj) = vt_s(ji,jj) + v_s(ji,jj,jl) ! snow volume
115               at_i(ji,jj) = at_i(ji,jj) + a_i(ji,jj,jl) ! ice concentration
116               !
117               zinda = MAX( zzero , SIGN( zone , at_i(ji,jj) - 0.10 ) ) 
118               icethi(ji,jj) = vt_i(ji,jj) / MAX( at_i(ji,jj) , eps16 ) * zinda  ! ice thickness
119            END DO
120         END DO
121      END DO
122
123      DO jj = 1, jpj
124         DO ji = 1, jpi
125            ato_i(ji,jj) = MAX( 1._wp - at_i(ji,jj), 0._wp )   ! open water fraction
126         END DO
127      END DO
128
129      IF( kn > 1 ) THEN
130         et_s (:,:) = 0._wp
131         ot_i (:,:) = 0._wp
132         smt_i(:,:) = 0._wp
133         et_i (:,:) = 0._wp
134         !
135         DO jl = 1, jpl
136            DO jj = 1, jpj
137               DO ji = 1, jpi
138                  et_s(ji,jj)  = et_s(ji,jj)  + e_s(ji,jj,1,jl)                                       ! snow heat content
139                  zinda = MAX( zzero , SIGN( zone , vt_i(ji,jj) - 0.10 ) ) 
140                  smt_i(ji,jj) = smt_i(ji,jj) + smv_i(ji,jj,jl) / MAX( vt_i(ji,jj) , eps13 ) * zinda   ! ice salinity
141                  zinda = MAX( zzero , SIGN( zone , at_i(ji,jj) - 0.10 ) ) 
142                  ot_i(ji,jj)  = ot_i(ji,jj)  + oa_i(ji,jj,jl)  / MAX( at_i(ji,jj) , eps13 ) * zinda   ! ice age
143               END DO
144            END DO
145         END DO
146         !
147         DO jl = 1, jpl
148            DO jk = 1, nlay_i
149               et_i(:,:) = et_i(:,:) + e_i(:,:,jk,jl)       ! ice heat content
150            END DO
151         END DO
152         !
153      ENDIF
154      !
155   END SUBROUTINE lim_var_agg
156
157
158   SUBROUTINE lim_var_glo2eqv
159      !!------------------------------------------------------------------
160      !!                ***  ROUTINE lim_var_glo2eqv ***
161      !!
162      !! ** Purpose :   computes equivalent variables as function of global variables
163      !!              i.e. it turns VGLO into VEQV
164      !!------------------------------------------------------------------
165      INTEGER  ::   ji, jj, jk, jl   ! dummy loop indices
166      REAL(wp) ::   zq_i, zaaa, zbbb, zccc, zdiscrim     ! local scalars
167      REAL(wp) ::   ztmelts, zindb, zq_s, zfac1, zfac2   !   -      -
168      !!------------------------------------------------------------------
169
170      !-------------------------------------------------------
171      ! Ice thickness, snow thickness, ice salinity, ice age
172      !-------------------------------------------------------
173      DO jl = 1, jpl
174         DO jj = 1, jpj
175            DO ji = 1, jpi
176               zindb = 1._wp - MAX( 0._wp , SIGN( 1._wp,- a_i(ji,jj,jl) ) )   !0 if no ice and 1 if yes
177               ht_i(ji,jj,jl) = v_i (ji,jj,jl) / MAX( a_i(ji,jj,jl) , eps10 ) * zindb
178               ht_s(ji,jj,jl) = v_s (ji,jj,jl) / MAX( a_i(ji,jj,jl) , eps10 ) * zindb
179               o_i(ji,jj,jl)  = oa_i(ji,jj,jl) / MAX( a_i(ji,jj,jl) , eps10 ) * zindb
180            END DO
181         END DO
182      END DO
183
184      IF(  num_sal == 2  )THEN
185         DO jl = 1, jpl
186            DO jj = 1, jpj
187               DO ji = 1, jpi
188                  zindb = 1._wp - MAX( 0._wp , SIGN( 1._wp,- a_i(ji,jj,jl) ) )   !0 if no ice and 1 if yes
189                  sm_i(ji,jj,jl) = smv_i(ji,jj,jl) / MAX( v_i(ji,jj,jl) , eps10 ) * zindb
190               END DO
191            END DO
192         END DO
193      ENDIF
194
195      CALL lim_var_salprof      ! salinity profile
196
197      !-------------------
198      ! Ice temperatures
199      !-------------------
200!CDIR NOVERRCHK
201      DO jl = 1, jpl
202!CDIR NOVERRCHK
203         DO jk = 1, nlay_i
204!CDIR NOVERRCHK
205            DO jj = 1, jpj
206!CDIR NOVERRCHK
207               DO ji = 1, jpi
208                  !                                                              ! Energy of melting q(S,T) [J.m-3]
209                  zq_i    = e_i(ji,jj,jk,jl) / area(ji,jj) / MAX( v_i(ji,jj,jl) , eps06 ) * REAL(nlay_i,wp) 
210                  zindb   = 1.0 - MAX( 0.0 , SIGN( 1.0 , - v_i(ji,jj,jl) ) )     ! zindb = 0 if no ice and 1 if yes
211                  zq_i    = zq_i * unit_fac * zindb                              !convert units
212                  ztmelts = -tmut * s_i(ji,jj,jk,jl) + rtt                       ! Ice layer melt temperature
213                  !
214                  zaaa       =  cpic                  ! Conversion q(S,T) -> T (second order equation)
215                  zbbb       =  ( rcp - cpic ) * ( ztmelts - rtt ) + zq_i / rhoic - lfus
216                  zccc       =  lfus * (ztmelts-rtt)
217                  zdiscrim   =  SQRT( MAX(zbbb*zbbb - 4._wp*zaaa*zccc , 0._wp) )
218                  t_i(ji,jj,jk,jl) = rtt + zindb *( - zbbb - zdiscrim ) / ( 2.0 *zaaa )
219                  t_i(ji,jj,jk,jl) = MIN( rtt, MAX( 173.15_wp, t_i(ji,jj,jk,jl) ) )       ! 100-rtt < t_i < rtt
220               END DO
221            END DO
222         END DO
223      END DO
224
225      !--------------------
226      ! Snow temperatures
227      !--------------------
228      zfac1 = 1._wp / ( rhosn * cpic )
229      zfac2 = lfus / cpic 
230      DO jl = 1, jpl
231         DO jk = 1, nlay_s
232            DO jj = 1, jpj
233               DO ji = 1, jpi
234                  !Energy of melting q(S,T) [J.m-3]
235                  zq_s  = e_s(ji,jj,jk,jl) / ( area(ji,jj) * MAX( v_s(ji,jj,jl) , eps06 ) ) * REAL(nlay_s,wp)
236                  zindb = 1._wp - MAX( 0._wp , SIGN( 1._wp , - v_s(ji,jj,jl) ) )     ! zindb = 0 if no ice and 1 if yes
237                  zq_s  = zq_s * unit_fac * zindb                                    ! convert units
238                  !
239                  t_s(ji,jj,jk,jl) = rtt + zindb * ( - zfac1 * zq_s + zfac2 )
240                  t_s(ji,jj,jk,jl) = MIN( rtt, MAX( 173.15, t_s(ji,jj,jk,jl) ) )     ! 100-rtt < t_i < rtt
241               END DO
242            END DO
243         END DO
244      END DO
245
246      !-------------------
247      ! Mean temperature
248      !-------------------
249      tm_i(:,:) = 0._wp
250      DO jl = 1, jpl
251         DO jk = 1, nlay_i
252            DO jj = 1, jpj
253               DO ji = 1, jpi
254                  zindb = (  1._wp - MAX( 0._wp , SIGN( 1._wp , -a_i(ji,jj,jl) ) )  )   &
255                     &  * (  1._wp - MAX( 0._wp , SIGN( 1._wp , -v_i(ji,jj,jl) ) )  )
256                  tm_i(ji,jj) = tm_i(ji,jj) + t_i(ji,jj,jk,jl) * v_i(ji,jj,jl)   &
257                     &                      / (  REAL(nlay_i,wp) * MAX( vt_i(ji,jj) , eps10 )  )
258               END DO
259            END DO
260         END DO
261      END DO
262      !
263   END SUBROUTINE lim_var_glo2eqv
264
265
266   SUBROUTINE lim_var_eqv2glo
267      !!------------------------------------------------------------------
268      !!                ***  ROUTINE lim_var_eqv2glo ***
269      !!
270      !! ** Purpose :   computes global variables as function of equivalent variables
271      !!                i.e. it turns VEQV into VGLO
272      !! ** Method  :
273      !!
274      !! ** History :  (01-2006) Martin Vancoppenolle, UCL-ASTR
275      !!------------------------------------------------------------------
276      !
277      v_i(:,:,:)   = ht_i(:,:,:) * a_i(:,:,:)
278      v_s(:,:,:)   = ht_s(:,:,:) * a_i(:,:,:)
279      smv_i(:,:,:) = sm_i(:,:,:) * v_i(:,:,:)
280      oa_i (:,:,:) = o_i (:,:,:) * a_i(:,:,:)
281      !
282   END SUBROUTINE lim_var_eqv2glo
283
284
285   SUBROUTINE lim_var_salprof
286      !!------------------------------------------------------------------
287      !!                ***  ROUTINE lim_var_salprof ***
288      !!
289      !! ** Purpose :   computes salinity profile in function of bulk salinity     
290      !!
291      !! ** Method  : If bulk salinity greater than s_i_1,
292      !!              the profile is assumed to be constant (S_inf)
293      !!              If bulk salinity lower than s_i_0,
294      !!              the profile is linear with 0 at the surface (S_zero)
295      !!              If it is between s_i_0 and s_i_1, it is a
296      !!              alpha-weighted linear combination of s_inf and s_zero
297      !!
298      !! ** References : Vancoppenolle et al., 2007 (in preparation)
299      !!------------------------------------------------------------------
300      INTEGER  ::   ji, jj, jk, jl   ! dummy loop index
301      REAL(wp) ::   dummy_fac0, dummy_fac1, dummy_fac, zsal      ! local scalar
302      REAL(wp) ::   zind0, zind01, zindbal, zargtemp , zs_zero   !   -      -
303      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_slope_s, zalpha   ! 3D pointer
304      !!------------------------------------------------------------------
305
306      CALL wrk_alloc( jpi, jpj, jpl, z_slope_s, zalpha )
307
308      !---------------------------------------
309      ! Vertically constant, constant in time
310      !---------------------------------------
311      IF(  num_sal == 1  )   s_i(:,:,:,:) = bulk_sal
312
313      !-----------------------------------
314      ! Salinity profile, varying in time
315      !-----------------------------------
316      IF(  num_sal == 2  ) THEN
317         !
318         DO jk = 1, nlay_i
319            s_i(:,:,jk,:)  = sm_i(:,:,:)
320         END DO
321         !
322         DO jl = 1, jpl                               ! Slope of the linear profile
323            DO jj = 1, jpj
324               DO ji = 1, jpi
325                  z_slope_s(ji,jj,jl) = 2._wp * sm_i(ji,jj,jl) / MAX( 0.01 , ht_i(ji,jj,jl) )
326               END DO
327            END DO
328         END DO
329         !
330         dummy_fac0 = 1._wp / ( s_i_0 - s_i_1 )       ! Weighting factor between zs_zero and zs_inf
331         dummy_fac1 = s_i_1 / ( s_i_1 - s_i_0 )
332         !
333         zalpha(:,:,:) = 0._wp
334         DO jl = 1, jpl
335            DO jj = 1, jpj
336               DO ji = 1, jpi
337                  ! zind0 = 1 if sm_i le s_i_0 and 0 otherwise
338                  zind0  = MAX( 0.0   , SIGN( 1.0  , s_i_0 - sm_i(ji,jj,jl) ) ) 
339                  ! zind01 = 1 if sm_i is between s_i_0 and s_i_1 and 0 othws
340                  zind01 = ( 1.0 - zind0 ) * MAX( 0.0   , SIGN( 1.0  , s_i_1 - sm_i(ji,jj,jl) ) ) 
341                  ! If 2.sm_i GE sss_m then zindbal = 1
342                  zindbal = MAX( 0.0 , SIGN( 1.0 , 2. * sm_i(ji,jj,jl) - sss_m(ji,jj) ) )
343                  zalpha(ji,jj,jl) = zind0  * 1.0 + zind01 * ( sm_i(ji,jj,jl) * dummy_fac0 + dummy_fac1 )
344                  zalpha(ji,jj,jl) = zalpha(ji,jj,jl) * ( 1.0 - zindbal )
345               END DO
346            END DO
347         END DO
348         !
349         dummy_fac = 1._wp / nlay_i                   ! Computation of the profile
350         DO jl = 1, jpl
351            DO jk = 1, nlay_i
352               DO jj = 1, jpj
353                  DO ji = 1, jpi
354                     !                                      ! linear profile with 0 at the surface
355                     zs_zero = z_slope_s(ji,jj,jl) * ( REAL(jk,wp) - 0.5_wp ) * ht_i(ji,jj,jl) * dummy_fac
356                     !                                      ! weighting the profile
357                     s_i(ji,jj,jk,jl) = zalpha(ji,jj,jl) * zs_zero + ( 1._wp - zalpha(ji,jj,jl) ) * sm_i(ji,jj,jl)
358                  END DO ! ji
359               END DO ! jj
360            END DO ! jk
361         END DO ! jl
362         !
363      ENDIF ! num_sal
364
365      !-------------------------------------------------------
366      ! Vertically varying salinity profile, constant in time
367      !-------------------------------------------------------
368
369      IF(  num_sal == 3  ) THEN      ! Schwarzacher (1959) multiyear salinity profile (mean = 2.30)
370         !
371         sm_i(:,:,:) = 2.30_wp
372         !
373         DO jl = 1, jpl
374!CDIR NOVERRCHK
375            DO jk = 1, nlay_i
376               zargtemp  = ( REAL(jk,wp) - 0.5_wp ) / REAL(nlay_i,wp)
377               zsal =  1.6_wp * (  1._wp - COS( rpi * zargtemp**(0.407_wp/(0.573_wp+zargtemp)) )  )
378               s_i(:,:,jk,jl) =  zsal
379            END DO
380         END DO
381         !
382      ENDIF ! num_sal
383      !
384      CALL wrk_dealloc( jpi, jpj, jpl, z_slope_s, zalpha )
385      !
386   END SUBROUTINE lim_var_salprof
387
388
389   SUBROUTINE lim_var_bv
390      !!------------------------------------------------------------------
391      !!                ***  ROUTINE lim_var_bv ***
392      !!
393      !! ** Purpose :   computes mean brine volume (%) in sea ice
394      !!
395      !! ** Method  : e = - 0.054 * S (ppt) / T (C)
396      !!
397      !! References : Vancoppenolle et al., JGR, 2007
398      !!------------------------------------------------------------------
399      INTEGER  ::   ji, jj, jk, jl   ! dummy loop indices
400      REAL(wp) ::   zbvi, zindb      ! local scalars
401      !!------------------------------------------------------------------
402      !
403      bv_i(:,:) = 0._wp
404      DO jl = 1, jpl
405         DO jk = 1, nlay_i
406            DO jj = 1, jpj
407               DO ji = 1, jpi
408                  zindb = 1.0-MAX(0.0,SIGN(1.0,-a_i(ji,jj,jl))) !0 if no ice and 1 if yes
409                  zbvi  = - zindb * tmut * s_i(ji,jj,jk,jl) / MIN( t_i(ji,jj,jk,jl) - 273.15 , eps13 )   &
410                     &                   * v_i(ji,jj,jl)    / REAL(nlay_i,wp)
411                  bv_i(ji,jj) = bv_i(ji,jj) + zbvi  / MAX( vt_i(ji,jj) , eps13 )
412               END DO
413            END DO
414         END DO
415      END DO
416      !
417   END SUBROUTINE lim_var_bv
418
419
420   SUBROUTINE lim_var_salprof1d( kideb, kiut )
421      !!-------------------------------------------------------------------
422      !!                  ***  ROUTINE lim_thd_salprof1d  ***
423      !!
424      !! ** Purpose :   1d computation of the sea ice salinity profile
425      !!                Works with 1d vectors and is used by thermodynamic modules
426      !!-------------------------------------------------------------------
427      INTEGER, INTENT(in) ::   kideb, kiut   ! thickness category index
428      !
429      INTEGER  ::   ji, jk    ! dummy loop indices
430      INTEGER  ::   zji, zjj  ! local integers
431      REAL(wp) ::   dummy_fac0, dummy_fac1, dummy_fac2, zargtemp, zsal   ! local scalars
432      REAL(wp) ::   zalpha, zind0, zind01, zindbal, zs_zero              !   -      -
433      !
434      REAL(wp), POINTER, DIMENSION(:) ::   z_slope_s
435      !!---------------------------------------------------------------------
436
437      CALL wrk_alloc( jpij, z_slope_s )
438
439      !---------------------------------------
440      ! Vertically constant, constant in time
441      !---------------------------------------
442      IF( num_sal == 1 )   s_i_b(:,:) = bulk_sal
443
444      !------------------------------------------------------
445      ! Vertically varying salinity profile, varying in time
446      !------------------------------------------------------
447
448      IF(  num_sal == 2  ) THEN
449         !
450         DO ji = kideb, kiut          ! Slope of the linear profile zs_zero
451            z_slope_s(ji) = 2._wp * sm_i_b(ji) / MAX( 0.01 , ht_i_b(ji) )
452         END DO
453
454         ! Weighting factor between zs_zero and zs_inf
455         !---------------------------------------------
456         dummy_fac0 = 1._wp / ( s_i_0 - s_i_1 )
457         dummy_fac1 = s_i_1 / ( s_i_1 - s_i_0 )
458         dummy_fac2 = 1._wp / REAL(nlay_i,wp)
459
460!CDIR NOVERRCHK
461         DO jk = 1, nlay_i
462!CDIR NOVERRCHK
463            DO ji = kideb, kiut
464               zji =  MOD( npb(ji) - 1 , jpi ) + 1
465               zjj =     ( npb(ji) - 1 ) / jpi + 1
466               ! zind0 = 1 if sm_i le s_i_0 and 0 otherwise
467               zind0  = MAX( 0._wp , SIGN( 1._wp  , s_i_0 - sm_i_b(ji) ) ) 
468               ! zind01 = 1 if sm_i is between s_i_0 and s_i_1 and 0 othws
469               zind01 = ( 1._wp - zind0 ) * MAX( 0._wp , SIGN( 1._wp , s_i_1 - sm_i_b(ji) ) ) 
470               ! if 2.sm_i GE sss_m then zindbal = 1
471               zindbal = MAX( 0._wp , SIGN( 1._wp , 2._wp * sm_i_b(ji) - sss_m(zji,zjj) ) )
472               !
473               zalpha = (  zind0 + zind01 * ( sm_i_b(ji) * dummy_fac0 + dummy_fac1 )  ) * ( 1.0 - zindbal )
474               !
475               zs_zero = z_slope_s(ji) * ( REAL(jk,wp) - 0.5_wp ) * ht_i_b(ji) * dummy_fac2
476               ! weighting the profile
477               s_i_b(ji,jk) = zalpha * zs_zero + ( 1._wp - zalpha ) * sm_i_b(ji)
478            END DO ! ji
479         END DO ! jk
480
481      ENDIF ! num_sal
482
483      !-------------------------------------------------------
484      ! Vertically varying salinity profile, constant in time
485      !-------------------------------------------------------
486
487      IF( num_sal == 3 ) THEN      ! Schwarzacher (1959) multiyear salinity profile (mean = 2.30)
488         !
489         sm_i_b(:) = 2.30_wp
490         !
491!CDIR NOVERRCHK
492         DO jk = 1, nlay_i
493            zargtemp  = ( REAL(jk,wp) - 0.5_wp ) / REAL(nlay_i,wp)
494            zsal =  1.6_wp * (  1._wp - COS( rpi * zargtemp**(0.407_wp/(0.573_wp+zargtemp)) )  )
495            DO ji = kideb, kiut
496               s_i_b(ji,jk) = zsal
497            END DO
498         END DO
499         !
500      ENDIF
501      !
502      CALL wrk_dealloc( jpij, z_slope_s )
503      !
504   END SUBROUTINE lim_var_salprof1d
505
506#else
507   !!----------------------------------------------------------------------
508   !!   Default option         Dummy module          NO  LIM3 sea-ice model
509   !!----------------------------------------------------------------------
510CONTAINS
511   SUBROUTINE lim_var_agg          ! Empty routines
512   END SUBROUTINE lim_var_agg
513   SUBROUTINE lim_var_glo2eqv      ! Empty routines
514   END SUBROUTINE lim_var_glo2eqv
515   SUBROUTINE lim_var_eqv2glo      ! Empty routines
516   END SUBROUTINE lim_var_eqv2glo
517   SUBROUTINE lim_var_salprof      ! Empty routines
518   END SUBROUTINE lim_var_salprof
519   SUBROUTINE lim_var_bv           ! Emtpy routines
520   END SUBROUTINE lim_var_bv
521   SUBROUTINE lim_var_salprof1d    ! Emtpy routines
522   END SUBROUTINE lim_var_salprof1d
523#endif
524
525   !!======================================================================
526END MODULE limvar
Note: See TracBrowser for help on using the repository browser.