source: branches/2013/dev_LOCEAN_CMCC_INGV_2013/NEMOGCM/NEMO/OFF_SRC/nemogcm.F90 @ 4230

Last change on this file since 4230 was 4230, checked in by cetlod, 7 years ago

dev_LOCEAN_CMCC_INGV_2013 : merge LOCEAN & CMCC_INGV branches, see ticket #1182

File size: 28.8 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Off-line Ocean   : passive tracer evolution, dynamics read in files
5   !!======================================================================
6   !! History :  3.3  ! 2010-05  (C. Ethe)  Full reorganization of the off-line: phasing with the on-line
7   !!            4.0  ! 2011-01  (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   nemo_gcm        : off-line: solve ocean tracer only
12   !!   nemo_init       : initialization of the nemo model
13   !!   nemo_ctl        : initialisation of algorithm flag
14   !!   nemo_closefile  : close remaining files
15   !!----------------------------------------------------------------------
16   USE dom_oce         ! ocean space domain variables
17   USE oce             ! dynamics and tracers variables
18   USE c1d             ! 1D configuration
19   USE domcfg          ! domain configuration               (dom_cfg routine)
20   USE domain          ! domain initialization             (dom_init routine)
21   USE istate          ! initial state setting          (istate_init routine)
22   USE eosbn2          ! equation of state            (eos bn2 routine)
23   !              ! ocean physics
24   USE ldftra          ! lateral diffusivity setting    (ldf_tra_init routine)
25   USE ldfslp          ! slopes of neutral surfaces     (ldf_slp_init routine)
26   USE traqsr          ! solar radiation penetration    (tra_qsr_init routine)
27   USE trabbl          ! bottom boundary layer          (tra_bbl_init routine)
28   USE zdfini          ! vertical physics: initialization
29   USE sbcmod          ! surface boundary condition       (sbc_init     routine)
30   USE phycst          ! physical constant                  (par_cst routine)
31   USE dtadyn          ! Lecture and Interpolation of the dynamical fields
32   USE trcini          ! Initilization of the passive tracers
33   USE daymod          ! calendar                         (day     routine)
34   USE trcstp          ! passive tracer time-stepping      (trc_stp routine)
35   USE dtadyn          ! Lecture and interpolation of the dynamical fields
36   USE stpctl          ! time stepping control            (stp_ctl routine)
37   !              ! I/O & MPP
38   USE iom             ! I/O library
39   USE in_out_manager  ! I/O manager
40   USE mppini          ! shared/distributed memory setting (mpp_init routine)
41   USE lib_mpp         ! distributed memory computing
42#if defined key_iomput
43   USE xios
44#endif
45   USE prtctl          ! Print control                    (prt_ctl_init routine)
46   USE timing          ! Timing
47   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
48   USE lbcnfd, ONLY: isendto, nsndto
49
50   USE trc
51   USE trcnam
52   USE trcrst
53
54   IMPLICIT NONE
55   PRIVATE
56   
57   PUBLIC   nemo_gcm   ! called by nemo.F90
58
59   CHARACTER (len=64) ::   cform_aaa="( /, 'AAAAAAAA', / ) "   ! flag for output listing
60
61   !!----------------------------------------------------------------------
62   !! NEMO/OFF 3.3 , NEMO Consortium (2010)
63   !! $Id: nemogcm.F90 2528 2010-12-27 17:33:53Z rblod $
64   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE nemo_gcm
69      !!----------------------------------------------------------------------
70      !!                     ***  ROUTINE nemo_gcm  ***
71      !!
72      !! ** Purpose :   nemo solves the primitive equations on an orthogonal
73      !!      curvilinear mesh on the sphere.
74      !!
75      !! ** Method  : - model general initialization
76      !!              - launch the time-stepping (dta_dyn and trc_stp)
77      !!              - finalize the run by closing files and communications
78      !!
79      !! References : Madec, Delecluse,Imbard, and Levy, 1997:  internal report, IPSL.
80      !!              Madec, 2008, internal report, IPSL.
81      !!----------------------------------------------------------------------
82      INTEGER :: istp, indic       ! time step index
83      !!----------------------------------------------------------------------
84
85      CALL nemo_init  ! Initializations
86
87      ! check that all process are still there... If some process have an error,
88      ! they will never enter in step and other processes will wait until the end of the cpu time!
89      IF( lk_mpp )   CALL mpp_max( nstop )
90
91      !                            !-----------------------!
92      !                            !==   time stepping   ==!
93      !                            !-----------------------!
94      istp = nit000
95      !
96      CALL iom_init( "nemo" )            ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
97      !
98      DO WHILE ( istp <= nitend .AND. nstop == 0 )    ! time stepping
99         !
100         IF( istp /= nit000 )   CALL day      ( istp )         ! Calendar (day was already called at nit000 in day_init)
101                                CALL iom_setkt( istp - nit000 + 1, "nemo" )   ! say to iom that we are at time step kstp
102                                CALL dta_dyn  ( istp )         ! Interpolation of the dynamical fields
103                                CALL trc_stp  ( istp )         ! time-stepping
104                                CALL stp_ctl  ( istp, indic )  ! Time loop: control and print
105         istp = istp + 1
106         IF( lk_mpp )   CALL mpp_max( nstop )
107      END DO
108#if defined key_iomput
109      CALL iom_context_finalize( "nemo" ) ! needed for XIOS+AGRIF
110#endif
111
112      !                            !------------------------!
113      !                            !==  finalize the run  ==!
114      !                            !------------------------!
115      IF(lwp) WRITE(numout,cform_aaa)                 ! Flag AAAAAAA
116
117      IF( nstop /= 0 .AND. lwp ) THEN                 ! error print
118         WRITE(numout,cform_err)
119         WRITE(numout,*) nstop, ' error have been found'
120      ENDIF
121      !
122      IF( nn_timing == 1 )   CALL timing_finalize
123      !
124      CALL nemo_closefile
125      !
126# if defined key_iomput
127      CALL xios_finalize             ! end mpp communications
128# else
129      IF( lk_mpp )   CALL mppstop       ! end mpp communications
130# endif
131      !
132   END SUBROUTINE nemo_gcm
133
134
135   SUBROUTINE nemo_init
136      !!----------------------------------------------------------------------
137      !!                     ***  ROUTINE nemo_init ***
138      !!
139      !! ** Purpose :   initialization of the nemo model in off-line mode
140      !!----------------------------------------------------------------------
141      INTEGER ::   ji            ! dummy loop indices
142      INTEGER ::   ilocal_comm   ! local integer
143      INTEGER ::   ios
144      CHARACTER(len=80), DIMENSION(16) ::   cltxt
145      !!
146      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
147         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
148         &             nn_bench, nn_timing
149      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
150         &             jpizoom, jpjzoom, jperio
151      !!----------------------------------------------------------------------
152      !
153      cltxt = ''
154      !
155      !                             ! Open reference namelist and configuration namelist files
156      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
157      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
158      CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
159      !
160      !
161      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
162      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
163901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', lwp )
164
165      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
166      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
167902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', lwp )
168      WRITE( numond, namctl )
169      !
170      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
171      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
172903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', lwp )
173
174      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
175      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
176904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', lwp )   
177      WRITE( numond, namcfg )
178      !                             !--------------------------------------------!
179      !                             !  set communicator & select the local node  !
180      !                             !--------------------------------------------!
181#if defined key_iomput
182         CALL  xios_initialize( "nemo",return_comm=ilocal_comm )
183      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection
184#else
185      ilocal_comm = 0
186      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop )                ! Nodes selection (control print return in cltxt)
187#endif
188
189      narea = narea + 1                       ! mynode return the rank of proc (0 --> jpnij -1 )
190
191      lwp = (narea == 1) .OR. ln_ctl          ! control of all listing output print
192
193      ! If dimensions of processor grid weren't specified in the namelist file
194      ! then we calculate them here now that we have our communicator size
195      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
196#if   defined key_mpp_mpi
197         CALL nemo_partition(mppsize)
198#else
199         jpni = 1
200         jpnj = 1
201         jpnij = jpni*jpnj
202#endif
203      END IF
204
205      ! Calculate domain dimensions given calculated jpni and jpnj
206      ! This used to be done in par_oce.F90 when they were parameters rather
207      ! than variables
208      jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
209      jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
210      jpk = jpkdta                                             ! third dim
211      jpim1 = jpi-1                                            ! inner domain indices
212      jpjm1 = jpj-1                                            !   "           "
213      jpkm1 = jpk-1                                            !   "           "
214      jpij  = jpi*jpj                                          !  jpi x j
215
216
217      IF(lwp) THEN                            ! open listing units
218         !
219         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
220         !
221         WRITE(numout,*)
222         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
223         WRITE(numout,*) '                       NEMO team'
224         WRITE(numout,*) '            Ocean General Circulation Model'
225         WRITE(numout,*) '                  version 3.5  (2012) '
226         WRITE(numout,*)
227         WRITE(numout,*)
228         DO ji = 1, SIZE(cltxt) 
229            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
230         END DO
231         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
232         !
233      ENDIF
234
235      ! Now we know the dimensions of the grid and numout has been set we can
236      ! allocate arrays
237      CALL nemo_alloc()
238
239      !                             !--------------------------------!
240      !                             !  Model general initialization  !
241      !                             !--------------------------------!
242
243      CALL nemo_ctl                           ! Control prints & Benchmark
244
245      !                                      ! Domain decomposition
246      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
247      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
248      ENDIF
249      !
250      IF( nn_timing == 1 )  CALL timing_init
251      !
252
253      !                                      ! General initialization
254      IF( nn_timing == 1 )  CALL timing_start( 'nemo_init')
255      !
256                            CALL     phy_cst    ! Physical constants
257                            CALL     eos_init   ! Equation of state
258                            CALL     dom_cfg    ! Domain configuration
259                            CALL     dom_init   ! Domain
260                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
261
262      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
263
264      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
265
266      !                                     ! Ocean physics
267                            CALL     sbc_init   ! Forcings : surface module
268#if ! defined key_degrad
269                            CALL ldf_tra_init   ! Lateral ocean tracer physics
270#endif
271      IF( lk_ldfslp )       CALL ldf_slp_init   ! slope of lateral mixing
272
273      !                                     ! Active tracers
274                            CALL tra_qsr_init   ! penetrative solar radiation qsr
275      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
276
277                            CALL trc_nam_run  ! Needed to get restart parameters for passive tracers
278      IF( ln_rsttr ) THEN
279        neuler = 1   ! Set time-step indicator at nit000 (leap-frog)
280        CALL trc_rst_cal( nit000, 'READ' )   ! calendar
281      ELSE
282        neuler = 0                  ! Set time-step indicator at nit000 (euler)
283        CALL day_init               ! set calendar
284      ENDIF
285      !                                     ! Dynamics
286                            CALL dta_dyn_init   ! Initialization for the dynamics
287
288      !                                     ! Passive tracers
289                            CALL     trc_init   ! Passive tracers initialization
290
291      IF(lwp) WRITE(numout,cform_aaa)       ! Flag AAAAAAA
292      !
293      IF( nn_timing == 1 )  CALL timing_stop( 'nemo_init')
294      !
295   END SUBROUTINE nemo_init
296
297
298   SUBROUTINE nemo_ctl
299      !!----------------------------------------------------------------------
300      !!                     ***  ROUTINE nemo_ctl  ***
301      !!
302      !! ** Purpose :   control print setting
303      !!
304      !! ** Method  : - print namctl information and check some consistencies
305      !!----------------------------------------------------------------------
306      !
307      IF(lwp) THEN                  ! Parameter print
308         WRITE(numout,*)
309         WRITE(numout,*) 'nemo_flg: Control prints & Benchmark'
310         WRITE(numout,*) '~~~~~~~ '
311         WRITE(numout,*) '   Namelist namctl'
312         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
313         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
314         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
315         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
316         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
317         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
318         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
319         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
320         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
321      ENDIF
322      !
323      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
324      nictls    = nn_ictls
325      nictle    = nn_ictle
326      njctls    = nn_jctls
327      njctle    = nn_jctle
328      isplt     = nn_isplt
329      jsplt     = nn_jsplt
330      nbench    = nn_bench
331     IF(lwp) THEN                  ! control print
332         WRITE(numout,*)
333         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
334         WRITE(numout,*) '~~~~~~~ '
335         WRITE(numout,*) '   Namelist namcfg'
336         WRITE(numout,*) '      configuration name              cp_cfg      = ', TRIM(cp_cfg)
337         WRITE(numout,*) '      configuration resolution        jp_cfg      = ', jp_cfg
338         WRITE(numout,*) '      1st lateral dimension ( >= jpi ) jpidta     = ', jpidta
339         WRITE(numout,*) '      2nd    "         "    ( >= jpj ) jpjdta     = ', jpjdta
340         WRITE(numout,*) '      3nd    "         "               jpkdta     = ', jpkdta
341         WRITE(numout,*) '      1st dimension of global domain in i jpiglo  = ', jpiglo
342         WRITE(numout,*) '      2nd    -                  -    in j jpjglo  = ', jpjglo
343         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
344         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
345         WRITE(numout,*) '      lateral cond. type (between 0 and 6) jperio = ', jperio   
346      ENDIF
347      !                             ! Parameter control
348      !
349      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
350         IF( lk_mpp ) THEN
351            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real splitted domain
352         ELSE
353            IF( isplt == 1 .AND. jsplt == 1  ) THEN
354               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
355                  &           ' - the print control will be done over the whole domain' )
356            ENDIF
357            ijsplt = isplt * jsplt            ! total number of processors ijsplt
358         ENDIF
359         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
360         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
361         !
362         !                              ! indices used for the SUM control
363         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
364            lsp_area = .FALSE.
365         ELSE                                             ! print control done over a specific  area
366            lsp_area = .TRUE.
367            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
368               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
369               nictls = 1
370            ENDIF
371            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
372               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
373               nictle = jpiglo
374            ENDIF
375            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
376               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
377               njctls = 1
378            ENDIF
379            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
380               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
381               njctle = jpjglo
382            ENDIF
383         ENDIF
384      ENDIF
385      !
386      IF( nbench == 1 )   THEN            ! Benchmark
387         SELECT CASE ( cp_cfg )
388         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
389         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
390            &                                 ' cp_cfg="gyre" in namelsit &namcfg or set nbench = 0' )
391         END SELECT
392      ENDIF
393      !
394      IF( lk_c1d .AND. .NOT.lk_iomput )   CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ',   &
395         &                                               'with the IOM Input/Output manager. '        ,   &
396         &                                               'Compile with key_iomput enabled' )
397      !
398      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
399         &                                               'f2003 standard. '                              ,  &
400         &                                               'Compile with key_nosignedzero enabled' )
401      !
402   END SUBROUTINE nemo_ctl
403
404
405   SUBROUTINE nemo_closefile
406      !!----------------------------------------------------------------------
407      !!                     ***  ROUTINE nemo_closefile  ***
408      !!
409      !! ** Purpose :   Close the files
410      !!----------------------------------------------------------------------
411      !
412      IF ( lk_mpp ) CALL mppsync
413      !
414      CALL iom_close                                 ! close all input/output files managed by iom_*
415      !
416      IF( numstp     /= -1 )   CLOSE( numstp     )   ! time-step file
417      IF( numnam_ref /= -1 )   CLOSE( numnam_ref )   ! oce reference namelist
418      IF( numnam_cfg /= -1 )   CLOSE( numnam_cfg )   ! oce configuration namelist
419      IF( numout     /=  6 )   CLOSE( numout     )   ! standard model output file
420      numout = 6                                     ! redefine numout in case it is used after this point...
421      !
422   END SUBROUTINE nemo_closefile
423
424
425   SUBROUTINE nemo_alloc
426      !!----------------------------------------------------------------------
427      !!                     ***  ROUTINE nemo_alloc  ***
428      !!
429      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
430      !!
431      !! ** Method  :
432      !!----------------------------------------------------------------------
433      USE diawri,       ONLY: dia_wri_alloc
434      USE dom_oce,      ONLY: dom_oce_alloc
435      USE zdf_oce,      ONLY: zdf_oce_alloc
436      USE ldftra_oce,   ONLY: ldftra_oce_alloc
437      USE trc_oce,      ONLY: trc_oce_alloc
438      !
439      INTEGER :: ierr
440      !!----------------------------------------------------------------------
441      !
442      ierr =        oce_alloc       ()          ! ocean
443      ierr = ierr + dia_wri_alloc   ()
444      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
445      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
446      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
447      !
448      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
449      !
450      IF( lk_mpp    )   CALL mpp_sum( ierr )
451      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
452      !
453   END SUBROUTINE nemo_alloc
454
455
456   SUBROUTINE nemo_partition( num_pes )
457      !!----------------------------------------------------------------------
458      !!                 ***  ROUTINE nemo_partition  ***
459      !!
460      !! ** Purpose :   
461      !!
462      !! ** Method  :
463      !!----------------------------------------------------------------------
464      INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
465      !
466      INTEGER, PARAMETER :: nfactmax = 20
467      INTEGER :: nfact ! The no. of factors returned
468      INTEGER :: ierr  ! Error flag
469      INTEGER :: ji
470      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
471      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
472      !!----------------------------------------------------------------------
473
474      ierr = 0
475
476      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
477
478      IF( nfact <= 1 ) THEN
479         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
480         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
481         jpnj = 1
482         jpni = num_pes
483      ELSE
484         ! Search through factors for the pair that are closest in value
485         mindiff = 1000000
486         imin    = 1
487         DO ji = 1, nfact-1, 2
488            idiff = ABS( ifact(ji) - ifact(ji+1) )
489            IF( idiff < mindiff ) THEN
490               mindiff = idiff
491               imin = ji
492            ENDIF
493         END DO
494         jpnj = ifact(imin)
495         jpni = ifact(imin + 1)
496      ENDIF
497      !
498      jpnij = jpni*jpnj
499      !
500   END SUBROUTINE nemo_partition
501
502
503   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
504      !!----------------------------------------------------------------------
505      !!                     ***  ROUTINE factorise  ***
506      !!
507      !! ** Purpose :   return the prime factors of n.
508      !!                knfax factors are returned in array kfax which is of
509      !!                maximum dimension kmaxfax.
510      !! ** Method  :
511      !!----------------------------------------------------------------------
512      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
513      INTEGER                    , INTENT(  out) ::   kerr, knfax
514      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
515      !
516      INTEGER :: ifac, jl, inu
517      INTEGER, PARAMETER :: ntest = 14
518      INTEGER :: ilfax(ntest)
519      !
520      ! lfax contains the set of allowed factors.
521      data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256,  &
522         &                            128,   64,   32,   16,    8,   4,   2  /
523      !!----------------------------------------------------------------------
524
525      ! Clear the error flag and initialise output vars
526      kerr = 0
527      kfax = 1
528      knfax = 0
529
530      ! Find the factors of n.
531      IF( kn == 1 )   GOTO 20
532
533      ! nu holds the unfactorised part of the number.
534      ! knfax holds the number of factors found.
535      ! l points to the allowed factor list.
536      ! ifac holds the current factor.
537
538      inu   = kn
539      knfax = 0
540
541      DO jl = ntest, 1, -1
542         !
543         ifac = ilfax(jl)
544         IF( ifac > inu )   CYCLE
545
546         ! Test whether the factor will divide.
547
548         IF( MOD(inu,ifac) == 0 ) THEN
549            !
550            knfax = knfax + 1            ! Add the factor to the list
551            IF( knfax > kmaxfax ) THEN
552               kerr = 6
553               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
554               return
555            ENDIF
556            kfax(knfax) = ifac
557            ! Store the other factor that goes with this one
558            knfax = knfax + 1
559            kfax(knfax) = inu / ifac
560            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
561         ENDIF
562         !
563      END DO
564
565   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
566      !
567   END SUBROUTINE factorise
568
569#if defined key_mpp_mpi
570   SUBROUTINE nemo_northcomms
571      !!======================================================================
572      !!                     ***  ROUTINE  nemo_northcomms  ***
573      !! nemo_northcomms    :  Setup for north fold exchanges with explicit
574      !!                       point-to-point messaging
575      !!=====================================================================
576      !!----------------------------------------------------------------------
577      !!
578      !! ** Purpose :   Initialization of the northern neighbours lists.
579      !!----------------------------------------------------------------------
580      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
581      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
582      !!----------------------------------------------------------------------
583
584      INTEGER  ::   sxM, dxM, sxT, dxT, jn
585      INTEGER  ::   njmppmax
586
587      njmppmax = MAXVAL( njmppt )
588
589      !initializes the north-fold communication variables
590      isendto(:) = 0
591      nsndto = 0
592
593      !if I am a process in the north
594      IF ( njmpp == njmppmax ) THEN
595          !sxM is the first point (in the global domain) needed to compute the
596          !north-fold for the current process
597          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
598          !dxM is the last point (in the global domain) needed to compute the
599          !north-fold for the current process
600          dxM = jpiglo - nimppt(narea) + 2
601
602          !loop over the other north-fold processes to find the processes
603          !managing the points belonging to the sxT-dxT range
604          DO jn = jpnij - jpni +1, jpnij
605             IF ( njmppt(jn) == njmppmax ) THEN
606                !sxT is the first point (in the global domain) of the jn
607                !process
608                sxT = nimppt(jn)
609                !dxT is the last point (in the global domain) of the jn
610                !process
611                dxT = nimppt(jn) + nlcit(jn) - 1
612                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
613                   nsndto = nsndto + 1
614                   isendto(nsndto) = jn
615                ELSEIF ((sxM .le. sxT) .AND. (dxM .gt. dxT)) THEN
616                   nsndto = nsndto + 1
617                   isendto(nsndto) = jn
618                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
619                   nsndto = nsndto + 1
620                   isendto(nsndto) = jn
621                END IF
622             END IF
623          END DO
624      ENDIF
625      l_north_nogather = .TRUE.
626
627   END SUBROUTINE nemo_northcomms
628#else
629   SUBROUTINE nemo_northcomms      ! Dummy routine
630      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
631   END SUBROUTINE nemo_northcomms
632#endif
633   !!======================================================================
634END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.