New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

sbcice_lim.F90 in branches/2013/dev_LOCEAN_2013/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

Context Navigation

source: branches/2013/dev_LOCEAN_2013/NEMOGCM/NEMO/OPA_SRC/SBC/sbcice_lim.F90 @ 4161

Last change on this file since 4161 was 4161, checked in by cetlod, 10 years ago
dev_LOCEAN_2013 : merge in the 3rd dev branch dev_r4028_CNRS_LIM3, see ticket #1169
Property svn:keywords set to `Id`
File size: 42.0 KB

Line
1	MODULE sbcice_lim
2	!!======================================================================
3	!! * MODULE sbcice_lim *
4	!! Surface module : update the ocean surface boundary condition over ice
5	!! & covered area using LIM sea-ice model
6	!! Sea-Ice model : LIM-3 Sea ice model time-stepping
7	!!=====================================================================
8	!! History : 2.0 ! 2006-12 (M. Vancoppenolle) Original code
9	!! 3.0 ! 2008-02 (C. Talandier) Surface module from icestp.F90
10	!! - ! 2008-04 (G. Madec) sltyle and lim_ctl routine
11	!! 3.3 ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step
12	!! 3.4 ! 2011-01 (A Porter) dynamical allocation
13	!! - ! 2012-10 (C. Rousset) add lim_diahsb
14	!!----------------------------------------------------------------------
15	#if defined key_lim3
16	!!----------------------------------------------------------------------
17	!! 'key_lim3' : LIM 3.0 sea-ice model
18	!!----------------------------------------------------------------------
19	!! sbc_ice_lim : sea-ice model time-stepping and update ocean sbc over ice-covered area
20	!! lim_ctl : alerts in case of ice model crash
21	!! lim_prt_state : ice control print at a given grid point
22	!!----------------------------------------------------------------------
23	USE oce ! ocean dynamics and tracers
24	USE dom_oce ! ocean space and time domain
25	USE par_ice ! sea-ice parameters
26	USE ice ! LIM-3: ice variables
27	USE iceini ! LIM-3: ice initialisation
28	USE dom_ice ! LIM-3: ice domain
29
30	USE sbc_oce ! Surface boundary condition: ocean fields
31	USE sbc_ice ! Surface boundary condition: ice fields
32	USE sbcblk_core ! Surface boundary condition: CORE bulk
33	USE sbcblk_clio ! Surface boundary condition: CLIO bulk
34	USE sbccpl ! Surface boundary condition: coupled interface
35	USE albedo ! ocean & ice albedo
36
37	USE phycst ! Define parameters for the routines
38	USE eosbn2 ! equation of state
39	USE limdyn ! Ice dynamics
40	USE limtrp ! Ice transport
41	USE limthd ! Ice thermodynamics
42	USE limitd_th ! Thermodynamics on ice thickness distribution
43	USE limitd_me ! Mechanics on ice thickness distribution
44	USE limsbc ! sea surface boundary condition
45	USE limdiahsb ! Ice budget diagnostics
46	USE limwri ! Ice outputs
47	USE limrst ! Ice restarts
48	USE limupdate1 ! update of global variables
49	USE limupdate2 ! update of global variables
50	USE limvar ! Ice variables switch
51
52	USE c1d ! 1D vertical configuration
53	USE lbclnk ! lateral boundary condition - MPP link
54	USE lib_mpp ! MPP library
55	USE wrk_nemo ! work arrays
56	USE timing ! Timing
57	USE iom ! I/O manager library
58	USE in_out_manager ! I/O manager
59	USE prtctl ! Print control
60
61	#if defined key_bdy
62	USE bdyice_lim ! unstructured open boundary data (bdy_ice_lim routine)
63	#endif
64
65	IMPLICIT NONE
66	PRIVATE
67
68	PUBLIC sbc_ice_lim ! routine called by sbcmod.F90
69
70	!! * Substitutions
71	# include "domzgr_substitute.h90"
72	# include "vectopt_loop_substitute.h90"
73	!!----------------------------------------------------------------------
74	!! NEMO/OPA 4.0 , UCL NEMO Consortium (2011)
75	!! $Id$
76	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
77	!!----------------------------------------------------------------------
78	CONTAINS
79
80	FUNCTION fice_cell_ave ( ptab)
81	!!--------------------------------------------------------------------------
82	!! * Compute average over categories, for grid cell (ice covered and free ocean)
83	!!--------------------------------------------------------------------------
84	REAL (wp), DIMENSION (jpi,jpj) :: fice_cell_ave
85	REAL (wp), DIMENSION (jpi,jpj,jpl), INTENT (in) :: ptab
86	INTEGER :: jl ! Dummy loop index
87
88	fice_cell_ave (:,:) = 0.0_wp
89
90	DO jl = 1, jpl
91	fice_cell_ave (:,:) = fice_cell_ave (:,:) &
92	& + a_i (:,:,jl) * ptab (:,:,jl)
93	END DO
94
95	END FUNCTION fice_cell_ave
96
97	FUNCTION fice_ice_ave ( ptab)
98	!!--------------------------------------------------------------------------
99	!! * Compute average over categories, for ice covered part of grid cell
100	!!--------------------------------------------------------------------------
101	REAL (kind=wp), DIMENSION (jpi,jpj) :: fice_ice_ave
102	REAL (kind=wp), DIMENSION (jpi,jpj,jpl), INTENT(in) :: ptab
103
104	fice_ice_ave (:,:) = 0.0_wp
105	WHERE ( at_i (:,:) .GT. 0.0_wp ) fice_ice_ave (:,:) = fice_cell_ave ( ptab (:,:,:)) / at_i (:,:)
106
107	END FUNCTION fice_ice_ave
108
109	!!======================================================================
110
111	SUBROUTINE sbc_ice_lim( kt, kblk )
112	!!---------------------------------------------------------------------
113	!! * ROUTINE sbc_ice_lim *
114	!!
115	!! ** Purpose : update the ocean surface boundary condition via the
116	!! Louvain la Neuve Sea Ice Model time stepping
117	!!
118	!! ** Method : ice model time stepping
119	!! - call the ice dynamics routine
120	!! - call the ice advection/diffusion routine
121	!! - call the ice thermodynamics routine
122	!! - call the routine that computes mass and
123	!! heat fluxes at the ice/ocean interface
124	!! - save the outputs
125	!! - save the outputs for restart when necessary
126	!!
127	!! ** Action : - time evolution of the LIM sea-ice model
128	!! - update all sbc variables below sea-ice:
129	!! utau, vtau, taum, wndm, qns , qsr, emp , sfx
130	!!---------------------------------------------------------------------
131	INTEGER, INTENT(in) :: kt ! ocean time step
132	INTEGER, INTENT(in) :: kblk ! type of bulk (=3 CLIO, =4 CORE)
133	!!
134	INTEGER :: jl ! dummy loop index
135	REAL(wp) :: zcoef ! local scalar
136	REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_ice_os, zalb_ice_cs ! albedo of the ice under overcast/clear sky
137	REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_ice ! mean albedo of ice (for coupled)
138
139	REAL(wp), POINTER, DIMENSION(:,:) :: zalb_ice_all ! Mean albedo over all categories
140	REAL(wp), POINTER, DIMENSION(:,:) :: ztem_ice_all ! Mean temperature over all categories
141
142	REAL(wp), POINTER, DIMENSION(:,:) :: z_qsr_ice_all ! Mean solar heat flux over all categories
143	REAL(wp), POINTER, DIMENSION(:,:) :: z_qns_ice_all ! Mean non solar heat flux over all categories
144	REAL(wp), POINTER, DIMENSION(:,:) :: z_qla_ice_all ! Mean latent heat flux over all categories
145	REAL(wp), POINTER, DIMENSION(:,:) :: z_dqns_ice_all ! Mean d(qns)/dT over all categories
146	REAL(wp), POINTER, DIMENSION(:,:) :: z_dqla_ice_all ! Mean d(qla)/dT over all categories
147	!!----------------------------------------------------------------------
148
149	!- O.M. : why do we allocate all these arrays even when MOD( kt-1, nn_fsbc ) /= 0 ?????
150
151	IF( nn_timing == 1 ) CALL timing_start('sbc_ice_lim')
152
153	CALL wrk_alloc( jpi,jpj,jpl, zalb_ice_os, zalb_ice_cs )
154
155	IF ( ln_cpl .OR. ln_iceflx_ave .OR. ln_iceflx_linear ) THEN
156	CALL wrk_alloc( jpi,jpj,jpl, zalb_ice)
157	END IF
158	IF ( ln_iceflx_ave .OR. ln_iceflx_linear ) THEN
159	CALL wrk_alloc( jpi,jpj, ztem_ice_all, zalb_ice_all, z_qsr_ice_all, z_qns_ice_all, z_qla_ice_all, z_dqns_ice_all, z_dqla_ice_all)
160	ENDIF
161
162
163	IF( kt == nit000 ) THEN
164	IF(lwp) WRITE(numout,*)
165	IF(lwp) WRITE(numout,*) 'sbc_ice_lim : update ocean surface boudary condition'
166	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ via Louvain la Neuve Ice Model (LIM-3) time stepping'
167	!
168	CALL ice_init
169	!
170	IF( ln_nicep ) THEN ! control print at a given point
171	jiindx = 15 ; jjindx = 46
172	WRITE(numout,*) ' The debugging point is : jiindx : ',jiindx, ' jjindx : ',jjindx
173	ENDIF
174	ENDIF
175
176	! !----------------------!
177	IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN ! Ice time-step only !
178	! !----------------------!
179	! ! Bulk Formulea !
180	! !----------------!
181	!
182	u_oce(:,:) = ssu_m(:,:) ! mean surface ocean current at ice velocity point
183	v_oce(:,:) = ssv_m(:,:) ! (C-grid dynamics : U- & V-points as the ocean)
184	!
185	t_bo(:,:) = tfreez( sss_m ) + rt0 ! masked sea surface freezing temperature [Kelvin]
186	! ! (set to rt0 over land)
187	CALL albedo_ice( t_su, ht_i, ht_s, zalb_ice_cs, zalb_ice_os ) ! ... ice albedo
188
189	DO jl = 1, jpl
190	t_su(:,:,jl) = t_su(:,:,jl) + rt0 * ( 1. - tmask(:,:,1) )
191	END DO
192
193	IF ( ln_cpl ) zalb_ice (:,:,:) = 0.5 * ( zalb_ice_cs (:,:,:) + zalb_ice_os (:,:,:) )
194
195	IF ( ln_iceflx_ave .OR. ln_iceflx_linear ) THEN
196	!
197	! Compute mean albedo and temperature
198	zalb_ice_all (:,:) = fice_ice_ave ( zalb_ice (:,:,:) )
199	ztem_ice_all (:,:) = fice_ice_ave ( tn_ice (:,:,:) )
200	!
201	ENDIF
202	! Bulk formulea - provides the following fields:
203	! utau_ice, vtau_ice : surface ice stress (U- & V-points) [N/m2]
204	! qsr_ice , qns_ice : solar & non solar heat flux over ice (T-point) [W/m2]
205	! qla_ice : latent heat flux over ice (T-point) [W/m2]
206	! dqns_ice, dqla_ice : non solar & latent heat sensistivity (T-point) [W/m2]
207	! tprecip , sprecip : total & solid precipitation (T-point) [Kg/m2/s]
208	! fr1_i0 , fr2_i0 : 1sr & 2nd fraction of qsr penetration in ice [%]
209	!
210	SELECT CASE( kblk )
211	CASE( 3 ) ! CLIO bulk formulation
212	CALL blk_ice_clio( t_su , zalb_ice_cs, zalb_ice_os, &
213	& utau_ice , vtau_ice , qns_ice , qsr_ice , &
214	& qla_ice , dqns_ice , dqla_ice , &
215	& tprecip , sprecip , &
216	& fr1_i0 , fr2_i0 , cp_ice_msh, jpl )
217	!
218	CASE( 4 ) ! CORE bulk formulation
219	CALL blk_ice_core( t_su , u_ice , v_ice , zalb_ice_cs, &
220	& utau_ice , vtau_ice , qns_ice , qsr_ice , &
221	& qla_ice , dqns_ice , dqla_ice , &
222	& tprecip , sprecip , &
223	& fr1_i0 , fr2_i0 , cp_ice_msh, jpl )
224	!
225	CASE ( 5 )
226	zalb_ice (:,:,:) = 0.5 * ( zalb_ice_cs (:,:,:) + zalb_ice_os (:,:,:) )
227
228	CALL sbc_cpl_ice_tau( utau_ice , vtau_ice )
229
230	CALL sbc_cpl_ice_flx( p_frld=ato_i, palbi=zalb_ice, psst=sst_m, pist=tn_ice )
231
232	! Latent heat flux is forced to 0 in coupled :
233	! it is included in qns (non-solar heat flux)
234	qla_ice (:,:,:) = 0.0e0_wp
235	dqla_ice (:,:,:) = 0.0e0_wp
236	!
237	END SELECT
238
239	! Average over all categories
240	IF ( ln_iceflx_ave .OR. ln_iceflx_linear ) THEN
241
242	z_qns_ice_all (:,:) = fice_ice_ave ( qns_ice (:,:,:) )
243	z_qsr_ice_all (:,:) = fice_ice_ave ( qsr_ice (:,:,:) )
244	z_dqns_ice_all (:,:) = fice_ice_ave ( dqns_ice (:,:,:) )
245	z_qla_ice_all (:,:) = fice_ice_ave ( qla_ice (:,:,:) )
246	z_dqla_ice_all (:,:) = fice_ice_ave ( dqla_ice (:,:,:) )
247
248	DO jl = 1, jpl
249	dqns_ice (:,:,jl) = z_dqns_ice_all (:,:)
250	dqla_ice (:,:,jl) = z_dqla_ice_all (:,:)
251	END DO
252	!
253	IF ( ln_iceflx_ave ) THEN
254	DO jl = 1, jpl
255	qns_ice (:,:,jl) = z_qns_ice_all (:,:)
256	qsr_ice (:,:,jl) = z_qsr_ice_all (:,:)
257	qla_ice (:,:,jl) = z_qla_ice_all (:,:)
258	END DO
259	END IF
260	!
261	IF ( ln_iceflx_linear ) THEN
262	DO jl = 1, jpl
263	qns_ice (:,:,jl) = z_qns_ice_all(:,:) + z_dqns_ice_all(:,:) * (tn_ice(:,:,jl) - ztem_ice_all(:,:))
264	qla_ice (:,:,jl) = z_qla_ice_all(:,:) + z_dqla_ice_all(:,:) * (tn_ice(:,:,jl) - ztem_ice_all(:,:))
265	qsr_ice (:,:,jl) = (1.0e0_wp-zalb_ice(:,:,jl)) / (1.0e0_wp-zalb_ice_all(:,:)) * z_qsr_ice_all(:,:)
266	END DO
267	END IF
268	END IF
269
270	! !----------------------!
271	! ! LIM-3 time-stepping !
272	! !----------------------!
273	!
274	numit = numit + nn_fsbc ! Ice model time step
275	!
276	! ! Store previous ice values
277	!!gm : remark old_... should becomes ...b as tn versus tb
278	old_a_i (:,:,:) = a_i (:,:,:) ! ice area
279	old_e_i (:,:,:,:) = e_i (:,:,:,:) ! ice thermal energy
280	old_v_i (:,:,:) = v_i (:,:,:) ! ice volume
281	old_v_s (:,:,:) = v_s (:,:,:) ! snow volume
282	old_e_s (:,:,:,:) = e_s (:,:,:,:) ! snow thermal energy
283	old_smv_i(:,:,:) = smv_i(:,:,:) ! salt content
284	old_oa_i (:,:,:) = oa_i (:,:,:) ! areal age content
285
286	! ! intialisation to zero !!gm is it truly necessary ???
287	d_a_i_thd (:,:,:) = 0._wp ; d_a_i_trp (:,:,:) = 0._wp
288	d_v_i_thd (:,:,:) = 0._wp ; d_v_i_trp (:,:,:) = 0._wp
289	d_e_i_thd (:,:,:,:) = 0._wp ; d_e_i_trp (:,:,:,:) = 0._wp
290	d_v_s_thd (:,:,:) = 0._wp ; d_v_s_trp (:,:,:) = 0._wp
291	d_e_s_thd (:,:,:,:) = 0._wp ; d_e_s_trp (:,:,:,:) = 0._wp
292	d_smv_i_thd(:,:,:) = 0._wp ; d_smv_i_trp(:,:,:) = 0._wp
293	d_oa_i_thd (:,:,:) = 0._wp ; d_oa_i_trp (:,:,:) = 0._wp
294	!
295	sfx (:,:) = 0._wp ; sfx_thd (:,:) = 0._wp
296	sfx_bri(:,:) = 0._wp ; sfx_mec (:,:) = 0._wp ; sfx_res (:,:) = 0._wp
297	fhbri (:,:) = 0._wp ; fheat_mec(:,:) = 0._wp ; fheat_res(:,:) = 0._wp
298	fhmec (:,:) = 0._wp ;
299	fmmec (:,:) = 0._wp
300	focea2D(:,:) = 0._wp
301	fsup2D (:,:) = 0._wp
302
303	! used in limthd.F90
304	rdvosif(:,:) = 0._wp ! variation of ice volume at surface
305	rdvobif(:,:) = 0._wp ! variation of ice volume at bottom
306	fdvolif(:,:) = 0._wp ! total variation of ice volume
307	rdvonif(:,:) = 0._wp ! lateral variation of ice volume
308	fstric (:,:) = 0._wp ! part of solar radiation transmitted through the ice
309	ffltbif(:,:) = 0._wp ! linked with fstric
310	qfvbq (:,:) = 0._wp ! linked with fstric
311	rdm_snw(:,:) = 0._wp ! variation of snow mass per unit area
312	rdm_ice(:,:) = 0._wp ! variation of ice mass per unit area
313	hicifp (:,:) = 0._wp ! daily thermodynamic ice production.
314	!
315	diag_sni_gr(:,:) = 0._wp ; diag_lat_gr(:,:) = 0._wp
316	diag_bot_gr(:,:) = 0._wp ; diag_dyn_gr(:,:) = 0._wp
317	diag_bot_me(:,:) = 0._wp ; diag_sur_me(:,:) = 0._wp
318	diag_res_pr(:,:) = 0._wp ; diag_trp_vi(:,:) = 0._wp
319	! dynamical invariants
320	delta_i(:,:) = 0._wp ; divu_i(:,:) = 0._wp ; shear_i(:,:) = 0._wp
321
322	CALL lim_rst_opn( kt ) ! Open Ice restart file
323	!
324	IF( ln_nicep ) CALL lim_prt_state( jiindx, jjindx, 1, ' - Beginning the time step - ' ) ! control print
325	!
326	IF( .NOT. lk_c1d ) THEN ! Ice dynamics & transport (except in 1D case)
327	CALL lim_dyn( kt ) ! Ice dynamics ( rheology/dynamics )
328	CALL lim_trp( kt ) ! Ice transport ( Advection/diffusion )
329	CALL lim_var_glo2eqv ! equivalent variables, requested for rafting
330	IF( ln_nicep ) CALL lim_prt_state( jiindx, jjindx,-1, ' - ice dyn & trp - ' ) ! control print
331	CALL lim_itd_me ! Mechanical redistribution ! (ridging/rafting)
332	CALL lim_var_agg( 1 )
333	CALL lim_update1
334	ENDIF
335	! !- Change old values for new values
336	old_u_ice(:,:) = u_ice (:,:)
337	old_v_ice(:,:) = v_ice (:,:)
338	old_a_i(:,:,:) = a_i (:,:,:)
339	old_v_s(:,:,:) = v_s (:,:,:)
340	old_v_i(:,:,:) = v_i (:,:,:)
341	old_e_s(:,:,:,:) = e_s (:,:,:,:)
342	old_e_i(:,:,:,:) = e_i (:,:,:,:)
343	old_oa_i(:,:,:) = oa_i(:,:,:)
344	old_smv_i(:,:,:) = smv_i (:,:,:)
345	! ! Ice thermodynamics
346	CALL lim_var_glo2eqv ! equivalent variables
347	CALL lim_var_agg(1) ! aggregate ice categories
348	CALL lim_var_bv ! bulk brine volume (diag)
349	CALL lim_thd( kt ) ! Ice thermodynamics
350	zcoef = rdt_ice /rday ! Ice natural aging
351	oa_i(:,:,:) = oa_i(:,:,:) + a_i(:,:,:) * zcoef
352	CALL lim_var_glo2eqv ! this CALL is maybe not necessary (Martin)
353	IF( ln_nicep ) CALL lim_prt_state( jiindx, jjindx, 1, ' - ice thermodyn. - ' ) ! control print
354	CALL lim_itd_th( kt ) ! Remap ice categories, lateral accretion !
355	!
356	! ! Global variables update
357	CALL lim_var_agg( 1 ) ! requested by limupdate
358	CALL lim_update2 ! Global variables update
359	#if defined key_bdy
360	CALL bdy_ice_lim( kt ) ! clem modif: bdy ice
361	#endif
362	CALL lim_var_glo2eqv ! equivalent variables (outputs)
363	CALL lim_var_agg(2) ! aggregate ice thickness categories
364	IF( ln_nicep ) CALL lim_prt_state( jiindx, jjindx, 2, ' - Final state - ' ) ! control print
365	!
366	CALL lim_sbc_flx( kt ) ! Update surface ocean mass, heat and salt fluxes
367	!
368	IF( ln_nicep ) CALL lim_prt_state( jiindx, jjindx, 3, ' - Final state lim_sbc - ' ) ! control print
369	!
370	! ! Diagnostics and outputs
371	IF (ln_limdiaout) CALL lim_diahsb
372	!clem # if ! defined key_iomput
373	CALL lim_wri( 1 ) ! Ice outputs
374	!clem # endif
375	IF( kt == nit000 ) CALL iom_close( numrir ) ! clem: close input ice restart file
376	IF( lrst_ice ) CALL lim_rst_write( kt ) ! Ice restart file
377	CALL lim_var_glo2eqv ! ???
378	!
379	IF( ln_nicep ) CALL lim_ctl ! alerts in case of model crash
380	!
381	ENDIF ! End sea-ice time step only
382
383	! !--------------------------!
384	! ! at all ocean time step !
385	! !--------------------------!
386	!
387	! ! Update surface ocean stresses (only in ice-dynamic case)
388	! ! otherwise the atm.-ocean stresses are used everywhere
389	IF( ln_limdyn ) CALL lim_sbc_tau( kt, ub(:,:,1), vb(:,:,1) ) ! using before instantaneous surf. currents
390
391	!!gm remark, the ocean-ice stress is not saved in ice diag call above ..... find a solution!!!
392	!
393	CALL wrk_dealloc( jpi,jpj,jpl, zalb_ice_os, zalb_ice_cs )
394	IF ( ln_cpl .OR. ln_iceflx_ave .OR. ln_iceflx_linear ) THEN
395	CALL wrk_dealloc( jpi,jpj,jpl, zalb_ice)
396	END IF
397	IF ( ln_iceflx_ave .OR. ln_iceflx_linear ) THEN
398	CALL wrk_dealloc( jpi,jpj, ztem_ice_all, zalb_ice_all, z_qsr_ice_all, z_qns_ice_all, z_qla_ice_all, z_dqns_ice_all, z_dqla_ice_all)
399	ENDIF
400	!
401	IF( nn_timing == 1 ) CALL timing_stop('sbc_ice_lim')
402	!
403	END SUBROUTINE sbc_ice_lim
404
405
406	SUBROUTINE lim_ctl
407	!!-----------------------------------------------------------------------
408	!! * ROUTINE lim_ctl *
409	!!
410	!! ** Purpose : Alerts in case of model crash
411	!!-------------------------------------------------------------------
412	INTEGER :: ji, jj, jk, jl ! dummy loop indices
413	INTEGER :: inb_altests ! number of alert tests (max 20)
414	INTEGER :: ialert_id ! number of the current alert
415	REAL(wp) :: ztmelts ! ice layer melting point
416	CHARACTER (len=30), DIMENSION(20) :: cl_alname ! name of alert
417	INTEGER , DIMENSION(20) :: inb_alp ! number of alerts positive
418	!!-------------------------------------------------------------------
419
420	inb_altests = 10
421	inb_alp(:) = 0
422
423	! Alert if incompatible volume and concentration
424	ialert_id = 2 ! reference number of this alert
425	cl_alname(ialert_id) = ' Incompat vol and con ' ! name of the alert
426
427	DO jl = 1, jpl
428	DO jj = 1, jpj
429	DO ji = 1, jpi
430	IF( v_i(ji,jj,jl) /= 0._wp .AND. a_i(ji,jj,jl) == 0._wp ) THEN
431	WRITE(numout,*) ' ALERTE 2 : Incompatible volume and concentration '
432	WRITE(numout,*) ' at_i ', at_i(ji,jj)
433	WRITE(numout,*) ' Point - category', ji, jj, jl
434	WRITE(numout,) ' a_i ** a_i_old ', a_i (ji,jj,jl), old_a_i (ji,jj,jl)
435	WRITE(numout,) ' v_i ** v_i_old ', v_i (ji,jj,jl), old_v_i (ji,jj,jl)
436	WRITE(numout,*) ' d_a_i_thd/trp ', d_a_i_thd(ji,jj,jl), d_a_i_trp(ji,jj,jl)
437	WRITE(numout,*) ' d_v_i_thd/trp ', d_v_i_thd(ji,jj,jl), d_v_i_trp(ji,jj,jl)
438	inb_alp(ialert_id) = inb_alp(ialert_id) + 1
439	ENDIF
440	END DO
441	END DO
442	END DO
443
444	! Alerte if very thick ice
445	ialert_id = 3 ! reference number of this alert
446	cl_alname(ialert_id) = ' Very thick ice ' ! name of the alert
447	jl = jpl
448	DO jj = 1, jpj
449	DO ji = 1, jpi
450	IF( ht_i(ji,jj,jl) > 50._wp ) THEN
451	CALL lim_prt_state( ji, jj, 2, ' ALERTE 3 : Very thick ice ' )
452	inb_alp(ialert_id) = inb_alp(ialert_id) + 1
453	ENDIF
454	END DO
455	END DO
456
457	! Alert if very fast ice
458	ialert_id = 4 ! reference number of this alert
459	cl_alname(ialert_id) = ' Very fast ice ' ! name of the alert
460	DO jj = 1, jpj
461	DO ji = 1, jpi
462	IF( MAX( ABS( u_ice(ji,jj) ), ABS( v_ice(ji,jj) ) ) > 0.5 .AND. &
463	& at_i(ji,jj) > 0._wp ) THEN
464	CALL lim_prt_state( ji, jj, 1, ' ALERTE 4 : Very fast ice ' )
465	WRITE(numout,*) ' ice strength : ', strength(ji,jj)
466	WRITE(numout,*) ' oceanic stress utau : ', utau(ji,jj)
467	WRITE(numout,*) ' oceanic stress vtau : ', vtau(ji,jj)
468	WRITE(numout,*) ' sea-ice stress utau_ice : ', utau_ice(ji,jj)
469	WRITE(numout,*) ' sea-ice stress vtau_ice : ', vtau_ice(ji,jj)
470	WRITE(numout,*) ' oceanic speed u : ', u_oce(ji,jj)
471	WRITE(numout,*) ' oceanic speed v : ', v_oce(ji,jj)
472	WRITE(numout,*) ' sst : ', sst_m(ji,jj)
473	WRITE(numout,*) ' sss : ', sss_m(ji,jj)
474	WRITE(numout,*)
475	inb_alp(ialert_id) = inb_alp(ialert_id) + 1
476	ENDIF
477	END DO
478	END DO
479
480	! Alert if there is ice on continents
481	ialert_id = 6 ! reference number of this alert
482	cl_alname(ialert_id) = ' Ice on continents ' ! name of the alert
483	DO jj = 1, jpj
484	DO ji = 1, jpi
485	IF( tms(ji,jj) <= 0._wp .AND. at_i(ji,jj) > 0._wp ) THEN
486	CALL lim_prt_state( ji, jj, 1, ' ALERTE 6 : Ice on continents ' )
487	WRITE(numout,*) ' masks s, u, v : ', tms(ji,jj), tmu(ji,jj), tmv(ji,jj)
488	WRITE(numout,*) ' sst : ', sst_m(ji,jj)
489	WRITE(numout,*) ' sss : ', sss_m(ji,jj)
490	WRITE(numout,*) ' at_i(ji,jj) : ', at_i(ji,jj)
491	WRITE(numout,*) ' v_ice(ji,jj) : ', v_ice(ji,jj)
492	WRITE(numout,*) ' v_ice(ji,jj-1) : ', v_ice(ji,jj-1)
493	WRITE(numout,*) ' u_ice(ji-1,jj) : ', u_ice(ji-1,jj)
494	WRITE(numout,*) ' u_ice(ji,jj) : ', v_ice(ji,jj)
495	!
496	inb_alp(ialert_id) = inb_alp(ialert_id) + 1
497	ENDIF
498	END DO
499	END DO
500
501	!
502	! ! Alert if very fresh ice
503	ialert_id = 7 ! reference number of this alert
504	cl_alname(ialert_id) = ' Very fresh ice ' ! name of the alert
505	DO jl = 1, jpl
506	DO jj = 1, jpj
507	DO ji = 1, jpi
508	!!gm test twice sm_i ... ???? bug?
509	IF( ( ( ABS( sm_i(ji,jj,jl) ) < 0.5 ) .OR. &
510	( ABS( sm_i(ji,jj,jl) ) < 0.5 ) ) .AND. &
511	( a_i(ji,jj,jl) > 0._wp ) ) THEN
512	! CALL lim_prt_state(ji,jj,1, ' ALERTE 7 : Very fresh ice ' )
513	! WRITE(numout,*) ' sst : ', sst_m(ji,jj)
514	! WRITE(numout,*) ' sss : ', sss_m(ji,jj)
515	! WRITE(numout,*) ' s_i_newice : ', s_i_newice(ji,jj,1:jpl)
516	! WRITE(numout,*)
517	inb_alp(ialert_id) = inb_alp(ialert_id) + 1
518	ENDIF
519	END DO
520	END DO
521	END DO
522	!
523
524	! ! Alert if too old ice
525	ialert_id = 9 ! reference number of this alert
526	cl_alname(ialert_id) = ' Very old ice ' ! name of the alert
527	DO jl = 1, jpl
528	DO jj = 1, jpj
529	DO ji = 1, jpi
530	IF ( ( ( ABS( o_i(ji,jj,jl) ) > rdt_ice ) .OR. &
531	( ABS( o_i(ji,jj,jl) ) < 0._wp) ) .AND. &
532	( a_i(ji,jj,jl) > 0._wp ) ) THEN
533	CALL lim_prt_state( ji, jj, 1, ' ALERTE 9 : Wrong ice age ')
534	inb_alp(ialert_id) = inb_alp(ialert_id) + 1
535	ENDIF
536	END DO
537	END DO
538	END DO
539
540	! Alert on salt flux
541	ialert_id = 5 ! reference number of this alert
542	cl_alname(ialert_id) = ' High salt flux ' ! name of the alert
543	DO jj = 1, jpj
544	DO ji = 1, jpi
545	IF( ABS( sfx (ji,jj) ) .GT. 1.0e-2 ) THEN
546	CALL lim_prt_state( ji, jj, 3, ' ALERTE 5 : High salt flux ' )
547	DO jl = 1, jpl
548	WRITE(numout,*) ' Category no: ', jl
549	WRITE(numout,*) ' a_i : ', a_i (ji,jj,jl) , ' old_a_i : ', old_a_i (ji,jj,jl)
550	WRITE(numout,*) ' d_a_i_trp : ', d_a_i_trp(ji,jj,jl) , ' d_a_i_thd : ', d_a_i_thd(ji,jj,jl)
551	WRITE(numout,*) ' v_i : ', v_i (ji,jj,jl) , ' old_v_i : ', old_v_i (ji,jj,jl)
552	WRITE(numout,*) ' d_v_i_trp : ', d_v_i_trp(ji,jj,jl) , ' d_v_i_thd : ', d_v_i_thd(ji,jj,jl)
553	WRITE(numout,*) ' '
554	END DO
555	inb_alp(ialert_id) = inb_alp(ialert_id) + 1
556	ENDIF
557	END DO
558	END DO
559
560	! Alert if qns very big
561	ialert_id = 8 ! reference number of this alert
562	cl_alname(ialert_id) = ' fnsolar very big ' ! name of the alert
563	DO jj = 1, jpj
564	DO ji = 1, jpi
565	IF( ABS( qns(ji,jj) ) > 1500._wp .AND. at_i(ji,jj) > 0._wp ) THEN
566	!
567	WRITE(numout,*) ' ALERTE 8 : Very high non-solar heat flux'
568	WRITE(numout,*) ' ji, jj : ', ji, jj
569	WRITE(numout,*) ' qns : ', qns(ji,jj)
570	WRITE(numout,*) ' sst : ', sst_m(ji,jj)
571	WRITE(numout,*) ' sss : ', sss_m(ji,jj)
572	WRITE(numout,*) ' qcmif : ', qcmif(ji,jj)
573	WRITE(numout,*) ' qldif : ', qldif(ji,jj)
574	WRITE(numout,*) ' qcmif : ', qcmif(ji,jj) / rdt_ice
575	WRITE(numout,*) ' qldif : ', qldif(ji,jj) / rdt_ice
576	WRITE(numout,*) ' qfvbq : ', qfvbq(ji,jj)
577	WRITE(numout,*) ' qdtcn : ', qdtcn(ji,jj)
578	WRITE(numout,*) ' qfvbq / dt: ', qfvbq(ji,jj) / rdt_ice
579	WRITE(numout,*) ' qdtcn / dt: ', qdtcn(ji,jj) / rdt_ice
580	WRITE(numout,*) ' fdtcn : ', fdtcn(ji,jj)
581	WRITE(numout,*) ' fhmec : ', fhmec(ji,jj)
582	WRITE(numout,*) ' fheat_mec : ', fheat_mec(ji,jj)
583	WRITE(numout,*) ' fheat_res : ', fheat_res(ji,jj)
584	WRITE(numout,*) ' fhbri : ', fhbri(ji,jj)
585	!
586	CALL lim_prt_state( ji, jj, 2, ' ')
587	inb_alp(ialert_id) = inb_alp(ialert_id) + 1
588	!
589	ENDIF
590	END DO
591	END DO
592	!+++++
593
594	! Alert if very warm ice
595	ialert_id = 10 ! reference number of this alert
596	cl_alname(ialert_id) = ' Very warm ice ' ! name of the alert
597	inb_alp(ialert_id) = 0
598	DO jl = 1, jpl
599	DO jk = 1, nlay_i
600	DO jj = 1, jpj
601	DO ji = 1, jpi
602	ztmelts = -tmut * s_i(ji,jj,jk,jl) + rtt
603	IF( t_i(ji,jj,jk,jl) >= ztmelts .AND. v_i(ji,jj,jl) > 1.e-6 &
604	& .AND. a_i(ji,jj,jl) > 0._wp ) THEN
605	WRITE(numout,*) ' ALERTE 10 : Very warm ice'
606	WRITE(numout,*) ' ji, jj, jk, jl : ', ji, jj, jk, jl
607	WRITE(numout,*) ' t_i : ', t_i(ji,jj,jk,jl)
608	WRITE(numout,*) ' e_i : ', e_i(ji,jj,jk,jl)
609	WRITE(numout,*) ' s_i : ', s_i(ji,jj,jk,jl)
610	WRITE(numout,*) ' ztmelts : ', ztmelts
611	inb_alp(ialert_id) = inb_alp(ialert_id) + 1
612	ENDIF
613	END DO
614	END DO
615	END DO
616	END DO
617
618	ialert_id = 1 ! reference number of this alert
619	cl_alname(ialert_id) = ' NO alerte 1 ' ! name of the alert
620	WRITE(numout,*)
621	WRITE(numout,*) ' All alerts at the end of ice model '
622	DO ialert_id = 1, inb_altests
623	WRITE(numout,*) ialert_id, cl_alname(ialert_id)//' : ', inb_alp(ialert_id), ' times ! '
624	END DO
625	!
626	END SUBROUTINE lim_ctl
627
628
629	SUBROUTINE lim_prt_state( ki, kj, kn, cd1 )
630	!!-----------------------------------------------------------------------
631	!! * ROUTINE lim_prt_state *
632	!!
633	!! ** Purpose : Writes global ice state on the (i,j) point
634	!! in ocean.ouput
635	!! 3 possibilities exist
636	!! n = 1/-1 -> simple ice state (plus Mechanical Check if -1)
637	!! n = 2 -> exhaustive state
638	!! n = 3 -> ice/ocean salt fluxes
639	!!
640	!! ** input : point coordinates (i,j)
641	!! n : number of the option
642	!!-------------------------------------------------------------------
643	INTEGER , INTENT(in) :: ki, kj, kn ! ocean gridpoint indices
644	CHARACTER(len=*), INTENT(in) :: cd1 !
645	!!
646	INTEGER :: jl
647	!!-------------------------------------------------------------------
648
649	WRITE(numout,*) cd1 ! print title
650
651	!----------------
652	! Simple state
653	!----------------
654
655	IF ( kn == 1 .OR. kn == -1 ) THEN
656	WRITE(numout,*) ' lim_prt_state - Point : ',ki,kj
657	WRITE(numout,*) ' ~~~~~~~~~~~~~~ '
658	WRITE(numout,*) ' Simple state '
659	WRITE(numout,*) ' masks s,u,v : ', tms(ki,kj), tmu(ki,kj), tmv(ki,kj)
660	WRITE(numout,*) ' lat - long : ', gphit(ki,kj), glamt(ki,kj)
661	WRITE(numout,*) ' Time step : ', numit
662	WRITE(numout,*) ' - Ice drift '
663	WRITE(numout,*) ' ~~~~~~~~~~~ '
664	WRITE(numout,*) ' u_ice(i-1,j) : ', u_ice(ki-1,kj)
665	WRITE(numout,*) ' u_ice(i ,j) : ', u_ice(ki,kj)
666	WRITE(numout,*) ' v_ice(i ,j-1): ', v_ice(ki,kj-1)
667	WRITE(numout,*) ' v_ice(i ,j) : ', v_ice(ki,kj)
668	WRITE(numout,*) ' strength : ', strength(ki,kj)
669	WRITE(numout,*)
670	WRITE(numout,*) ' - Cell values '
671	WRITE(numout,*) ' ~~~~~~~~~~~ '
672	WRITE(numout,*) ' cell area : ', area(ki,kj)
673	WRITE(numout,*) ' at_i : ', at_i(ki,kj)
674	WRITE(numout,*) ' vt_i : ', vt_i(ki,kj)
675	WRITE(numout,*) ' vt_s : ', vt_s(ki,kj)
676	DO jl = 1, jpl
677	WRITE(numout,*) ' - Category (', jl,')'
678	WRITE(numout,*) ' a_i : ', a_i(ki,kj,jl)
679	WRITE(numout,*) ' ht_i : ', ht_i(ki,kj,jl)
680	WRITE(numout,*) ' ht_s : ', ht_s(ki,kj,jl)
681	WRITE(numout,*) ' v_i : ', v_i(ki,kj,jl)
682	WRITE(numout,*) ' v_s : ', v_s(ki,kj,jl)
683	WRITE(numout,*) ' e_s : ', e_s(ki,kj,1,jl)/1.0e9
684	WRITE(numout,*) ' e_i : ', e_i(ki,kj,1:nlay_i,jl)/1.0e9
685	WRITE(numout,*) ' t_su : ', t_su(ki,kj,jl)
686	WRITE(numout,*) ' t_snow : ', t_s(ki,kj,1,jl)
687	WRITE(numout,*) ' t_i : ', t_i(ki,kj,1:nlay_i,jl)
688	WRITE(numout,*) ' sm_i : ', sm_i(ki,kj,jl)
689	WRITE(numout,*) ' smv_i : ', smv_i(ki,kj,jl)
690	WRITE(numout,*)
691	WRITE(numout,*) ' Pathological case : ', patho_case(ki,kj,jl)
692	END DO
693	ENDIF
694	IF( kn == -1 ) THEN
695	WRITE(numout,) ' Mechanical Check ************* '
696	WRITE(numout,*) ' Check what means ice divergence '
697	WRITE(numout,*) ' Total ice concentration ', at_i (ki,kj)
698	WRITE(numout,*) ' Total lead fraction ', ato_i(ki,kj)
699	WRITE(numout,*) ' Sum of both ', ato_i(ki,kj) + at_i(ki,kj)
700	WRITE(numout,*) ' Sum of both minus 1 ', ato_i(ki,kj) + at_i(ki,kj) - 1.00
701	ENDIF
702
703
704	!--------------------
705	! Exhaustive state
706	!--------------------
707
708	IF ( kn .EQ. 2 ) THEN
709	WRITE(numout,*) ' lim_prt_state - Point : ',ki,kj
710	WRITE(numout,*) ' ~~~~~~~~~~~~~~ '
711	WRITE(numout,*) ' Exhaustive state '
712	WRITE(numout,*) ' lat - long ', gphit(ki,kj), glamt(ki,kj)
713	WRITE(numout,*) ' Time step ', numit
714	WRITE(numout,*)
715	WRITE(numout,*) ' - Cell values '
716	WRITE(numout,*) ' ~~~~~~~~~~~ '
717	WRITE(numout,*) ' cell area : ', area(ki,kj)
718	WRITE(numout,*) ' at_i : ', at_i(ki,kj)
719	WRITE(numout,*) ' vt_i : ', vt_i(ki,kj)
720	WRITE(numout,*) ' vt_s : ', vt_s(ki,kj)
721	WRITE(numout,*) ' u_ice(i-1,j) : ', u_ice(ki-1,kj)
722	WRITE(numout,*) ' u_ice(i ,j) : ', u_ice(ki,kj)
723	WRITE(numout,*) ' v_ice(i ,j-1): ', v_ice(ki,kj-1)
724	WRITE(numout,*) ' v_ice(i ,j) : ', v_ice(ki,kj)
725	WRITE(numout,*) ' strength : ', strength(ki,kj)
726	WRITE(numout,*) ' d_u_ice_dyn : ', d_u_ice_dyn(ki,kj), ' d_v_ice_dyn : ', d_v_ice_dyn(ki,kj)
727	WRITE(numout,*) ' old_u_ice : ', old_u_ice(ki,kj) , ' old_v_ice : ', old_v_ice(ki,kj)
728	WRITE(numout,*)
729
730	DO jl = 1, jpl
731	WRITE(numout,*) ' - Category (',jl,')'
732	WRITE(numout,*) ' ~~~~~~~~ '
733	WRITE(numout,*) ' ht_i : ', ht_i(ki,kj,jl) , ' ht_s : ', ht_s(ki,kj,jl)
734	WRITE(numout,*) ' t_i : ', t_i(ki,kj,1:nlay_i,jl)
735	WRITE(numout,*) ' t_su : ', t_su(ki,kj,jl) , ' t_s : ', t_s(ki,kj,1,jl)
736	WRITE(numout,*) ' sm_i : ', sm_i(ki,kj,jl) , ' o_i : ', o_i(ki,kj,jl)
737	WRITE(numout,*) ' a_i : ', a_i(ki,kj,jl) , ' old_a_i : ', old_a_i(ki,kj,jl)
738	WRITE(numout,*) ' d_a_i_trp : ', d_a_i_trp(ki,kj,jl) , ' d_a_i_thd : ', d_a_i_thd(ki,kj,jl)
739	WRITE(numout,*) ' v_i : ', v_i(ki,kj,jl) , ' old_v_i : ', old_v_i(ki,kj,jl)
740	WRITE(numout,*) ' d_v_i_trp : ', d_v_i_trp(ki,kj,jl) , ' d_v_i_thd : ', d_v_i_thd(ki,kj,jl)
741	WRITE(numout,*) ' v_s : ', v_s(ki,kj,jl) , ' old_v_s : ', old_v_s(ki,kj,jl)
742	WRITE(numout,*) ' d_v_s_trp : ', d_v_s_trp(ki,kj,jl) , ' d_v_s_thd : ', d_v_s_thd(ki,kj,jl)
743	WRITE(numout,*) ' e_i1 : ', e_i(ki,kj,1,jl)/1.0e9 , ' old_ei1 : ', old_e_i(ki,kj,1,jl)/1.0e9
744	WRITE(numout,*) ' de_i1_trp : ', d_e_i_trp(ki,kj,1,jl)/1.0e9, ' de_i1_thd : ', d_e_i_thd(ki,kj,1,jl)/1.0e9
745	WRITE(numout,*) ' e_i2 : ', e_i(ki,kj,2,jl)/1.0e9 , ' old_ei2 : ', old_e_i(ki,kj,2,jl)/1.0e9
746	WRITE(numout,*) ' de_i2_trp : ', d_e_i_trp(ki,kj,2,jl)/1.0e9, ' de_i2_thd : ', d_e_i_thd(ki,kj,2,jl)/1.0e9
747	WRITE(numout,*) ' e_snow : ', e_s(ki,kj,1,jl) , ' old_e_snow : ', old_e_s(ki,kj,1,jl)
748	WRITE(numout,*) ' d_e_s_trp : ', d_e_s_trp(ki,kj,1,jl) , ' d_e_s_thd : ', d_e_s_thd(ki,kj,1,jl)
749	WRITE(numout,*) ' smv_i : ', smv_i(ki,kj,jl) , ' old_smv_i : ', old_smv_i(ki,kj,jl)
750	WRITE(numout,*) ' d_smv_i_trp: ', d_smv_i_trp(ki,kj,jl) , ' d_smv_i_thd: ', d_smv_i_thd(ki,kj,jl)
751	WRITE(numout,*) ' oa_i : ', oa_i(ki,kj,jl) , ' old_oa_i : ', old_oa_i(ki,kj,jl)
752	WRITE(numout,*) ' d_oa_i_trp : ', d_oa_i_trp(ki,kj,jl) , ' d_oa_i_thd : ', d_oa_i_thd(ki,kj,jl)
753	WRITE(numout,*) ' Path. case : ', patho_case(ki,kj,jl)
754	END DO !jl
755
756	WRITE(numout,*)
757	WRITE(numout,*) ' - Heat / FW fluxes '
758	WRITE(numout,*) ' ~~~~~~~~~~~~~~~~ '
759	! WRITE(numout,*) ' sfx_bri : ', sfx_bri (ki,kj)
760	! WRITE(numout,*) ' sfx : ', sfx (ki,kj)
761	! WRITE(numout,*) ' sfx_res : ', sfx_res(ki,kj)
762	WRITE(numout,*) ' fmmec : ', fmmec (ki,kj)
763	WRITE(numout,*) ' fhmec : ', fhmec (ki,kj)
764	WRITE(numout,*) ' fhbri : ', fhbri (ki,kj)
765	WRITE(numout,*) ' fheat_mec : ', fheat_mec(ki,kj)
766	WRITE(numout,*)
767	WRITE(numout,*) ' sst : ', sst_m(ki,kj)
768	WRITE(numout,*) ' sss : ', sss_m(ki,kj)
769	WRITE(numout,*)
770	WRITE(numout,*) ' - Stresses '
771	WRITE(numout,*) ' ~~~~~~~~ '
772	WRITE(numout,*) ' utau_ice : ', utau_ice(ki,kj)
773	WRITE(numout,*) ' vtau_ice : ', vtau_ice(ki,kj)
774	WRITE(numout,*) ' utau : ', utau (ki,kj)
775	WRITE(numout,*) ' vtau : ', vtau (ki,kj)
776	WRITE(numout,*) ' oc. vel. u : ', u_oce (ki,kj)
777	WRITE(numout,*) ' oc. vel. v : ', v_oce (ki,kj)
778	ENDIF
779
780	!---------------------
781	! Salt / heat fluxes
782	!---------------------
783
784	IF ( kn .EQ. 3 ) THEN
785	WRITE(numout,*) ' lim_prt_state - Point : ',ki,kj
786	WRITE(numout,*) ' ~~~~~~~~~~~~~~ '
787	WRITE(numout,*) ' - Salt / Heat Fluxes '
788	WRITE(numout,*) ' ~~~~~~~~~~~~~~~~ '
789	WRITE(numout,*) ' lat - long ', gphit(ki,kj), glamt(ki,kj)
790	WRITE(numout,*) ' Time step ', numit
791	WRITE(numout,*)
792	WRITE(numout,) ' - Heat fluxes at bottom interface **'
793	WRITE(numout,*) ' qsr : ', qsr(ki,kj)
794	WRITE(numout,*) ' qns : ', qns(ki,kj)
795	WRITE(numout,*)
796	WRITE(numout,) ' - Salt fluxes at bottom interface **'
797	WRITE(numout,*) ' emp : ', emp (ki,kj)
798	WRITE(numout,*) ' sfx_bri : ', sfx_bri(ki,kj)
799	WRITE(numout,*) ' sfx : ', sfx (ki,kj)
800	WRITE(numout,*) ' sfx_res : ', sfx_res(ki,kj)
801	WRITE(numout,*) ' sfx_mec : ', sfx_mec(ki,kj)
802	WRITE(numout,) ' - Heat fluxes at bottom interface **'
803	WRITE(numout,*) ' fheat_res : ', fheat_res(ki,kj)
804	WRITE(numout,*)
805	WRITE(numout,*) ' - Momentum fluxes '
806	WRITE(numout,*) ' utau : ', utau(ki,kj)
807	WRITE(numout,*) ' vtau : ', vtau(ki,kj)
808	ENDIF
809	WRITE(numout,*) ' '
810	!
811	END SUBROUTINE lim_prt_state
812
813	#else
814	!!----------------------------------------------------------------------
815	!! Default option Dummy module NO LIM 3.0 sea-ice model
816	!!----------------------------------------------------------------------
817	CONTAINS
818	SUBROUTINE sbc_ice_lim ( kt, kblk ) ! Dummy routine
819	WRITE(,) 'sbc_ice_lim: You should not have seen this print! error?', kt, kblk
820	END SUBROUTINE sbc_ice_lim
821	#endif
822
823	!!======================================================================
824	END MODULE sbcice_lim

Note: See TracBrowser for help on using the repository browser.

Download in other formats: