New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traqsr.F90 in branches/2012/dev_v3_4_STABLE_2012/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2012/dev_v3_4_STABLE_2012/NEMOGCM/NEMO/OPA_SRC/TRA/traqsr.F90 @ 4836

Last change on this file since 4836 was 4836, checked in by flavoni, 9 years ago

add initialization of qsr_hc array, see ticket #1407
  • Property svn:keywords set to Id
File size: 27.1 KB
Line 
1MODULE traqsr
2   !!======================================================================
3   !!                       ***  MODULE  traqsr  ***
4   !! Ocean physics: solar radiation penetration in the top ocean levels
5   !!======================================================================
6   !! History :  OPA  !  1990-10  (B. Blanke)  Original code
7   !!            7.0  !  1991-11  (G. Madec)
8   !!                 !  1996-01  (G. Madec)  s-coordinates
9   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
10   !!             -   !  2005-11  (G. Madec) zco, zps, sco coordinate
11   !!            3.2  !  2009-04  (G. Madec & NEMO team)
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_qsr      : trend due to the solar radiation penetration
16   !!   tra_qsr_init : solar radiation penetration initialization
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and active tracers
19   USE dom_oce         ! ocean space and time domain
20   USE sbc_oce         ! surface boundary condition: ocean
21   USE trc_oce         ! share SMS/Ocean variables
22   USE trdmod_oce      ! ocean variables trends
23   USE trdtra          ! ocean active tracers trends
24   USE in_out_manager  ! I/O manager
25   USE phycst          ! physical constants
26   USE prtctl          ! Print control
27   USE iom             ! I/O manager
28   USE fldread         ! read input fields
29   USE restart         ! ocean restart
30   USE lib_mpp         ! MPP library
31   USE wrk_nemo       ! Memory Allocation
32   USE timing         ! Timing
33
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   tra_qsr       ! routine called by step.F90 (ln_traqsr=T)
39   PUBLIC   tra_qsr_init  ! routine called by opa.F90
40
41   !                                           !!* Namelist namtra_qsr: penetrative solar radiation
42   LOGICAL , PUBLIC ::   ln_traqsr  = .TRUE.    !: light absorption (qsr) flag
43   LOGICAL , PUBLIC ::   ln_qsr_rgb = .FALSE.   !: Red-Green-Blue light absorption flag 
44   LOGICAL , PUBLIC ::   ln_qsr_2bd = .TRUE.    !: 2 band         light absorption flag
45   LOGICAL , PUBLIC ::   ln_qsr_bio = .FALSE.   !: bio-model      light absorption flag
46   INTEGER , PUBLIC ::   nn_chldta  = 0         !: use Chlorophyll data (=1) or not (=0)
47   REAL(wp), PUBLIC ::   rn_abs     = 0.58_wp   !: fraction absorbed in the very near surface (RGB & 2 bands)
48   REAL(wp), PUBLIC ::   rn_si0     = 0.35_wp   !: very near surface depth of extinction      (RGB & 2 bands)
49   REAL(wp), PUBLIC ::   rn_si1     = 23.0_wp   !: deepest depth of extinction (water type I)       (2 bands)
50   
51   ! Module variables
52   REAL(wp) ::   xsi0r                           !: inverse of rn_si0
53   REAL(wp) ::   xsi1r                           !: inverse of rn_si1
54   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_chl   ! structure of input Chl (file informations, fields read)
55   INTEGER, PUBLIC ::   nksr              ! levels below which the light cannot penetrate ( depth larger than 391 m)
56   REAL(wp), DIMENSION(3,61) ::   rkrgb   !: tabulated attenuation coefficients for RGB absorption
57
58   !! * Substitutions
59#  include "domzgr_substitute.h90"
60#  include "vectopt_loop_substitute.h90"
61   !!----------------------------------------------------------------------
62   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
63   !! $Id$
64   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE tra_qsr( kt )
69      !!----------------------------------------------------------------------
70      !!                  ***  ROUTINE tra_qsr  ***
71      !!
72      !! ** Purpose :   Compute the temperature trend due to the solar radiation
73      !!      penetration and add it to the general temperature trend.
74      !!
75      !! ** Method  : The profile of the solar radiation within the ocean is defined
76      !!      through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs
77      !!      Considering the 2 wavebands case:
78      !!         I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) )
79      !!         The temperature trend associated with the solar radiation penetration
80      !!         is given by : zta = 1/e3t dk[ I ] / (rau0*Cp)
81      !!         At the bottom, boudary condition for the radiation is no flux :
82      !!      all heat which has not been absorbed in the above levels is put
83      !!      in the last ocean level.
84      !!         In z-coordinate case, the computation is only done down to the
85      !!      level where I(k) < 1.e-15 W/m2. In addition, the coefficients
86      !!      used for the computation are calculated one for once as they
87      !!      depends on k only.
88      !!
89      !! ** Action  : - update ta with the penetrative solar radiation trend
90      !!              - save the trend in ttrd ('key_trdtra')
91      !!
92      !! Reference  : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
93      !!              Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516.
94      !!----------------------------------------------------------------------
95      !
96      INTEGER, INTENT(in) ::   kt     ! ocean time-step
97      !
98      INTEGER  ::   ji, jj, jk           ! dummy loop indices
99      INTEGER  ::   irgb                 ! local integers
100      REAL(wp) ::   zchl, zcoef, zfact   ! local scalars
101      REAL(wp) ::   zc0, zc1, zc2, zc3   !    -         -
102      REAL(wp) ::   zz0, zz1, z1_e3t     !    -         -
103      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
104      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea, ztrdt
105      !!----------------------------------------------------------------------
106      !
107      IF( nn_timing == 1 )  CALL timing_start('tra_qsr')
108      !
109      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        ) 
110      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
111      !
112      IF( kt == nit000 ) THEN
113         IF(lwp) WRITE(numout,*)
114         IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation'
115         IF(lwp) WRITE(numout,*) '~~~~~~~'
116         IF( .NOT.ln_traqsr )   RETURN
117      ENDIF
118
119      IF( l_trdtra ) THEN      ! Save ta and sa trends
120         CALL wrk_alloc( jpi, jpj, jpk, ztrdt ) 
121         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
122      ENDIF
123
124      !                                        Set before qsr tracer content field
125      !                                        ***********************************
126      IF( kt == nit000 ) THEN                     ! Set the forcing field at nit000 - 1
127         !                                        ! -----------------------------------
128         qsr_hc(:,:,:) = 0.e0
129         !
130         IF( ln_rstart .AND.    &                    ! Restart: read in restart file
131              & iom_varid( numror, 'qsr_hc_b', ldstop = .FALSE. ) > 0 ) THEN
132            IF(lwp) WRITE(numout,*) '          nit000-1 qsr tracer content forcing field red in the restart file'
133            zfact = 0.5e0
134            CALL iom_get( numror, jpdom_autoglo, 'qsr_hc_b', qsr_hc_b )   ! before heat content trend due to Qsr flux
135         ELSE                                           ! No restart or restart not found: Euler forward time stepping
136            zfact = 1.e0
137            qsr_hc_b(:,:,:) = 0.e0
138         ENDIF
139      ELSE                                        ! Swap of forcing field
140         !                                        ! ---------------------
141         zfact = 0.5e0
142         qsr_hc_b(:,:,:) = qsr_hc(:,:,:)
143      ENDIF
144      !                                        Compute now qsr tracer content field
145      !                                        ************************************
146     
147      !                                           ! ============================================== !
148      IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN      !  bio-model fluxes  : all vertical coordinates  !
149         !                                        ! ============================================== !
150         DO jk = 1, jpkm1
151            qsr_hc(:,:,jk) = ro0cpr * ( etot3(:,:,jk) - etot3(:,:,jk+1) )
152         END DO
153         !                                        Add to the general trend
154         DO jk = 1, jpkm1
155            DO jj = 2, jpjm1 
156               DO ji = fs_2, fs_jpim1   ! vector opt.
157                  z1_e3t = zfact / fse3t(ji,jj,jk)
158                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
159               END DO
160            END DO
161         END DO
162         CALL iom_put( 'qsr3d', etot3 )   ! Shortwave Radiation 3D distribution
163         !                                        ! ============================================== !
164      ELSE                                        !  Ocean alone :
165         !                                        ! ============================================== !
166         !
167         !                                                ! ------------------------- !
168         IF( ln_qsr_rgb) THEN                             !  R-G-B  light penetration !
169            !                                             ! ------------------------- !
170            ! Set chlorophyl concentration
171            IF( nn_chldta == 1 .OR. lk_vvl ) THEN            !*  Variable Chlorophyll or ocean volume
172               !
173               IF( nn_chldta == 1 ) THEN                             !*  Variable Chlorophyll
174                  !
175                  CALL fld_read( kt, 1, sf_chl )                         ! Read Chl data and provides it at the current time step
176                  !         
177!CDIR COLLAPSE
178!CDIR NOVERRCHK
179                  DO jj = 1, jpj                                         ! Separation in R-G-B depending of the surface Chl
180!CDIR NOVERRCHK
181                     DO ji = 1, jpi
182                        zchl = MIN( 10. , MAX( 0.03, sf_chl(1)%fnow(ji,jj,1) ) )
183                        irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
184                        zekb(ji,jj) = rkrgb(1,irgb)
185                        zekg(ji,jj) = rkrgb(2,irgb)
186                        zekr(ji,jj) = rkrgb(3,irgb)
187                     END DO
188                  END DO
189               ELSE                                            ! Variable ocean volume but constant chrlorophyll
190                  zchl = 0.05                                     ! constant chlorophyll
191                  irgb = NINT( 41 + 20.*LOG10( zchl ) + 1.e-15 )
192                  zekb(:,:) = rkrgb(1,irgb)                       ! Separation in R-G-B depending of the chlorophyll
193                  zekg(:,:) = rkrgb(2,irgb)
194                  zekr(:,:) = rkrgb(3,irgb)
195               ENDIF
196               !
197               zcoef  = ( 1. - rn_abs ) / 3.e0                        ! equi-partition in R-G-B
198               ze0(:,:,1) = rn_abs  * qsr(:,:)
199               ze1(:,:,1) = zcoef * qsr(:,:)
200               ze2(:,:,1) = zcoef * qsr(:,:)
201               ze3(:,:,1) = zcoef * qsr(:,:)
202               zea(:,:,1) =         qsr(:,:)
203               !
204               DO jk = 2, nksr+1
205!CDIR NOVERRCHK
206                  DO jj = 1, jpj
207!CDIR NOVERRCHK   
208                     DO ji = 1, jpi
209                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r     )
210                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) )
211                        zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) )
212                        zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) )
213                        ze0(ji,jj,jk) = zc0
214                        ze1(ji,jj,jk) = zc1
215                        ze2(ji,jj,jk) = zc2
216                        ze3(ji,jj,jk) = zc3
217                        zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
218                     END DO
219                  END DO
220               END DO
221               !
222               DO jk = 1, nksr                                        ! compute and add qsr trend to ta
223                  qsr_hc(:,:,jk) = ro0cpr * ( zea(:,:,jk) - zea(:,:,jk+1) )
224               END DO
225               zea(:,:,nksr+1:jpk) = 0.e0     ! below 400m set to zero
226               CALL iom_put( 'qsr3d', zea )   ! Shortwave Radiation 3D distribution
227               !
228            ELSE                                                 !*  Constant Chlorophyll
229               DO jk = 1, nksr
230                  qsr_hc(:,:,jk) =  etot3(:,:,jk) * qsr(:,:)
231               END DO
232            ENDIF
233
234         ENDIF
235         !                                                ! ------------------------- !
236         IF( ln_qsr_2bd ) THEN                            !  2 band light penetration !
237            !                                             ! ------------------------- !
238            !
239            IF( lk_vvl ) THEN                                  !* variable volume
240               zz0   =        rn_abs   * ro0cpr
241               zz1   = ( 1. - rn_abs ) * ro0cpr
242               DO jk = 1, nksr                    ! solar heat absorbed at T-point in the top 400m
243                  DO jj = 1, jpj
244                     DO ji = 1, jpi
245                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
246                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
247                        qsr_hc(ji,jj,jk) = qsr(ji,jj) * ( zc0*tmask(ji,jj,jk) - zc1*tmask(ji,jj,jk+1) ) 
248                     END DO
249                  END DO
250               END DO
251            ELSE                                               !* constant volume: coef. computed one for all
252               DO jk = 1, nksr
253                  DO jj = 2, jpjm1
254                     DO ji = fs_2, fs_jpim1   ! vector opt.
255                        qsr_hc(ji,jj,jk) =  etot3(ji,jj,jk) * qsr(ji,jj)
256                     END DO
257                  END DO
258               END DO
259               !
260            ENDIF
261            !
262         ENDIF
263         !
264         !                                        Add to the general trend
265         DO jk = 1, nksr
266            DO jj = 2, jpjm1 
267               DO ji = fs_2, fs_jpim1   ! vector opt.
268                  z1_e3t = zfact / fse3t(ji,jj,jk)
269                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
270               END DO
271            END DO
272         END DO
273         !
274      ENDIF
275      !
276      IF( lrst_oce ) THEN   !                  Write in the ocean restart file
277         !                                     *******************************
278         IF(lwp) WRITE(numout,*)
279         IF(lwp) WRITE(numout,*) 'qsr tracer content forcing field written in ocean restart file ',   &
280            &                    'at it= ', kt,' date= ', ndastp
281         IF(lwp) WRITE(numout,*) '~~~~'
282         CALL iom_rstput( kt, nitrst, numrow, 'qsr_hc_b', qsr_hc )
283         !
284      ENDIF
285
286      IF( l_trdtra ) THEN     ! qsr tracers trends saved for diagnostics
287         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
288         CALL trd_tra( kt, 'TRA', jp_tem, jptra_trd_qsr, ztrdt )
289         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt ) 
290      ENDIF
291      !                       ! print mean trends (used for debugging)
292      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' qsr  - Ta: ', mask1=tmask, clinfo3='tra-ta' )
293      !
294      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        ) 
295      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
296      !
297      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr')
298      !
299   END SUBROUTINE tra_qsr
300
301
302   SUBROUTINE tra_qsr_init
303      !!----------------------------------------------------------------------
304      !!                  ***  ROUTINE tra_qsr_init  ***
305      !!
306      !! ** Purpose :   Initialization for the penetrative solar radiation
307      !!
308      !! ** Method  :   The profile of solar radiation within the ocean is set
309      !!      from two length scale of penetration (rn_si0,rn_si1) and a ratio
310      !!      (rn_abs). These parameters are read in the namtra_qsr namelist. The
311      !!      default values correspond to clear water (type I in Jerlov'
312      !!      (1968) classification.
313      !!         called by tra_qsr at the first timestep (nit000)
314      !!
315      !! ** Action  : - initialize rn_si0, rn_si1 and rn_abs
316      !!
317      !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
318      !!----------------------------------------------------------------------
319      !
320      INTEGER  ::   ji, jj, jk     ! dummy loop indices
321      INTEGER  ::   irgb, ierror, ioptio, nqsr   ! local integer
322      REAL(wp) ::   zz0, zc0  , zc1, zcoef       ! local scalars
323      REAL(wp) ::   zz1, zc2  , zc3, zchl        !   -      -
324      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
325      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea
326      !
327      CHARACTER(len=100) ::   cn_dir   ! Root directory for location of ssr files
328      TYPE(FLD_N)        ::   sn_chl   ! informations about the chlorofyl field to be read
329      !!
330      NAMELIST/namtra_qsr/  sn_chl, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio,   &
331         &                  nn_chldta, rn_abs, rn_si0, rn_si1
332      !!----------------------------------------------------------------------
333
334      !
335      IF( nn_timing == 1 )  CALL timing_start('tra_qsr_init')
336      !
337      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        ) 
338      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
339      !
340
341      cn_dir = './'       ! directory in which the model is executed
342      ! ... default values (NB: frequency positive => hours, negative => months)
343      !            !     file       ! frequency !  variable  ! time interp !  clim   ! 'yearly' or ! weights  ! rotation   !
344      !            !     name       !  (hours)  !    name    !    (T/F)    !  (T/F)  ! 'monthly'   ! filename ! pairs      !
345      sn_chl = FLD_N( 'chlorophyll' ,    -1     ,  'CHLA'    ,  .true.     , .true.  ,   'yearly'  , ''       , ''         )
346      !
347      REWIND( numnam )            ! Read Namelist namtra_qsr : ratio and length of penetration
348      READ  ( numnam, namtra_qsr )
349      !
350      IF(lwp) THEN                ! control print
351         WRITE(numout,*)
352         WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation'
353         WRITE(numout,*) '~~~~~~~~~~~~'
354         WRITE(numout,*) '   Namelist namtra_qsr : set the parameter of penetration'
355         WRITE(numout,*) '      Light penetration (T) or not (F)         ln_traqsr  = ', ln_traqsr
356         WRITE(numout,*) '      RGB (Red-Green-Blue) light penetration   ln_qsr_rgb = ', ln_qsr_rgb
357         WRITE(numout,*) '      2 band               light penetration   ln_qsr_2bd = ', ln_qsr_2bd
358         WRITE(numout,*) '      bio-model            light penetration   ln_qsr_bio = ', ln_qsr_bio
359         WRITE(numout,*) '      RGB : Chl data (=1) or cst value (=0)    nn_chldta  = ', nn_chldta
360         WRITE(numout,*) '      RGB & 2 bands: fraction of light (rn_si1)    rn_abs = ', rn_abs
361         WRITE(numout,*) '      RGB & 2 bands: shortess depth of extinction  rn_si0 = ', rn_si0
362         WRITE(numout,*) '      2 bands: longest depth of extinction         rn_si1 = ', rn_si1
363      ENDIF
364
365      IF( ln_traqsr ) THEN     ! control consistency
366         !                     
367         IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio )   THEN
368            CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' )
369            ln_qsr_bio = .FALSE.
370         ENDIF
371         !
372         ioptio = 0                      ! Parameter control
373         IF( ln_qsr_rgb  )   ioptio = ioptio + 1
374         IF( ln_qsr_2bd  )   ioptio = ioptio + 1
375         IF( ln_qsr_bio  )   ioptio = ioptio + 1
376         !
377         IF( ioptio /= 1 ) &
378            CALL ctl_stop( '          Choose ONE type of light penetration in namelist namtra_qsr',  &
379            &              ' 2 bands, 3 RGB bands or bio-model light penetration' )
380         !
381         IF( ln_qsr_rgb .AND. nn_chldta == 0 )   nqsr =  1 
382         IF( ln_qsr_rgb .AND. nn_chldta == 1 )   nqsr =  2
383         IF( ln_qsr_2bd                      )   nqsr =  3
384         IF( ln_qsr_bio                      )   nqsr =  4
385         !
386         IF(lwp) THEN                   ! Print the choice
387            WRITE(numout,*)
388            IF( nqsr ==  1 )   WRITE(numout,*) '         R-G-B   light penetration - Constant Chlorophyll'
389            IF( nqsr ==  2 )   WRITE(numout,*) '         R-G-B   light penetration - Chl data '
390            IF( nqsr ==  3 )   WRITE(numout,*) '         2 bands light penetration'
391            IF( nqsr ==  4 )   WRITE(numout,*) '         bio-model light penetration'
392         ENDIF
393         !
394      ENDIF
395      !                          ! ===================================== !
396      IF( ln_traqsr  ) THEN      !  Initialisation of Light Penetration  ! 
397         !                       ! ===================================== !
398         !
399         xsi0r = 1.e0 / rn_si0
400         xsi1r = 1.e0 / rn_si1
401         !                                ! ---------------------------------- !
402         IF( ln_qsr_rgb ) THEN            !  Red-Green-Blue light penetration  !
403            !                             ! ---------------------------------- !
404            !
405            CALL trc_oce_rgb( rkrgb )           !* tabulated attenuation coef.
406            !
407            !                                   !* level of light extinction
408            IF(  ln_sco ) THEN   ;   nksr = jpkm1
409            ELSE                 ;   nksr = trc_oce_ext_lev( r_si2, 0.33e2 )
410            ENDIF
411
412            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m'
413            !
414            IF( nn_chldta == 1 ) THEN           !* Chl data : set sf_chl structure
415               IF(lwp) WRITE(numout,*)
416               IF(lwp) WRITE(numout,*) '        Chlorophyll read in a file'
417               ALLOCATE( sf_chl(1), STAT=ierror )
418               IF( ierror > 0 ) THEN
419                  CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' )   ;   RETURN
420               ENDIF
421               ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1)   )
422               IF( sn_chl%ln_tint )ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) )
423               !                                        ! fill sf_chl with sn_chl and control print
424               CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init',   &
425                  &                                         'Solar penetration function of read chlorophyll', 'namtra_qsr' )
426               !
427            ELSE                                !* constant Chl : compute once for all the distribution of light (etot3)
428               IF(lwp) WRITE(numout,*)
429               IF(lwp) WRITE(numout,*) '        Constant Chlorophyll concentration = 0.05'
430               IF( lk_vvl ) THEN                   ! variable volume
431                  IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
432               ELSE                                ! constant volume: computes one for all
433                  IF(lwp) WRITE(numout,*) '        fixed volume: light distribution computed one for all'
434                  !
435                  zchl = 0.05                                 ! constant chlorophyll
436                  irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
437                  zekb(:,:) = rkrgb(1,irgb)                   ! Separation in R-G-B depending of the chlorophyll
438                  zekg(:,:) = rkrgb(2,irgb)
439                  zekr(:,:) = rkrgb(3,irgb)
440                  !
441                  zcoef = ( 1. - rn_abs ) / 3.e0              ! equi-partition in R-G-B
442                  ze0(:,:,1) = rn_abs
443                  ze1(:,:,1) = zcoef
444                  ze2(:,:,1) = zcoef 
445                  ze3(:,:,1) = zcoef
446                  zea(:,:,1) = tmask(:,:,1)                   ! = ( ze0+ze1+z2+ze3 ) * tmask
447               
448                  DO jk = 2, nksr+1
449!CDIR NOVERRCHK
450                     DO jj = 1, jpj
451!CDIR NOVERRCHK   
452                        DO ji = 1, jpi
453                           zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * xsi0r     )
454                           zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * zekb(ji,jj) )
455                           zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * zekg(ji,jj) )
456                           zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * zekr(ji,jj) )
457                           ze0(ji,jj,jk) = zc0
458                           ze1(ji,jj,jk) = zc1
459                           ze2(ji,jj,jk) = zc2
460                           ze3(ji,jj,jk) = zc3
461                           zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
462                        END DO
463                     END DO
464                  END DO 
465                  !
466                  DO jk = 1, nksr
467                     etot3(:,:,jk) = ro0cpr * ( zea(:,:,jk) - zea(:,:,jk+1) ) 
468                  END DO
469                  etot3(:,:,nksr+1:jpk) = 0.e0                ! below 400m set to zero
470               ENDIF
471            ENDIF
472            !
473         ENDIF
474            !                             ! ---------------------------------- !
475         IF( ln_qsr_2bd ) THEN            !    2 bands    light penetration    !
476            !                             ! ---------------------------------- !
477            !
478            !                                ! level of light extinction
479            nksr = trc_oce_ext_lev( rn_si1, 1.e2 )
480            IF(lwp) THEN
481               WRITE(numout,*)
482            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m'
483            ENDIF
484            !
485            IF( lk_vvl ) THEN                   ! variable volume
486               IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
487            ELSE                                ! constant volume: computes one for all
488               zz0 =        rn_abs   * ro0cpr
489               zz1 = ( 1. - rn_abs ) * ro0cpr
490               DO jk = 1, nksr                    !*  solar heat absorbed at T-point computed once for all
491                  DO jj = 1, jpj                              ! top 400 meters
492                     DO ji = 1, jpi
493                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
494                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
495                        etot3(ji,jj,jk) = (  zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1)  ) 
496                     END DO
497                  END DO
498               END DO
499               etot3(:,:,nksr+1:jpk) = 0.e0                   ! below 400m set to zero
500               !
501            ENDIF
502         ENDIF
503         !                       ! ===================================== !
504      ELSE                       !        No light penetration           !                   
505         !                       ! ===================================== !
506         IF(lwp) THEN
507            WRITE(numout,*)
508            WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration'
509            WRITE(numout,*) '~~~~~~~~~~~~'
510         ENDIF
511      ENDIF
512      !
513      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        ) 
514      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
515      !
516      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr_init')
517      !
518   END SUBROUTINE tra_qsr_init
519
520   !!======================================================================
521END MODULE traqsr
Note: See TracBrowser for help on using the repository browser.