New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diahsb.F90 in branches/2013/dev_LOCEAN_2013/NEMOGCM/NEMO/OPA_SRC/DIA – NEMO

source: branches/2013/dev_LOCEAN_2013/NEMOGCM/NEMO/OPA_SRC/DIA/diahsb.F90 @ 4152

Last change on this file since 4152 was 4152, checked in by cetlod, 10 years ago

merge in dev_LOCEAN_2013 the 2nd development branch dev_r3940_CNRS4_IOCRS, see ticket #1169
  • Property svn:keywords set to Id
File size: 16.6 KB
Line 
1MODULE diahsb
2   !!======================================================================
3   !!                       ***  MODULE  diahsb  ***
4   !! Ocean diagnostics: Heat, salt and volume budgets
5   !!======================================================================
6   !! History :  3.3  ! 2010-09  (M. Leclair)  Original code
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   USE oce             ! ocean dynamics and tracers
11   USE dom_oce         ! ocean space and time domain
12   USE phycst          ! physical constants
13   USE sbc_oce         ! surface thermohaline fluxes
14   USE in_out_manager  ! I/O manager
15   USE domvvl          ! vertical scale factors
16   USE traqsr          ! penetrative solar radiation
17   USE trabbc          ! bottom boundary condition
18   USE lib_mpp         ! distributed memory computing library
19   USE trabbc          ! bottom boundary condition
20   USE obc_par         ! (for lk_obc)
21   USE bdy_par         ! (for lk_bdy)
22   USE timing          ! preformance summary
23   USE lib_fortran
24   USE sbcrnf
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   dia_hsb        ! routine called by step.F90
30   PUBLIC   dia_hsb_init   ! routine called by opa.F90
31
32   LOGICAL, PUBLIC ::   ln_diahsb   !: check the heat and salt budgets
33
34   INTEGER                                 ::   numhsb                           !
35   REAL(dp)                                ::   surf_tot   , vol_tot             !
36   REAL(dp)                                ::   frc_t      , frc_s     , frc_v   ! global forcing trends
37   REAL(dp)                                ::   frc_wn_t      , frc_wn_s ! global forcing trends
38   REAL(dp)                                ::   fact1                            ! conversion factors
39   REAL(dp)                                ::   fact21    , fact22               !     -         -
40   REAL(dp)                                ::   fact31    , fact32               !     -         -
41   REAL(dp), DIMENSION(:,:)  , ALLOCATABLE ::   surf      , ssh_ini              !
42   REAL(dp), DIMENSION(:,:,:), ALLOCATABLE ::   hc_loc_ini, sc_loc_ini, e3t_ini  !
43   REAL(dp), DIMENSION(:,:)  , ALLOCATABLE ::   ssh_hc_loc_ini, ssh_sc_loc_ini
44
45   !! * Substitutions
46#  include "domzgr_substitute.h90"
47#  include "vectopt_loop_substitute.h90"
48
49   !!----------------------------------------------------------------------
50   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
51   !! $Id$
52   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
53   !!----------------------------------------------------------------------
54
55CONTAINS
56
57   SUBROUTINE dia_hsb( kt )
58      !!---------------------------------------------------------------------------
59      !!                  ***  ROUTINE dia_hsb  ***
60      !!     
61      !! ** Purpose: Compute the ocean global heat content, salt content and volume conservation
62      !!
63      !! ** Method : - Compute the deviation of heat content, salt content and volume
64      !!             at the current time step from their values at nit000
65      !!             - Compute the contribution of forcing and remove it from these deviations
66      !!
67      !! ** Action : Write the results in the 'heat_salt_volume_budgets.txt' ASCII file
68      !!---------------------------------------------------------------------------
69      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
70      !!
71      INTEGER    ::   jk                          ! dummy loop indice
72      REAL(dp)   ::   zdiff_hc    , zdiff_sc      ! heat and salt content variations
73      REAL(dp)   ::   zdiff_hc1   , zdiff_sc1     ! heat and salt content variations of ssh
74      REAL(dp)   ::   zdiff_v1    , zdiff_v2      ! volume variation
75      REAL(dp)   ::   zerr_hc1    , zerr_sc1      ! Non conservation due to free surface
76      REAL(dp)   ::   zdeltat                     !    -     -
77      REAL(dp)   ::   z_frc_trd_t , z_frc_trd_s   !    -     -
78      REAL(dp)   ::   z_frc_trd_v                 !    -     -
79      REAL(dp)   ::   z_wn_trd_t , z_wn_trd_s   !    -     -
80      REAL(dp)   ::   z_ssh_hc , z_ssh_sc   !    -     -
81      !!---------------------------------------------------------------------------
82      IF( nn_timing == 1 )   CALL timing_start('dia_hsb')
83
84      ! ------------------------- !
85      ! 1 - Trends due to forcing !
86      ! ------------------------- !
87      z_frc_trd_v = r1_rau0 * glob_sum( - ( emp(:,:) - rnf(:,:) ) * surf(:,:) )     ! volume fluxes
88      z_frc_trd_t =           glob_sum( sbc_tsc(:,:,jp_tem) * surf(:,:) )     ! heat fluxes
89      z_frc_trd_s =           glob_sum( sbc_tsc(:,:,jp_sal) * surf(:,:) )     ! salt fluxes
90      ! Add runoff heat & salt input
91      IF( ln_rnf    )   z_frc_trd_t = z_frc_trd_t + glob_sum( rnf_tsc(:,:,jp_tem) * surf(:,:) )
92      IF( ln_rnf_sal)   z_frc_trd_s = z_frc_trd_s + glob_sum( rnf_tsc(:,:,jp_sal) * surf(:,:) )
93      ! Add penetrative solar radiation
94      IF( ln_traqsr )   z_frc_trd_t = z_frc_trd_t + r1_rau0_rcp * glob_sum( qsr     (:,:) * surf(:,:) )
95      ! Add geothermal heat flux
96      IF( ln_trabbc )   z_frc_trd_t = z_frc_trd_t +  glob_sum( qgh_trd0(:,:) * surf(:,:) )
97      IF( .NOT. lk_vvl ) THEN
98         z_wn_trd_t = - glob_sum( surf(:,:) * wn(:,:,1) * tsb(:,:,1,jp_tem) )
99         z_wn_trd_s = - glob_sum( surf(:,:) * wn(:,:,1) * tsb(:,:,1,jp_sal) )
100      ENDIF
101
102      frc_v = frc_v + z_frc_trd_v * rdt
103      frc_t = frc_t + z_frc_trd_t * rdt
104      frc_s = frc_s + z_frc_trd_s * rdt
105      !                                          ! Advection flux through fixed surface (z=0)
106      IF( .NOT. lk_vvl ) THEN
107         frc_wn_t = frc_wn_t + z_wn_trd_t * rdt
108         frc_wn_s = frc_wn_s + z_wn_trd_s * rdt
109      ENDIF
110
111      ! ----------------------- !
112      ! 2 -  Content variations !
113      ! ----------------------- !
114      zdiff_v2 = 0.d0
115      zdiff_hc = 0.d0
116      zdiff_sc = 0.d0
117
118      ! volume variation (calculated with ssh)
119      zdiff_v1 = glob_sum( surf(:,:) * ( sshn(:,:) - ssh_ini(:,:) ) )
120
121      ! heat & salt content variation (associated with ssh)
122      IF( .NOT. lk_vvl ) THEN
123         z_ssh_hc = glob_sum( surf(:,:) * ( tsn(:,:,1,jp_tem) * sshn(:,:) - ssh_hc_loc_ini(:,:) ) )
124         z_ssh_sc = glob_sum( surf(:,:) * ( tsn(:,:,1,jp_sal) * sshn(:,:) - ssh_sc_loc_ini(:,:) ) )
125      ENDIF
126
127      DO jk = 1, jpkm1
128        ! volume variation (calculated with scale factors)
129         zdiff_v2 = zdiff_v2 + glob_sum( surf(:,:) * tmask(:,:,jk)   &
130            &                       * ( fse3t_n(:,:,jk)         &
131            &                           - e3t_ini(:,:,jk) ) )
132         ! heat content variation
133         zdiff_hc = zdiff_hc + glob_sum( surf(:,:) * tmask(:,:,jk)          &
134            &                       * ( fse3t_n(:,:,jk) * tsn(:,:,jk,jp_tem)   &
135            &                           - hc_loc_ini(:,:,jk) ) )
136         ! salt content variation
137         zdiff_sc = zdiff_sc + glob_sum( surf(:,:) * tmask(:,:,jk)          &
138            &                       * ( fse3t_n(:,:,jk) * tsn(:,:,jk,jp_sal)   &
139            &                           - sc_loc_ini(:,:,jk) ) )
140      ENDDO
141
142      ! Substract forcing from heat content, salt content and volume variations
143      zdiff_v1 = zdiff_v1 - frc_v
144      IF( lk_vvl )   zdiff_v2 = zdiff_v2 - frc_v
145      zdiff_hc = zdiff_hc - frc_t
146      zdiff_sc = zdiff_sc - frc_s
147      IF( .NOT. lk_vvl ) THEN
148         zdiff_hc1 = zdiff_hc + z_ssh_hc 
149         zdiff_sc1 = zdiff_sc + z_ssh_sc
150         zerr_hc1  = z_ssh_hc - frc_wn_t
151         zerr_sc1  = z_ssh_sc - frc_wn_s
152      ENDIF
153     
154      ! ----------------------- !
155      ! 3 - Diagnostics writing !
156      ! ----------------------- !
157      zdeltat  = 1.e0 / ( ( kt - nit000 + 1 ) * rdt )
158      IF( lk_vvl ) THEN
159         WRITE(numhsb , 9020) kt , zdiff_hc / vol_tot , zdiff_hc * fact1  * zdeltat,                                &
160            &                      zdiff_sc / vol_tot , zdiff_sc * fact21 * zdeltat, zdiff_sc * fact22 * zdeltat,   &
161            &                      zdiff_v1           , zdiff_v1 * fact31 * zdeltat, zdiff_v1 * fact32 * zdeltat,   &
162            &                      zdiff_v2           , zdiff_v2 * fact31 * zdeltat, zdiff_v2 * fact32 * zdeltat
163      ELSE
164         WRITE(numhsb , 9030) kt , zdiff_hc1 / vol_tot , zdiff_hc1 * fact1  * zdeltat,                                &
165            &                      zdiff_sc1 / vol_tot , zdiff_sc1 * fact21 * zdeltat, zdiff_sc1 * fact22 * zdeltat,   &
166            &                      zdiff_v1            , zdiff_v1  * fact31 * zdeltat, zdiff_v1  * fact32 * zdeltat,   &
167            &                      zerr_hc1 / vol_tot  , zerr_sc1 / vol_tot
168      ENDIF
169
170      IF ( kt == nitend ) CLOSE( numhsb )
171
172      IF( nn_timing == 1 )   CALL timing_stop('dia_hsb')
173
1749020  FORMAT(I5,11D15.7)
1759030  FORMAT(I5,10D15.7)
176      !
177   END SUBROUTINE dia_hsb
178
179
180   SUBROUTINE dia_hsb_init
181      !!---------------------------------------------------------------------------
182      !!                  ***  ROUTINE dia_hsb  ***
183      !!     
184      !! ** Purpose: Initialization for the heat salt volume budgets
185      !!
186      !! ** Method : Compute initial heat content, salt content and volume
187      !!
188      !! ** Action : - Compute initial heat content, salt content and volume
189      !!             - Initialize forcing trends
190      !!             - Compute coefficients for conversion
191      !!---------------------------------------------------------------------------
192      CHARACTER (len=32) ::   cl_name  ! output file name
193      INTEGER            ::   jk       ! dummy loop indice
194      INTEGER            ::   ierror   ! local integer
195      INTEGER            ::   ios      ! Local integer output status for namelist read
196      !!
197      NAMELIST/namhsb/ ln_diahsb
198      !!----------------------------------------------------------------------
199      !
200      REWIND( numnam_ref )              ! Namelist namhsb in reference namelist : Heat & salt budget
201      READ  ( numnam_ref, namhsb, IOSTAT = ios, ERR = 901)
202901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namhsb in reference namelist', lwp )
203
204      REWIND( numnam_cfg )              ! Namelist namhsb in configuration namelist : Heat & salt budget
205      READ  ( numnam_cfg, namhsb, IOSTAT = ios, ERR = 902 )
206902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namhsb in configuration namelist', lwp )
207      WRITE ( numond, namhsb )
208      !
209      IF(lwp) THEN                   ! Control print
210         WRITE(numout,*)
211         WRITE(numout,*) 'dia_hsb_init : check the heat and salt budgets'
212         WRITE(numout,*) '~~~~~~~~~~~~'
213         WRITE(numout,*) '   Namelist namhsb : set hsb parameters'
214         WRITE(numout,*) '      Switch for hsb diagnostic (T) or not (F)  ln_diahsb  = ', ln_diahsb
215      ENDIF
216
217      IF( .NOT. ln_diahsb )   RETURN
218      IF( .NOT. lk_mpp_rep ) &
219        CALL ctl_stop (' Your global mpp_sum if performed in single precision - 64 bits -', &
220             &         ' whereas the global sum to be precise must be done in double precision ',&
221             &         ' please add key_mpp_rep')
222
223      ! ------------------- !
224      ! 1 - Allocate memory !
225      ! ------------------- !
226      ALLOCATE( hc_loc_ini(jpi,jpj,jpk), sc_loc_ini(jpi,jpj,jpk), &
227         &      ssh_hc_loc_ini(jpi,jpj), ssh_sc_loc_ini(jpi,jpj), &
228         &      e3t_ini(jpi,jpj,jpk)                            , &
229         &      surf(jpi,jpj),  ssh_ini(jpi,jpj), STAT=ierror )
230      IF( ierror > 0 ) THEN
231         CALL ctl_stop( 'dia_hsb: unable to allocate hc_loc_ini' )   ;   RETURN
232      ENDIF
233
234      ! ----------------------------------------------- !
235      ! 2 - Time independant variables and file opening !
236      ! ----------------------------------------------- !
237      WRITE(numout,*) "dia_hsb: heat salt volume budgets activated"
238      WRITE(numout,*) "~~~~~~~  output written in the 'heat_salt_volume_budgets.txt' ASCII file"
239      IF( lk_obc .or. lk_bdy ) THEN
240         CALL ctl_warn( 'dia_hsb does not take open boundary fluxes into account' )         
241      ENDIF
242      cl_name    = 'heat_salt_volume_budgets.txt'                         ! name of output file
243      surf(:,:) = e1t(:,:) * e2t(:,:) * tmask(:,:,1) * tmask_i(:,:)      ! masked surface grid cell area
244      surf_tot  = glob_sum( surf(:,:) )                                       ! total ocean surface area
245      vol_tot   = 0.d0                                                   ! total ocean volume
246      DO jk = 1, jpkm1
247         vol_tot  = vol_tot + glob_sum( surf(:,:) * tmask(:,:,jk)     &
248            &                         * fse3t_n(:,:,jk)         )
249      END DO
250
251      CALL ctl_opn( numhsb , cl_name , 'UNKNOWN' , 'FORMATTED' , 'SEQUENTIAL' , 1 , numout , lwp , 1 )
252      IF( lk_vvl ) THEN
253         !                   12345678901234567890123456789012345678901234567890123456789012345678901234567890 -> 80
254         WRITE( numhsb, 9010 ) "kt   |     heat content budget     |            salt content budget             ",   &
255            !                                                   123456789012345678901234567890123456789012345 -> 45
256            &                                                  "|            volume budget (ssh)             ",   &
257            !                                                   678901234567890123456789012345678901234567890 -> 45
258            &                                                  "|            volume budget (e3t)             "
259         WRITE( numhsb, 9010 ) "     |      [C]         [W/m2]     |     [psu]        [mmm/s]          [SV]     ",   &
260            &                                                  "|     [m3]         [mmm/s]          [SV]     ",   &
261            &                                                  "|     [m3]         [mmm/s]          [SV]     "
262      ELSE
263         !                   12345678901234567890123456789012345678901234567890123456789012345678901234567890 -> 80
264         WRITE( numhsb, 9011 ) "kt   |     heat content budget     |            salt content budget             ",   &
265            !                                                   123456789012345678901234567890123456789012345 -> 45
266            &                                                  "|            volume budget (ssh)             ",   &
267            !                                                   678901234567890123456789012345678901234567890 -> 45
268            &                                                  "|  Non conservation due to free surface      "
269         WRITE( numhsb, 9011 ) "     |      [C]         [W/m2]     |     [psu]        [mmm/s]          [SV]     ",   &
270            &                                                  "|     [m3]         [mmm/s]          [SV]     ",   &
271            &                                                  "|  [heat - C]     [salt - psu]                "
272      ENDIF
273      ! --------------- !
274      ! 3 - Conversions ! (factors will be multiplied by duration afterwards)
275      ! --------------- !
276
277      ! heat content variation   =>   equivalent heat flux:
278      fact1  = rau0 * rcp / surf_tot                                         ! [C*m3]   ->  [W/m2]
279      ! salt content variation   =>   equivalent EMP and equivalent "flow":
280      fact21 = 1.e3  / ( soce * surf_tot )                                   ! [psu*m3] ->  [mm/s]
281      fact22 = 1.e-6 / soce                                                  ! [psu*m3] ->  [Sv]
282      ! volume variation         =>   equivalent EMP and equivalent "flow":
283      fact31 = 1.e3  / surf_tot                                              ! [m3]     ->  [mm/s]
284      fact32 = 1.e-6                                                         ! [m3]     ->  [SV]
285
286      ! ---------------------------------- !
287      ! 4 - initial conservation variables !
288      ! ---------------------------------- !
289      ssh_ini(:,:) = sshn(:,:)                                       ! initial ssh
290      DO jk = 1, jpk
291         e3t_ini   (:,:,jk) = fse3t_n(:,:,jk)                        ! initial vertical scale factors
292         hc_loc_ini(:,:,jk) = tsn(:,:,jk,jp_tem) * fse3t_n(:,:,jk)   ! initial heat content
293         sc_loc_ini(:,:,jk) = tsn(:,:,jk,jp_sal) * fse3t_n(:,:,jk)   ! initial salt content
294      END DO
295      frc_v = 0.d0                                           ! volume       trend due to forcing
296      frc_t = 0.d0                                           ! heat content   -    -   -    -   
297      frc_s = 0.d0                                           ! salt content   -    -   -    -         
298      IF( .NOT. lk_vvl ) THEN
299         ssh_hc_loc_ini(:,:) = tsn(:,:,1,jp_tem) * ssh_ini(:,:)   ! initial heat content associated with ssh
300         ssh_sc_loc_ini(:,:) = tsn(:,:,1,jp_sal) * ssh_ini(:,:)   ! initial salt content associated with ssh
301         frc_wn_t = 0.d0
302         frc_wn_s = 0.d0
303      ENDIF
304      !
3059010  FORMAT(A80,A45,A45)
3069011  FORMAT(A80,A45,A45)
307      !
308   END SUBROUTINE dia_hsb_init
309
310   !!======================================================================
311END MODULE diahsb
Note: See TracBrowser for help on using the repository browser.