New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dyndmp.F90 in branches/2013/dev_MERCATOR_UKMO_2013/NEMOGCM/NEMO/OPA_SRC/C1D – NEMO

source: branches/2013/dev_MERCATOR_UKMO_2013/NEMOGCM/NEMO/OPA_SRC/C1D/dyndmp.F90 @ 4229

Last change on this file since 4229 was 4229, checked in by cbricaud, 10 years ago

merge UKMO branch into dev_MERCATOR_UKMO_2013
File size: 12.0 KB
Line 
1MODULE dyndmp
2   !!======================================================================
3   !!                       ***  MODULE  dyndmp  ***
4   !! Ocean dynamics: internal restoring trend on momentum (U and V current)
5   !!======================================================================
6   !! History :  3.5  ! 2013-08  (D. Calvert)  Original code
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   dyn_dmp_alloc : allocate dyndmp arrays
11   !!   dyn_dmp_init  : namelist read, parameter control and resto coeff.
12   !!   dyn_dmp       : update the momentum trend with the internal damping
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean: variables
15   USE dom_oce        ! ocean: domain variables
16   USE c1d            ! 1D vertical configuration
17   USE trdmod         ! ocean: trends
18   USE tradmp         ! ocean: internal damping
19   USE zdf_oce        ! ocean: vertical physics
20   USE phycst         ! physical constants
21   USE dtauvd         ! data: U & V current
22   USE zdfmxl         ! vertical physics: mixed layer depth
23   USE in_out_manager ! I/O manager
24   USE lib_mpp        ! MPP library
25   USE prtctl         ! Print control
26   USE wrk_nemo       ! Memory allocation
27   USE timing         ! Timing
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   dyn_dmp_init ! routine called by nemogcm.F90
33   PUBLIC   dyn_dmp      ! routine called by step_c1d.F90
34
35   LOGICAL, PUBLIC ::   ln_dyndmp = .TRUE.                             ! Flag for Newtonian damping
36
37   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::  utrdmp    ! damping U current trend (m/s2)
38   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::  vtrdmp    ! damping V current trend (m/s2)
39   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::  resto_uv  ! restoring coeff. on U & V current
40
41   !! * Substitutions
42#  include "domzgr_substitute.h90"
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
46   !! $Id: dyndmp.F90 3294 2012-01-28 16:44:18Z rblod $
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   INTEGER FUNCTION dyn_dmp_alloc()
52      !!----------------------------------------------------------------------
53      !!                ***  FUNCTION dyn_dmp_alloc  ***
54      !!----------------------------------------------------------------------
55      ALLOCATE( utrdmp(jpi,jpj,jpk), vtrdmp(jpi,jpj,jpk), resto_uv(jpi,jpj,jpk), STAT= dyn_dmp_alloc )
56      !
57      IF( lk_mpp            )   CALL mpp_sum ( dyn_dmp_alloc )
58      IF( dyn_dmp_alloc > 0 )   CALL ctl_warn('dyn_dmp_alloc: allocation of arrays failed')
59      !
60   END FUNCTION dyn_dmp_alloc
61
62
63   SUBROUTINE dyn_dmp_init
64      !!----------------------------------------------------------------------
65      !!                  ***  ROUTINE dyn_dmp_init  ***
66      !!
67      !! ** Purpose :   Initialization for the Newtonian damping
68      !!
69      !! ** Method  : - read the ln_dyndmp parameter from the namc1d_dyndmp namelist
70      !!              - allocate damping arrays
71      !!              - check the parameters of the namtra_dmp namelist
72      !!              - calculate damping coefficient
73      !!----------------------------------------------------------------------
74      NAMELIST/namc1d_dyndmp/ ln_dyndmp
75      !!----------------------------------------------------------------------
76
77      REWIND ( numnam )                      !==   read namelist namc1d_dyndmp : momentum damping flag     ==!
78      READ   ( numnam, namc1d_dyndmp )       !==   (namelist of namtra_dmp is used for other parameters)   ==!
79
80      IF(lwp) THEN                           ! control print
81         WRITE(numout,*)
82         WRITE(numout,*) 'dyn_dmp_init : U and V current Newtonian damping'
83         WRITE(numout,*) '~~~~~~~~~~~~'
84         WRITE(numout,*) '   Namelist namc1d_dyndmp : Set damping flag'
85         WRITE(numout,*) '      add a damping term or not       ln_dyndmp = ', ln_dyndmp
86         WRITE(numout,*) '   Namelist namtra_dmp    : Set damping parameters'
87         WRITE(numout,*) '      horizontal damping option       nn_hdmp   = ', nn_hdmp
88         WRITE(numout,*) '      mixed layer damping option      nn_zdmp   = ', nn_zdmp, '(non-C1D zoom: forced to 0)'
89         WRITE(numout,*) '      surface time scale (days)       rn_surf   = ', rn_surf
90         WRITE(numout,*) '      bottom time scale (days)        rn_bot    = ', rn_bot
91         WRITE(numout,*) '      depth of transition (meters)    rn_dep    = ', rn_dep
92         WRITE(numout,*) '      create a damping.coeff file     nn_file   = ', nn_file
93         WRITE(numout,*)
94      ENDIF
95
96      IF( ln_dyndmp ) THEN
97         !                                   !==   allocate the data arrays   ==!
98         IF( dyn_dmp_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'dyn_dmp_init: unable to allocate arrays' )
99         !
100#if ! defined key_c1d
101         SELECT CASE ( nn_hdmp )             !==   control print of horizontal option   ==!
102         CASE (  -1  )   ;   IF(lwp) WRITE(numout,*) '   momentum damping in the Med & Red seas only'
103         CASE ( 1:90 )   ;   IF(lwp) WRITE(numout,*) '   momentum damping poleward of', nn_hdmp, ' degrees'
104         CASE DEFAULT
105            WRITE(ctmp1,*) '          bad flag value for nn_hdmp = ', nn_hdmp
106            CALL ctl_stop(ctmp1)
107         END SELECT
108         !
109#endif
110         SELECT CASE ( nn_zdmp )             !==   control print of vertical option   ==!
111         CASE ( 0    )   ;   IF(lwp) WRITE(numout,*) '   momentum damping throughout the water column'
112         CASE ( 1    )   ;   IF(lwp) WRITE(numout,*) '   no momentum damping in the turbocline (avt > 5 cm2/s)'
113         CASE ( 2    )   ;   IF(lwp) WRITE(numout,*) '   no momentum damping in the mixed layer'
114         CASE DEFAULT
115            WRITE(ctmp1,*) '          bad flag value for nn_zdmp = ', nn_zdmp
116            CALL ctl_stop(ctmp1)
117         END SELECT
118         !
119         IF( .NOT. ln_uvd_dyndmp ) THEN      ! force the initialization of U & V current data for damping
120            CALL ctl_warn( 'dyn_dmp_init: U & V current read data not initialized, we force ln_uvd_dyndmp=T' )
121            CALL dta_uvd_init( ld_dyndmp=ln_dyndmp )
122         ENDIF
123         !
124         utrdmp(:,:,:) = 0._wp               ! internal damping trends
125         vtrdmp(:,:,:) = 0._wp
126         !                                   !==   Damping coefficients calculation:                           ==!
127         !                                   !==   use tradmp.F90 subroutines dtacof, dtacof_zoom and cofdis   ==!
128         !                                   !!!   NOTE: these need to be altered for use in this module if
129         !                                   !!!       they are to be used outside the C1D context
130         !                                   !!!       (use of U,V grid variables)
131         IF( lzoom .AND. .NOT. lk_c1d ) THEN   ;   CALL dtacof_zoom( resto_uv )
132         ELSE               ;   CALL dtacof( nn_hdmp, rn_surf, rn_bot, rn_dep, nn_file, 'DYN', resto_uv )
133         ENDIF
134         !
135      ENDIF
136      !
137   END SUBROUTINE dyn_dmp_init
138
139
140   SUBROUTINE dyn_dmp( kt )
141      !!----------------------------------------------------------------------
142      !!                   ***  ROUTINE dyn_dmp  ***
143      !!                 
144      !! ** Purpose :   Compute the momentum trends due to a newtonian damping
145      !!      of the ocean velocities towards the given data and add it to the
146      !!      general momentum trends.
147      !!
148      !! ** Method  :   Compute Newtonian damping towards u_dta and v_dta
149      !!      and add to the general momentum trends:
150      !!                     ua = ua + resto_uv * (u_dta - ub)
151      !!                     va = va + resto_uv * (v_dta - vb)
152      !!      The trend is computed either throughout the water column
153      !!      (nn_zdmp=0), where the vertical mixing is weak (nn_zdmp=1) or
154      !!      below the well mixed layer (nn_zdmp=2)
155      !!
156      !! ** Action  : - (ua,va)   momentum trends updated with the damping trend
157      !!----------------------------------------------------------------------
158      !
159      INTEGER, INTENT(in) ::   kt                        ! ocean time-step index
160      !!
161      INTEGER  ::   ji, jj, jk                           ! dummy loop indices
162      REAL(wp) ::   zua, zva                             ! local scalars
163      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::  zuv_dta  ! Read in data
164      !!----------------------------------------------------------------------
165      !
166      IF( nn_timing == 1 )  CALL timing_start( 'dyn_dmp' )
167      !
168      CALL wrk_alloc( jpi, jpj, jpk, 2,  zuv_dta )
169      !
170      !                           !==   read and interpolate U & V current data at kt   ==!
171      CALL dta_uvd( kt, zuv_dta ) !!! NOTE: This subroutine must be altered for use outside
172                                  !!!       the C1D context (use of U,V grid variables)
173      !
174      SELECT CASE ( nn_zdmp )     !==   Calculate/add Newtonian damping to the momentum trend   ==!
175      !
176      CASE( 0 )                   ! Newtonian damping throughout the water column
177         DO jk = 1, jpkm1
178            DO jj = 2, jpjm1
179               DO ji = fs_2, fs_jpim1   ! vector opt.
180                  zua = resto_uv(ji,jj,jk) * ( zuv_dta(ji,jj,jk,1) - ub(ji,jj,jk) )
181                  zva = resto_uv(ji,jj,jk) * ( zuv_dta(ji,jj,jk,2) - vb(ji,jj,jk) )
182                  ua(ji,jj,jk) = ua(ji,jj,jk) + zua
183                  va(ji,jj,jk) = va(ji,jj,jk) + zva
184                  utrdmp(ji,jj,jk) = zua           ! save the trends
185                  vtrdmp(ji,jj,jk) = zva     
186               END DO
187            END DO
188         END DO
189         !
190      CASE ( 1 )                  ! no damping above the turbocline (avt > 5 cm2/s)
191         DO jk = 1, jpkm1
192            DO jj = 2, jpjm1
193               DO ji = fs_2, fs_jpim1   ! vector opt.
194                  IF( avt(ji,jj,jk) <= 5.e-4_wp ) THEN
195                     zua = resto_uv(ji,jj,jk) * ( zuv_dta(ji,jj,jk,1) - ub(ji,jj,jk) )
196                     zva = resto_uv(ji,jj,jk) * ( zuv_dta(ji,jj,jk,2) - vb(ji,jj,jk) )
197                  ELSE
198                     zua = 0._wp
199                     zva = 0._wp 
200                  ENDIF
201                  ua(ji,jj,jk) = ua(ji,jj,jk) + zua
202                  va(ji,jj,jk) = va(ji,jj,jk) + zva
203                  utrdmp(ji,jj,jk) = zua           ! save the trends
204                  vtrdmp(ji,jj,jk) = zva
205               END DO
206            END DO
207         END DO
208         !
209      CASE ( 2 )                  ! no damping in the mixed layer
210         DO jk = 1, jpkm1
211            DO jj = 2, jpjm1
212               DO ji = fs_2, fs_jpim1   ! vector opt.
213                  IF( fsdept(ji,jj,jk) >= hmlp (ji,jj) ) THEN
214                     zua = resto_uv(ji,jj,jk) * ( zuv_dta(ji,jj,jk,1) - ub(ji,jj,jk) )
215                     zva = resto_uv(ji,jj,jk) * ( zuv_dta(ji,jj,jk,2) - vb(ji,jj,jk) )
216                  ELSE
217                     zua = 0._wp
218                     zva = 0._wp 
219                  ENDIF
220                  ua(ji,jj,jk) = ua(ji,jj,jk) + zua
221                  va(ji,jj,jk) = va(ji,jj,jk) + zva
222                  utrdmp(ji,jj,jk) = zua           ! save the trends
223                  vtrdmp(ji,jj,jk) = zva
224               END DO
225            END DO
226         END DO
227         !
228      END SELECT
229      !
230      !                           ! Trend diagnostic
231      IF( l_trddyn )   CALL trd_mod( utrdmp, vtrdmp, jpdyn_trd_dat, 'DYN', kt )
232      !
233      !                           ! Control print
234      IF( ln_ctl   )   CALL prt_ctl( tab3d_1=ua(:,:,:), clinfo1=' dmp  - Ua: ', mask1=umask,   &
235         &                           tab3d_2=va(:,:,:), clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
236      !
237      CALL wrk_dealloc( jpi, jpj, jpk, 2,  zuv_dta )
238      !
239      IF( nn_timing == 1 )  CALL timing_stop( 'dyn_dmp')
240      !
241   END SUBROUTINE dyn_dmp
242
243   !!======================================================================
244END MODULE dyndmp
Note: See TracBrowser for help on using the repository browser.