New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

sbcblk_core.F90 in branches/2013/dev_LOCEAN_2013/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

Context Navigation

source: branches/2013/dev_LOCEAN_2013/NEMOGCM/NEMO/OPA_SRC/SBC/sbcblk_core.F90 @ 4161

Last change on this file since 4161 was 4161, checked in by cetlod, 10 years ago
dev_LOCEAN_2013 : merge in the 3rd dev branch dev_r4028_CNRS_LIM3, see ticket #1169
Property svn:keywords set to `Id`
File size: 54.4 KB

Line
1	MODULE sbcblk_core
2	!!======================================================================
3	!! * MODULE sbcblk_core *
4	!! Ocean forcing: momentum, heat and freshwater flux formulation
5	!!=====================================================================
6	!! History : 1.0 ! 2004-08 (U. Schweckendiek) Original code
7	!! 2.0 ! 2005-04 (L. Brodeau, A.M. Treguier) additions:
8	!! - new bulk routine for efficiency
9	!! - WINDS ARE NOW ASSUMED TO BE AT T POINTS in input files !!!!
10	!! - file names and file characteristics in namelist
11	!! - Implement reading of 6-hourly fields
12	!! 3.0 ! 2006-06 (G. Madec) sbc rewritting
13	!! - ! 2006-12 (L. Brodeau) Original code for TURB_CORE_2Z
14	!! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put
15	!! 3.3 ! 2010-10 (S. Masson) add diurnal cycle
16	!! 3.4 ! 2011-11 (C. Harris) Fill arrays required by CICE
17	!!----------------------------------------------------------------------
18
19	!!----------------------------------------------------------------------
20	!! sbc_blk_core : bulk formulation as ocean surface boundary condition
21	!! (forced mode, CORE bulk formulea)
22	!! blk_oce_core : ocean: computes momentum, heat and freshwater fluxes
23	!! blk_ice_core : ice : computes momentum, heat and freshwater fluxes
24	!! turb_core : computes the CORE turbulent transfer coefficients
25	!!----------------------------------------------------------------------
26	USE oce ! ocean dynamics and tracers
27	USE dom_oce ! ocean space and time domain
28	USE phycst ! physical constants
29	USE fldread ! read input fields
30	USE sbc_oce ! Surface boundary condition: ocean fields
31	USE cyclone ! Cyclone 10m wind form trac of cyclone centres
32	USE sbcdcy ! surface boundary condition: diurnal cycle
33	USE iom ! I/O manager library
34	USE in_out_manager ! I/O manager
35	USE lib_mpp ! distribued memory computing library
36	USE wrk_nemo ! work arrays
37	USE timing ! Timing
38	USE lbclnk ! ocean lateral boundary conditions (or mpp link)
39	USE prtctl ! Print control
40	USE sbcwave,ONLY : cdn_wave !wave module
41	#if defined key_lim3 \|\| defined key_cice
42	USE sbc_ice ! Surface boundary condition: ice fields
43	#endif
44	USE lib_fortran ! to use key_nosignedzero
45
46	IMPLICIT NONE
47	PRIVATE
48
49	PUBLIC sbc_blk_core ! routine called in sbcmod module
50	PUBLIC blk_ice_core ! routine called in sbc_ice_lim module
51	PUBLIC turb_core_2z ! routine calles in sbcblk_mfs module
52
53	INTEGER , PARAMETER :: jpfld = 9 ! maximum number of files to read
54	INTEGER , PARAMETER :: jp_wndi = 1 ! index of 10m wind velocity (i-component) (m/s) at T-point
55	INTEGER , PARAMETER :: jp_wndj = 2 ! index of 10m wind velocity (j-component) (m/s) at T-point
56	INTEGER , PARAMETER :: jp_humi = 3 ! index of specific humidity ( % )
57	INTEGER , PARAMETER :: jp_qsr = 4 ! index of solar heat (W/m2)
58	INTEGER , PARAMETER :: jp_qlw = 5 ! index of Long wave (W/m2)
59	INTEGER , PARAMETER :: jp_tair = 6 ! index of 10m air temperature (Kelvin)
60	INTEGER , PARAMETER :: jp_prec = 7 ! index of total precipitation (rain+snow) (Kg/m2/s)
61	INTEGER , PARAMETER :: jp_snow = 8 ! index of snow (solid prcipitation) (kg/m2/s)
62	INTEGER , PARAMETER :: jp_tdif = 9 ! index of tau diff associated to HF tau (N/m2) at T-point
63
64	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf ! structure of input fields (file informations, fields read)
65
66	! !!! CORE bulk parameters
67	REAL(wp), PARAMETER :: rhoa = 1.22 ! air density
68	REAL(wp), PARAMETER :: cpa = 1000.5 ! specific heat of air
69	REAL(wp), PARAMETER :: Lv = 2.5e6 ! latent heat of vaporization
70	REAL(wp), PARAMETER :: Ls = 2.839e6 ! latent heat of sublimation
71	REAL(wp), PARAMETER :: Stef = 5.67e-8 ! Stefan Boltzmann constant
72	REAL(wp), PARAMETER :: Cice = 1.4e-3 ! iovi 1.63e-3 ! transfer coefficient over ice
73	REAL(wp), PARAMETER :: albo = 0.066 ! ocean albedo assumed to be constant
74
75	! !!* Namelist namsbc_core : CORE bulk parameters
76	LOGICAL :: ln_2m ! logical flag for height of air temp. and hum
77	LOGICAL :: ln_taudif ! logical flag to use the "mean of stress module - module of mean stress" data
78	REAL(wp) :: rn_pfac ! multiplication factor for precipitation
79	REAL(wp) :: rn_efac ! multiplication factor for evaporation (clem)
80	REAL(wp) :: rn_vfac ! multiplication factor for ice/ocean velocity in the calculation of wind stress (clem)
81
82	!! * Substitutions
83	# include "domzgr_substitute.h90"
84	# include "vectopt_loop_substitute.h90"
85	!!----------------------------------------------------------------------
86	!! NEMO/OPA 3.3 , NEMO-consortium (2010)
87	!! $Id$
88	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
89	!!----------------------------------------------------------------------
90	CONTAINS
91
92	SUBROUTINE sbc_blk_core( kt )
93	!!---------------------------------------------------------------------
94	!! * ROUTINE sbc_blk_core *
95	!!
96	!! ** Purpose : provide at each time step the surface ocean fluxes
97	!! (momentum, heat, freshwater and runoff)
98	!!
99	!! ** Method : (1) READ each fluxes in NetCDF files:
100	!! the 10m wind velocity (i-component) (m/s) at T-point
101	!! the 10m wind velocity (j-component) (m/s) at T-point
102	!! the 10m or 2m specific humidity ( % )
103	!! the solar heat (W/m2)
104	!! the Long wave (W/m2)
105	!! the 10m or 2m air temperature (Kelvin)
106	!! the total precipitation (rain+snow) (Kg/m2/s)
107	!! the snow (solid prcipitation) (kg/m2/s)
108	!! the tau diff associated to HF tau (N/m2) at T-point (ln_taudif=T)
109	!! (2) CALL blk_oce_core
110	!!
111	!! C A U T I O N : never mask the surface stress fields
112	!! the stress is assumed to be in the (i,j) mesh referential
113	!!
114	!! ** Action : defined at each time-step at the air-sea interface
115	!! - utau, vtau i- and j-component of the wind stress
116	!! - taum, wndm wind stress and 10m wind modules at T-point
117	!! - qns, qsr non-solar and solar heat fluxes
118	!! - emp upward mass flux (evapo. - precip.)
119	!! - sfx salt flux due to freezing/melting (non-zero only if ice is present)
120	!! (set in limsbc(_2).F90)
121	!!----------------------------------------------------------------------
122	INTEGER, INTENT(in) :: kt ! ocean time step
123	!!
124	INTEGER :: ierror ! return error code
125	INTEGER :: ifpr ! dummy loop indice
126	INTEGER :: jfld ! dummy loop arguments
127	INTEGER :: ios ! Local integer output status for namelist read
128	!!
129	CHARACTER(len=100) :: cn_dir ! Root directory for location of core files
130	TYPE(FLD_N), DIMENSION(jpfld) :: slf_i ! array of namelist informations on the fields to read
131	TYPE(FLD_N) :: sn_wndi, sn_wndj, sn_humi, sn_qsr ! informations about the fields to be read
132	TYPE(FLD_N) :: sn_qlw , sn_tair, sn_prec, sn_snow ! " "
133	TYPE(FLD_N) :: sn_tdif ! " "
134	NAMELIST/namsbc_core/ cn_dir , ln_2m , ln_taudif, rn_pfac, rn_efac, rn_vfac, &
135	& sn_wndi, sn_wndj, sn_humi , sn_qsr , &
136	& sn_qlw , sn_tair, sn_prec , sn_snow, sn_tdif
137	!!---------------------------------------------------------------------
138
139	! ! ====================== !
140	IF( kt == nit000 ) THEN ! First call kt=nit000 !
141	! ! ====================== !
142	!
143
144	REWIND( numnam_ref ) ! Namelist namsbc_core in reference namelist : CORE bulk parameters
145	READ ( numnam_ref, namsbc_core, IOSTAT = ios, ERR = 901)
146	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_core in reference namelist', lwp )
147
148	REWIND( numnam_cfg ) ! Namelist namsbc_core in configuration namelist : CORE bulk parameters
149	READ ( numnam_cfg, namsbc_core, IOSTAT = ios, ERR = 902 )
150	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_core in configuration namelist', lwp )
151
152	WRITE ( numond, namsbc_core )
153	! ! check: do we plan to use ln_dm2dc with non-daily forcing?
154	IF( ln_dm2dc .AND. sn_qsr%nfreqh /= 24 ) &
155	& CALL ctl_stop( 'sbc_blk_core: ln_dm2dc can be activated only with daily short-wave forcing' )
156	IF( ln_dm2dc .AND. sn_qsr%ln_tint ) THEN
157	CALL ctl_warn( 'sbc_blk_core: ln_dm2dc is taking care of the temporal interpolation of daily qsr', &
158	& ' ==> We force time interpolation = .false. for qsr' )
159	sn_qsr%ln_tint = .false.
160	ENDIF
161	! ! store namelist information in an array
162	slf_i(jp_wndi) = sn_wndi ; slf_i(jp_wndj) = sn_wndj
163	slf_i(jp_qsr ) = sn_qsr ; slf_i(jp_qlw ) = sn_qlw
164	slf_i(jp_tair) = sn_tair ; slf_i(jp_humi) = sn_humi
165	slf_i(jp_prec) = sn_prec ; slf_i(jp_snow) = sn_snow
166	slf_i(jp_tdif) = sn_tdif
167	!
168	lhftau = ln_taudif ! do we use HF tau information?
169	jfld = jpfld - COUNT( (/.NOT. lhftau/) )
170	!
171	ALLOCATE( sf(jfld), STAT=ierror ) ! set sf structure
172	IF( ierror > 0 ) CALL ctl_stop( 'STOP', 'sbc_blk_core: unable to allocate sf structure' )
173	DO ifpr= 1, jfld
174	ALLOCATE( sf(ifpr)%fnow(jpi,jpj,1) )
175	IF( slf_i(ifpr)%ln_tint ) ALLOCATE( sf(ifpr)%fdta(jpi,jpj,1,2) )
176	END DO
177	! ! fill sf with slf_i and control print
178	CALL fld_fill( sf, slf_i, cn_dir, 'sbc_blk_core', 'flux formulation for ocean surface boundary condition', 'namsbc_core' )
179	!
180	sfx(:,:) = 0._wp ! salt flux; zero unless ice is present (computed in limsbc(_2).F90)
181	!
182	ENDIF
183
184	CALL fld_read( kt, nn_fsbc, sf ) ! input fields provided at the current time-step
185
186	! ! compute the surface ocean fluxes using CORE bulk formulea
187	IF( MOD( kt - 1, nn_fsbc ) == 0 ) CALL blk_oce_core( kt, sf, sst_m, ssu_m, ssv_m )
188
189	#if defined key_cice
190	IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
191	qlw_ice(:,:,1) = sf(jp_qlw)%fnow(:,:,1)
192	qsr_ice(:,:,1) = sf(jp_qsr)%fnow(:,:,1)
193	tatm_ice(:,:) = sf(jp_tair)%fnow(:,:,1)
194	qatm_ice(:,:) = sf(jp_humi)%fnow(:,:,1)
195	tprecip(:,:) = sf(jp_prec)%fnow(:,:,1) * rn_pfac
196	sprecip(:,:) = sf(jp_snow)%fnow(:,:,1) * rn_pfac
197	wndi_ice(:,:) = sf(jp_wndi)%fnow(:,:,1)
198	wndj_ice(:,:) = sf(jp_wndj)%fnow(:,:,1)
199	ENDIF
200	#endif
201	!
202	END SUBROUTINE sbc_blk_core
203
204
205	SUBROUTINE blk_oce_core( kt, sf, pst, pu, pv )
206	!!---------------------------------------------------------------------
207	!! * ROUTINE blk_core *
208	!!
209	!! ** Purpose : provide the momentum, heat and freshwater fluxes at
210	!! the ocean surface at each time step
211	!!
212	!! ** Method : CORE bulk formulea for the ocean using atmospheric
213	!! fields read in sbc_read
214	!!
215	!! ** Outputs : - utau : i-component of the stress at U-point (N/m2)
216	!! - vtau : j-component of the stress at V-point (N/m2)
217	!! - taum : Wind stress module at T-point (N/m2)
218	!! - wndm : Wind speed module at T-point (m/s)
219	!! - qsr : Solar heat flux over the ocean (W/m2)
220	!! - qns : Non Solar heat flux over the ocean (W/m2)
221	!! - evap : Evaporation over the ocean (kg/m2/s)
222	!! - emp : evaporation minus precipitation (kg/m2/s)
223	!!
224	!! ** Nota : sf has to be a dummy argument for AGRIF on NEC
225	!!---------------------------------------------------------------------
226	INTEGER , INTENT(in ) :: kt ! time step index
227	TYPE(fld), INTENT(inout), DIMENSION(:) :: sf ! input data
228	REAL(wp) , INTENT(in) , DIMENSION(:,:) :: pst ! surface temperature [Celcius]
229	REAL(wp) , INTENT(in) , DIMENSION(:,:) :: pu ! surface current at U-point (i-component) [m/s]
230	REAL(wp) , INTENT(in) , DIMENSION(:,:) :: pv ! surface current at V-point (j-component) [m/s]
231	!
232	INTEGER :: ji, jj ! dummy loop indices
233	REAL(wp) :: zcoef_qsatw, zztmp ! local variable
234	REAL(wp), DIMENSION(:,:), POINTER :: zwnd_i, zwnd_j ! wind speed components at T-point
235	REAL(wp), DIMENSION(:,:), POINTER :: zqsatw ! specific humidity at pst
236	REAL(wp), DIMENSION(:,:), POINTER :: zqlw, zqsb ! long wave and sensible heat fluxes
237	REAL(wp), DIMENSION(:,:), POINTER :: zqla, zevap ! latent heat fluxes and evaporation
238	REAL(wp), DIMENSION(:,:), POINTER :: Cd ! transfer coefficient for momentum (tau)
239	REAL(wp), DIMENSION(:,:), POINTER :: Ch ! transfer coefficient for sensible heat (Q_sens)
240	REAL(wp), DIMENSION(:,:), POINTER :: Ce ! tansfert coefficient for evaporation (Q_lat)
241	REAL(wp), DIMENSION(:,:), POINTER :: zst ! surface temperature in Kelvin
242	REAL(wp), DIMENSION(:,:), POINTER :: zt_zu ! air temperature at wind speed height
243	REAL(wp), DIMENSION(:,:), POINTER :: zq_zu ! air spec. hum. at wind speed height
244	!!---------------------------------------------------------------------
245	!
246	IF( nn_timing == 1 ) CALL timing_start('blk_oce_core')
247	!
248	CALL wrk_alloc( jpi,jpj, zwnd_i, zwnd_j, zqsatw, zqlw, zqsb, zqla, zevap )
249	CALL wrk_alloc( jpi,jpj, Cd, Ch, Ce, zst, zt_zu, zq_zu )
250	!
251	! local scalars ( place there for vector optimisation purposes)
252	zcoef_qsatw = 0.98 * 640380. / rhoa
253
254	zst(:,:) = pst(:,:) + rt0 ! convert SST from Celcius to Kelvin (and set minimum value far above 0 K)
255
256	! ----------------------------------------------------------------------------- !
257	! 0 Wind components and module at T-point relative to the moving ocean !
258	! ----------------------------------------------------------------------------- !
259
260	! ... components ( U10m - U_oce ) at T-point (unmasked)
261	zwnd_i(:,:) = 0.e0
262	zwnd_j(:,:) = 0.e0
263	#if defined key_cyclone
264	# if defined key_vectopt_loop
265	!CDIR COLLAPSE
266	# endif
267	CALL wnd_cyc( kt, zwnd_i, zwnd_j ) ! add Manu !
268	DO jj = 2, jpjm1
269	DO ji = fs_2, fs_jpim1 ! vect. opt.
270	sf(jp_wndi)%fnow(ji,jj,1) = sf(jp_wndi)%fnow(ji,jj,1) + zwnd_i(ji,jj)
271	sf(jp_wndj)%fnow(ji,jj,1) = sf(jp_wndj)%fnow(ji,jj,1) + zwnd_j(ji,jj)
272	END DO
273	END DO
274	#endif
275	#if defined key_vectopt_loop
276	!CDIR COLLAPSE
277	#endif
278	DO jj = 2, jpjm1
279	DO ji = fs_2, fs_jpim1 ! vect. opt.
280	zwnd_i(ji,jj) = ( sf(jp_wndi)%fnow(ji,jj,1) - rn_vfac * 0.5 * ( pu(ji-1,jj ) + pu(ji,jj) ) )
281	zwnd_j(ji,jj) = ( sf(jp_wndj)%fnow(ji,jj,1) - rn_vfac * 0.5 * ( pv(ji ,jj-1) + pv(ji,jj) ) )
282	END DO
283	END DO
284	CALL lbc_lnk( zwnd_i(:,:) , 'T', -1. )
285	CALL lbc_lnk( zwnd_j(:,:) , 'T', -1. )
286	! ... scalar wind ( = \| U10m - U_oce \| ) at T-point (masked)
287	!CDIR NOVERRCHK
288	!CDIR COLLAPSE
289	wndm(:,:) = SQRT( zwnd_i(:,:) * zwnd_i(:,:) &
290	& + zwnd_j(:,:) * zwnd_j(:,:) ) * tmask(:,:,1)
291
292	! ----------------------------------------------------------------------------- !
293	! I Radiative FLUXES !
294	! ----------------------------------------------------------------------------- !
295
296	! ocean albedo assumed to be constant + modify now Qsr to include the diurnal cycle ! Short Wave
297	zztmp = 1. - albo
298	IF( ln_dm2dc ) THEN ; qsr(:,:) = zztmp * sbc_dcy( sf(jp_qsr)%fnow(:,:,1) ) * tmask(:,:,1)
299	ELSE ; qsr(:,:) = zztmp * sf(jp_qsr)%fnow(:,:,1) * tmask(:,:,1)
300	ENDIF
301	!CDIR COLLAPSE
302	zqlw(:,:) = ( sf(jp_qlw)%fnow(:,:,1) - Stef * zst(:,:)zst(:,:)zst(:,:)zst(:,:) ) tmask(:,:,1) ! Long Wave
303	! ----------------------------------------------------------------------------- !
304	! II Turbulent FLUXES !
305	! ----------------------------------------------------------------------------- !
306
307	! ... specific humidity at SST and IST
308	!CDIR NOVERRCHK
309	!CDIR COLLAPSE
310	zqsatw(:,:) = zcoef_qsatw * EXP( -5107.4 / zst(:,:) )
311
312	! ... NCAR Bulk formulae, computation of Cd, Ch, Ce at T-point :
313	IF( ln_2m ) THEN
314	!! If air temp. and spec. hum. are given at different height (2m) than wind (10m) :
315	CALL TURB_CORE_2Z(2.,10., zst , sf(jp_tair)%fnow, &
316	& zqsatw, sf(jp_humi)%fnow, wndm, &
317	& Cd , Ch , Ce , &
318	& zt_zu , zq_zu )
319	ELSE
320	!! If air temp. and spec. hum. are given at same height than wind (10m) :
321	!gm bug? at the compiling phase, add a copy in temporary arrays... ==> check perf
322	! CALL TURB_CORE_1Z( 10., zst (:,:), sf(jp_tair)%fnow(:,:), &
323	! & zqsatw(:,:), sf(jp_humi)%fnow(:,:), wndm(:,:), &
324	! & Cd (:,:), Ch (:,:), Ce (:,:) )
325	!gm bug
326	! ARPDBG - this won't compile with gfortran. Fix but check performance
327	! as per comment above.
328	CALL TURB_CORE_1Z( 10., zst , sf(jp_tair)%fnow(:,:,1), &
329	& zqsatw, sf(jp_humi)%fnow(:,:,1), wndm, &
330	& Cd , Ch , Ce )
331	ENDIF
332
333	! ... tau module, i and j component
334	DO jj = 1, jpj
335	DO ji = 1, jpi
336	zztmp = rhoa * wndm(ji,jj) * Cd(ji,jj)
337	taum (ji,jj) = zztmp * wndm (ji,jj)
338	zwnd_i(ji,jj) = zztmp * zwnd_i(ji,jj)
339	zwnd_j(ji,jj) = zztmp * zwnd_j(ji,jj)
340	END DO
341	END DO
342
343	! ... add the HF tau contribution to the wind stress module?
344	IF( lhftau ) THEN
345	!CDIR COLLAPSE
346	taum(:,:) = taum(:,:) + sf(jp_tdif)%fnow(:,:,1)
347	ENDIF
348	CALL iom_put( "taum_oce", taum ) ! output wind stress module
349
350	! ... utau, vtau at U- and V_points, resp.
351	! Note the use of 0.5*(2-umask) in order to unmask the stress along coastlines
352	DO jj = 1, jpjm1
353	DO ji = 1, fs_jpim1
354	utau(ji,jj) = 0.5 * ( 2. - umask(ji,jj,1) ) * ( zwnd_i(ji,jj) + zwnd_i(ji+1,jj ) )
355	vtau(ji,jj) = 0.5 * ( 2. - vmask(ji,jj,1) ) * ( zwnd_j(ji,jj) + zwnd_j(ji ,jj+1) )
356	END DO
357	END DO
358	CALL lbc_lnk( utau(:,:), 'U', -1. )
359	CALL lbc_lnk( vtau(:,:), 'V', -1. )
360
361	! Turbulent fluxes over ocean
362	! -----------------------------
363	IF( ln_2m ) THEN
364	! Values of temp. and hum. adjusted to 10m must be used instead of 2m values
365	zevap(:,:) = rn_efac * MAX( 0.e0, rhoa Ce(:,:)( zqsatw(:,:) - zq_zu(:,:) ) * wndm(:,:) ) ! Evaporation
366	zqsb (:,:) = rhoacpaCh(:,:)( zst (:,:) - zt_zu(:,:) ) wndm(:,:) ! Sensible Heat
367	ELSE
368	!CDIR COLLAPSE
369	zevap(:,:) = rn_efac * MAX( 0.e0, rhoa Ce(:,:)( zqsatw(:,:) - sf(jp_humi)%fnow(:,:,1) ) * wndm(:,:) ) ! Evaporation
370	!CDIR COLLAPSE
371	zqsb (:,:) = rhoacpaCh(:,:)( zst (:,:) - sf(jp_tair)%fnow(:,:,1) ) wndm(:,:) ! Sensible Heat
372	ENDIF
373	!CDIR COLLAPSE
374	zqla (:,:) = Lv * zevap(:,:) ! Latent Heat
375
376	IF(ln_ctl) THEN
377	CALL prt_ctl( tab2d_1=zqla , clinfo1=' blk_oce_core: zqla : ', tab2d_2=Ce , clinfo2=' Ce : ' )
378	CALL prt_ctl( tab2d_1=zqsb , clinfo1=' blk_oce_core: zqsb : ', tab2d_2=Ch , clinfo2=' Ch : ' )
379	CALL prt_ctl( tab2d_1=zqlw , clinfo1=' blk_oce_core: zqlw : ', tab2d_2=qsr, clinfo2=' qsr : ' )
380	CALL prt_ctl( tab2d_1=zqsatw, clinfo1=' blk_oce_core: zqsatw : ', tab2d_2=zst, clinfo2=' zst : ' )
381	CALL prt_ctl( tab2d_1=utau , clinfo1=' blk_oce_core: utau : ', mask1=umask, &
382	& tab2d_2=vtau , clinfo2= ' vtau : ' , mask2=vmask )
383	CALL prt_ctl( tab2d_1=wndm , clinfo1=' blk_oce_core: wndm : ')
384	CALL prt_ctl( tab2d_1=zst , clinfo1=' blk_oce_core: zst : ')
385	ENDIF
386
387	! ----------------------------------------------------------------------------- !
388	! III Total FLUXES !
389	! ----------------------------------------------------------------------------- !
390
391	!CDIR COLLAPSE
392	emp (:,:) = ( zevap(:,:) & ! mass flux (evap. - precip.)
393	& - sf(jp_prec)%fnow(:,:,1) * rn_pfac ) * tmask(:,:,1)
394	!CDIR COLLAPSE
395	qns(:,:) = zqlw(:,:) - zqsb(:,:) - zqla(:,:) & ! Downward Non Solar flux
396	& - sf(jp_snow)%fnow(:,:,1) * rn_pfac * lfus & ! remove latent melting heat for solid precip
397	& - zevap(:,:) * pst(:,:) * rcp & ! remove evap heat content at SST
398	& + ( sf(jp_prec)%fnow(:,:,1) - sf(jp_snow)%fnow(:,:,1) ) * rn_pfac & ! add liquid precip heat content at Tair
399	& * ( sf(jp_tair)%fnow(:,:,1) - rt0 ) * rcp &
400	& + sf(jp_snow)%fnow(:,:,1) * rn_pfac & ! add solid precip heat content at min(Tair,Tsnow)
401	& * ( MIN( sf(jp_tair)%fnow(:,:,1), rt0_snow ) - rt0 ) * cpic
402	!
403	CALL iom_put( "qlw_oce", zqlw ) ! output downward longwave heat over the ocean
404	CALL iom_put( "qsb_oce", - zqsb ) ! output downward sensible heat over the ocean
405	CALL iom_put( "qla_oce", - zqla ) ! output downward latent heat over the ocean
406	CALL iom_put( "qhc_oce", qns-zqlw+zqsb+zqla ) ! output downward heat content of E-P over the ocean
407	CALL iom_put( "qns_oce", qns ) ! output downward non solar heat over the ocean
408	!
409	IF(ln_ctl) THEN
410	CALL prt_ctl(tab2d_1=zqsb , clinfo1=' blk_oce_core: zqsb : ', tab2d_2=zqlw , clinfo2=' zqlw : ')
411	CALL prt_ctl(tab2d_1=zqla , clinfo1=' blk_oce_core: zqla : ', tab2d_2=qsr , clinfo2=' qsr : ')
412	CALL prt_ctl(tab2d_1=pst , clinfo1=' blk_oce_core: pst : ', tab2d_2=emp , clinfo2=' emp : ')
413	CALL prt_ctl(tab2d_1=utau , clinfo1=' blk_oce_core: utau : ', mask1=umask, &
414	& tab2d_2=vtau , clinfo2= ' vtau : ' , mask2=vmask )
415	ENDIF
416	!
417	CALL wrk_dealloc( jpi,jpj, zwnd_i, zwnd_j, zqsatw, zqlw, zqsb, zqla, zevap )
418	CALL wrk_dealloc( jpi,jpj, Cd, Ch, Ce, zst, zt_zu, zq_zu )
419	!
420	IF( nn_timing == 1 ) CALL timing_stop('blk_oce_core')
421	!
422	END SUBROUTINE blk_oce_core
423
424
425	SUBROUTINE blk_ice_core( pst , pui , pvi , palb , &
426	& p_taui, p_tauj, p_qns , p_qsr, &
427	& p_qla , p_dqns, p_dqla, &
428	& p_tpr , p_spr , &
429	& p_fr1 , p_fr2 , cd_grid, pdim )
430	!!---------------------------------------------------------------------
431	!! * ROUTINE blk_ice_core *
432	!!
433	!! ** Purpose : provide the surface boundary condition over sea-ice
434	!!
435	!! ** Method : compute momentum, heat and freshwater exchanged
436	!! between atmosphere and sea-ice using CORE bulk
437	!! formulea, ice variables and read atmmospheric fields.
438	!! NB: ice drag coefficient is assumed to be a constant
439	!!
440	!! caution : the net upward water flux has with mm/day unit
441	!!---------------------------------------------------------------------
442	REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: pst ! ice surface temperature (>0, =rt0 over land) [Kelvin]
443	REAL(wp), DIMENSION(:,:) , INTENT(in ) :: pui ! ice surface velocity (i- and i- components [m/s]
444	REAL(wp), DIMENSION(:,:) , INTENT(in ) :: pvi ! at I-point (B-grid) or U & V-point (C-grid)
445	REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: palb ! ice albedo (clear sky) (alb_ice_cs) [%]
446	REAL(wp), DIMENSION(:,:) , INTENT( out) :: p_taui ! i- & j-components of surface ice stress [N/m2]
447	REAL(wp), DIMENSION(:,:) , INTENT( out) :: p_tauj ! at I-point (B-grid) or U & V-point (C-grid)
448	REAL(wp), DIMENSION(:,:,:), INTENT( out) :: p_qns ! non solar heat flux over ice (T-point) [W/m2]
449	REAL(wp), DIMENSION(:,:,:), INTENT( out) :: p_qsr ! solar heat flux over ice (T-point) [W/m2]
450	REAL(wp), DIMENSION(:,:,:), INTENT( out) :: p_qla ! latent heat flux over ice (T-point) [W/m2]
451	REAL(wp), DIMENSION(:,:,:), INTENT( out) :: p_dqns ! non solar heat sensistivity (T-point) [W/m2]
452	REAL(wp), DIMENSION(:,:,:), INTENT( out) :: p_dqla ! latent heat sensistivity (T-point) [W/m2]
453	REAL(wp), DIMENSION(:,:) , INTENT( out) :: p_tpr ! total precipitation (T-point) [Kg/m2/s]
454	REAL(wp), DIMENSION(:,:) , INTENT( out) :: p_spr ! solid precipitation (T-point) [Kg/m2/s]
455	REAL(wp), DIMENSION(:,:) , INTENT( out) :: p_fr1 ! 1sr fraction of qsr penetration in ice (T-point) [%]
456	REAL(wp), DIMENSION(:,:) , INTENT( out) :: p_fr2 ! 2nd fraction of qsr penetration in ice (T-point) [%]
457	CHARACTER(len=1) , INTENT(in ) :: cd_grid ! ice grid ( C or B-grid)
458	INTEGER , INTENT(in ) :: pdim ! number of ice categories
459	!!
460	INTEGER :: ji, jj, jl ! dummy loop indices
461	INTEGER :: ijpl ! number of ice categories (size of 3rd dim of input arrays)
462	REAL(wp) :: zst2, zst3
463	REAL(wp) :: zcoef_wnorm, zcoef_wnorm2, zcoef_dqlw, zcoef_dqla, zcoef_dqsb
464	REAL(wp) :: zztmp ! temporary variable
465	REAL(wp) :: zcoef_frca ! fractional cloud amount
466	REAL(wp) :: zwnorm_f, zwndi_f , zwndj_f ! relative wind module and components at F-point
467	REAL(wp) :: zwndi_t , zwndj_t ! relative wind components at T-point
468	!!
469	REAL(wp), DIMENSION(:,:) , POINTER :: z_wnds_t ! wind speed ( = \| U10m - U_ice \| ) at T-point
470	REAL(wp), DIMENSION(:,:,:), POINTER :: z_qlw ! long wave heat flux over ice
471	REAL(wp), DIMENSION(:,:,:), POINTER :: z_qsb ! sensible heat flux over ice
472	REAL(wp), DIMENSION(:,:,:), POINTER :: z_dqlw ! long wave heat sensitivity over ice
473	REAL(wp), DIMENSION(:,:,:), POINTER :: z_dqsb ! sensible heat sensitivity over ice
474	!!---------------------------------------------------------------------
475	!
476	IF( nn_timing == 1 ) CALL timing_start('blk_ice_core')
477	!
478	CALL wrk_alloc( jpi,jpj, z_wnds_t )
479	CALL wrk_alloc( jpi,jpj,pdim, z_qlw, z_qsb, z_dqlw, z_dqsb )
480
481	ijpl = pdim ! number of ice categories
482
483	! local scalars ( place there for vector optimisation purposes)
484	zcoef_wnorm = rhoa * Cice
485	zcoef_wnorm2 = rhoa * Cice * 0.5
486	zcoef_dqlw = 4.0 * 0.95 * Stef
487	zcoef_dqla = -Ls * Cice * 11637800. * (-5897.8)
488	zcoef_dqsb = rhoa * cpa * Cice
489	zcoef_frca = 1.0 - 0.3
490
491	!!gm brutal....
492	z_wnds_t(:,:) = 0.e0
493	p_taui (:,:) = 0.e0
494	p_tauj (:,:) = 0.e0
495	!!gm end
496
497	#if defined key_lim3
498	tatm_ice(:,:) = sf(jp_tair)%fnow(:,:,1) ! LIM3: make Tair available in sea-ice. WARNING allocated after call to ice_init
499	#endif
500	! ----------------------------------------------------------------------------- !
501	! Wind components and module relative to the moving ocean ( U10m - U_ice ) !
502	! ----------------------------------------------------------------------------- !
503	SELECT CASE( cd_grid )
504	CASE( 'I' ) ! B-grid ice dynamics : I-point (i.e. F-point with sea-ice indexation)
505	! and scalar wind at T-point ( = \| U10m - U_ice \| ) (masked)
506	!CDIR NOVERRCHK
507	DO jj = 2, jpjm1
508	DO ji = 2, jpim1 ! B grid : NO vector opt
509	! ... scalar wind at I-point (fld being at T-point)
510	zwndi_f = 0.25 * ( sf(jp_wndi)%fnow(ji-1,jj ,1) + sf(jp_wndi)%fnow(ji ,jj ,1) &
511	& + sf(jp_wndi)%fnow(ji-1,jj-1,1) + sf(jp_wndi)%fnow(ji ,jj-1,1) ) - rn_vfac * pui(ji,jj)
512	zwndj_f = 0.25 * ( sf(jp_wndj)%fnow(ji-1,jj ,1) + sf(jp_wndj)%fnow(ji ,jj ,1) &
513	& + sf(jp_wndj)%fnow(ji-1,jj-1,1) + sf(jp_wndj)%fnow(ji ,jj-1,1) ) - rn_vfac * pvi(ji,jj)
514	zwnorm_f = zcoef_wnorm * SQRT( zwndi_f * zwndi_f + zwndj_f * zwndj_f )
515	! ... ice stress at I-point
516	p_taui(ji,jj) = zwnorm_f * zwndi_f
517	p_tauj(ji,jj) = zwnorm_f * zwndj_f
518	! ... scalar wind at T-point (fld being at T-point)
519	zwndi_t = sf(jp_wndi)%fnow(ji,jj,1) - rn_vfac * 0.25 * ( pui(ji,jj+1) + pui(ji+1,jj+1) &
520	& + pui(ji,jj ) + pui(ji+1,jj ) )
521	zwndj_t = sf(jp_wndj)%fnow(ji,jj,1) - rn_vfac * 0.25 * ( pvi(ji,jj+1) + pvi(ji+1,jj+1) &
522	& + pvi(ji,jj ) + pvi(ji+1,jj ) )
523	z_wnds_t(ji,jj) = SQRT( zwndi_t * zwndi_t + zwndj_t * zwndj_t ) * tmask(ji,jj,1)
524	END DO
525	END DO
526	CALL lbc_lnk( p_taui , 'I', -1. )
527	CALL lbc_lnk( p_tauj , 'I', -1. )
528	CALL lbc_lnk( z_wnds_t, 'T', 1. )
529	!
530	CASE( 'C' ) ! C-grid ice dynamics : U & V-points (same as ocean)
531	#if defined key_vectopt_loop
532	!CDIR COLLAPSE
533	#endif
534	DO jj = 2, jpj
535	DO ji = fs_2, jpi ! vect. opt.
536	zwndi_t = ( sf(jp_wndi)%fnow(ji,jj,1) - rn_vfac * 0.5 * ( pui(ji-1,jj ) + pui(ji,jj) ) )
537	zwndj_t = ( sf(jp_wndj)%fnow(ji,jj,1) - rn_vfac * 0.5 * ( pvi(ji ,jj-1) + pvi(ji,jj) ) )
538	z_wnds_t(ji,jj) = SQRT( zwndi_t * zwndi_t + zwndj_t * zwndj_t ) * tmask(ji,jj,1)
539	END DO
540	END DO
541	#if defined key_vectopt_loop
542	!CDIR COLLAPSE
543	#endif
544	DO jj = 2, jpjm1
545	DO ji = fs_2, fs_jpim1 ! vect. opt.
546	p_taui(ji,jj) = zcoef_wnorm2 * ( z_wnds_t(ji+1,jj ) + z_wnds_t(ji,jj) ) &
547	& * ( 0.5 * (sf(jp_wndi)%fnow(ji+1,jj,1) + sf(jp_wndi)%fnow(ji,jj,1) ) - rn_vfac * pui(ji,jj) )
548	p_tauj(ji,jj) = zcoef_wnorm2 * ( z_wnds_t(ji,jj+1 ) + z_wnds_t(ji,jj) ) &
549	& * ( 0.5 * (sf(jp_wndj)%fnow(ji,jj+1,1) + sf(jp_wndj)%fnow(ji,jj,1) ) - rn_vfac * pvi(ji,jj) )
550	END DO
551	END DO
552	CALL lbc_lnk( p_taui , 'U', -1. )
553	CALL lbc_lnk( p_tauj , 'V', -1. )
554	CALL lbc_lnk( z_wnds_t, 'T', 1. )
555	!
556	END SELECT
557
558	zztmp = 1. / ( 1. - albo )
559	! ! ========================== !
560	DO jl = 1, ijpl ! Loop over ice categories !
561	! ! ========================== !
562	!CDIR NOVERRCHK
563	!CDIR COLLAPSE
564	DO jj = 1 , jpj
565	!CDIR NOVERRCHK
566	DO ji = 1, jpi
567	! ----------------------------!
568	! I Radiative FLUXES !
569	! ----------------------------!
570	zst2 = pst(ji,jj,jl) * pst(ji,jj,jl)
571	zst3 = pst(ji,jj,jl) * zst2
572	! Short Wave (sw)
573	p_qsr(ji,jj,jl) = zztmp * ( 1. - palb(ji,jj,jl) ) * qsr(ji,jj)
574	! Long Wave (lw)
575	! iovino
576	IF( ff(ji,jj) .GT. 0._wp ) THEN
577	z_qlw(ji,jj,jl) = ( 0.95 * sf(jp_qlw)%fnow(ji,jj,1) - Stef * pst(ji,jj,jl) * zst3 ) * tmask(ji,jj,1)
578	ELSE
579	z_qlw(ji,jj,jl) = 0.95 * ( sf(jp_qlw)%fnow(ji,jj,1) - Stef * pst(ji,jj,jl) * zst3 ) * tmask(ji,jj,1)
580	ENDIF
581	! lw sensitivity
582	z_dqlw(ji,jj,jl) = zcoef_dqlw * zst3
583
584	! ----------------------------!
585	! II Turbulent FLUXES !
586	! ----------------------------!
587
588	! ... turbulent heat fluxes
589	! Sensible Heat
590	z_qsb(ji,jj,jl) = rhoa * cpa * Cice * z_wnds_t(ji,jj) * ( pst(ji,jj,jl) - sf(jp_tair)%fnow(ji,jj,1) )
591	! Latent Heat
592	p_qla(ji,jj,jl) = rn_efac * MAX( 0.e0, rhoa * Ls * Cice * z_wnds_t(ji,jj) &
593	& * ( 11637800. * EXP( -5897.8 / pst(ji,jj,jl) ) / rhoa - sf(jp_humi)%fnow(ji,jj,1) ) )
594	! Latent heat sensitivity for ice (Dqla/Dt)
595	p_dqla(ji,jj,jl) = rn_efac * zcoef_dqla * z_wnds_t(ji,jj) / ( zst2 ) * EXP( -5897.8 / pst(ji,jj,jl) )
596	! Sensible heat sensitivity (Dqsb_ice/Dtn_ice)
597	z_dqsb(ji,jj,jl) = zcoef_dqsb * z_wnds_t(ji,jj)
598
599	! ----------------------------!
600	! III Total FLUXES !
601	! ----------------------------!
602	! Downward Non Solar flux
603	p_qns (ji,jj,jl) = z_qlw (ji,jj,jl) - z_qsb (ji,jj,jl) - p_qla (ji,jj,jl)
604	! Total non solar heat flux sensitivity for ice
605	p_dqns(ji,jj,jl) = - ( z_dqlw(ji,jj,jl) + z_dqsb(ji,jj,jl) + p_dqla(ji,jj,jl) )
606	END DO
607	!
608	END DO
609	!
610	END DO
611	!
612	!--------------------------------------------------------------------
613	! FRACTIONs of net shortwave radiation which is not absorbed in the
614	! thin surface layer and penetrates inside the ice cover
615	! ( Maykut and Untersteiner, 1971 ; Ebert and Curry, 1993 )
616
617	!CDIR COLLAPSE
618	p_fr1(:,:) = ( 0.18 * ( 1.0 - zcoef_frca ) + 0.35 * zcoef_frca )
619	!CDIR COLLAPSE
620	p_fr2(:,:) = ( 0.82 * ( 1.0 - zcoef_frca ) + 0.65 * zcoef_frca )
621
622	!CDIR COLLAPSE
623	p_tpr(:,:) = sf(jp_prec)%fnow(:,:,1) * rn_pfac ! total precipitation [kg/m2/s]
624	!CDIR COLLAPSE
625	p_spr(:,:) = sf(jp_snow)%fnow(:,:,1) * rn_pfac ! solid precipitation [kg/m2/s]
626	CALL iom_put( 'snowpre', p_spr * 86400. ) ! Snow precipitation
627	CALL iom_put( 'precip', p_tpr * 86400. ) ! Total precipitation
628	!
629	IF(ln_ctl) THEN
630	CALL prt_ctl(tab3d_1=p_qla , clinfo1=' blk_ice_core: p_qla : ', tab3d_2=z_qsb , clinfo2=' z_qsb : ', kdim=ijpl)
631	CALL prt_ctl(tab3d_1=z_qlw , clinfo1=' blk_ice_core: z_qlw : ', tab3d_2=p_dqla , clinfo2=' p_dqla : ', kdim=ijpl)
632	CALL prt_ctl(tab3d_1=z_dqsb , clinfo1=' blk_ice_core: z_dqsb : ', tab3d_2=z_dqlw , clinfo2=' z_dqlw : ', kdim=ijpl)
633	CALL prt_ctl(tab3d_1=p_dqns , clinfo1=' blk_ice_core: p_dqns : ', tab3d_2=p_qsr , clinfo2=' p_qsr : ', kdim=ijpl)
634	CALL prt_ctl(tab3d_1=pst , clinfo1=' blk_ice_core: pst : ', tab3d_2=p_qns , clinfo2=' p_qns : ', kdim=ijpl)
635	CALL prt_ctl(tab2d_1=p_tpr , clinfo1=' blk_ice_core: p_tpr : ', tab2d_2=p_spr , clinfo2=' p_spr : ')
636	CALL prt_ctl(tab2d_1=p_taui , clinfo1=' blk_ice_core: p_taui : ', tab2d_2=p_tauj , clinfo2=' p_tauj : ')
637	CALL prt_ctl(tab2d_1=z_wnds_t, clinfo1=' blk_ice_core: z_wnds_t : ')
638	ENDIF
639
640	CALL wrk_dealloc( jpi,jpj, z_wnds_t )
641	CALL wrk_dealloc( jpi,jpj,pdim, z_qlw, z_qsb, z_dqlw, z_dqsb )
642	!
643	IF( nn_timing == 1 ) CALL timing_stop('blk_ice_core')
644	!
645	END SUBROUTINE blk_ice_core
646
647
648	SUBROUTINE TURB_CORE_1Z(zu, sst, T_a, q_sat, q_a, &
649	& dU , Cd , Ch , Ce )
650	!!----------------------------------------------------------------------
651	!! * ROUTINE turb_core *
652	!!
653	!! ** Purpose : Computes turbulent transfert coefficients of surface
654	!! fluxes according to Large & Yeager (2004)
655	!!
656	!! ** Method : I N E R T I A L D I S S I P A T I O N M E T H O D
657	!! Momentum, Latent and sensible heat exchange coefficients
658	!! Caution: this procedure should only be used in cases when air
659	!! temperature (T_air), air specific humidity (q_air) and wind (dU)
660	!! are provided at the same height 'zzu'!
661	!!
662	!! References : Large & Yeager, 2004 : ???
663	!!----------------------------------------------------------------------
664	REAL(wp) , INTENT(in ) :: zu ! altitude of wind measurement [m]
665	REAL(wp), DIMENSION(:,:), INTENT(in ) :: sst ! sea surface temperature [Kelvin]
666	REAL(wp), DIMENSION(:,:), INTENT(in ) :: T_a ! potential air temperature [Kelvin]
667	REAL(wp), DIMENSION(:,:), INTENT(in ) :: q_sat ! sea surface specific humidity [kg/kg]
668	REAL(wp), DIMENSION(:,:), INTENT(in ) :: q_a ! specific air humidity [kg/kg]
669	REAL(wp), DIMENSION(:,:), INTENT(in ) :: dU ! wind module \|U(zu)-U(0)\| [m/s]
670	REAL(wp), DIMENSION(:,:), INTENT( out) :: Cd ! transfert coefficient for momentum (tau)
671	REAL(wp), DIMENSION(:,:), INTENT( out) :: Ch ! transfert coefficient for temperature (Q_sens)
672	REAL(wp), DIMENSION(:,:), INTENT( out) :: Ce ! transfert coefficient for evaporation (Q_lat)
673	!!
674	INTEGER :: j_itt
675	INTEGER , PARAMETER :: nb_itt = 3
676	REAL(wp), PARAMETER :: grav = 9.8 ! gravity
677	REAL(wp), PARAMETER :: kappa = 0.4 ! von Karman s constant
678
679	REAL(wp), DIMENSION(:,:), POINTER :: dU10 ! dU [m/s]
680	REAL(wp), DIMENSION(:,:), POINTER :: dT ! air/sea temperature differeence [K]
681	REAL(wp), DIMENSION(:,:), POINTER :: dq ! air/sea humidity difference [K]
682	REAL(wp), DIMENSION(:,:), POINTER :: Cd_n10 ! 10m neutral drag coefficient
683	REAL(wp), DIMENSION(:,:), POINTER :: Ce_n10 ! 10m neutral latent coefficient
684	REAL(wp), DIMENSION(:,:), POINTER :: Ch_n10 ! 10m neutral sensible coefficient
685	REAL(wp), DIMENSION(:,:), POINTER :: sqrt_Cd_n10 ! root square of Cd_n10
686	REAL(wp), DIMENSION(:,:), POINTER :: sqrt_Cd ! root square of Cd
687	REAL(wp), DIMENSION(:,:), POINTER :: T_vpot ! virtual potential temperature [K]
688	REAL(wp), DIMENSION(:,:), POINTER :: T_star ! turbulent scale of tem. fluct.
689	REAL(wp), DIMENSION(:,:), POINTER :: q_star ! turbulent humidity of temp. fluct.
690	REAL(wp), DIMENSION(:,:), POINTER :: U_star ! turb. scale of velocity fluct.
691	REAL(wp), DIMENSION(:,:), POINTER :: L ! Monin-Obukov length [m]
692	REAL(wp), DIMENSION(:,:), POINTER :: zeta ! stability parameter at height zu
693	REAL(wp), DIMENSION(:,:), POINTER :: U_n10 ! neutral wind velocity at 10m [m]
694	REAL(wp), DIMENSION(:,:), POINTER :: xlogt, xct, zpsi_h, zpsi_m
695
696	INTEGER , DIMENSION(:,:), POINTER :: stab ! 1st guess stability test integer
697	!!----------------------------------------------------------------------
698	!
699	IF( nn_timing == 1 ) CALL timing_start('TURB_CORE_1Z')
700	!
701	CALL wrk_alloc( jpi,jpj, stab ) ! integer
702	CALL wrk_alloc( jpi,jpj, dU10, dT, dq, Cd_n10, Ce_n10, Ch_n10, sqrt_Cd_n10, sqrt_Cd, L )
703	CALL wrk_alloc( jpi,jpj, T_vpot, T_star, q_star, U_star, zeta, U_n10, xlogt, xct, zpsi_h, zpsi_m )
704
705	!! * Start
706	!! Air/sea differences
707	dU10 = max(0.5, dU) ! we don't want to fall under 0.5 m/s
708	dT = T_a - sst ! assuming that T_a is allready the potential temp. at zzu
709	dq = q_a - q_sat
710	!!
711	!! Virtual potential temperature
712	T_vpot = T_a(1. + 0.608q_a)
713	!!
714	!! Neutral Drag Coefficient
715	stab = 0.5 + sign(0.5,dT) ! stable : stab = 1 ; unstable : stab = 0
716	IF ( ln_cdgw ) THEN
717	cdn_wave = cdn_wave - rsmall*(tmask(:,:,1)-1)
718	Cd_n10(:,:) = cdn_wave
719	ELSE
720	Cd_n10 = 1E-3 * ( 2.7/dU10 + 0.142 + dU10/13.09 ) ! L & Y eq. (6a)
721	ENDIF
722	sqrt_Cd_n10 = sqrt(Cd_n10)
723	Ce_n10 = 1E-3 * ( 34.6 * sqrt_Cd_n10 ) ! L & Y eq. (6b)
724	Ch_n10 = 1E-3sqrt_Cd_n10(18stab + 32.7(1-stab)) ! L & Y eq. (6c), (6d)
725	!!
726	!! Initializing transfert coefficients with their first guess neutral equivalents :
727	Cd = Cd_n10 ; Ce = Ce_n10 ; Ch = Ch_n10 ; sqrt_Cd = sqrt(Cd)
728
729	!! * Now starting iteration loop
730	DO j_itt=1, nb_itt
731	!! Turbulent scales :
732	U_star = sqrt_Cd*dU10 ! L & Y eq. (7a)
733	T_star = Ch/sqrt_Cd*dT ! L & Y eq. (7b)
734	q_star = Ce/sqrt_Cd*dq ! L & Y eq. (7c)
735
736	!! Estimate the Monin-Obukov length :
737	L = (U_star*2)/( kappagrav*(T_star/T_vpot + q_star/(q_a + 1./0.608)) )
738
739	!! Stability parameters :
740	zeta = zu/L ; zeta = sign( min(abs(zeta),10.0), zeta )
741	zpsi_h = psi_h(zeta)
742	zpsi_m = psi_m(zeta)
743
744	IF ( ln_cdgw ) THEN
745	sqrt_Cd=kappa/((kappa/sqrt_Cd_n10) - zpsi_m) ; Cd=sqrt_Cd*sqrt_Cd;
746	ELSE
747	!! Shifting the wind speed to 10m and neutral stability :
748	U_n10 = dU101./(1. + sqrt_Cd_n10/kappa(log(zu/10.) - zpsi_m)) ! L & Y eq. (9a)
749
750	!! Updating the neutral 10m transfer coefficients :
751	Cd_n10 = 1E-3 * (2.7/U_n10 + 0.142 + U_n10/13.09) ! L & Y eq. (6a)
752	sqrt_Cd_n10 = sqrt(Cd_n10)
753	Ce_n10 = 1E-3 * (34.6 * sqrt_Cd_n10) ! L & Y eq. (6b)
754	stab = 0.5 + sign(0.5,zeta)
755	Ch_n10 = 1E-3sqrt_Cd_n10(18.stab + 32.7(1-stab)) ! L & Y eq. (6c), (6d)
756
757	!! Shifting the neutral 10m transfer coefficients to ( zu , zeta ) :
758	!!
759	xct = 1. + sqrt_Cd_n10/kappa*(log(zu/10) - zpsi_m)
760	Cd = Cd_n10/(xct*xct) ; sqrt_Cd = sqrt(Cd)
761	ENDIF
762	!!
763	xlogt = log(zu/10.) - zpsi_h
764	!!
765	xct = 1. + Ch_n10*xlogt/kappa/sqrt_Cd_n10
766	Ch = Ch_n10*sqrt_Cd/sqrt_Cd_n10/xct
767	!!
768	xct = 1. + Ce_n10*xlogt/kappa/sqrt_Cd_n10
769	Ce = Ce_n10*sqrt_Cd/sqrt_Cd_n10/xct
770	!!
771	END DO
772	!!
773	CALL wrk_dealloc( jpi,jpj, stab ) ! integer
774	CALL wrk_dealloc( jpi,jpj, dU10, dT, dq, Cd_n10, Ce_n10, Ch_n10, sqrt_Cd_n10, sqrt_Cd, L )
775	CALL wrk_dealloc( jpi,jpj, T_vpot, T_star, q_star, U_star, zeta, U_n10, xlogt, xct, zpsi_h, zpsi_m )
776	!
777	IF( nn_timing == 1 ) CALL timing_stop('TURB_CORE_1Z')
778	!
779	END SUBROUTINE TURB_CORE_1Z
780
781
782	SUBROUTINE TURB_CORE_2Z(zt, zu, sst, T_zt, q_sat, q_zt, dU, Cd, Ch, Ce, T_zu, q_zu)
783	!!----------------------------------------------------------------------
784	!! * ROUTINE turb_core *
785	!!
786	!! ** Purpose : Computes turbulent transfert coefficients of surface
787	!! fluxes according to Large & Yeager (2004).
788	!!
789	!! ** Method : I N E R T I A L D I S S I P A T I O N M E T H O D
790	!! Momentum, Latent and sensible heat exchange coefficients
791	!! Caution: this procedure should only be used in cases when air
792	!! temperature (T_air) and air specific humidity (q_air) are at 2m
793	!! whereas wind (dU) is at 10m.
794	!!
795	!! References : Large & Yeager, 2004 : ???
796	!!----------------------------------------------------------------------
797	REAL(wp), INTENT(in ) :: zt ! height for T_zt and q_zt [m]
798	REAL(wp), INTENT(in ) :: zu ! height for dU [m]
799	REAL(wp), INTENT(in ), DIMENSION(jpi,jpj) :: sst ! sea surface temperature [Kelvin]
800	REAL(wp), INTENT(in ), DIMENSION(jpi,jpj) :: T_zt ! potential air temperature [Kelvin]
801	REAL(wp), INTENT(in ), DIMENSION(jpi,jpj) :: q_sat ! sea surface specific humidity [kg/kg]
802	REAL(wp), INTENT(in ), DIMENSION(jpi,jpj) :: q_zt ! specific air humidity [kg/kg]
803	REAL(wp), INTENT(in ), DIMENSION(jpi,jpj) :: dU ! relative wind module \|U(zu)-U(0)\| [m/s]
804	REAL(wp), INTENT( out), DIMENSION(jpi,jpj) :: Cd ! transfer coefficient for momentum (tau)
805	REAL(wp), INTENT( out), DIMENSION(jpi,jpj) :: Ch ! transfer coefficient for sensible heat (Q_sens)
806	REAL(wp), INTENT( out), DIMENSION(jpi,jpj) :: Ce ! transfert coefficient for evaporation (Q_lat)
807	REAL(wp), INTENT( out), DIMENSION(jpi,jpj) :: T_zu ! air temp. shifted at zu [K]
808	REAL(wp), INTENT( out), DIMENSION(jpi,jpj) :: q_zu ! spec. hum. shifted at zu [kg/kg]
809
810	INTEGER :: j_itt
811	INTEGER , PARAMETER :: nb_itt = 3 ! number of itterations
812	REAL(wp), PARAMETER :: grav = 9.8 ! gravity
813	REAL(wp), PARAMETER :: kappa = 0.4 ! von Karman's constant
814
815	REAL(wp), DIMENSION(:,:), POINTER :: dU10 ! dU [m/s]
816	REAL(wp), DIMENSION(:,:), POINTER :: dT ! air/sea temperature differeence [K]
817	REAL(wp), DIMENSION(:,:), POINTER :: dq ! air/sea humidity difference [K]
818	REAL(wp), DIMENSION(:,:), POINTER :: Cd_n10 ! 10m neutral drag coefficient
819	REAL(wp), DIMENSION(:,:), POINTER :: Ce_n10 ! 10m neutral latent coefficient
820	REAL(wp), DIMENSION(:,:), POINTER :: Ch_n10 ! 10m neutral sensible coefficient
821	REAL(wp), DIMENSION(:,:), POINTER :: sqrt_Cd_n10 ! root square of Cd_n10
822	REAL(wp), DIMENSION(:,:), POINTER :: sqrt_Cd ! root square of Cd
823	REAL(wp), DIMENSION(:,:), POINTER :: T_vpot ! virtual potential temperature [K]
824	REAL(wp), DIMENSION(:,:), POINTER :: T_star ! turbulent scale of tem. fluct.
825	REAL(wp), DIMENSION(:,:), POINTER :: q_star ! turbulent humidity of temp. fluct.
826	REAL(wp), DIMENSION(:,:), POINTER :: U_star ! turb. scale of velocity fluct.
827	REAL(wp), DIMENSION(:,:), POINTER :: L ! Monin-Obukov length [m]
828	REAL(wp), DIMENSION(:,:), POINTER :: zeta_u ! stability parameter at height zu
829	REAL(wp), DIMENSION(:,:), POINTER :: zeta_t ! stability parameter at height zt
830	REAL(wp), DIMENSION(:,:), POINTER :: U_n10 ! neutral wind velocity at 10m [m]
831	REAL(wp), DIMENSION(:,:), POINTER :: xlogt, xct, zpsi_hu, zpsi_ht, zpsi_m
832
833	INTEGER , DIMENSION(:,:), POINTER :: stab ! 1st stability test integer
834	!!----------------------------------------------------------------------
835	!
836	IF( nn_timing == 1 ) CALL timing_start('TURB_CORE_2Z')
837	!
838	CALL wrk_alloc( jpi,jpj, dU10, dT, dq, Cd_n10, Ce_n10, Ch_n10, sqrt_Cd_n10, sqrt_Cd, L )
839	CALL wrk_alloc( jpi,jpj, T_vpot, T_star, q_star, U_star, zeta_u, zeta_t, U_n10 )
840	CALL wrk_alloc( jpi,jpj, xlogt, xct, zpsi_hu, zpsi_ht, zpsi_m )
841	CALL wrk_alloc( jpi,jpj, stab ) ! interger
842
843	!! Initial air/sea differences
844	dU10 = max(0.5, dU) ! we don't want to fall under 0.5 m/s
845	dT = T_zt - sst
846	dq = q_zt - q_sat
847
848	!! Neutral Drag Coefficient :
849	stab = 0.5 + sign(0.5,dT) ! stab = 1 if dT > 0 -> STABLE
850	IF( ln_cdgw ) THEN
851	cdn_wave = cdn_wave - rsmall*(tmask(:,:,1)-1)
852	Cd_n10(:,:) = cdn_wave
853	ELSE
854	Cd_n10 = 1E-3*( 2.7/dU10 + 0.142 + dU10/13.09 )
855	ENDIF
856	sqrt_Cd_n10 = sqrt(Cd_n10)
857	Ce_n10 = 1E-3( 34.6 sqrt_Cd_n10 )
858	Ch_n10 = 1E-3sqrt_Cd_n10(18stab + 32.7(1 - stab))
859
860	!! Initializing transf. coeff. with their first guess neutral equivalents :
861	Cd = Cd_n10 ; Ce = Ce_n10 ; Ch = Ch_n10 ; sqrt_Cd = sqrt(Cd)
862
863	!! Initializing z_u values with z_t values :
864	T_zu = T_zt ; q_zu = q_zt
865
866	!! * Now starting iteration loop
867	DO j_itt=1, nb_itt
868	dT = T_zu - sst ; dq = q_zu - q_sat ! Updating air/sea differences
869	T_vpot = T_zu(1. + 0.608q_zu) ! Updating virtual potential temperature at zu
870	U_star = sqrt_Cd*dU10 ! Updating turbulent scales : (L & Y eq. (7))
871	T_star = Ch/sqrt_Cd*dT !
872	q_star = Ce/sqrt_Cd*dq !
873	!!
874	L = (U_star*U_star) & ! Estimate the Monin-Obukov length at height zu
875	& / (kappagrav/T_vpot(T_star(1.+0.608q_zu) + 0.608T_zuq_star))
876	!! Stability parameters :
877	zeta_u = zu/L ; zeta_u = sign( min(abs(zeta_u),10.0), zeta_u )
878	zeta_t = zt/L ; zeta_t = sign( min(abs(zeta_t),10.0), zeta_t )
879	zpsi_hu = psi_h(zeta_u)
880	zpsi_ht = psi_h(zeta_t)
881	zpsi_m = psi_m(zeta_u)
882	!!
883	!! Shifting the wind speed to 10m and neutral stability : (L & Y eq.(9a))
884	! U_n10 = dU10/(1. + sqrt_Cd_n10/kappa*(log(zu/10.) - psi_m(zeta_u)))
885	U_n10 = dU10/(1. + sqrt_Cd_n10/kappa*(log(zu/10.) - zpsi_m))
886	!!
887	!! Shifting temperature and humidity at zu : (L & Y eq. (9b-9c))
888	! T_zu = T_zt - T_star/kappa*(log(zt/zu) + psi_h(zeta_u) - psi_h(zeta_t))
889	T_zu = T_zt - T_star/kappa*(log(zt/zu) + zpsi_hu - zpsi_ht)
890	! q_zu = q_zt - q_star/kappa*(log(zt/zu) + psi_h(zeta_u) - psi_h(zeta_t))
891	q_zu = q_zt - q_star/kappa*(log(zt/zu) + zpsi_hu - zpsi_ht)
892	!!
893	!! q_zu cannot have a negative value : forcing 0
894	stab = 0.5 + sign(0.5,q_zu) ; q_zu = stab*q_zu
895	!!
896	IF( ln_cdgw ) THEN
897	sqrt_Cd=kappa/((kappa/sqrt_Cd_n10) - zpsi_m) ; Cd=sqrt_Cd*sqrt_Cd;
898	ELSE
899	!! Updating the neutral 10m transfer coefficients :
900	Cd_n10 = 1E-3 * (2.7/U_n10 + 0.142 + U_n10/13.09) ! L & Y eq. (6a)
901	sqrt_Cd_n10 = sqrt(Cd_n10)
902	Ce_n10 = 1E-3 * (34.6 * sqrt_Cd_n10) ! L & Y eq. (6b)
903	stab = 0.5 + sign(0.5,zeta_u)
904	Ch_n10 = 1E-3sqrt_Cd_n10(18.stab + 32.7(1-stab)) ! L & Y eq. (6c-6d)
905	!!
906	!!
907	!! Shifting the neutral 10m transfer coefficients to (zu,zeta_u) :
908	xct = 1. + sqrt_Cd_n10/kappa*(log(zu/10.) - zpsi_m)
909	Cd = Cd_n10/(xct*xct) ; sqrt_Cd = sqrt(Cd)
910	ENDIF
911	!!
912	xlogt = log(zu/10.) - zpsi_hu
913	!!
914	xct = 1. + Ch_n10*xlogt/kappa/sqrt_Cd_n10
915	Ch = Ch_n10*sqrt_Cd/sqrt_Cd_n10/xct
916	!!
917	xct = 1. + Ce_n10*xlogt/kappa/sqrt_Cd_n10
918	Ce = Ce_n10*sqrt_Cd/sqrt_Cd_n10/xct
919	!!
920	!!
921	END DO
922	!!
923	CALL wrk_dealloc( jpi,jpj, dU10, dT, dq, Cd_n10, Ce_n10, Ch_n10, sqrt_Cd_n10, sqrt_Cd, L )
924	CALL wrk_dealloc( jpi,jpj, T_vpot, T_star, q_star, U_star, zeta_u, zeta_t, U_n10 )
925	CALL wrk_dealloc( jpi,jpj, xlogt, xct, zpsi_hu, zpsi_ht, zpsi_m )
926	CALL wrk_dealloc( jpi,jpj, stab ) ! interger
927	!
928	IF( nn_timing == 1 ) CALL timing_stop('TURB_CORE_2Z')
929	!
930	END SUBROUTINE TURB_CORE_2Z
931
932
933	FUNCTION psi_m(zta) !! Psis, L & Y eq. (8c), (8d), (8e)
934	!-------------------------------------------------------------------------------
935	REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: zta
936
937	REAL(wp), PARAMETER :: pi = 3.141592653589793_wp
938	REAL(wp), DIMENSION(jpi,jpj) :: psi_m
939	REAL(wp), DIMENSION(:,:), POINTER :: X2, X, stabit
940	!-------------------------------------------------------------------------------
941
942	CALL wrk_alloc( jpi,jpj, X2, X, stabit )
943
944	X2 = sqrt(abs(1. - 16.*zta)) ; X2 = max(X2 , 1.0) ; X = sqrt(X2)
945	stabit = 0.5 + sign(0.5,zta)
946	psi_m = -5.ztastabit & ! Stable
947	& + (1. - stabit)(2log((1. + X)/2) + log((1. + X2)/2) - 2*atan(X) + pi/2) ! Unstable
948
949	CALL wrk_dealloc( jpi,jpj, X2, X, stabit )
950	!
951	END FUNCTION psi_m
952
953
954	FUNCTION psi_h( zta ) !! Psis, L & Y eq. (8c), (8d), (8e)
955	!-------------------------------------------------------------------------------
956	REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: zta
957	!
958	REAL(wp), DIMENSION(jpi,jpj) :: psi_h
959	REAL(wp), DIMENSION(:,:), POINTER :: X2, X, stabit
960	!-------------------------------------------------------------------------------
961
962	CALL wrk_alloc( jpi,jpj, X2, X, stabit )
963
964	X2 = sqrt(abs(1. - 16.*zta)) ; X2 = max(X2 , 1.) ; X = sqrt(X2)
965	stabit = 0.5 + sign(0.5,zta)
966	psi_h = -5.ztastabit & ! Stable
967	& + (1. - stabit)(2.log( (1. + X2)/2. )) ! Unstable
968
969	CALL wrk_dealloc( jpi,jpj, X2, X, stabit )
970	!
971	END FUNCTION psi_h
972
973	!!======================================================================
974	END MODULE sbcblk_core

Note: See TracBrowser for help on using the repository browser.

Download in other formats: