New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in branches/2013/dev_CMCC_2013/NEMOGCM/NEMO/OPA_SRC – NEMO

Context Navigation

source: branches/2013/dev_CMCC_2013/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 4174

Last change on this file since 4174 was 4174, checked in by vichi, 10 years ago
ticket #1173 step 2: Add in changes from the 2013/dev_r3948_CMCC_NorthFold_Opt
Property svn:keywords set to `Id`
File size: 34.4 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) LIM sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!! 3.4 ! 2011-11 (C. Harris) decomposition changes for running with CICE
31	!!----------------------------------------------------------------------
32
33	!!----------------------------------------------------------------------
34	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
35	!! nemo_init : initialization of the NEMO system
36	!! nemo_ctl : initialisation of the contol print
37	!! nemo_closefile : close remaining open files
38	!! nemo_alloc : dynamical allocation
39	!! nemo_partition : calculate MPP domain decomposition
40	!! factorise : calculate the factors of the no. of MPI processes
41	!!----------------------------------------------------------------------
42	USE step_oce ! module used in the ocean time stepping module
43	USE sbc_oce ! surface boundary condition: ocean
44	USE cla ! cross land advection (tra_cla routine)
45	USE domcfg ! domain configuration (dom_cfg routine)
46	USE mppini ! shared/distributed memory setting (mpp_init routine)
47	USE domain ! domain initialization (dom_init routine)
48	#if defined key_nemocice_decomp
49	USE ice_domain_size, only: nx_global, ny_global
50	#endif
51	USE tideini ! tidal components initialization (tide_ini routine)
52	USE obcini ! open boundary cond. initialization (obc_ini routine)
53	USE bdyini ! open boundary cond. initialization (bdy_init routine)
54	USE bdydta ! open boundary cond. initialization (bdy_dta_init routine)
55	USE bdytides ! open boundary cond. initialization (bdytide_init routine)
56	USE istate ! initial state setting (istate_init routine)
57	USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine)
58	USE ldftra ! lateral diffusivity setting (ldftra_init routine)
59	USE zdfini ! vertical physics setting (zdf_init routine)
60	USE phycst ! physical constant (par_cst routine)
61	USE trdmod ! momentum/tracers trends (trd_mod_init routine)
62	USE asminc ! assimilation increments
63	USE asmbkg ! writing out state trajectory
64	USE diaptr ! poleward transports (dia_ptr_init routine)
65	USE diadct ! sections transports (dia_dct_init routine)
66	USE diaobs ! Observation diagnostics (dia_obs_init routine)
67	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
68	USE step ! NEMO time-stepping (stp routine)
69	USE icbini ! handle bergs, initialisation
70	USE icbstp ! handle bergs, calving, themodynamics and transport
71	#if defined key_oasis3
72	USE cpl_oasis3 ! OASIS3 coupling
73	#elif defined key_oasis4
74	USE cpl_oasis4 ! OASIS4 coupling (not working)
75	#endif
76	USE c1d ! 1D configuration
77	USE step_c1d ! Time stepping loop for the 1D configuration
78	#if defined key_top
79	USE trcini ! passive tracer initialisation
80	#endif
81	USE lib_mpp ! distributed memory computing
82	#if defined key_iomput
83	USE xios
84	#endif
85	USE sbctide, ONLY: lk_tide
86	USE lbcnfd, ONLY: isendto, nsndto ! Setup of north fold exchanges
87
88	IMPLICIT NONE
89	PRIVATE
90
91	PUBLIC nemo_gcm ! called by model.F90
92	PUBLIC nemo_init ! needed by AGRIF
93	PUBLIC nemo_alloc ! needed by TAM
94
95	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
96
97	!!----------------------------------------------------------------------
98	!! NEMO/OPA 4.0 , NEMO Consortium (2011)
99	!! $Id$
100	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
101	!!----------------------------------------------------------------------
102	CONTAINS
103
104	SUBROUTINE nemo_gcm
105	!!----------------------------------------------------------------------
106	!! * ROUTINE nemo_gcm *
107	!!
108	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
109	!! curvilinear mesh on the sphere.
110	!!
111	!! ** Method : - model general initialization
112	!! - launch the time-stepping (stp routine)
113	!! - finalize the run by closing files and communications
114	!!
115	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
116	!! Madec, 2008, internal report, IPSL.
117	!!----------------------------------------------------------------------
118	INTEGER :: istp ! time step index
119	!!----------------------------------------------------------------------
120	!
121	#if defined key_agrif
122	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
123	#endif
124
125	! !-----------------------!
126	CALL nemo_init !== Initialisations ==!
127	! !-----------------------!
128	#if defined key_agrif
129	CALL Agrif_Declare_Var_dom ! AGRIF: set the meshes for DOM
130	CALL Agrif_Declare_Var ! " " " " " DYN/TRA
131	# if defined key_top
132	CALL Agrif_Declare_Var_top ! " " " " " TOP
133	# endif
134	# if defined key_lim2
135	CALL Agrif_Declare_Var_lim2 ! " " " " " LIM
136	# endif
137	#endif
138	! check that all process are still there... If some process have an error,
139	! they will never enter in step and other processes will wait until the end of the cpu time!
140	IF( lk_mpp ) CALL mpp_max( nstop )
141
142	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
143
144	! !-----------------------!
145	! !== time stepping ==!
146	! !-----------------------!
147	istp = nit000
148	#if defined key_c1d
149	DO WHILE ( istp <= nitend .AND. nstop == 0 )
150	CALL stp_c1d( istp )
151	istp = istp + 1
152	END DO
153	#else
154	IF( lk_asminc ) THEN
155	IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 ) ! Output background fields
156	IF( ln_asmdin ) THEN ! Direct initialization
157	IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 ) ! Tracers
158	IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 ) ! Dynamics
159	IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 ) ! SSH
160	ENDIF
161	ENDIF
162
163	DO WHILE ( istp <= nitend .AND. nstop == 0 )
164	#if defined key_agrif
165	CALL Agrif_Step( stp ) ! AGRIF: time stepping
166	#else
167	CALL stp( istp ) ! standard time stepping
168	#endif
169	istp = istp + 1
170	IF( lk_mpp ) CALL mpp_max( nstop )
171	END DO
172	#endif
173
174	IF( lk_diaobs ) CALL dia_obs_wri
175	!
176	IF( ln_icebergs ) CALL icb_end( nitend )
177
178	! !------------------------!
179	! !== finalize the run ==!
180	! !------------------------!
181	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
182	!
183	IF( nstop /= 0 .AND. lwp ) THEN ! error print
184	WRITE(numout,cform_err)
185	WRITE(numout,*) nstop, ' error have been found'
186	ENDIF
187	!
188	#if defined key_agrif
189	CALL Agrif_ParentGrid_To_ChildGrid()
190	IF( lk_diaobs ) CALL dia_obs_wri
191	IF( nn_timing == 1 ) CALL timing_finalize
192	CALL Agrif_ChildGrid_To_ParentGrid()
193	#endif
194	IF( nn_timing == 1 ) CALL timing_finalize
195	!
196	CALL nemo_closefile
197	#if defined key_iomput
198	CALL xios_finalize ! end mpp communications with xios
199	# if defined key_oasis3 \|\| defined key_oasis4
200	CALL cpl_prism_finalize ! end coupling and mpp communications with OASIS
201	# endif
202	#else
203	# if defined key_oasis3 \|\| defined key_oasis4
204	CALL cpl_prism_finalize ! end coupling and mpp communications with OASIS
205	# else
206	IF( lk_mpp ) CALL mppstop ! end mpp communications
207	# endif
208	#endif
209	!
210	END SUBROUTINE nemo_gcm
211
212
213	SUBROUTINE nemo_init
214	!!----------------------------------------------------------------------
215	!! * ROUTINE nemo_init *
216	!!
217	!! ** Purpose : initialization of the NEMO GCM
218	!!----------------------------------------------------------------------
219	INTEGER :: ji ! dummy loop indices
220	INTEGER :: ilocal_comm ! local integer
221	CHARACTER(len=80), DIMENSION(16) :: cltxt
222	!!
223	NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, &
224	& nn_isplt, nn_jsplt, nn_jctls, nn_jctle, &
225	& nn_bench, nn_timing
226	!!----------------------------------------------------------------------
227	!
228	cltxt = ''
229	!
230	! ! open Namelist file
231	CALL ctl_opn( numnam, 'namelist', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
232	!
233	READ( numnam, namctl ) ! Namelist namctl : Control prints & Benchmark
234	!
235	! !--------------------------------------------!
236	! ! set communicator & select the local node !
237	! !--------------------------------------------!
238	#if defined key_iomput
239	IF( Agrif_Root() ) THEN
240	# if defined key_oasis3 \|\| defined key_oasis4
241	CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis
242	CALL xios_initialize( "oceanx",local_comm=ilocal_comm )
243	# else
244	CALL xios_initialize( "nemo",return_comm=ilocal_comm )
245	# endif
246	ENDIF
247	narea = mynode( cltxt, numnam, nstop, ilocal_comm ) ! Nodes selection
248	#else
249	# if defined key_oasis3 \|\| defined key_oasis4
250	IF( Agrif_Root() ) THEN
251	CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis
252	ENDIF
253	narea = mynode( cltxt, numnam, nstop, ilocal_comm ) ! Nodes selection (control print return in cltxt)
254	# else
255	ilocal_comm = 0
256	narea = mynode( cltxt, numnam, nstop ) ! Nodes selection (control print return in cltxt)
257	# endif
258	#endif
259	narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 )
260
261	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
262
263	! If dimensions of processor grid weren't specified in the namelist file
264	! then we calculate them here now that we have our communicator size
265	IF( (jpni < 1) .OR. (jpnj < 1) )THEN
266	#if defined key_mpp_mpi
267	IF( Agrif_Root() ) CALL nemo_partition(mppsize)
268	#else
269	jpni = 1
270	jpnj = 1
271	jpnij = jpni*jpnj
272	#endif
273	END IF
274
275	! Calculate domain dimensions given calculated jpni and jpnj
276	! This used to be done in par_oce.F90 when they were parameters rather
277	! than variables
278	IF( Agrif_Root() ) THEN
279	#if defined key_nemocice_decomp
280	jpi = ( nx_global+2-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
281	jpj = ( ny_global+2-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
282	#else
283	jpi = ( jpiglo-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
284	jpj = ( jpjglo-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
285	#endif
286	jpk = jpkdta ! third dim
287	jpim1 = jpi-1 ! inner domain indices
288	jpjm1 = jpj-1 ! " "
289	jpkm1 = jpk-1 ! " "
290	jpij = jpi*jpj ! jpi x j
291	ENDIF
292
293	IF(lwp) THEN ! open listing units
294	!
295	CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
296	!
297	WRITE(numout,*)
298	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
299	WRITE(numout,*) ' NEMO team'
300	WRITE(numout,*) ' Ocean General Circulation Model'
301	WRITE(numout,*) ' version 3.4 (2011) '
302	WRITE(numout,*)
303	WRITE(numout,*)
304	DO ji = 1, SIZE(cltxt)
305	IF( TRIM(cltxt(ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode
306	END DO
307	WRITE(numout,cform_aaa) ! Flag AAAAAAA
308	!
309	ENDIF
310
311	! Now we know the dimensions of the grid and numout has been set we can
312	! allocate arrays
313	CALL nemo_alloc()
314
315	! !-------------------------------!
316	! ! NEMO general initialization !
317	! !-------------------------------!
318
319	CALL nemo_ctl ! Control prints & Benchmark
320
321	! ! Domain decomposition
322	IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out
323	ELSE ; CALL mpp_init2 ! eliminate land processors
324	ENDIF
325	!
326	IF( nn_timing == 1 ) CALL timing_init
327	!
328	! ! General initialization
329	CALL phy_cst ! Physical constants
330	CALL eos_init ! Equation of state
331	CALL dom_cfg ! Domain configuration
332	CALL dom_init ! Domain
333
334	IF( ln_nnogather ) CALL nemo_northcomms ! Initialise the northfold neighbour lists (must be done after the masks are defined)
335
336	IF( ln_ctl ) CALL prt_ctl_init ! Print control
337
338	IF( lk_obc ) CALL obc_init ! Open boundaries
339
340	CALL istate_init ! ocean initial state (Dynamics and tracers)
341
342	IF( lk_tide ) CALL tide_init( nit000 ) ! Initialisation of the tidal harmonics
343
344	IF( lk_bdy ) CALL bdy_init ! Open boundaries initialisation
345	IF( lk_bdy ) CALL bdy_dta_init ! Open boundaries initialisation of external data arrays
346	IF( lk_bdy ) CALL bdytide_init ! Open boundaries initialisation of tidal harmonic forcing
347
348	CALL dyn_nept_init ! simplified form of Neptune effect
349
350	! ! Ocean physics
351	CALL sbc_init ! Forcings : surface module
352	! ! Vertical physics
353	CALL zdf_init ! namelist read
354	CALL zdf_bfr_init ! bottom friction
355	IF( lk_zdfric ) CALL zdf_ric_init ! Richardson number dependent Kz
356	IF( lk_zdftke ) CALL zdf_tke_init ! TKE closure scheme
357	IF( lk_zdfgls ) CALL zdf_gls_init ! GLS closure scheme
358	IF( lk_zdfkpp ) CALL zdf_kpp_init ! KPP closure scheme
359	IF( lk_zdftmx ) CALL zdf_tmx_init ! tidal vertical mixing
360	IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) &
361	& CALL zdf_ddm_init ! double diffusive mixing
362	! ! Lateral physics
363	CALL ldf_tra_init ! Lateral ocean tracer physics
364	CALL ldf_dyn_init ! Lateral ocean momentum physics
365	IF( lk_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
366
367	! ! Active tracers
368	CALL tra_qsr_init ! penetrative solar radiation qsr
369	CALL tra_bbc_init ! bottom heat flux
370	IF( lk_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
371	IF( ln_tradmp ) CALL tra_dmp_init ! internal damping trends
372	CALL tra_adv_init ! horizontal & vertical advection
373	CALL tra_ldf_init ! lateral mixing
374	CALL tra_zdf_init ! vertical mixing and after tracer fields
375
376	! ! Dynamics
377	CALL dyn_adv_init ! advection (vector or flux form)
378	CALL dyn_vor_init ! vorticity term including Coriolis
379	CALL dyn_ldf_init ! lateral mixing
380	CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure
381	CALL dyn_zdf_init ! vertical diffusion
382	CALL dyn_spg_init ! surface pressure gradient
383
384	! ! Misc. options
385	IF( nn_cla == 1 ) CALL cla_init ! Cross Land Advection
386	CALL icb_init( rdt, nit000) ! initialise icebergs instance
387
388	#if defined key_top
389	! ! Passive tracers
390	CALL trc_init
391	#endif
392	! ! Diagnostics
393	IF( lk_floats ) CALL flo_init ! drifting Floats
394	IF( lk_diaar5 ) CALL dia_ar5_init ! ar5 diag
395	CALL dia_ptr_init ! Poleward TRansports initialization
396	IF( lk_diadct ) CALL dia_dct_init ! Sections tranports
397	CALL dia_hsb_init ! heat content, salt content and volume budgets
398	CALL trd_mod_init ! Mixed-layer/Vorticity/Integral constraints trends
399	IF( lk_diaobs ) THEN ! Observation & model comparison
400	CALL dia_obs_init ! Initialize observational data
401	CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
402	ENDIF
403	! ! Assimilation increments
404	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
405	IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
406	!
407	END SUBROUTINE nemo_init
408
409
410	SUBROUTINE nemo_ctl
411	!!----------------------------------------------------------------------
412	!! * ROUTINE nemo_ctl *
413	!!
414	!! ** Purpose : control print setting
415	!!
416	!! ** Method : - print namctl information and check some consistencies
417	!!----------------------------------------------------------------------
418	!
419	IF(lwp) THEN ! control print
420	WRITE(numout,*)
421	WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
422	WRITE(numout,*) '~~~~~~~ '
423	WRITE(numout,*) ' Namelist namctl'
424	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
425	WRITE(numout,*) ' level of print nn_print = ', nn_print
426	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
427	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
428	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
429	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
430	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
431	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
432	WRITE(numout,*) ' benchmark parameter (0/1) nn_bench = ', nn_bench
433	WRITE(numout,*) ' timing activated (0/1) nn_timing = ', nn_timing
434	ENDIF
435	!
436	nprint = nn_print ! convert DOCTOR namelist names into OLD names
437	nictls = nn_ictls
438	nictle = nn_ictle
439	njctls = nn_jctls
440	njctle = nn_jctle
441	isplt = nn_isplt
442	jsplt = nn_jsplt
443	nbench = nn_bench
444	! ! Parameter control
445	!
446	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
447	IF( lk_mpp .AND. jpnij > 1 ) THEN
448	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
449	ELSE
450	IF( isplt == 1 .AND. jsplt == 1 ) THEN
451	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
452	& ' - the print control will be done over the whole domain' )
453	ENDIF
454	ijsplt = isplt * jsplt ! total number of processors ijsplt
455	ENDIF
456	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
457	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
458	!
459	! ! indices used for the SUM control
460	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
461	lsp_area = .FALSE.
462	ELSE ! print control done over a specific area
463	lsp_area = .TRUE.
464	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
465	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
466	nictls = 1
467	ENDIF
468	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
469	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
470	nictle = jpiglo
471	ENDIF
472	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
473	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
474	njctls = 1
475	ENDIF
476	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
477	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
478	njctle = jpjglo
479	ENDIF
480	ENDIF
481	ENDIF
482	!
483	IF( nbench == 1 ) THEN ! Benchmark
484	SELECT CASE ( cp_cfg )
485	CASE ( 'gyre' ) ; CALL ctl_warn( ' The Benchmark is activated ' )
486	CASE DEFAULT ; CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:', &
487	& ' key_gyre must be used or set nbench = 0' )
488	END SELECT
489	ENDIF
490	!
491	IF( lk_c1d .AND. .NOT.lk_iomput ) CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ', &
492	& 'with the IOM Input/Output manager. ' , &
493	& 'Compile with key_iomput enabled' )
494	!
495	IF( 1_wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ', &
496	& 'f2003 standard. ' , &
497	& 'Compile with key_nosignedzero enabled' )
498	!
499	END SUBROUTINE nemo_ctl
500
501
502	SUBROUTINE nemo_closefile
503	!!----------------------------------------------------------------------
504	!! * ROUTINE nemo_closefile *
505	!!
506	!! ** Purpose : Close the files
507	!!----------------------------------------------------------------------
508	!
509	IF( lk_mpp ) CALL mppsync
510	!
511	CALL iom_close ! close all input/output files managed by iom_*
512	!
513	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
514	IF( numsol /= -1 ) CLOSE( numsol ) ! solver file
515	IF( numnam /= -1 ) CLOSE( numnam ) ! oce namelist
516	IF( numnam_ice /= -1 ) CLOSE( numnam_ice ) ! ice namelist
517	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
518	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
519	IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports
520	IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports
521	IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports
522
523	!
524	numout = 6 ! redefine numout in case it is used after this point...
525	!
526	END SUBROUTINE nemo_closefile
527
528
529	SUBROUTINE nemo_alloc
530	!!----------------------------------------------------------------------
531	!! * ROUTINE nemo_alloc *
532	!!
533	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
534	!!
535	!! ** Method :
536	!!----------------------------------------------------------------------
537	USE diawri , ONLY: dia_wri_alloc
538	USE dom_oce , ONLY: dom_oce_alloc
539	USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
540	USE ldftra_oce, ONLY: ldftra_oce_alloc
541	USE trc_oce , ONLY: trc_oce_alloc
542	#if defined key_diadct
543	USE diadct , ONLY: diadct_alloc
544	#endif
545	!
546	INTEGER :: ierr
547	!!----------------------------------------------------------------------
548	!
549	ierr = oce_alloc () ! ocean
550	ierr = ierr + dia_wri_alloc ()
551	ierr = ierr + dom_oce_alloc () ! ocean domain
552	ierr = ierr + ldfdyn_oce_alloc() ! ocean lateral physics : dynamics
553	ierr = ierr + ldftra_oce_alloc() ! ocean lateral physics : tracers
554	ierr = ierr + zdf_oce_alloc () ! ocean vertical physics
555	!
556	ierr = ierr + lib_mpp_alloc (numout) ! mpp exchanges
557	ierr = ierr + trc_oce_alloc () ! shared TRC / TRA arrays
558	!
559	#if defined key_diadct
560	ierr = ierr + diadct_alloc () !
561	#endif
562	!
563	IF( lk_mpp ) CALL mpp_sum( ierr )
564	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
565	!
566	END SUBROUTINE nemo_alloc
567
568
569	SUBROUTINE nemo_partition( num_pes )
570	!!----------------------------------------------------------------------
571	!! * ROUTINE nemo_partition *
572	!!
573	!! ** Purpose :
574	!!
575	!! ** Method :
576	!!----------------------------------------------------------------------
577	INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
578	!
579	INTEGER, PARAMETER :: nfactmax = 20
580	INTEGER :: nfact ! The no. of factors returned
581	INTEGER :: ierr ! Error flag
582	INTEGER :: ji
583	INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
584	INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
585	!!----------------------------------------------------------------------
586
587	ierr = 0
588
589	CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
590
591	IF( nfact <= 1 ) THEN
592	WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
593	WRITE (numout, *) ' : using grid of ',num_pes,' x 1'
594	jpnj = 1
595	jpni = num_pes
596	ELSE
597	! Search through factors for the pair that are closest in value
598	mindiff = 1000000
599	imin = 1
600	DO ji = 1, nfact-1, 2
601	idiff = ABS( ifact(ji) - ifact(ji+1) )
602	IF( idiff < mindiff ) THEN
603	mindiff = idiff
604	imin = ji
605	ENDIF
606	END DO
607	jpnj = ifact(imin)
608	jpni = ifact(imin + 1)
609	ENDIF
610	!
611	jpnij = jpni*jpnj
612	!
613	END SUBROUTINE nemo_partition
614
615
616	SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
617	!!----------------------------------------------------------------------
618	!! * ROUTINE factorise *
619	!!
620	!! ** Purpose : return the prime factors of n.
621	!! knfax factors are returned in array kfax which is of
622	!! maximum dimension kmaxfax.
623	!! ** Method :
624	!!----------------------------------------------------------------------
625	INTEGER , INTENT(in ) :: kn, kmaxfax
626	INTEGER , INTENT( out) :: kerr, knfax
627	INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax
628	!
629	INTEGER :: ifac, jl, inu
630	INTEGER, PARAMETER :: ntest = 14
631	INTEGER :: ilfax(ntest)
632
633	! lfax contains the set of allowed factors.
634	data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256, &
635	& 128, 64, 32, 16, 8, 4, 2 /
636	!!----------------------------------------------------------------------
637
638	! Clear the error flag and initialise output vars
639	kerr = 0
640	kfax = 1
641	knfax = 0
642
643	! Find the factors of n.
644	IF( kn == 1 ) GOTO 20
645
646	! nu holds the unfactorised part of the number.
647	! knfax holds the number of factors found.
648	! l points to the allowed factor list.
649	! ifac holds the current factor.
650
651	inu = kn
652	knfax = 0
653
654	DO jl = ntest, 1, -1
655	!
656	ifac = ilfax(jl)
657	IF( ifac > inu ) CYCLE
658
659	! Test whether the factor will divide.
660
661	IF( MOD(inu,ifac) == 0 ) THEN
662	!
663	knfax = knfax + 1 ! Add the factor to the list
664	IF( knfax > kmaxfax ) THEN
665	kerr = 6
666	write (,) 'FACTOR: insufficient space in factor array ', knfax
667	return
668	ENDIF
669	kfax(knfax) = ifac
670	! Store the other factor that goes with this one
671	knfax = knfax + 1
672	kfax(knfax) = inu / ifac
673	!WRITE (,) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
674	ENDIF
675	!
676	END DO
677
678	20 CONTINUE ! Label 20 is the exit point from the factor search loop.
679	!
680	END SUBROUTINE factorise
681
682	#if defined key_mpp_mpi
683	SUBROUTINE nemo_northcomms
684	!!======================================================================
685	!! * ROUTINE nemo_northcomms *
686	!! nemo_northcomms : Setup for north fold exchanges with explicit
687	!! point-to-point messaging
688	!!=====================================================================
689	!!----------------------------------------------------------------------
690	!!
691	!! ** Purpose : Initialization of the northern neighbours lists.
692	!!----------------------------------------------------------------------
693	!! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE)
694	!! 2.0 ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
695	!!----------------------------------------------------------------------
696
697	INTEGER :: sxM, dxM, sxT, dxT, jn
698	INTEGER :: njmppmax
699
700	njmppmax = MAXVAL( njmppt )
701
702	!initializes the north-fold communication variables
703	isendto(:) = 0
704	nsndto = 0
705
706	!if I am a process in the north
707	IF ( njmpp == njmppmax ) THEN
708	!sxM is the first point (in the global domain) needed to compute the
709	!north-fold for the current process
710	sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
711	!dxM is the last point (in the global domain) needed to compute the
712	!north-fold for the current process
713	dxM = jpiglo - nimppt(narea) + 2
714
715	!loop over the other north-fold processes to find the processes
716	!managing the points belonging to the sxT-dxT range
717	DO jn = jpnij - jpni +1, jpnij
718	IF ( njmppt(jn) == njmppmax ) THEN
719	!sxT is the first point (in the global domain) of the jn
720	!process
721	sxT = nimppt(jn)
722	!dxT is the last point (in the global domain) of the jn
723	!process
724	dxT = nimppt(jn) + nlcit(jn) - 1
725	IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
726	nsndto = nsndto + 1
727	isendto(nsndto) = jn
728	ELSEIF ((sxM .le. sxT) .AND. (dxM .gt. dxT)) THEN
729	nsndto = nsndto + 1
730	isendto(nsndto) = jn
731	ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
732	nsndto = nsndto + 1
733	isendto(nsndto) = jn
734	END IF
735	END IF
736	END DO
737	ENDIF
738	l_north_nogather = .TRUE.
739	END SUBROUTINE nemo_northcomms
740	#else
741	SUBROUTINE nemo_northcomms ! Dummy routine
742	WRITE(,) 'nemo_northcomms: You should not have seen this print! error?'
743	END SUBROUTINE nemo_northcomms
744	#endif
745	!!======================================================================
746	END MODULE nemogcm

Note: See TracBrowser for help on using the repository browser.

Download in other formats: