New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dtatsd.F90 in branches/2013/dev_LOCEAN_CMCC_INGV_2013/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/2013/dev_LOCEAN_CMCC_INGV_2013/NEMOGCM/NEMO/OPA_SRC/DOM/dtatsd.F90 @ 4230

Last change on this file since 4230 was 4230, checked in by cetlod, 10 years ago

dev_LOCEAN_CMCC_INGV_2013 : merge LOCEAN & CMCC_INGV branches, see ticket #1182

File size: 16.3 KB
Line 
1MODULE dtatsd
2   !!======================================================================
3   !!                     ***  MODULE  dtatsd  ***
4   !! Ocean data  :  read ocean Temperature & Salinity Data from gridded data
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  ()  Original code
7   !!             -   ! 1992-07  (M. Imbard)
8   !!            8.0  ! 1999-10  (M.A. Foujols, M. Imbard)  NetCDF FORMAT
9   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
10   !!            3.3  ! 2010-10  (C. Bricaud, S. Masson)  use of fldread
11   !!            3.4  ! 2010-11  (G. Madec, C. Ethe) Merge of dtatem and dtasal + suppression of CPP keys
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   dta_tsd      : read and time interpolated ocean Temperature & Salinity Data
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers
18   USE dom_oce         ! ocean space and time domain
19   USE fldread         ! read input fields
20   USE in_out_manager  ! I/O manager
21   USE phycst          ! physical constants
22   USE lib_mpp         ! MPP library
23   USE wrk_nemo        ! Memory allocation
24   USE timing          ! Timing
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   dta_tsd_init   ! called by opa.F90
30   PUBLIC   dta_tsd        ! called by istate.F90 and tradmp.90
31
32   LOGICAL , PUBLIC ::   ln_tsd_init      !: T & S data flag
33   LOGICAL , PUBLIC ::   ln_tsd_tradmp    !: internal damping toward input data flag
34
35   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tsd   ! structure of input SST (file informations, fields read)
36
37   !! * Substitutions
38#  include "domzgr_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
41   !! $Id: dtatem.F90 2392 2010-11-15 21:20:05Z gm $
42   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE dta_tsd_init( ld_tradmp )
47      !!----------------------------------------------------------------------
48      !!                   ***  ROUTINE dta_tsd_init  ***
49      !!                   
50      !! ** Purpose :   initialisation of T & S input data
51      !!
52      !! ** Method  : - Read namtsd namelist
53      !!              - allocates T & S data structure
54      !!----------------------------------------------------------------------
55      LOGICAL, INTENT(in), OPTIONAL ::   ld_tradmp   ! force the initialization when tradp is used
56      !
57      INTEGER ::   ierr0, ierr1, ierr2, ierr3   ! temporary integers
58      !
59      CHARACTER(len=100)            ::   cn_dir          ! Root directory for location of ssr files
60      TYPE(FLD_N), DIMENSION( jpts) ::   slf_i           ! array of namelist informations on the fields to read
61      TYPE(FLD_N)                   ::   sn_tem, sn_sal
62      !!
63      NAMELIST/namtsd/   ln_tsd_init, ln_tsd_tradmp, cn_dir, sn_tem, sn_sal
64      INTEGER  ::   ios
65      !!----------------------------------------------------------------------
66      !
67      IF( nn_timing == 1 )  CALL timing_start('dta_tsd_init')
68      !
69      !  Initialisation
70      ierr0 = 0  ;  ierr1 = 0  ;  ierr2 = 0  ;  ierr3 = 0
71      !
72      !                             ! set default namelist values
73      cn_dir = './'                       ! directory in which the model is executed
74      !                                   ! sn_... default values (NB: frequency positive => hours, negative => months)
75      !            !   file    ! frequency ! variable  ! time intep !  clim   ! 'yearly' or ! weights  ! rotation ! land/sea mask !
76      !            !   name    !  (hours)  !  name     !   (T/F)    !  (T/F)  !  'monthly'  ! filename ! pairs    ! filename      !
77      sn_tem = FLD_N( 'temperature',  -1.  , 'votemper',  .false.   , .true.  ,  'monthly'  , ''       , &
78           & ''       , ''            )
79      sn_sal = FLD_N( 'salinity'   ,  -1.  , 'vosaline',  .false.   , .true.  ,  'monthly'  , ''       , &
80           & ''       , ''            )
81 
82      REWIND( numnam_ref )              ! Namelist namtsd in reference namelist :
83      READ  ( numnam_ref, namtsd, IOSTAT = ios, ERR = 901)
84901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtsd in reference namelist', lwp )
85
86      REWIND( numnam_cfg )              ! Namelist namtsd in configuration namelist : Parameters of the run
87      READ  ( numnam_cfg, namtsd, IOSTAT = ios, ERR = 902 )
88902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtsd in configuration namelist', lwp )
89      WRITE ( numond, namtsd )
90
91      IF( PRESENT( ld_tradmp ) )   ln_tsd_tradmp = .TRUE.     ! forces the initialization when tradmp is used
92     
93      IF(lwp) THEN                  ! control print
94         WRITE(numout,*)
95         WRITE(numout,*) 'dta_tsd_init : Temperature & Salinity data '
96         WRITE(numout,*) '~~~~~~~~~~~~ '
97         WRITE(numout,*) '   Namelist namtsd'
98         WRITE(numout,*) '      Initialisation of ocean T & S with T &S input data   ln_tsd_init   = ', ln_tsd_init
99         WRITE(numout,*) '      damping of ocean T & S toward T &S input data        ln_tsd_tradmp = ', ln_tsd_tradmp
100         WRITE(numout,*)
101         IF( .NOT.ln_tsd_init .AND. .NOT.ln_tsd_tradmp ) THEN
102            WRITE(numout,*)
103            WRITE(numout,*) '   T & S data not used'
104         ENDIF
105      ENDIF
106      !
107      IF( ln_rstart .AND. ln_tsd_init ) THEN
108         CALL ctl_warn( 'dta_tsd_init: ocean restart and T & S data intialisation, ',   &
109            &           'we keep the restart T & S values and set ln_tsd_init to FALSE' )
110         ln_tsd_init = .FALSE.
111      ENDIF
112      !
113      !                             ! allocate the arrays (if necessary)
114      IF(  ln_tsd_init .OR. ln_tsd_tradmp  ) THEN
115         !
116         ALLOCATE( sf_tsd(jpts), STAT=ierr0 )
117         IF( ierr0 > 0 ) THEN
118            CALL ctl_stop( 'dta_tsd_init: unable to allocate sf_tsd structure' )   ;   RETURN
119         ENDIF
120         !
121                                ALLOCATE( sf_tsd(jp_tem)%fnow(jpi,jpj,jpk)   , STAT=ierr0 )
122         IF( sn_tem%ln_tint )   ALLOCATE( sf_tsd(jp_tem)%fdta(jpi,jpj,jpk,2) , STAT=ierr1 )
123                                ALLOCATE( sf_tsd(jp_sal)%fnow(jpi,jpj,jpk)   , STAT=ierr2 )
124         IF( sn_sal%ln_tint )   ALLOCATE( sf_tsd(jp_sal)%fdta(jpi,jpj,jpk,2) , STAT=ierr3 )
125         !
126         IF( ierr0 + ierr1 + ierr2 + ierr3 > 0 ) THEN
127            CALL ctl_stop( 'dta_tsd : unable to allocate T & S data arrays' )   ;   RETURN
128         ENDIF
129         !                         ! fill sf_tsd with sn_tem & sn_sal and control print
130         slf_i(jp_tem) = sn_tem   ;   slf_i(jp_sal) = sn_sal
131         CALL fld_fill( sf_tsd, slf_i, cn_dir, 'dta_tsd', 'Temperature & Salinity data', 'namtsd' )
132         !
133      ENDIF
134      !
135      IF( nn_timing == 1 )  CALL timing_stop('dta_tsd_init')
136      !
137   END SUBROUTINE dta_tsd_init
138
139
140   SUBROUTINE dta_tsd( kt, ptsd )
141      !!----------------------------------------------------------------------
142      !!                   ***  ROUTINE dta_tsd  ***
143      !!                   
144      !! ** Purpose :   provides T and S data at kt
145      !!
146      !! ** Method  : - call fldread routine
147      !!              - ORCA_R2: add some hand made alteration to read data 
148      !!              - 'key_orca_lev10' interpolates on 10 times more levels
149      !!              - s- or mixed z-s coordinate: vertical interpolation on model mesh
150      !!              - ln_tsd_tradmp=F: deallocates the T-S data structure
151      !!                as T-S data are no are used
152      !!
153      !! ** Action  :   ptsd   T-S data on medl mesh and interpolated at time-step kt
154      !!----------------------------------------------------------------------
155      INTEGER                              , INTENT(in   ) ::   kt     ! ocean time-step
156      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(  out) ::   ptsd   ! T & S data
157      !
158      INTEGER ::   ji, jj, jk, jl, jkk   ! dummy loop indicies
159      INTEGER ::   ik, il0, il1, ii0, ii1, ij0, ij1   ! local integers
160      REAL(wp)::   zl, zi
161      REAL(wp), POINTER, DIMENSION(:) ::  ztp, zsp   ! 1D workspace
162      !!----------------------------------------------------------------------
163      !
164      IF( nn_timing == 1 )  CALL timing_start('dta_tsd')
165      !
166      CALL fld_read( kt, 1, sf_tsd )      !==   read T & S data at kt time step   ==!
167      !
168      !
169      !                                   !==   ORCA_R2 configuration and T & S damping   ==!
170      IF( cp_cfg == "orca" .AND. jp_cfg == 2 .AND. ln_tsd_tradmp ) THEN    ! some hand made alterations
171         !
172         ij0 = 101   ;   ij1 = 109                       ! Reduced T & S in the Alboran Sea
173         ii0 = 141   ;   ii1 = 155
174         DO jj = mj0(ij0), mj1(ij1)
175            DO ji = mi0(ii0), mi1(ii1)
176               sf_tsd(jp_tem)%fnow(ji,jj,13:13) = sf_tsd(jp_tem)%fnow(ji,jj,13:13) - 0.20_wp
177               sf_tsd(jp_tem)%fnow(ji,jj,14:15) = sf_tsd(jp_tem)%fnow(ji,jj,14:15) - 0.35_wp
178               sf_tsd(jp_tem)%fnow(ji,jj,16:25) = sf_tsd(jp_tem)%fnow(ji,jj,16:25) - 0.40_wp
179               !
180               sf_tsd(jp_sal)%fnow(ji,jj,13:13) = sf_tsd(jp_sal)%fnow(ji,jj,13:13) - 0.15_wp
181               sf_tsd(jp_sal)%fnow(ji,jj,14:15) = sf_tsd(jp_sal)%fnow(ji,jj,14:15) - 0.25_wp
182               sf_tsd(jp_sal)%fnow(ji,jj,16:17) = sf_tsd(jp_sal)%fnow(ji,jj,16:17) - 0.30_wp
183               sf_tsd(jp_sal)%fnow(ji,jj,18:25) = sf_tsd(jp_sal)%fnow(ji,jj,18:25) - 0.35_wp
184            END DO
185         END DO
186         IF( nn_cla == 1 ) THEN                          ! Cross Land advection
187            il0 = 138   ;   il1 = 138                          ! set T & S profile at Gibraltar Strait
188            ij0 = 101   ;   ij1 = 102
189            ii0 = 139   ;   ii1 = 139
190            DO jl = mi0(il0), mi1(il1)
191               DO jj = mj0(ij0), mj1(ij1)
192                  DO ji = mi0(ii0), mi1(ii1)
193                     sf_tsd(jp_tem)%fnow(ji,jj,:) = sf_tsd(jp_tem)%fnow(jl,jj,:)
194                     sf_tsd(jp_sal)%fnow(ji,jj,:) = sf_tsd(jp_sal)%fnow(jl,jj,:)
195                  END DO
196               END DO
197            END DO
198            il0 = 164   ;   il1 = 164                          ! set T & S profile at Bab el Mandeb Strait
199            ij0 =  87   ;   ij1 =  88
200            ii0 = 161   ;   ii1 = 163
201            DO jl = mi0(il0), mi1(il1)
202               DO jj = mj0(ij0), mj1(ij1)
203                  DO ji = mi0(ii0), mi1(ii1)
204                     sf_tsd(jp_tem)%fnow(ji,jj,:) = sf_tsd(jp_tem)%fnow(jl,jj,:)
205                     sf_tsd(jp_sal)%fnow(ji,jj,:) = sf_tsd(jp_sal)%fnow(jl,jj,:)
206                  END DO
207               END DO
208            END DO
209         ELSE                                            ! No Cross Land advection
210            ij0 =  87   ;   ij1 =  96                          ! Reduced temperature in Red Sea
211            ii0 = 148   ;   ii1 = 160
212            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ,  4:10 ) = 7.0_wp
213            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 11:13 ) = 6.5_wp
214            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 14:20 ) = 6.0_wp
215         ENDIF
216      ENDIF
217      !
218      ptsd(:,:,:,jp_tem) = sf_tsd(jp_tem)%fnow(:,:,:)    ! NO mask
219      ptsd(:,:,:,jp_sal) = sf_tsd(jp_sal)%fnow(:,:,:) 
220      !
221      IF( ln_sco ) THEN                   !==   s- or mixed s-zps-coordinate   ==!
222         !
223         CALL wrk_alloc( jpk, ztp, zsp )
224         !
225         IF( kt == nit000 .AND. lwp )THEN
226            WRITE(numout,*)
227            WRITE(numout,*) 'dta_tsd: interpolates T & S data onto the s- or mixed s-z-coordinate mesh'
228         ENDIF
229         !
230         DO jj = 1, jpj                         ! vertical interpolation of T & S
231            DO ji = 1, jpi
232               DO jk = 1, jpk                        ! determines the intepolated T-S profiles at each (i,j) points
233                  zl = fsdept_0(ji,jj,jk)
234                  IF(     zl < gdept_0(1  ) ) THEN          ! above the first level of data
235                     ztp(jk) =  ptsd(ji,jj,1    ,jp_tem)
236                     zsp(jk) =  ptsd(ji,jj,1    ,jp_sal)
237                  ELSEIF( zl > gdept_0(jpk) ) THEN          ! below the last level of data
238                     ztp(jk) =  ptsd(ji,jj,jpkm1,jp_tem)
239                     zsp(jk) =  ptsd(ji,jj,jpkm1,jp_sal)
240                  ELSE                                      ! inbetween : vertical interpolation between jkk & jkk+1
241                     DO jkk = 1, jpkm1                                  ! when  gdept(jkk) < zl < gdept(jkk+1)
242                        IF( (zl-gdept_0(jkk)) * (zl-gdept_0(jkk+1)) <= 0._wp ) THEN
243                           zi = ( zl - gdept_0(jkk) ) / (gdept_0(jkk+1)-gdept_0(jkk))
244                           ztp(jk) = ptsd(ji,jj,jkk,jp_tem) + ( ptsd(ji,jj,jkk+1,jp_tem) - ptsd(ji,jj,jkk,jp_tem) ) * zi 
245                           zsp(jk) = ptsd(ji,jj,jkk,jp_sal) + ( ptsd(ji,jj,jkk+1,jp_sal) - ptsd(ji,jj,jkk,jp_sal) ) * zi
246                        ENDIF
247                     END DO
248                  ENDIF
249               END DO
250               DO jk = 1, jpkm1
251                  ptsd(ji,jj,jk,jp_tem) = ztp(jk) * tmask(ji,jj,jk)     ! mask required for mixed zps-s-coord
252                  ptsd(ji,jj,jk,jp_sal) = zsp(jk) * tmask(ji,jj,jk)
253               END DO
254               ptsd(ji,jj,jpk,jp_tem) = 0._wp
255               ptsd(ji,jj,jpk,jp_sal) = 0._wp
256            END DO
257         END DO
258         !
259         CALL wrk_dealloc( jpk, ztp, zsp )
260         !
261      ELSE                                !==   z- or zps- coordinate   ==!
262         !                             
263         ptsd(:,:,:,jp_tem) = ptsd(:,:,:,jp_tem) * tmask(:,:,:)    ! Mask
264         ptsd(:,:,:,jp_sal) = ptsd(:,:,:,jp_sal) * tmask(:,:,:)
265         !
266         IF( ln_zps ) THEN                      ! zps-coordinate (partial steps) interpolation at the last ocean level
267            DO jj = 1, jpj
268               DO ji = 1, jpi
269                  ik = mbkt(ji,jj) 
270                  IF( ik > 1 ) THEN
271                     zl = ( gdept_0(ik) - fsdept_0(ji,jj,ik) ) / ( gdept_0(ik) - gdept_0(ik-1) )
272                     ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik-1,jp_tem)
273                     ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik-1,jp_sal)
274                  ENDIF
275               END DO
276            END DO
277         ENDIF
278         !
279      ENDIF
280      !
281      IF( lwp .AND. kt == nit000 ) THEN
282         WRITE(numout,*) ' temperature Levitus '
283         WRITE(numout,*)
284         WRITE(numout,*)'  level = 1'
285         CALL prihre( ptsd(:,:,1    ,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
286         WRITE(numout,*)'  level = ', jpk/2
287         CALL prihre( ptsd(:,:,jpk/2,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
288         WRITE(numout,*)'  level = ', jpkm1
289         CALL prihre( ptsd(:,:,jpkm1,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
290         WRITE(numout,*)
291         WRITE(numout,*) ' salinity Levitus '
292         WRITE(numout,*)
293         WRITE(numout,*)'  level = 1'
294         CALL prihre( ptsd(:,:,1    ,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
295         WRITE(numout,*)'  level = ', jpk/2
296         CALL prihre( ptsd(:,:,jpk/2,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
297         WRITE(numout,*)'  level = ', jpkm1
298         CALL prihre( ptsd(:,:,jpkm1,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
299         WRITE(numout,*)
300      ENDIF
301      !
302      IF( .NOT.ln_tsd_tradmp ) THEN                   !==   deallocate T & S structure   ==!
303         !                                              (data used only for initialisation)
304         IF(lwp) WRITE(numout,*) 'dta_tsd: deallocte T & S arrays as they are only use to initialize the run'
305                                        DEALLOCATE( sf_tsd(jp_tem)%fnow )     ! T arrays in the structure
306         IF( sf_tsd(jp_tem)%ln_tint )   DEALLOCATE( sf_tsd(jp_tem)%fdta )
307                                        DEALLOCATE( sf_tsd(jp_sal)%fnow )     ! S arrays in the structure
308         IF( sf_tsd(jp_sal)%ln_tint )   DEALLOCATE( sf_tsd(jp_sal)%fdta )
309                                        DEALLOCATE( sf_tsd              )     ! the structure itself
310      ENDIF
311      !
312      IF( nn_timing == 1 )  CALL timing_stop('dta_tsd')
313      !
314   END SUBROUTINE dta_tsd
315
316   !!======================================================================
317END MODULE dtatsd
Note: See TracBrowser for help on using the repository browser.