New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in branches/2012/dev_r3385_NOCS04_HAMF/NEMOGCM/NEMO/OPA_SRC – NEMO

Context Navigation

source: branches/2012/dev_r3385_NOCS04_HAMF/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 3515

Last change on this file since 3515 was 3515, checked in by charris, 12 years ago
Some of the changes from the dev_3352_UKMO8_CICE branch already had to be merged into this branch, so it no longer seems sensible to maintain these other minor changes in a separate branch (so dev_3352_UKMO8_CICE is now redundant). These changes have no impact on configurations not using CICE.
Property svn:keywords set to `Id`
File size: 36.0 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) LIM sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!! 3.4 ! 2011-11 (C. Harris) decomposition changes for running with CICE
31	!!----------------------------------------------------------------------
32
33	!!----------------------------------------------------------------------
34	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
35	!! nemo_init : initialization of the NEMO system
36	!! nemo_ctl : initialisation of the contol print
37	!! nemo_closefile : close remaining open files
38	!! nemo_alloc : dynamical allocation
39	!! nemo_partition : calculate MPP domain decomposition
40	!! factorise : calculate the factors of the no. of MPI processes
41	!!----------------------------------------------------------------------
42	USE step_oce ! module used in the ocean time stepping module
43	USE sbc_oce ! surface boundary condition: ocean
44	USE cla ! cross land advection (tra_cla routine)
45	USE domcfg ! domain configuration (dom_cfg routine)
46	USE mppini ! shared/distributed memory setting (mpp_init routine)
47	USE domain ! domain initialization (dom_init routine)
48	#if defined key_nemocice_decomp
49	USE ice_domain_size, only: nx_global, ny_global
50	#endif
51	USE obcini ! open boundary cond. initialization (obc_ini routine)
52	USE bdyini ! open boundary cond. initialization (bdy_init routine)
53	USE bdydta ! open boundary cond. initialization (bdy_dta_init routine)
54	USE bdytides ! open boundary cond. initialization (tide_init routine)
55	USE istate ! initial state setting (istate_init routine)
56	USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine)
57	USE ldftra ! lateral diffusivity setting (ldftra_init routine)
58	USE zdfini ! vertical physics setting (zdf_init routine)
59	USE phycst ! physical constant (par_cst routine)
60	USE trdmod ! momentum/tracers trends (trd_mod_init routine)
61	USE asmtrj ! writing out state trajectory
62	USE diaptr ! poleward transports (dia_ptr_init routine)
63	USE diadct ! sections transports (dia_dct_init routine)
64	USE diaobs ! Observation diagnostics (dia_obs_init routine)
65	USE step ! NEMO time-stepping (stp routine)
66	#if defined key_oasis3
67	USE cpl_oasis3 ! OASIS3 coupling
68	#elif defined key_oasis4
69	USE cpl_oasis4 ! OASIS4 coupling (not working)
70	#endif
71	USE c1d ! 1D configuration
72	USE step_c1d ! Time stepping loop for the 1D configuration
73	#if defined key_top
74	USE trcini ! passive tracer initialisation
75	#endif
76	USE lib_mpp ! distributed memory computing
77	#if defined key_iomput
78	USE mod_ioclient
79	#endif
80
81	IMPLICIT NONE
82	PRIVATE
83
84	PUBLIC nemo_gcm ! called by model.F90
85	PUBLIC nemo_init ! needed by AGRIF
86
87	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
88
89	!!----------------------------------------------------------------------
90	!! NEMO/OPA 4.0 , NEMO Consortium (2011)
91	!! $Id$
92	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
93	!!----------------------------------------------------------------------
94	CONTAINS
95
96	SUBROUTINE nemo_gcm
97	!!----------------------------------------------------------------------
98	!! * ROUTINE nemo_gcm *
99	!!
100	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
101	!! curvilinear mesh on the sphere.
102	!!
103	!! ** Method : - model general initialization
104	!! - launch the time-stepping (stp routine)
105	!! - finalize the run by closing files and communications
106	!!
107	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
108	!! Madec, 2008, internal report, IPSL.
109	!!----------------------------------------------------------------------
110	INTEGER :: istp ! time step index
111	!!----------------------------------------------------------------------
112	!
113	#if defined key_agrif
114	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
115	#endif
116
117	! !-----------------------!
118	CALL nemo_init !== Initialisations ==!
119	! !-----------------------!
120	#if defined key_agrif
121	CALL Agrif_Declare_Var ! AGRIF: set the meshes
122	# if defined key_top
123	CALL Agrif_Declare_Var_Top ! AGRIF: set the meshes
124	# endif
125	#endif
126	! check that all process are still there... If some process have an error,
127	! they will never enter in step and other processes will wait until the end of the cpu time!
128	IF( lk_mpp ) CALL mpp_max( nstop )
129
130	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
131
132	! !-----------------------!
133	! !== time stepping ==!
134	! !-----------------------!
135	istp = nit000
136	#if defined key_c1d
137	DO WHILE ( istp <= nitend .AND. nstop == 0 )
138	CALL stp_c1d( istp )
139	istp = istp + 1
140	END DO
141	#else
142	IF( lk_asminc ) THEN
143	IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 ) ! Output background fields
144	IF( ln_trjwri ) CALL asm_trj_wri( nit000 - 1 ) ! Output trajectory fields
145	IF( ln_asmdin ) THEN ! Direct initialization
146	IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 ) ! Tracers
147	IF( ln_dyninc ) THEN
148	CALL dyn_asm_inc( nit000 - 1 ) ! Dynamics
149	IF ( ln_asmdin ) CALL ssh_wzv ( nit000 - 1 ) ! update vertical velocity
150	ENDIF
151	IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 ) ! SSH
152	ENDIF
153	ENDIF
154
155	DO WHILE ( istp <= nitend .AND. nstop == 0 )
156	#if defined key_agrif
157	CALL Agrif_Step( stp ) ! AGRIF: time stepping
158	#else
159	CALL stp( istp ) ! standard time stepping
160	#endif
161	istp = istp + 1
162	IF( lk_mpp ) CALL mpp_max( nstop )
163	END DO
164	#endif
165
166	IF( lk_diaobs ) CALL dia_obs_wri
167
168	! !------------------------!
169	! !== finalize the run ==!
170	! !------------------------!
171	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
172	!
173	IF( nstop /= 0 .AND. lwp ) THEN ! error print
174	WRITE(numout,cform_err)
175	WRITE(numout,*) nstop, ' error have been found'
176	ENDIF
177	!
178	#if defined key_agrif
179	CALL Agrif_ParentGrid_To_ChildGrid()
180	IF( lk_diaobs ) CALL dia_obs_wri
181	IF( nn_timing == 1 ) CALL timing_finalize
182	CALL Agrif_ChildGrid_To_ParentGrid()
183	#endif
184	IF( nn_timing == 1 ) CALL timing_finalize
185	!
186	CALL nemo_closefile
187	#if defined key_oasis3 \|\| defined key_oasis4
188	CALL cpl_prism_finalize ! end coupling and mpp communications with OASIS
189	#else
190	IF( lk_mpp ) CALL mppstop ! end mpp communications
191	#endif
192	!
193	END SUBROUTINE nemo_gcm
194
195
196	SUBROUTINE nemo_init
197	!!----------------------------------------------------------------------
198	!! * ROUTINE nemo_init *
199	!!
200	!! ** Purpose : initialization of the NEMO GCM
201	!!----------------------------------------------------------------------
202	INTEGER :: ji ! dummy loop indices
203	INTEGER :: ilocal_comm ! local integer
204	CHARACTER(len=80), DIMENSION(16) :: cltxt
205	!!
206	NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, &
207	& nn_isplt, nn_jsplt, nn_jctls, nn_jctle, &
208	& nn_bench, nn_timing
209	!!----------------------------------------------------------------------
210	!
211	cltxt = ''
212	!
213	! ! open Namelist file
214	CALL ctl_opn( numnam, 'namelist', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
215	!
216	READ( numnam, namctl ) ! Namelist namctl : Control prints & Benchmark
217	!
218	! !--------------------------------------------!
219	! ! set communicator & select the local node !
220	! !--------------------------------------------!
221	#if defined key_iomput
222	IF( Agrif_Root() ) THEN
223	# if defined key_oasis3 \|\| defined key_oasis4
224	CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis
225	# endif
226	CALL init_ioclient( ilocal_comm ) ! exchange io_server nemo local communicator with the io_server
227	ENDIF
228	narea = mynode( cltxt, numnam, nstop, ilocal_comm ) ! Nodes selection
229	#else
230	# if defined key_oasis3 \|\| defined key_oasis4
231	IF( Agrif_Root() ) THEN
232	CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis
233	ENDIF
234	narea = mynode( cltxt, numnam, nstop, ilocal_comm ) ! Nodes selection (control print return in cltxt)
235	# else
236	ilocal_comm = 0
237	narea = mynode( cltxt, numnam, nstop ) ! Nodes selection (control print return in cltxt)
238	# endif
239	#endif
240	narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 )
241
242	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
243
244	! If dimensions of processor grid weren't specified in the namelist file
245	! then we calculate them here now that we have our communicator size
246	IF( (jpni < 1) .OR. (jpnj < 1) )THEN
247	#if defined key_mpp_mpi
248	IF( Agrif_Root() ) CALL nemo_partition(mppsize)
249	#else
250	jpni = 1
251	jpnj = 1
252	jpnij = jpni*jpnj
253	#endif
254	END IF
255
256	! Calculate domain dimensions given calculated jpni and jpnj
257	! This used to be done in par_oce.F90 when they were parameters rather
258	! than variables
259	IF( Agrif_Root() ) THEN
260	#if defined key_nemocice_decomp
261	jpi = ( nx_global+2-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
262	jpj = ( ny_global+2-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
263	#else
264	jpi = ( jpiglo-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
265	jpj = ( jpjglo-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
266	#endif
267	jpk = jpkdta ! third dim
268	jpim1 = jpi-1 ! inner domain indices
269	jpjm1 = jpj-1 ! " "
270	jpkm1 = jpk-1 ! " "
271	jpij = jpi*jpj ! jpi x j
272	ENDIF
273
274	IF(lwp) THEN ! open listing units
275	!
276	CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
277	!
278	WRITE(numout,*)
279	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
280	WRITE(numout,*) ' NEMO team'
281	WRITE(numout,*) ' Ocean General Circulation Model'
282	WRITE(numout,*) ' version 3.4 (2011) '
283	WRITE(numout,*)
284	WRITE(numout,*)
285	DO ji = 1, SIZE(cltxt)
286	IF( TRIM(cltxt(ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode
287	END DO
288	WRITE(numout,cform_aaa) ! Flag AAAAAAA
289	!
290	ENDIF
291
292	! Now we know the dimensions of the grid and numout has been set we can
293	! allocate arrays
294	CALL nemo_alloc()
295
296	! !-------------------------------!
297	! ! NEMO general initialization !
298	! !-------------------------------!
299
300	CALL nemo_ctl ! Control prints & Benchmark
301
302	! ! Domain decomposition
303	IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out
304	ELSE ; CALL mpp_init2 ! eliminate land processors
305	ENDIF
306	!
307	IF( nn_timing == 1 ) CALL timing_init
308	!
309	! ! General initialization
310	CALL phy_cst ! Physical constants
311	CALL eos_init ! Equation of state
312	CALL dom_cfg ! Domain configuration
313	CALL dom_init ! Domain
314
315	IF( ln_nnogather ) CALL nemo_northcomms ! Initialise the northfold neighbour lists (must be done after the masks are defined)
316
317	IF( ln_ctl ) CALL prt_ctl_init ! Print control
318
319	IF( lk_obc ) CALL obc_init ! Open boundaries
320	IF( lk_bdy ) CALL bdy_init ! Open boundaries initialisation
321	IF( lk_bdy ) CALL bdy_dta_init ! Open boundaries initialisation of external data arrays
322	IF( lk_bdy ) CALL tide_init ! Open boundaries initialisation of tidal harmonic forcing
323
324	CALL dyn_nept_init ! simplified form of Neptune effect
325
326	CALL istate_init ! ocean initial state (Dynamics and tracers)
327
328	! ! Ocean physics
329	CALL sbc_init ! Forcings : surface module
330	! ! Vertical physics
331	CALL zdf_init ! namelist read
332	CALL zdf_bfr_init ! bottom friction
333	IF( lk_zdfric ) CALL zdf_ric_init ! Richardson number dependent Kz
334	IF( lk_zdftke ) CALL zdf_tke_init ! TKE closure scheme
335	IF( lk_zdfgls ) CALL zdf_gls_init ! GLS closure scheme
336	IF( lk_zdfkpp ) CALL zdf_kpp_init ! KPP closure scheme
337	IF( lk_zdftmx ) CALL zdf_tmx_init ! tidal vertical mixing
338	IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) &
339	& CALL zdf_ddm_init ! double diffusive mixing
340	! ! Lateral physics
341	CALL ldf_tra_init ! Lateral ocean tracer physics
342	CALL ldf_dyn_init ! Lateral ocean momentum physics
343	IF( lk_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
344
345	! ! Active tracers
346	CALL tra_qsr_init ! penetrative solar radiation qsr
347	CALL tra_bbc_init ! bottom heat flux
348	IF( lk_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
349	IF( ln_tradmp ) CALL tra_dmp_init ! internal damping trends
350	CALL tra_adv_init ! horizontal & vertical advection
351	CALL tra_ldf_init ! lateral mixing
352	CALL tra_zdf_init ! vertical mixing and after tracer fields
353
354	! ! Dynamics
355	CALL dyn_adv_init ! advection (vector or flux form)
356	CALL dyn_vor_init ! vorticity term including Coriolis
357	CALL dyn_ldf_init ! lateral mixing
358	CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure
359	CALL dyn_zdf_init ! vertical diffusion
360	CALL dyn_spg_init ! surface pressure gradient
361
362	! ! Misc. options
363	IF( nn_cla == 1 ) CALL cla_init ! Cross Land Advection
364
365	#if defined key_top
366	! ! Passive tracers
367	CALL trc_init
368	#endif
369	! ! Diagnostics
370	IF( lk_floats ) CALL flo_init ! drifting Floats
371	CALL iom_init ! iom_put initialization
372	IF( lk_diaar5 ) CALL dia_ar5_init ! ar5 diag
373	CALL dia_ptr_init ! Poleward TRansports initialization
374	IF( lk_diadct ) CALL dia_dct_init ! Sections tranports
375	CALL dia_hsb_init ! heat content, salt content and volume budgets
376	CALL trd_mod_init ! Mixed-layer/Vorticity/Integral constraints trends
377	IF( lk_diaobs ) THEN ! Observation & model comparison
378	CALL dia_obs_init ! Initialize observational data
379	CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
380	ENDIF
381	! ! Assimilation increments
382	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
383	IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
384	!
385	END SUBROUTINE nemo_init
386
387
388	SUBROUTINE nemo_ctl
389	!!----------------------------------------------------------------------
390	!! * ROUTINE nemo_ctl *
391	!!
392	!! ** Purpose : control print setting
393	!!
394	!! ** Method : - print namctl information and check some consistencies
395	!!----------------------------------------------------------------------
396	!
397	IF(lwp) THEN ! control print
398	WRITE(numout,*)
399	WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
400	WRITE(numout,*) '~~~~~~~ '
401	WRITE(numout,*) ' Namelist namctl'
402	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
403	WRITE(numout,*) ' level of print nn_print = ', nn_print
404	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
405	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
406	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
407	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
408	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
409	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
410	WRITE(numout,*) ' benchmark parameter (0/1) nn_bench = ', nn_bench
411	WRITE(numout,*) ' timing activated (0/1) nn_timing = ', nn_timing
412	ENDIF
413	!
414	nprint = nn_print ! convert DOCTOR namelist names into OLD names
415	nictls = nn_ictls
416	nictle = nn_ictle
417	njctls = nn_jctls
418	njctle = nn_jctle
419	isplt = nn_isplt
420	jsplt = nn_jsplt
421	nbench = nn_bench
422	! ! Parameter control
423	!
424	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
425	IF( lk_mpp .AND. jpnij > 1 ) THEN
426	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
427	ELSE
428	IF( isplt == 1 .AND. jsplt == 1 ) THEN
429	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
430	& ' - the print control will be done over the whole domain' )
431	ENDIF
432	ijsplt = isplt * jsplt ! total number of processors ijsplt
433	ENDIF
434	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
435	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
436	!
437	! ! indices used for the SUM control
438	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
439	lsp_area = .FALSE.
440	ELSE ! print control done over a specific area
441	lsp_area = .TRUE.
442	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
443	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
444	nictls = 1
445	ENDIF
446	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
447	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
448	nictle = jpiglo
449	ENDIF
450	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
451	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
452	njctls = 1
453	ENDIF
454	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
455	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
456	njctle = jpjglo
457	ENDIF
458	ENDIF
459	ENDIF
460	!
461	IF( nbench == 1 ) THEN ! Benchmark
462	SELECT CASE ( cp_cfg )
463	CASE ( 'gyre' ) ; CALL ctl_warn( ' The Benchmark is activated ' )
464	CASE DEFAULT ; CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:', &
465	& ' key_gyre must be used or set nbench = 0' )
466	END SELECT
467	ENDIF
468	!
469	IF( lk_c1d .AND. .NOT.lk_iomput ) CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ', &
470	& 'with the IOM Input/Output manager. ' , &
471	& 'Compile with key_iomput enabled' )
472	!
473	END SUBROUTINE nemo_ctl
474
475
476	SUBROUTINE nemo_closefile
477	!!----------------------------------------------------------------------
478	!! * ROUTINE nemo_closefile *
479	!!
480	!! ** Purpose : Close the files
481	!!----------------------------------------------------------------------
482	!
483	IF( lk_mpp ) CALL mppsync
484	!
485	CALL iom_close ! close all input/output files managed by iom_*
486	!
487	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
488	IF( numsol /= -1 ) CLOSE( numsol ) ! solver file
489	IF( numnam /= -1 ) CLOSE( numnam ) ! oce namelist
490	IF( numnam_ice /= -1 ) CLOSE( numnam_ice ) ! ice namelist
491	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
492	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
493	IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports
494	IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports
495	IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports
496
497	!
498	numout = 6 ! redefine numout in case it is used after this point...
499	!
500	END SUBROUTINE nemo_closefile
501
502
503	SUBROUTINE nemo_alloc
504	!!----------------------------------------------------------------------
505	!! * ROUTINE nemo_alloc *
506	!!
507	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
508	!!
509	!! ** Method :
510	!!----------------------------------------------------------------------
511	USE diawri , ONLY: dia_wri_alloc
512	USE dom_oce , ONLY: dom_oce_alloc
513	USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
514	USE ldftra_oce, ONLY: ldftra_oce_alloc
515	USE trc_oce , ONLY: trc_oce_alloc
516	!
517	INTEGER :: ierr
518	!!----------------------------------------------------------------------
519	!
520	ierr = oce_alloc () ! ocean
521	ierr = ierr + dia_wri_alloc ()
522	ierr = ierr + dom_oce_alloc () ! ocean domain
523	ierr = ierr + ldfdyn_oce_alloc() ! ocean lateral physics : dynamics
524	ierr = ierr + ldftra_oce_alloc() ! ocean lateral physics : tracers
525	ierr = ierr + zdf_oce_alloc () ! ocean vertical physics
526	!
527	ierr = ierr + lib_mpp_alloc (numout) ! mpp exchanges
528	ierr = ierr + trc_oce_alloc () ! shared TRC / TRA arrays
529	!
530	IF( lk_mpp ) CALL mpp_sum( ierr )
531	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
532	!
533	END SUBROUTINE nemo_alloc
534
535
536	SUBROUTINE nemo_partition( num_pes )
537	!!----------------------------------------------------------------------
538	!! * ROUTINE nemo_partition *
539	!!
540	!! ** Purpose :
541	!!
542	!! ** Method :
543	!!----------------------------------------------------------------------
544	INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
545	!
546	INTEGER, PARAMETER :: nfactmax = 20
547	INTEGER :: nfact ! The no. of factors returned
548	INTEGER :: ierr ! Error flag
549	INTEGER :: ji
550	INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
551	INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
552	!!----------------------------------------------------------------------
553
554	ierr = 0
555
556	CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
557
558	IF( nfact <= 1 ) THEN
559	WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
560	WRITE (numout, *) ' : using grid of ',num_pes,' x 1'
561	jpnj = 1
562	jpni = num_pes
563	ELSE
564	! Search through factors for the pair that are closest in value
565	mindiff = 1000000
566	imin = 1
567	DO ji = 1, nfact-1, 2
568	idiff = ABS( ifact(ji) - ifact(ji+1) )
569	IF( idiff < mindiff ) THEN
570	mindiff = idiff
571	imin = ji
572	ENDIF
573	END DO
574	jpnj = ifact(imin)
575	jpni = ifact(imin + 1)
576	ENDIF
577	!
578	jpnij = jpni*jpnj
579	!
580	END SUBROUTINE nemo_partition
581
582
583	SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
584	!!----------------------------------------------------------------------
585	!! * ROUTINE factorise *
586	!!
587	!! ** Purpose : return the prime factors of n.
588	!! knfax factors are returned in array kfax which is of
589	!! maximum dimension kmaxfax.
590	!! ** Method :
591	!!----------------------------------------------------------------------
592	INTEGER , INTENT(in ) :: kn, kmaxfax
593	INTEGER , INTENT( out) :: kerr, knfax
594	INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax
595	!
596	INTEGER :: ifac, jl, inu
597	INTEGER, PARAMETER :: ntest = 14
598	INTEGER :: ilfax(ntest)
599
600	! lfax contains the set of allowed factors.
601	data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256, &
602	& 128, 64, 32, 16, 8, 4, 2 /
603	!!----------------------------------------------------------------------
604
605	! Clear the error flag and initialise output vars
606	kerr = 0
607	kfax = 1
608	knfax = 0
609
610	! Find the factors of n.
611	IF( kn == 1 ) GOTO 20
612
613	! nu holds the unfactorised part of the number.
614	! knfax holds the number of factors found.
615	! l points to the allowed factor list.
616	! ifac holds the current factor.
617
618	inu = kn
619	knfax = 0
620
621	DO jl = ntest, 1, -1
622	!
623	ifac = ilfax(jl)
624	IF( ifac > inu ) CYCLE
625
626	! Test whether the factor will divide.
627
628	IF( MOD(inu,ifac) == 0 ) THEN
629	!
630	knfax = knfax + 1 ! Add the factor to the list
631	IF( knfax > kmaxfax ) THEN
632	kerr = 6
633	write (,) 'FACTOR: insufficient space in factor array ', knfax
634	return
635	ENDIF
636	kfax(knfax) = ifac
637	! Store the other factor that goes with this one
638	knfax = knfax + 1
639	kfax(knfax) = inu / ifac
640	!WRITE (,) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
641	ENDIF
642	!
643	END DO
644
645	20 CONTINUE ! Label 20 is the exit point from the factor search loop.
646	!
647	END SUBROUTINE factorise
648
649	#if defined key_mpp_mpi
650	SUBROUTINE nemo_northcomms
651	!!======================================================================
652	!! * ROUTINE nemo_northcomms *
653	!! nemo_northcomms : Setup for north fold exchanges with explicit peer to peer messaging
654	!!=====================================================================
655	!!----------------------------------------------------------------------
656	!!
657	!! ** Purpose : Initialization of the northern neighbours lists.
658	!!----------------------------------------------------------------------
659	!! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE)
660	!!----------------------------------------------------------------------
661
662	INTEGER :: ji, jj, jk, ij, jtyp ! dummy loop indices
663	INTEGER :: ijpj ! number of rows involved in north-fold exchange
664	INTEGER :: northcomms_alloc ! allocate return status
665	REAL(wp), ALLOCATABLE, DIMENSION ( :,: ) :: znnbrs ! workspace
666	LOGICAL, ALLOCATABLE, DIMENSION ( : ) :: lrankset ! workspace
667
668	IF(lwp) WRITE(numout,*)
669	IF(lwp) WRITE(numout,*) 'nemo_northcomms : Initialization of the northern neighbours lists'
670	IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
671
672	!!----------------------------------------------------------------------
673	ALLOCATE( znnbrs(jpi,jpj), stat = northcomms_alloc )
674	ALLOCATE( lrankset(jpnij), stat = northcomms_alloc )
675	IF( northcomms_alloc /= 0 ) THEN
676	WRITE(numout,cform_war)
677	WRITE(numout,*) 'northcomms_alloc : failed to allocate arrays'
678	CALL ctl_stop( 'STOP', 'nemo_northcomms : unable to allocate temporary arrays' )
679	ENDIF
680	nsndto = 0
681	isendto = -1
682	ijpj = 4
683	!
684	! This routine has been called because ln_nnogather has been set true ( nammpp )
685	! However, these first few exchanges have to use the mpi_allgather method to
686	! establish the neighbour lists to use in subsequent peer to peer exchanges.
687	! Consequently, set l_north_nogather to be false here and set it true only after
688	! the lists have been established.
689	!
690	l_north_nogather = .FALSE.
691	!
692	! Exchange and store ranks on northern rows
693
694	DO jtyp = 1,4
695
696	lrankset = .FALSE.
697	znnbrs = narea
698	SELECT CASE (jtyp)
699	CASE(1)
700	CALL lbc_lnk( znnbrs, 'T', 1. ) ! Type 1: T,W-points
701	CASE(2)
702	CALL lbc_lnk( znnbrs, 'U', 1. ) ! Type 2: U-point
703	CASE(3)
704	CALL lbc_lnk( znnbrs, 'V', 1. ) ! Type 3: V-point
705	CASE(4)
706	CALL lbc_lnk( znnbrs, 'F', 1. ) ! Type 4: F-point
707	END SELECT
708
709	IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
710	DO jj = nlcj-ijpj+1, nlcj
711	ij = jj - nlcj + ijpj
712	DO ji = 1,jpi
713	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
714	& lrankset(INT(znnbrs(ji,jj))) = .true.
715	END DO
716	END DO
717
718	DO jj = 1,jpnij
719	IF ( lrankset(jj) ) THEN
720	nsndto(jtyp) = nsndto(jtyp) + 1
721	IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
722	CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
723	& ' jpmaxngh will need to be increased ')
724	ENDIF
725	isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank
726	ENDIF
727	END DO
728	ENDIF
729
730	END DO
731
732	!
733	! Type 5: I-point
734	!
735	! ICE point exchanges may involve some averaging. The neighbours list is
736	! built up using two exchanges to ensure that the whole stencil is covered.
737	! lrankset should not be reset between these 'J' and 'K' point exchanges
738
739	jtyp = 5
740	lrankset = .FALSE.
741	znnbrs = narea
742	CALL lbc_lnk( znnbrs, 'J', 1. ) ! first ice U-V point
743
744	IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
745	DO jj = nlcj-ijpj+1, nlcj
746	ij = jj - nlcj + ijpj
747	DO ji = 1,jpi
748	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
749	& lrankset(INT(znnbrs(ji,jj))) = .true.
750	END DO
751	END DO
752	ENDIF
753
754	znnbrs = narea
755	CALL lbc_lnk( znnbrs, 'K', 1. ) ! second ice U-V point
756
757	IF ( njmppt(narea) .EQ. MAXVAL( njmppt )) THEN
758	DO jj = nlcj-ijpj+1, nlcj
759	ij = jj - nlcj + ijpj
760	DO ji = 1,jpi
761	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
762	& lrankset( INT(znnbrs(ji,jj))) = .true.
763	END DO
764	END DO
765
766	DO jj = 1,jpnij
767	IF ( lrankset(jj) ) THEN
768	nsndto(jtyp) = nsndto(jtyp) + 1
769	IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
770	CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
771	& ' jpmaxngh will need to be increased ')
772	ENDIF
773	isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank
774	ENDIF
775	END DO
776	!
777	! For northern row areas, set l_north_nogather so that all subsequent exchanges
778	! can use peer to peer communications at the north fold
779	!
780	l_north_nogather = .TRUE.
781	!
782	ENDIF
783	DEALLOCATE( znnbrs )
784	DEALLOCATE( lrankset )
785
786	END SUBROUTINE nemo_northcomms
787	#else
788	SUBROUTINE nemo_northcomms ! Dummy routine
789	WRITE(,) 'nemo_northcomms: You should not have seen this print! error?'
790	END SUBROUTINE nemo_northcomms
791	#endif
792	!!======================================================================
793	END MODULE nemogcm

Note: See TracBrowser for help on using the repository browser.

Download in other formats: