New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diahsb.F90 in branches/2012/dev_v3_4_STABLE_2012/NEMOGCM/NEMO/OPA_SRC/DIA – NEMO

source: branches/2012/dev_v3_4_STABLE_2012/NEMOGCM/NEMO/OPA_SRC/DIA/diahsb.F90 @ 4612

Last change on this file since 4612 was 4076, checked in by cetlod, 11 years ago

v3_4 stable: minor correction, see ticket #1161
  • Property svn:keywords set to Id
File size: 16.2 KB
Line 
1MODULE diahsb
2   !!======================================================================
3   !!                       ***  MODULE  diahsb  ***
4   !! Ocean diagnostics: Heat, salt and volume budgets
5   !!======================================================================
6   !! History :  3.3  ! 2010-09  (M. Leclair)  Original code
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   USE oce             ! ocean dynamics and tracers
11   USE dom_oce         ! ocean space and time domain
12   USE phycst          ! physical constants
13   USE sbc_oce         ! surface thermohaline fluxes
14   USE in_out_manager  ! I/O manager
15   USE domvvl          ! vertical scale factors
16   USE traqsr          ! penetrative solar radiation
17   USE trabbc          ! bottom boundary condition
18   USE lib_mpp         ! distributed memory computing library
19   USE trabbc          ! bottom boundary condition
20   USE obc_par         ! (for lk_obc)
21   USE bdy_par         ! (for lk_bdy)
22   USE timing          ! preformance summary
23   USE lib_fortran
24   USE sbcrnf
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   dia_hsb        ! routine called by step.F90
30   PUBLIC   dia_hsb_init   ! routine called by opa.F90
31
32   LOGICAL, PUBLIC ::   ln_diahsb  = .FALSE.   !: check the heat and salt budgets
33
34   INTEGER                                 ::   numhsb                           !
35   REAL(dp)                                ::   surf_tot   , vol_tot             !
36   REAL(dp)                                ::   frc_t      , frc_s     , frc_v   ! global forcing trends
37   REAL(dp)                                ::   frc_wn_t      , frc_wn_s ! global forcing trends
38   REAL(dp)                                ::   fact1                            ! conversion factors
39   REAL(dp)                                ::   fact21    , fact22               !     -         -
40   REAL(dp)                                ::   fact31    , fact32               !     -         -
41   REAL(dp), DIMENSION(:,:)  , ALLOCATABLE ::   surf      , ssh_ini              !
42   REAL(dp), DIMENSION(:,:,:), ALLOCATABLE ::   hc_loc_ini, sc_loc_ini, e3t_ini  !
43   REAL(dp), DIMENSION(:,:)  , ALLOCATABLE ::   ssh_hc_loc_ini, ssh_sc_loc_ini
44
45   !! * Substitutions
46#  include "domzgr_substitute.h90"
47#  include "vectopt_loop_substitute.h90"
48
49   !!----------------------------------------------------------------------
50   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
51   !! $Id$
52   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
53   !!----------------------------------------------------------------------
54
55CONTAINS
56
57   SUBROUTINE dia_hsb( kt )
58      !!---------------------------------------------------------------------------
59      !!                  ***  ROUTINE dia_hsb  ***
60      !!     
61      !! ** Purpose: Compute the ocean global heat content, salt content and volume conservation
62      !!
63      !! ** Method : - Compute the deviation of heat content, salt content and volume
64      !!             at the current time step from their values at nit000
65      !!             - Compute the contribution of forcing and remove it from these deviations
66      !!
67      !! ** Action : Write the results in the 'heat_salt_volume_budgets.txt' ASCII file
68      !!---------------------------------------------------------------------------
69      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
70      !!
71      INTEGER    ::   jk                          ! dummy loop indice
72      REAL(dp)   ::   zdiff_hc    , zdiff_sc      ! heat and salt content variations
73      REAL(dp)   ::   zdiff_hc1   , zdiff_sc1     ! heat and salt content variations of ssh
74      REAL(dp)   ::   zdiff_v1    , zdiff_v2      ! volume variation
75      REAL(dp)   ::   zerr_hc1    , zerr_sc1      ! Non conservation due to free surface
76      REAL(dp)   ::   z1_rau0                     ! local scalars
77      REAL(dp)   ::   zdeltat                     !    -     -
78      REAL(dp)   ::   z_frc_trd_t , z_frc_trd_s   !    -     -
79      REAL(dp)   ::   z_frc_trd_v                 !    -     -
80      REAL(dp)   ::   z_wn_trd_t , z_wn_trd_s   !    -     -
81      REAL(dp)   ::   z_ssh_hc , z_ssh_sc   !    -     -
82      !!---------------------------------------------------------------------------
83      IF( nn_timing == 1 )   CALL timing_start('dia_hsb')
84
85      ! ------------------------- !
86      ! 1 - Trends due to forcing !
87      ! ------------------------- !
88      z1_rau0 = 1.e0 / rau0
89      z_frc_trd_v = z1_rau0 * glob_sum( - ( emp(:,:) - rnf(:,:) ) * surf(:,:) )     ! volume fluxes
90      z_frc_trd_t =           glob_sum( sbc_tsc(:,:,jp_tem) * surf(:,:) )     ! heat fluxes
91      z_frc_trd_s =           glob_sum( sbc_tsc(:,:,jp_sal) * surf(:,:) )     ! salt fluxes
92      ! Add runoff heat & salt input
93      IF( ln_rnf    )   z_frc_trd_t = z_frc_trd_t + glob_sum( rnf_tsc(:,:,jp_tem) * surf(:,:) )
94      IF( ln_rnf_sal)   z_frc_trd_s = z_frc_trd_s + glob_sum( rnf_tsc(:,:,jp_sal) * surf(:,:) )
95      ! Add penetrative solar radiation
96      IF( ln_traqsr )   z_frc_trd_t = z_frc_trd_t + ro0cpr * glob_sum( qsr     (:,:) * surf(:,:) )
97      ! Add geothermal heat flux
98      IF( ln_trabbc )   z_frc_trd_t = z_frc_trd_t +  glob_sum( qgh_trd0(:,:) * surf(:,:) )
99      IF( .NOT. lk_vvl ) THEN
100         z_wn_trd_t = - glob_sum( surf(:,:) * wn(:,:,1) * tsb(:,:,1,jp_tem) )
101         z_wn_trd_s = - glob_sum( surf(:,:) * wn(:,:,1) * tsb(:,:,1,jp_sal) )
102      ENDIF
103
104      frc_v = frc_v + z_frc_trd_v * rdt
105      frc_t = frc_t + z_frc_trd_t * rdt
106      frc_s = frc_s + z_frc_trd_s * rdt
107      !                                          ! Advection flux through fixed surface (z=0)
108      IF( .NOT. lk_vvl ) THEN
109         frc_wn_t = frc_wn_t + z_wn_trd_t * rdt
110         frc_wn_s = frc_wn_s + z_wn_trd_s * rdt
111      ENDIF
112
113      ! ----------------------- !
114      ! 2 -  Content variations !
115      ! ----------------------- !
116      zdiff_v2 = 0.d0
117      zdiff_hc = 0.d0
118      zdiff_sc = 0.d0
119
120      ! volume variation (calculated with ssh)
121      zdiff_v1 = glob_sum( surf(:,:) * ( sshn(:,:) - ssh_ini(:,:) ) )
122
123      ! heat & salt content variation (associated with ssh)
124      IF( .NOT. lk_vvl ) THEN
125         z_ssh_hc = glob_sum( surf(:,:) * ( tsn(:,:,1,jp_tem) * sshn(:,:) - ssh_hc_loc_ini(:,:) ) )
126         z_ssh_sc = glob_sum( surf(:,:) * ( tsn(:,:,1,jp_sal) * sshn(:,:) - ssh_sc_loc_ini(:,:) ) )
127      ENDIF
128
129      DO jk = 1, jpkm1
130        ! volume variation (calculated with scale factors)
131         zdiff_v2 = zdiff_v2 + glob_sum( surf(:,:) * tmask(:,:,jk)   &
132            &                       * ( fse3t_n(:,:,jk)         &
133            &                           - e3t_ini(:,:,jk) ) )
134         ! heat content variation
135         zdiff_hc = zdiff_hc + glob_sum( surf(:,:) * tmask(:,:,jk)          &
136            &                       * ( fse3t_n(:,:,jk) * tsn(:,:,jk,jp_tem)   &
137            &                           - hc_loc_ini(:,:,jk) ) )
138         ! salt content variation
139         zdiff_sc = zdiff_sc + glob_sum( surf(:,:) * tmask(:,:,jk)          &
140            &                       * ( fse3t_n(:,:,jk) * tsn(:,:,jk,jp_sal)   &
141            &                           - sc_loc_ini(:,:,jk) ) )
142      ENDDO
143
144      ! Substract forcing from heat content, salt content and volume variations
145      zdiff_v1 = zdiff_v1 - frc_v
146      IF( lk_vvl )   zdiff_v2 = zdiff_v2 - frc_v
147      zdiff_hc = zdiff_hc - frc_t
148      zdiff_sc = zdiff_sc - frc_s
149      IF( .NOT. lk_vvl ) THEN
150         zdiff_hc1 = zdiff_hc + z_ssh_hc 
151         zdiff_sc1 = zdiff_sc + z_ssh_sc
152         zerr_hc1  = z_ssh_hc - frc_wn_t
153         zerr_sc1  = z_ssh_sc - frc_wn_s
154      ENDIF
155     
156      ! ----------------------- !
157      ! 3 - Diagnostics writing !
158      ! ----------------------- !
159      zdeltat  = 1.e0 / ( ( kt - nit000 + 1 ) * rdt )
160      IF( lk_vvl ) THEN
161         WRITE(numhsb , 9020) kt , zdiff_hc / vol_tot , zdiff_hc * fact1  * zdeltat,                                &
162            &                      zdiff_sc / vol_tot , zdiff_sc * fact21 * zdeltat, zdiff_sc * fact22 * zdeltat,   &
163            &                      zdiff_v1           , zdiff_v1 * fact31 * zdeltat, zdiff_v1 * fact32 * zdeltat,   &
164            &                      zdiff_v2           , zdiff_v2 * fact31 * zdeltat, zdiff_v2 * fact32 * zdeltat
165      ELSE
166         WRITE(numhsb , 9030) kt , zdiff_hc1 / vol_tot , zdiff_hc1 * fact1  * zdeltat,                                &
167            &                      zdiff_sc1 / vol_tot , zdiff_sc1 * fact21 * zdeltat, zdiff_sc1 * fact22 * zdeltat,   &
168            &                      zdiff_v1            , zdiff_v1  * fact31 * zdeltat, zdiff_v1  * fact32 * zdeltat,   &
169            &                      zerr_hc1 / vol_tot  , zerr_sc1 / vol_tot
170      ENDIF
171
172      IF ( kt == nitend ) CLOSE( numhsb )
173
174      IF( nn_timing == 1 )   CALL timing_stop('dia_hsb')
175
1769020  FORMAT(I5,11D15.7)
1779030  FORMAT(I5,10D15.7)
178      !
179   END SUBROUTINE dia_hsb
180
181
182   SUBROUTINE dia_hsb_init
183      !!---------------------------------------------------------------------------
184      !!                  ***  ROUTINE dia_hsb  ***
185      !!     
186      !! ** Purpose: Initialization for the heat salt volume budgets
187      !!
188      !! ** Method : Compute initial heat content, salt content and volume
189      !!
190      !! ** Action : - Compute initial heat content, salt content and volume
191      !!             - Initialize forcing trends
192      !!             - Compute coefficients for conversion
193      !!---------------------------------------------------------------------------
194      CHARACTER (len=32) ::   cl_name  ! output file name
195      INTEGER            ::   jk       ! dummy loop indice
196      INTEGER            ::   ierror   ! local integer
197      !!
198      NAMELIST/namhsb/ ln_diahsb
199      !!----------------------------------------------------------------------
200      !
201      REWIND ( numnam )              ! Read Namelist namhsb
202      READ   ( numnam, namhsb )
203      !
204      IF(lwp) THEN                   ! Control print
205         WRITE(numout,*)
206         WRITE(numout,*) 'dia_hsb_init : check the heat and salt budgets'
207         WRITE(numout,*) '~~~~~~~~~~~~'
208         WRITE(numout,*) '   Namelist namhsb : set hsb parameters'
209         WRITE(numout,*) '      Switch for hsb diagnostic (T) or not (F)  ln_diahsb  = ', ln_diahsb
210      ENDIF
211
212      IF( .NOT. ln_diahsb )   RETURN
213      IF( .NOT. lk_mpp_rep ) &
214        CALL ctl_stop (' Your global mpp_sum if performed in single precision - 64 bits -', &
215             &         ' whereas the global sum to be precise must be done in double precision ',&
216             &         ' please add key_mpp_rep')
217
218      ! ------------------- !
219      ! 1 - Allocate memory !
220      ! ------------------- !
221      ALLOCATE( hc_loc_ini(jpi,jpj,jpk), sc_loc_ini(jpi,jpj,jpk), &
222         &      ssh_hc_loc_ini(jpi,jpj), ssh_sc_loc_ini(jpi,jpj), &
223         &      e3t_ini(jpi,jpj,jpk)                            , &
224         &      surf(jpi,jpj),  ssh_ini(jpi,jpj), STAT=ierror )
225      IF( ierror > 0 ) THEN
226         CALL ctl_stop( 'dia_hsb: unable to allocate hc_loc_ini' )   ;   RETURN
227      ENDIF
228
229      ! ----------------------------------------------- !
230      ! 2 - Time independant variables and file opening !
231      ! ----------------------------------------------- !
232      WRITE(numout,*) "dia_hsb: heat salt volume budgets activated"
233      WRITE(numout,*) "~~~~~~~  output written in the 'heat_salt_volume_budgets.txt' ASCII file"
234      IF( lk_obc .or. lk_bdy ) THEN
235         CALL ctl_warn( 'dia_hsb does not take open boundary fluxes into account' )         
236      ENDIF
237      cl_name    = 'heat_salt_volume_budgets.txt'                         ! name of output file
238      surf(:,:) = e1t(:,:) * e2t(:,:) * tmask(:,:,1) * tmask_i(:,:)      ! masked surface grid cell area
239      surf_tot  = glob_sum( surf(:,:) )                                       ! total ocean surface area
240      vol_tot   = 0.d0                                                   ! total ocean volume
241      DO jk = 1, jpkm1
242         vol_tot  = vol_tot + glob_sum( surf(:,:) * tmask(:,:,jk)     &
243            &                         * fse3t_n(:,:,jk)         )
244      END DO
245
246      CALL ctl_opn( numhsb , cl_name , 'UNKNOWN' , 'FORMATTED' , 'SEQUENTIAL' , 1 , numout , lwp , 1 )
247      IF( lk_vvl ) THEN
248         !                   12345678901234567890123456789012345678901234567890123456789012345678901234567890 -> 80
249         WRITE( numhsb, 9010 ) "kt   |     heat content budget     |            salt content budget             ",   &
250            !                                                   123456789012345678901234567890123456789012345 -> 45
251            &                                                  "|            volume budget (ssh)             ",   &
252            !                                                   678901234567890123456789012345678901234567890 -> 45
253            &                                                  "|            volume budget (e3t)             "
254         WRITE( numhsb, 9010 ) "     |      [C]         [W/m2]     |     [psu]        [mmm/s]          [SV]     ",   &
255            &                                                  "|     [m3]         [mmm/s]          [SV]     ",   &
256            &                                                  "|     [m3]         [mmm/s]          [SV]     "
257      ELSE
258         !                   12345678901234567890123456789012345678901234567890123456789012345678901234567890 -> 80
259         WRITE( numhsb, 9011 ) "kt   |     heat content budget     |            salt content budget             ",   &
260            !                                                   123456789012345678901234567890123456789012345 -> 45
261            &                                                  "|            volume budget (ssh)             ",   &
262            !                                                   678901234567890123456789012345678901234567890 -> 45
263            &                                                  "|  Non conservation due to free surface      "
264         WRITE( numhsb, 9011 ) "     |      [C]         [W/m2]     |     [psu]        [mmm/s]          [SV]     ",   &
265            &                                                  "|     [m3]         [mmm/s]          [SV]     ",   &
266            &                                                  "|  [heat - C]     [salt - psu]                "
267      ENDIF
268      ! --------------- !
269      ! 3 - Conversions ! (factors will be multiplied by duration afterwards)
270      ! --------------- !
271
272      ! heat content variation   =>   equivalent heat flux:
273      fact1  = rau0 * rcp / surf_tot                                         ! [C*m3]   ->  [W/m2]
274      ! salt content variation   =>   equivalent EMP and equivalent "flow":
275      fact21 = 1.e3  / ( soce * surf_tot )                                   ! [psu*m3] ->  [mm/s]
276      fact22 = 1.e-6 / soce                                                  ! [psu*m3] ->  [Sv]
277      ! volume variation         =>   equivalent EMP and equivalent "flow":
278      fact31 = 1.e3  / surf_tot                                              ! [m3]     ->  [mm/s]
279      fact32 = 1.e-6                                                         ! [m3]     ->  [SV]
280
281      ! ---------------------------------- !
282      ! 4 - initial conservation variables !
283      ! ---------------------------------- !
284      ssh_ini(:,:) = sshn(:,:)                                       ! initial ssh
285      DO jk = 1, jpk
286         e3t_ini   (:,:,jk) = fse3t_n(:,:,jk)                        ! initial vertical scale factors
287         hc_loc_ini(:,:,jk) = tsn(:,:,jk,jp_tem) * fse3t_n(:,:,jk)   ! initial heat content
288         sc_loc_ini(:,:,jk) = tsn(:,:,jk,jp_sal) * fse3t_n(:,:,jk)   ! initial salt content
289      END DO
290      frc_v = 0.d0                                           ! volume       trend due to forcing
291      frc_t = 0.d0                                           ! heat content   -    -   -    -   
292      frc_s = 0.d0                                           ! salt content   -    -   -    -         
293      IF( .NOT. lk_vvl ) THEN
294         ssh_hc_loc_ini(:,:) = tsn(:,:,1,jp_tem) * ssh_ini(:,:)   ! initial heat content associated with ssh
295         ssh_sc_loc_ini(:,:) = tsn(:,:,1,jp_sal) * ssh_ini(:,:)   ! initial salt content associated with ssh
296         frc_wn_t = 0.d0
297         frc_wn_s = 0.d0
298      ENDIF
299      !
3009010  FORMAT(A80,A45,A45)
3019011  FORMAT(A80,A45,A45)
302      !
303   END SUBROUTINE dia_hsb_init
304
305   !!======================================================================
306END MODULE diahsb
Note: See TracBrowser for help on using the repository browser.