New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dtatsd.F90 in branches/2013/dev_CMCC_INGV_2013/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/2013/dev_CMCC_INGV_2013/NEMOGCM/NEMO/OPA_SRC/DOM/dtatsd.F90 @ 4217

Last change on this file since 4217 was 4217, checked in by poddo, 11 years ago

Solved problems with namelist parameter land/sea mask
File size: 15.9 KB
Line 
1MODULE dtatsd
2   !!======================================================================
3   !!                     ***  MODULE  dtatsd  ***
4   !! Ocean data  :  read ocean Temperature & Salinity Data from gridded data
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  ()  Original code
7   !!             -   ! 1992-07  (M. Imbard)
8   !!            8.0  ! 1999-10  (M.A. Foujols, M. Imbard)  NetCDF FORMAT
9   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
10   !!            3.3  ! 2010-10  (C. Bricaud, S. Masson)  use of fldread
11   !!            3.4  ! 2010-11  (G. Madec, C. Ethe) Merge of dtatem and dtasal + suppression of CPP keys
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   dta_tsd      : read and time interpolated ocean Temperature & Salinity Data
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers
18   USE dom_oce         ! ocean space and time domain
19   USE fldread         ! read input fields
20   USE in_out_manager  ! I/O manager
21   USE phycst          ! physical constants
22   USE lib_mpp         ! MPP library
23   USE wrk_nemo        ! Memory allocation
24   USE timing          ! Timing
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   dta_tsd_init   ! called by opa.F90
30   PUBLIC   dta_tsd        ! called by istate.F90 and tradmp.90
31
32   LOGICAL , PUBLIC ::   ln_tsd_init   = .FALSE.    !: T & S data flag
33   LOGICAL , PUBLIC ::   ln_tsd_tradmp = .FALSE.    !: internal damping toward input data flag
34
35   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tsd   ! structure of input SST (file informations, fields read)
36
37   !! * Substitutions
38#  include "domzgr_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
41   !! $Id: dtatem.F90 2392 2010-11-15 21:20:05Z gm $
42   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE dta_tsd_init( ld_tradmp )
47      !!----------------------------------------------------------------------
48      !!                   ***  ROUTINE dta_tsd_init  ***
49      !!                   
50      !! ** Purpose :   initialisation of T & S input data
51      !!
52      !! ** Method  : - Read namtsd namelist
53      !!              - allocates T & S data structure
54      !!----------------------------------------------------------------------
55      LOGICAL, INTENT(in), OPTIONAL ::   ld_tradmp   ! force the initialization when tradp is used
56      !
57      INTEGER ::   ierr0, ierr1, ierr2, ierr3   ! temporary integers
58      !
59      CHARACTER(len=100)            ::   cn_dir          ! Root directory for location of ssr files
60      TYPE(FLD_N), DIMENSION( jpts) ::   slf_i           ! array of namelist informations on the fields to read
61      TYPE(FLD_N)                   ::   sn_tem, sn_sal
62      !!
63      NAMELIST/namtsd/   ln_tsd_init, ln_tsd_tradmp, cn_dir, sn_tem, sn_sal
64      !!----------------------------------------------------------------------
65      !
66      IF( nn_timing == 1 )  CALL timing_start('dta_tsd_init')
67      !
68      !  Initialisation
69      ierr0 = 0  ;  ierr1 = 0  ;  ierr2 = 0  ;  ierr3 = 0
70      !
71      !                             ! set default namelist values
72      cn_dir = './'                       ! directory in which the model is executed
73      !                                   ! sn_... default values (NB: frequency positive => hours, negative => months)
74      !            !   file    ! frequency ! variable  ! time intep !  clim   ! 'yearly' or ! weights  ! rotation ! land/sea mask !
75      !            !   name    !  (hours)  !  name     !   (T/F)    !  (T/F)  !  'monthly'  ! filename ! pairs    ! filename      !
76      sn_tem = FLD_N( 'temperature',  -1.  , 'votemper',  .false.   , .true.  ,  'monthly'  , ''       , &
77           & ''       , ''            )
78      sn_sal = FLD_N( 'salinity'   ,  -1.  , 'vosaline',  .false.   , .true.  ,  'monthly'  , ''       , &
79           & ''       , ''            )
80
81      REWIND( numnam )              ! read in namlist namdta_tsd
82      READ  ( numnam, namtsd ) 
83
84      IF( PRESENT( ld_tradmp ) )   ln_tsd_tradmp = .TRUE.     ! forces the initialization when tradmp is used
85     
86      IF(lwp) THEN                  ! control print
87         WRITE(numout,*)
88         WRITE(numout,*) 'dta_tsd_init : Temperature & Salinity data '
89         WRITE(numout,*) '~~~~~~~~~~~~ '
90         WRITE(numout,*) '   Namelist namtsd'
91         WRITE(numout,*) '      Initialisation of ocean T & S with T &S input data   ln_tsd_init   = ', ln_tsd_init
92         WRITE(numout,*) '      damping of ocean T & S toward T &S input data        ln_tsd_tradmp = ', ln_tsd_tradmp
93         WRITE(numout,*)
94         IF( .NOT.ln_tsd_init .AND. .NOT.ln_tsd_tradmp ) THEN
95            WRITE(numout,*)
96            WRITE(numout,*) '   T & S data not used'
97         ENDIF
98      ENDIF
99      !
100      IF( ln_rstart .AND. ln_tsd_init ) THEN
101         CALL ctl_warn( 'dta_tsd_init: ocean restart and T & S data intialisation, ',   &
102            &           'we keep the restart T & S values and set ln_tsd_init to FALSE' )
103         ln_tsd_init = .FALSE.
104      ENDIF
105      !
106      !                             ! allocate the arrays (if necessary)
107      IF(  ln_tsd_init .OR. ln_tsd_tradmp  ) THEN
108         !
109         ALLOCATE( sf_tsd(jpts), STAT=ierr0 )
110         IF( ierr0 > 0 ) THEN
111            CALL ctl_stop( 'dta_tsd_init: unable to allocate sf_tsd structure' )   ;   RETURN
112         ENDIF
113         !
114                                ALLOCATE( sf_tsd(jp_tem)%fnow(jpi,jpj,jpk)   , STAT=ierr0 )
115         IF( sn_tem%ln_tint )   ALLOCATE( sf_tsd(jp_tem)%fdta(jpi,jpj,jpk,2) , STAT=ierr1 )
116                                ALLOCATE( sf_tsd(jp_sal)%fnow(jpi,jpj,jpk)   , STAT=ierr2 )
117         IF( sn_sal%ln_tint )   ALLOCATE( sf_tsd(jp_sal)%fdta(jpi,jpj,jpk,2) , STAT=ierr3 )
118         !
119         IF( ierr0 + ierr1 + ierr2 + ierr3 > 0 ) THEN
120            CALL ctl_stop( 'dta_tsd : unable to allocate T & S data arrays' )   ;   RETURN
121         ENDIF
122         !                         ! fill sf_tsd with sn_tem & sn_sal and control print
123         slf_i(jp_tem) = sn_tem   ;   slf_i(jp_sal) = sn_sal
124         CALL fld_fill( sf_tsd, slf_i, cn_dir, 'dta_tsd', 'Temperature & Salinity data', 'namtsd' )
125         !
126      ENDIF
127      !
128      IF( nn_timing == 1 )  CALL timing_stop('dta_tsd_init')
129      !
130   END SUBROUTINE dta_tsd_init
131
132
133   SUBROUTINE dta_tsd( kt, ptsd )
134      !!----------------------------------------------------------------------
135      !!                   ***  ROUTINE dta_tsd  ***
136      !!                   
137      !! ** Purpose :   provides T and S data at kt
138      !!
139      !! ** Method  : - call fldread routine
140      !!              - ORCA_R2: add some hand made alteration to read data 
141      !!              - 'key_orca_lev10' interpolates on 10 times more levels
142      !!              - s- or mixed z-s coordinate: vertical interpolation on model mesh
143      !!              - ln_tsd_tradmp=F: deallocates the T-S data structure
144      !!                as T-S data are no are used
145      !!
146      !! ** Action  :   ptsd   T-S data on medl mesh and interpolated at time-step kt
147      !!----------------------------------------------------------------------
148      INTEGER                              , INTENT(in   ) ::   kt     ! ocean time-step
149      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(  out) ::   ptsd   ! T & S data
150      !
151      INTEGER ::   ji, jj, jk, jl, jkk   ! dummy loop indicies
152      INTEGER ::   ik, il0, il1, ii0, ii1, ij0, ij1   ! local integers
153      REAL(wp)::   zl, zi
154      REAL(wp), POINTER, DIMENSION(:) ::  ztp, zsp   ! 1D workspace
155      !!----------------------------------------------------------------------
156      !
157      IF( nn_timing == 1 )  CALL timing_start('dta_tsd')
158      !
159      CALL fld_read( kt, 1, sf_tsd )      !==   read T & S data at kt time step   ==!
160      !
161      !
162      !                                   !==   ORCA_R2 configuration and T & S damping   ==!
163      IF( cp_cfg == "orca" .AND. jp_cfg == 2 .AND. ln_tsd_tradmp ) THEN    ! some hand made alterations
164         !
165         ij0 = 101   ;   ij1 = 109                       ! Reduced T & S in the Alboran Sea
166         ii0 = 141   ;   ii1 = 155
167         DO jj = mj0(ij0), mj1(ij1)
168            DO ji = mi0(ii0), mi1(ii1)
169               sf_tsd(jp_tem)%fnow(ji,jj,13:13) = sf_tsd(jp_tem)%fnow(ji,jj,13:13) - 0.20_wp
170               sf_tsd(jp_tem)%fnow(ji,jj,14:15) = sf_tsd(jp_tem)%fnow(ji,jj,14:15) - 0.35_wp
171               sf_tsd(jp_tem)%fnow(ji,jj,16:25) = sf_tsd(jp_tem)%fnow(ji,jj,16:25) - 0.40_wp
172               !
173               sf_tsd(jp_sal)%fnow(ji,jj,13:13) = sf_tsd(jp_sal)%fnow(ji,jj,13:13) - 0.15_wp
174               sf_tsd(jp_sal)%fnow(ji,jj,14:15) = sf_tsd(jp_sal)%fnow(ji,jj,14:15) - 0.25_wp
175               sf_tsd(jp_sal)%fnow(ji,jj,16:17) = sf_tsd(jp_sal)%fnow(ji,jj,16:17) - 0.30_wp
176               sf_tsd(jp_sal)%fnow(ji,jj,18:25) = sf_tsd(jp_sal)%fnow(ji,jj,18:25) - 0.35_wp
177            END DO
178         END DO
179         IF( nn_cla == 1 ) THEN                          ! Cross Land advection
180            il0 = 138   ;   il1 = 138                          ! set T & S profile at Gibraltar Strait
181            ij0 = 101   ;   ij1 = 102
182            ii0 = 139   ;   ii1 = 139
183            DO jl = mi0(il0), mi1(il1)
184               DO jj = mj0(ij0), mj1(ij1)
185                  DO ji = mi0(ii0), mi1(ii1)
186                     sf_tsd(jp_tem)%fnow(ji,jj,:) = sf_tsd(jp_tem)%fnow(jl,jj,:)
187                     sf_tsd(jp_sal)%fnow(ji,jj,:) = sf_tsd(jp_sal)%fnow(jl,jj,:)
188                  END DO
189               END DO
190            END DO
191            il0 = 164   ;   il1 = 164                          ! set T & S profile at Bab el Mandeb Strait
192            ij0 =  87   ;   ij1 =  88
193            ii0 = 161   ;   ii1 = 163
194            DO jl = mi0(il0), mi1(il1)
195               DO jj = mj0(ij0), mj1(ij1)
196                  DO ji = mi0(ii0), mi1(ii1)
197                     sf_tsd(jp_tem)%fnow(ji,jj,:) = sf_tsd(jp_tem)%fnow(jl,jj,:)
198                     sf_tsd(jp_sal)%fnow(ji,jj,:) = sf_tsd(jp_sal)%fnow(jl,jj,:)
199                  END DO
200               END DO
201            END DO
202         ELSE                                            ! No Cross Land advection
203            ij0 =  87   ;   ij1 =  96                          ! Reduced temperature in Red Sea
204            ii0 = 148   ;   ii1 = 160
205            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ,  4:10 ) = 7.0_wp
206            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 11:13 ) = 6.5_wp
207            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 14:20 ) = 6.0_wp
208         ENDIF
209      ENDIF
210      !
211      ptsd(:,:,:,jp_tem) = sf_tsd(jp_tem)%fnow(:,:,:)    ! NO mask
212      ptsd(:,:,:,jp_sal) = sf_tsd(jp_sal)%fnow(:,:,:) 
213      !
214      IF( ln_sco ) THEN                   !==   s- or mixed s-zps-coordinate   ==!
215         !
216         CALL wrk_alloc( jpk, ztp, zsp )
217         !
218         IF( kt == nit000 .AND. lwp )THEN
219            WRITE(numout,*)
220            WRITE(numout,*) 'dta_tsd: interpolates T & S data onto the s- or mixed s-z-coordinate mesh'
221         ENDIF
222         !
223         DO jj = 1, jpj                         ! vertical interpolation of T & S
224            DO ji = 1, jpi
225               DO jk = 1, jpk                        ! determines the intepolated T-S profiles at each (i,j) points
226                  zl = fsdept_0(ji,jj,jk)
227                  IF(     zl < gdept_0(1  ) ) THEN          ! above the first level of data
228                     ztp(jk) =  ptsd(ji,jj,1    ,jp_tem)
229                     zsp(jk) =  ptsd(ji,jj,1    ,jp_sal)
230                  ELSEIF( zl > gdept_0(jpk) ) THEN          ! below the last level of data
231                     ztp(jk) =  ptsd(ji,jj,jpkm1,jp_tem)
232                     zsp(jk) =  ptsd(ji,jj,jpkm1,jp_sal)
233                  ELSE                                      ! inbetween : vertical interpolation between jkk & jkk+1
234                     DO jkk = 1, jpkm1                                  ! when  gdept(jkk) < zl < gdept(jkk+1)
235                        IF( (zl-gdept_0(jkk)) * (zl-gdept_0(jkk+1)) <= 0._wp ) THEN
236                           zi = ( zl - gdept_0(jkk) ) / (gdept_0(jkk+1)-gdept_0(jkk))
237                           ztp(jk) = ptsd(ji,jj,jkk,jp_tem) + ( ptsd(ji,jj,jkk+1,jp_tem) - ptsd(ji,jj,jkk,jp_tem) ) * zi 
238                           zsp(jk) = ptsd(ji,jj,jkk,jp_sal) + ( ptsd(ji,jj,jkk+1,jp_sal) - ptsd(ji,jj,jkk,jp_sal) ) * zi
239                        ENDIF
240                     END DO
241                  ENDIF
242               END DO
243               DO jk = 1, jpkm1
244                  ptsd(ji,jj,jk,jp_tem) = ztp(jk) * tmask(ji,jj,jk)     ! mask required for mixed zps-s-coord
245                  ptsd(ji,jj,jk,jp_sal) = zsp(jk) * tmask(ji,jj,jk)
246               END DO
247               ptsd(ji,jj,jpk,jp_tem) = 0._wp
248               ptsd(ji,jj,jpk,jp_sal) = 0._wp
249            END DO
250         END DO
251         !
252         CALL wrk_dealloc( jpk, ztp, zsp )
253         !
254      ELSE                                !==   z- or zps- coordinate   ==!
255         !                             
256         ptsd(:,:,:,jp_tem) = ptsd(:,:,:,jp_tem) * tmask(:,:,:)    ! Mask
257         ptsd(:,:,:,jp_sal) = ptsd(:,:,:,jp_sal) * tmask(:,:,:)
258         !
259         IF( ln_zps ) THEN                      ! zps-coordinate (partial steps) interpolation at the last ocean level
260            DO jj = 1, jpj
261               DO ji = 1, jpi
262                  ik = mbkt(ji,jj) 
263                  IF( ik > 1 ) THEN
264                     zl = ( gdept_0(ik) - fsdept_0(ji,jj,ik) ) / ( gdept_0(ik) - gdept_0(ik-1) )
265                     ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik-1,jp_tem)
266                     ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik-1,jp_sal)
267                  ENDIF
268               END DO
269            END DO
270         ENDIF
271         !
272      ENDIF
273      !
274      IF( lwp .AND. kt == nit000 ) THEN
275         WRITE(numout,*) ' temperature Levitus '
276         WRITE(numout,*)
277         WRITE(numout,*)'  level = 1'
278         CALL prihre( ptsd(:,:,1    ,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
279         WRITE(numout,*)'  level = ', jpk/2
280         CALL prihre( ptsd(:,:,jpk/2,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
281         WRITE(numout,*)'  level = ', jpkm1
282         CALL prihre( ptsd(:,:,jpkm1,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
283         WRITE(numout,*)
284         WRITE(numout,*) ' salinity Levitus '
285         WRITE(numout,*)
286         WRITE(numout,*)'  level = 1'
287         CALL prihre( ptsd(:,:,1    ,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
288         WRITE(numout,*)'  level = ', jpk/2
289         CALL prihre( ptsd(:,:,jpk/2,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
290         WRITE(numout,*)'  level = ', jpkm1
291         CALL prihre( ptsd(:,:,jpkm1,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
292         WRITE(numout,*)
293      ENDIF
294      !
295      IF( .NOT.ln_tsd_tradmp ) THEN                   !==   deallocate T & S structure   ==!
296         !                                              (data used only for initialisation)
297         IF(lwp) WRITE(numout,*) 'dta_tsd: deallocte T & S arrays as they are only use to initialize the run'
298                                        DEALLOCATE( sf_tsd(jp_tem)%fnow )     ! T arrays in the structure
299         IF( sf_tsd(jp_tem)%ln_tint )   DEALLOCATE( sf_tsd(jp_tem)%fdta )
300                                        DEALLOCATE( sf_tsd(jp_sal)%fnow )     ! S arrays in the structure
301         IF( sf_tsd(jp_sal)%ln_tint )   DEALLOCATE( sf_tsd(jp_sal)%fdta )
302                                        DEALLOCATE( sf_tsd              )     ! the structure itself
303      ENDIF
304      !
305      IF( nn_timing == 1 )  CALL timing_stop('dta_tsd')
306      !
307   END SUBROUTINE dta_tsd
308
309   !!======================================================================
310END MODULE dtatsd
Note: See TracBrowser for help on using the repository browser.