1 | MODULE p4zsed |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE p4sed *** |
---|
4 | !! TOP : PISCES Compute loss of organic matter in the sediments |
---|
5 | !!====================================================================== |
---|
6 | !! History : 1.0 ! 2004-03 (O. Aumont) Original code |
---|
7 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
---|
8 | !! 3.4 ! 2011-06 (C. Ethe) USE of fldread |
---|
9 | !! 3.5 ! 2012-07 (O. Aumont) improvment of river input of nutrients |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | #if defined key_pisces |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! 'key_pisces' PISCES bio-model |
---|
14 | !!---------------------------------------------------------------------- |
---|
15 | !! p4z_sed : Compute loss of organic matter in the sediments |
---|
16 | !!---------------------------------------------------------------------- |
---|
17 | USE oce_trc ! shared variables between ocean and passive tracers |
---|
18 | USE trc ! passive tracers common variables |
---|
19 | USE sms_pisces ! PISCES Source Minus Sink variables |
---|
20 | USE p4zsink ! vertical flux of particulate matter due to sinking |
---|
21 | USE p4zopt ! optical model |
---|
22 | USE p4zlim ! Co-limitations of differents nutrients |
---|
23 | USE p4zrem ! Remineralisation of organic matter |
---|
24 | USE p4zsbc ! External source of nutrients |
---|
25 | USE p4zint ! interpolation and computation of various fields |
---|
26 | USE iom ! I/O manager |
---|
27 | USE prtctl_trc ! print control for debugging |
---|
28 | |
---|
29 | IMPLICIT NONE |
---|
30 | PRIVATE |
---|
31 | |
---|
32 | PUBLIC p4z_sed |
---|
33 | |
---|
34 | !! * Module variables |
---|
35 | REAL(wp) :: ryyss !: number of seconds per year |
---|
36 | REAL(wp) :: r1_ryyss !: inverse of ryyss |
---|
37 | REAL(wp) :: rmtss !: number of seconds per month |
---|
38 | REAL(wp) :: r1_rday !: inverse of rday |
---|
39 | |
---|
40 | INTEGER :: numnit |
---|
41 | |
---|
42 | |
---|
43 | !!* Substitution |
---|
44 | # include "top_substitute.h90" |
---|
45 | !!---------------------------------------------------------------------- |
---|
46 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
---|
47 | !! $Header:$ |
---|
48 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
49 | !!---------------------------------------------------------------------- |
---|
50 | CONTAINS |
---|
51 | |
---|
52 | SUBROUTINE p4z_sed( kt, jnt ) |
---|
53 | !!--------------------------------------------------------------------- |
---|
54 | !! *** ROUTINE p4z_sed *** |
---|
55 | !! |
---|
56 | !! ** Purpose : Compute loss of organic matter in the sediments. This |
---|
57 | !! is by no way a sediment model. The loss is simply |
---|
58 | !! computed to balance the inout from rivers and dust |
---|
59 | !! |
---|
60 | !! ** Method : - ??? |
---|
61 | !!--------------------------------------------------------------------- |
---|
62 | ! |
---|
63 | INTEGER, INTENT(in) :: kt, jnt ! ocean time step |
---|
64 | INTEGER :: ji, jj, jk, ikt |
---|
65 | #if ! defined key_sed |
---|
66 | REAL(wp) :: zsumsedsi, zsumsedpo4, zsumsedcal |
---|
67 | REAL(wp) :: zrivalk, zrivsil, zrivno3 |
---|
68 | #endif |
---|
69 | REAL(wp) :: zwflux, zfminus, zfplus |
---|
70 | REAL(wp) :: zlim, zfact, zfactcal |
---|
71 | REAL(wp) :: zo2, zno3, zflx, zpdenit, z1pdenit |
---|
72 | REAL(wp) :: zsiloss, zcaloss, zwsbio3, zwsbio4, zwscal, zdep, zwstpoc |
---|
73 | REAL(wp) :: ztrfer, ztrpo4, zwdust |
---|
74 | REAL(wp) :: zrdenittot, zsdenittot, znitrpottot |
---|
75 | ! |
---|
76 | CHARACTER (len=25) :: charout |
---|
77 | REAL(wp), POINTER, DIMENSION(:,: ) :: zpdep, zsidep, zwork1, zwork2, zwork3, zwork4 |
---|
78 | REAL(wp), POINTER, DIMENSION(:,: ) :: zdenit2d, zironice |
---|
79 | REAL(wp), POINTER, DIMENSION(:,:,:) :: znitrpot, zirondep |
---|
80 | !!--------------------------------------------------------------------- |
---|
81 | ! |
---|
82 | IF( nn_timing == 1 ) CALL timing_start('p4z_sed') |
---|
83 | ! |
---|
84 | IF( kt == nit000 .AND. jnt == 1 ) THEN |
---|
85 | ryyss = nyear_len(1) * rday ! number of seconds per year and per month |
---|
86 | rmtss = ryyss / raamo |
---|
87 | r1_rday = 1. / rday |
---|
88 | r1_ryyss = 1. / ryyss |
---|
89 | IF( ln_check_mass .AND. lwp) & |
---|
90 | & CALL ctl_opn( numnit, 'nitrogen.budget', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea ) |
---|
91 | ENDIF |
---|
92 | ! |
---|
93 | ! Allocate temporary workspace |
---|
94 | CALL wrk_alloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zwork4 ) |
---|
95 | CALL wrk_alloc( jpi, jpj, jpk, znitrpot ) |
---|
96 | zdenit2d(:,:) = 0.e0 |
---|
97 | |
---|
98 | ! Iron input/uptake due to sea ice : Crude parameterization based on Lancelot et al. |
---|
99 | ! ---------------------------------------------------- |
---|
100 | IF( ln_ironice ) THEN |
---|
101 | ! |
---|
102 | CALL wrk_alloc( jpi, jpj, zironice ) |
---|
103 | ! |
---|
104 | DO jj = 1, jpj |
---|
105 | DO ji = 1, jpi |
---|
106 | zdep = rfact2 / fse3t(ji,jj,1) |
---|
107 | ! zwflux = ( emps(ji,jj) - emp(ji,jj) ) & |
---|
108 | ! & * tsn(ji,jj,1,jp_sal) / ( tsn(ji,jj,1,jp_sal) - 6.0 ) / 1000. |
---|
109 | zwflux = 0. |
---|
110 | zfminus = MIN( 0., -zwflux ) * trn(ji,jj,1,jpfer) * zdep |
---|
111 | zfplus = MAX( 0., -zwflux ) * 10E-9 * zdep |
---|
112 | zironice(ji,jj) = zfplus + zfminus |
---|
113 | END DO |
---|
114 | END DO |
---|
115 | ! |
---|
116 | trn(:,:,1,jpfer) = trn(:,:,1,jpfer) + zironice(:,:) |
---|
117 | ! |
---|
118 | IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc ) & |
---|
119 | & CALL iom_put( "Ironice", zironice(:,:) * 1.e+3 * rfact2r * fse3t(:,:,1) * tmask(:,:,1) ) ! iron flux from ice |
---|
120 | CALL wrk_dealloc( jpi, jpj, zironice ) |
---|
121 | ! |
---|
122 | ENDIF |
---|
123 | |
---|
124 | ! Add the external input of nutrients from dust deposition |
---|
125 | ! ---------------------------------------------------------- |
---|
126 | IF( ln_dust ) THEN |
---|
127 | ! |
---|
128 | CALL wrk_alloc( jpi, jpj, zpdep, zsidep ) |
---|
129 | CALL wrk_alloc( jpi, jpj, jpk, zirondep ) |
---|
130 | ! ! Iron and Si deposition at the surface |
---|
131 | IF( ln_solub ) THEN |
---|
132 | zirondep(:,:,1) = solub(:,:) * dust(:,:) * rfact2 / fse3t(:,:,1) / ( 55.85 * rmtss ) + 3.e-10 * r1_ryyss |
---|
133 | ELSE |
---|
134 | zirondep(:,:,1) = dustsolub * dust(:,:) * rfact2 / fse3t(:,:,1) / ( 55.85 * rmtss ) + 3.e-10 * r1_ryyss |
---|
135 | ENDIF |
---|
136 | zsidep(:,:) = 8.8 * 0.075 * dust(:,:) * rfact2 / fse3t(:,:,1) / ( 28.1 * rmtss ) |
---|
137 | zpdep (:,:) = 0.1 * 0.021 * dust(:,:) * rfact2 / fse3t(:,:,1) / ( 31. * rmtss ) |
---|
138 | ! ! Iron solubilization of particles in the water column |
---|
139 | zwdust = 0.005 / ( wdust * 55.85 * 30.42 ) / ( 45. * rday ) |
---|
140 | DO jk = 2, jpkm1 |
---|
141 | zirondep(:,:,jk) = dust(:,:) * zwdust * rfact2 * EXP( -fsdept(:,:,jk) / 1000. ) |
---|
142 | END DO |
---|
143 | ! ! Iron solubilization of particles in the water column |
---|
144 | trn(:,:,1,jppo4) = trn(:,:,1,jppo4) + zpdep (:,:) |
---|
145 | trn(:,:,1,jpsil) = trn(:,:,1,jpsil) + zsidep (:,:) |
---|
146 | trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + zirondep(:,:,:) |
---|
147 | ! |
---|
148 | IF( ln_diatrc ) THEN |
---|
149 | zfact = 1.e+3 * rfact2r |
---|
150 | IF( lk_iomput ) THEN |
---|
151 | IF( jnt == nrdttrc ) THEN |
---|
152 | CALL iom_put( "Irondep", zirondep(:,:,1) * zfact * fse3t(:,:,1) * tmask(:,:,1) ) ! surface downward dust depo of iron |
---|
153 | CALL iom_put( "pdust" , dust(:,:) / ( wdust * 30.42 * 0.035 ) * tmask(:,:,1) ) ! dust concentration at surface |
---|
154 | ENDIF |
---|
155 | ELSE |
---|
156 | trc2d(:,:,jp_pcs0_2d + 11) = zirondep(:,:,1) * zfact * fse3t(:,:,1) * tmask(:,:,1) |
---|
157 | ENDIF |
---|
158 | ENDIF |
---|
159 | CALL wrk_dealloc( jpi, jpj, zpdep, zsidep ) |
---|
160 | CALL wrk_dealloc( jpi, jpj, jpk, zirondep ) |
---|
161 | ! |
---|
162 | ENDIF |
---|
163 | |
---|
164 | ! Add the external input of nutrients from river |
---|
165 | ! ---------------------------------------------------------- |
---|
166 | IF( ln_river ) THEN |
---|
167 | trn(:,:,1,jppo4) = trn(:,:,1,jppo4) + rivdip(:,:) * rfact2 |
---|
168 | trn(:,:,1,jpno3) = trn(:,:,1,jpno3) + rivdin(:,:) * rfact2 |
---|
169 | trn(:,:,1,jpfer) = trn(:,:,1,jpfer) + rivdic(:,:) * 5.e-5 * rfact2 |
---|
170 | trn(:,:,1,jpsil) = trn(:,:,1,jpsil) + rivdsi(:,:) * rfact2 |
---|
171 | trn(:,:,1,jpdic) = trn(:,:,1,jpdic) + rivdic(:,:) * rfact2 |
---|
172 | trn(:,:,1,jptal) = trn(:,:,1,jptal) + ( rivalk(:,:) - rno3 * rivdin(:,:) ) * rfact2 |
---|
173 | ENDIF |
---|
174 | |
---|
175 | ! Add the external input of nutrients from nitrogen deposition |
---|
176 | ! ---------------------------------------------------------- |
---|
177 | IF( ln_ndepo ) THEN |
---|
178 | trn(:,:,1,jpno3) = trn(:,:,1,jpno3) + nitdep(:,:) * rfact2 |
---|
179 | trn(:,:,1,jptal) = trn(:,:,1,jptal) - rno3 * nitdep(:,:) * rfact2 |
---|
180 | ENDIF |
---|
181 | |
---|
182 | ! Add the external input of iron from sediment mobilization |
---|
183 | ! ------------------------------------------------------ |
---|
184 | IF( ln_ironsed ) THEN |
---|
185 | trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + ironsed(:,:,:) * rfact2 |
---|
186 | ! |
---|
187 | IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc ) & |
---|
188 | & CALL iom_put( "Ironsed", ironsed(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! iron inputs from sediments |
---|
189 | ENDIF |
---|
190 | |
---|
191 | ! Add the external input of iron from hydrothermal vents |
---|
192 | ! ------------------------------------------------------ |
---|
193 | IF( ln_hydrofe ) THEN |
---|
194 | trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + hydrofe(:,:,:) * rfact2 |
---|
195 | ! |
---|
196 | IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc ) & |
---|
197 | & CALL iom_put( "HYDR", hydrofe(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! hydrothermal iron input |
---|
198 | ENDIF |
---|
199 | |
---|
200 | #if ! defined key_sed |
---|
201 | ! Computation of the sediment denitrification proportion: The metamodel from midlleburg (2006) is being used |
---|
202 | ! ------------------------------------------------------- |
---|
203 | DO jj = 1, jpj |
---|
204 | DO ji = 1, jpi |
---|
205 | IF( tmask(ji,jj,1) == 1 ) THEN |
---|
206 | ikt = mbkt(ji,jj) |
---|
207 | # if defined key_kriest |
---|
208 | zflx = trn(ji,jj,ikt,jppoc) * wsbio3(ji,jj,ikt) * 1E3 * 1E6 / 1E4 |
---|
209 | # else |
---|
210 | zflx = ( trn(ji,jj,ikt,jpgoc) * wsbio4(ji,jj,ikt) & |
---|
211 | & + trn(ji,jj,ikt,jppoc) * wsbio3(ji,jj,ikt) ) * 1E3 * 1E6 / 1E4 |
---|
212 | #endif |
---|
213 | zflx = LOG10( MAX( 1E-3, zflx ) ) |
---|
214 | zo2 = LOG10( MAX( 10. , trn(ji,jj,ikt,jpoxy) * 1E6 ) ) |
---|
215 | zno3 = LOG10( MAX( 1. , trn(ji,jj,ikt,jpno3) * 1E6 * rno3 ) ) |
---|
216 | zdep = LOG10( fsdepw(ji,jj,ikt+1) ) |
---|
217 | zdenit2d(ji,jj) = -2.2567 - 1.185 * zflx - 0.221 * zflx**2 - 0.3995 * zno3 * zo2 + 1.25 * zno3 & |
---|
218 | & + 0.4721 * zo2 - 0.0996 * zdep + 0.4256 * zflx * zo2 |
---|
219 | zdenit2d(ji,jj) = 10.0**( zdenit2d(ji,jj) ) |
---|
220 | ENDIF |
---|
221 | END DO |
---|
222 | END DO |
---|
223 | ! Loss of biogenic silicon, Caco3 organic carbon in the sediments. |
---|
224 | ! First, the total loss is computed. |
---|
225 | ! The factor for calcite comes from the alkalinity effect |
---|
226 | ! ------------------------------------------------------------- |
---|
227 | DO jj = 1, jpj |
---|
228 | DO ji = 1, jpi |
---|
229 | ikt = mbkt(ji,jj) |
---|
230 | # if defined key_kriest |
---|
231 | zwork1(ji,jj) = trn(ji,jj,ikt,jpgsi) * wscal (ji,jj,ikt) |
---|
232 | zwork2(ji,jj) = trn(ji,jj,ikt,jppoc) * wsbio3(ji,jj,ikt) |
---|
233 | # else |
---|
234 | zwork1(ji,jj) = trn(ji,jj,ikt,jpgsi) * wsbio4(ji,jj,ikt) |
---|
235 | zwork2(ji,jj) = trn(ji,jj,ikt,jpgoc) * wsbio4(ji,jj,ikt) + trn(ji,jj,ikt,jppoc) * wsbio3(ji,jj,ikt) |
---|
236 | # endif |
---|
237 | ! For calcite, burial efficiency is made a function of saturation |
---|
238 | zfactcal = MIN( excess(ji,jj,ikt), 0.2 ) |
---|
239 | zfactcal = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) ) |
---|
240 | zwork3(ji,jj) = trn(ji,jj,ikt,jpcal) * wscal (ji,jj,ikt) * 2.e0 * zfactcal |
---|
241 | END DO |
---|
242 | END DO |
---|
243 | zsumsedsi = glob_sum( zwork1(:,:) * e1e2t(:,:) ) * r1_rday |
---|
244 | zsumsedpo4 = glob_sum( zwork2(:,:) * e1e2t(:,:) ) * r1_rday |
---|
245 | zsumsedcal = glob_sum( zwork3(:,:) * e1e2t(:,:) ) * r1_rday |
---|
246 | #endif |
---|
247 | |
---|
248 | ! THEN this loss is scaled at each bottom grid cell for |
---|
249 | ! equilibrating the total budget of silica in the ocean. |
---|
250 | ! Thus, the amount of silica lost in the sediments equal |
---|
251 | ! the supply at the surface (dust+rivers) |
---|
252 | ! ------------------------------------------------------ |
---|
253 | #if ! defined key_sed |
---|
254 | zrivsil = 1._wp - ( sumdepsi + rivdsiinput * r1_ryyss ) / zsumsedsi |
---|
255 | zrivno3 = 1._wp - ( rivdininput * r1_ryyss ) / zsumsedpo4 |
---|
256 | #endif |
---|
257 | |
---|
258 | DO jj = 1, jpj |
---|
259 | DO ji = 1, jpi |
---|
260 | ikt = mbkt(ji,jj) |
---|
261 | zdep = xstep / fse3t(ji,jj,ikt) |
---|
262 | zwsbio4 = wsbio4(ji,jj,ikt) * zdep |
---|
263 | zwscal = wscal (ji,jj,ikt) * zdep |
---|
264 | # if defined key_kriest |
---|
265 | zsiloss = trn(ji,jj,ikt,jpgsi) * zwsbio4 |
---|
266 | # else |
---|
267 | zsiloss = trn(ji,jj,ikt,jpgsi) * zwscal |
---|
268 | # endif |
---|
269 | zcaloss = trn(ji,jj,ikt,jpcal) * zwscal |
---|
270 | ! |
---|
271 | trn(ji,jj,ikt,jpgsi) = trn(ji,jj,ikt,jpgsi) - zsiloss |
---|
272 | trn(ji,jj,ikt,jpcal) = trn(ji,jj,ikt,jpcal) - zcaloss |
---|
273 | #if ! defined key_sed |
---|
274 | trn(ji,jj,ikt,jpsil) = trn(ji,jj,ikt,jpsil) + zsiloss * zrivsil |
---|
275 | zfactcal = MIN( excess(ji,jj,ikt), 0.2 ) |
---|
276 | zfactcal = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) ) |
---|
277 | zrivalk = 1._wp - ( rivalkinput * r1_ryyss ) * zfactcal / zsumsedcal |
---|
278 | trn(ji,jj,ikt,jptal) = trn(ji,jj,ikt,jptal) + zcaloss * zrivalk * 2.0 |
---|
279 | trn(ji,jj,ikt,jpdic) = trn(ji,jj,ikt,jpdic) + zcaloss * zrivalk |
---|
280 | #endif |
---|
281 | END DO |
---|
282 | END DO |
---|
283 | |
---|
284 | DO jj = 1, jpj |
---|
285 | DO ji = 1, jpi |
---|
286 | ikt = mbkt(ji,jj) |
---|
287 | zdep = xstep / fse3t(ji,jj,ikt) |
---|
288 | zwsbio4 = wsbio4(ji,jj,ikt) * zdep |
---|
289 | zwsbio3 = wsbio3(ji,jj,ikt) * zdep |
---|
290 | # if ! defined key_kriest |
---|
291 | trn(ji,jj,ikt,jpgoc) = trn(ji,jj,ikt,jpgoc) - trn(ji,jj,ikt,jpgoc) * zwsbio4 |
---|
292 | trn(ji,jj,ikt,jppoc) = trn(ji,jj,ikt,jppoc) - trn(ji,jj,ikt,jppoc) * zwsbio3 |
---|
293 | trn(ji,jj,ikt,jpbfe) = trn(ji,jj,ikt,jpbfe) - trn(ji,jj,ikt,jpbfe) * zwsbio4 |
---|
294 | trn(ji,jj,ikt,jpsfe) = trn(ji,jj,ikt,jpsfe) - trn(ji,jj,ikt,jpsfe) * zwsbio3 |
---|
295 | zwstpoc = trn(ji,jj,ikt,jpgoc) * zwsbio4 + trn(ji,jj,ikt,jppoc) * zwsbio3 |
---|
296 | # else |
---|
297 | trn(ji,jj,ikt,jpnum) = trn(ji,jj,ikt,jpnum) - trn(ji,jj,ikt,jpnum) * zwsbio4 |
---|
298 | trn(ji,jj,ikt,jppoc) = trn(ji,jj,ikt,jppoc) - trn(ji,jj,ikt,jppoc) * zwsbio3 |
---|
299 | trn(ji,jj,ikt,jpsfe) = trn(ji,jj,ikt,jpsfe) - trn(ji,jj,ikt,jpsfe) * zwsbio3 |
---|
300 | zwstpoc = trn(ji,jj,ikt,jppoc) * zwsbio3 |
---|
301 | # endif |
---|
302 | |
---|
303 | #if ! defined key_sed |
---|
304 | zpdenit = MIN( ( trn(ji,jj,ikt,jpno3) - rtrn ) / rdenit, zdenit2d(ji,jj) * zwstpoc * zrivno3 ) |
---|
305 | z1pdenit = zwstpoc * zrivno3 - zpdenit |
---|
306 | trn(ji,jj,ikt,jpdoc) = trn(ji,jj,ikt,jpdoc) + z1pdenit |
---|
307 | trn(ji,jj,ikt,jppo4) = trn(ji,jj,ikt,jppo4) + zpdenit |
---|
308 | trn(ji,jj,ikt,jpnh4) = trn(ji,jj,ikt,jpnh4) + zpdenit |
---|
309 | trn(ji,jj,ikt,jpno3) = trn(ji,jj,ikt,jpno3) - rdenit * zpdenit |
---|
310 | trn(ji,jj,ikt,jptal) = trn(ji,jj,ikt,jptal) + rno3 * ( 1. + rdenit ) * zpdenit |
---|
311 | trn(ji,jj,ikt,jpdic) = trn(ji,jj,ikt,jpdic) + zpdenit |
---|
312 | zwork4(ji,jj) = rdenit * zpdenit * fse3t(ji,jj,ikt) |
---|
313 | #endif |
---|
314 | END DO |
---|
315 | END DO |
---|
316 | |
---|
317 | ! Nitrogen fixation process |
---|
318 | !----------------------------------- |
---|
319 | DO jk = 1, jpkm1 |
---|
320 | DO jj = 1, jpj |
---|
321 | DO ji = 1, jpi |
---|
322 | ! ! Potential nitrogen fixation dependant on temperature and iron |
---|
323 | zlim = ( 1.- xnanono3(ji,jj,jk) - xnanonh4(ji,jj,jk) ) |
---|
324 | IF( zlim <= 0.2 ) zlim = 0.01 |
---|
325 | #if defined key_degrad |
---|
326 | zfact = zlim * rfact2 * facvol(ji,jj,jk) |
---|
327 | #else |
---|
328 | zfact = zlim * rfact2 |
---|
329 | #endif |
---|
330 | ztrfer = biron(ji,jj,jk) / ( concfediaz + biron(ji,jj,jk) ) |
---|
331 | ztrpo4 = trn (ji,jj,jk,jppo4) / ( concnnh4 + trn (ji,jj,jk,jppo4) ) |
---|
332 | znitrpot(ji,jj,jk) = MAX( 0.e0, ( 0.6 * tgfunc(ji,jj,jk) - 2.15 ) * r1_rday ) & |
---|
333 | & * zfact * MIN( ztrfer, ztrpo4 ) * ( 1.- EXP( -etot(ji,jj,jk) / diazolight ) ) |
---|
334 | END DO |
---|
335 | END DO |
---|
336 | END DO |
---|
337 | |
---|
338 | IF( ln_check_mass ) THEN |
---|
339 | ! The total gain from nitrogen fixation is scaled to balance the loss by denitrification |
---|
340 | ! ------------------------------------------------------------- |
---|
341 | zrdenittot = glob_sum ( denitr(:,:,:) * rdenit * xnegtr(:,:,:) * cvol(:,:,:) ) |
---|
342 | zsdenittot = glob_sum ( zwork4(:,:) * e1e2t(:,:) ) |
---|
343 | znitrpottot = glob_sum ( znitrpot(:,:,:) * cvol(:,:,:) ) |
---|
344 | IF( kt == nitend .AND. jnt == nrdttrc ) THEN |
---|
345 | zfact = 1.e+3 * rfact2r * rno3 * 365. * 86400. * 14. / 1e12 |
---|
346 | IF(lwp) WRITE(numnit,9100) ndastp, znitrpottot * nitrfix * zfact, zrdenittot * zfact , zsdenittot * zfact |
---|
347 | ENDIF |
---|
348 | ENDIF |
---|
349 | |
---|
350 | ! Nitrogen change due to nitrogen fixation |
---|
351 | ! ---------------------------------------- |
---|
352 | DO jk = 1, jpkm1 |
---|
353 | DO jj = 1, jpj |
---|
354 | DO ji = 1, jpi |
---|
355 | ! zfact = znitrpot(ji,jj,jk) * ( zrdenittot + zsdenittot ) / znitrpottot |
---|
356 | zfact = znitrpot(ji,jj,jk) * nitrfix |
---|
357 | trn(ji,jj,jk,jpnh4) = trn(ji,jj,jk,jpnh4) + zfact |
---|
358 | trn(ji,jj,jk,jptal) = trn(ji,jj,jk,jptal) + rno3 * zfact |
---|
359 | trn(ji,jj,jk,jpoxy) = trn(ji,jj,jk,jpoxy) + o2nit * zfact |
---|
360 | trn(ji,jj,jk,jppo4) = trn(ji,jj,jk,jppo4) + 30. / 46. * zfact |
---|
361 | END DO |
---|
362 | END DO |
---|
363 | END DO |
---|
364 | ! |
---|
365 | IF( ln_diatrc ) THEN |
---|
366 | zfact = 1.e+3 * rfact2r |
---|
367 | IF( lk_iomput ) THEN |
---|
368 | IF( jnt == nrdttrc ) THEN |
---|
369 | CALL iom_put( "Nfix" , znitrpot(:,:,:) * nitrfix * rno3 * zfact * tmask(:,:,:) ) ! nitrogen fixation |
---|
370 | CALL iom_put( "Sdenit", zwork4(:,:) * rno3 * zfact * tmask(:,:,1) ) ! Nitrate reduction in the sediments |
---|
371 | ENDIF |
---|
372 | ELSE |
---|
373 | trc2d(:,:,jp_pcs0_2d + 12) = znitrpot(:,:,1) * nitrfix * zfact * fse3t(:,:,1) * tmask(:,:,1) |
---|
374 | ENDIF |
---|
375 | ENDIF |
---|
376 | ! |
---|
377 | IF(ln_ctl) THEN ! print mean trends (USEd for debugging) |
---|
378 | WRITE(charout, fmt="('sed ')") |
---|
379 | CALL prt_ctl_trc_info(charout) |
---|
380 | CALL prt_ctl_trc(tab4d=trn, mask=tmask, clinfo=ctrcnm) |
---|
381 | ENDIF |
---|
382 | ! |
---|
383 | CALL wrk_dealloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zwork4 ) |
---|
384 | CALL wrk_dealloc( jpi, jpj, jpk, znitrpot ) |
---|
385 | ! |
---|
386 | IF( nn_timing == 1 ) CALL timing_stop('p4z_sed') |
---|
387 | ! |
---|
388 | 9100 FORMAT(i8,3f10.5) |
---|
389 | ! |
---|
390 | END SUBROUTINE p4z_sed |
---|
391 | |
---|
392 | #else |
---|
393 | !!====================================================================== |
---|
394 | !! Dummy module : No PISCES bio-model |
---|
395 | !!====================================================================== |
---|
396 | CONTAINS |
---|
397 | SUBROUTINE p4z_sed ! Empty routine |
---|
398 | END SUBROUTINE p4z_sed |
---|
399 | #endif |
---|
400 | |
---|
401 | !!====================================================================== |
---|
402 | END MODULE p4zsed |
---|