| 1 | MODULE limsbc_2 |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE limsbc_2 *** |
|---|
| 4 | !! LIM-2 : updates the fluxes at the ocean surface with ice-ocean fluxes |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : LIM ! 2000-01 (H. Goosse) Original code |
|---|
| 7 | !! 1.0 ! 2002-07 (C. Ethe, G. Madec) re-writing F90 |
|---|
| 8 | !! 3.0 ! 2006-07 (G. Madec) surface module |
|---|
| 9 | !! 3.3 ! 2009-05 (G. Garric, C. Bricaud) addition of the lim2_evp case |
|---|
| 10 | !! - ! 2010-11 (G. Madec) ice-ocean stress computed at each ocean time-step |
|---|
| 11 | !! 3.3.1 ! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation |
|---|
| 12 | !! 3.5 ! 2012-11 ((G. Madec, Y. Aksenov, A. Coward) salt and heat fluxes associated with e-p |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | #if defined key_lim2 |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! 'key_lim2' LIM 2.0 sea-ice model |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | !! lim_sbc_alloc_2 : allocate the limsbc arrays |
|---|
| 19 | !! lim_sbc_init : initialisation |
|---|
| 20 | !! lim_sbc_flx_2 : update mass, heat and salt fluxes at the ocean surface |
|---|
| 21 | !! lim_sbc_tau_2 : update i- and j-stresses, and its modulus at the ocean surface |
|---|
| 22 | !!---------------------------------------------------------------------- |
|---|
| 23 | USE par_oce ! ocean parameters |
|---|
| 24 | USE phycst ! physical constants |
|---|
| 25 | USE dom_oce ! ocean domain |
|---|
| 26 | USE domvvl ! ocean vertical scale factors |
|---|
| 27 | USE dom_ice_2 ! LIM-2: ice domain |
|---|
| 28 | USE ice_2 ! LIM-2: ice variables |
|---|
| 29 | USE sbc_ice ! surface boundary condition: ice |
|---|
| 30 | USE sbc_oce ! surface boundary condition: ocean |
|---|
| 31 | USE sbccpl |
|---|
| 32 | USE cpl_oasis3, ONLY : lk_cpl |
|---|
| 33 | USE oce , ONLY : sshn, sshb, snwice_mass, snwice_mass_b, snwice_fmass |
|---|
| 34 | USE albedo ! albedo parameters |
|---|
| 35 | USE lbclnk ! ocean lateral boundary condition - MPP exchanges |
|---|
| 36 | USE lib_mpp ! MPP library |
|---|
| 37 | USE wrk_nemo ! work arrays |
|---|
| 38 | USE in_out_manager ! I/O manager |
|---|
| 39 | USE diaar5, ONLY : lk_diaar5 |
|---|
| 40 | USE iom ! I/O library |
|---|
| 41 | USE prtctl ! Print control |
|---|
| 42 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 43 | |
|---|
| 44 | IMPLICIT NONE |
|---|
| 45 | PRIVATE |
|---|
| 46 | |
|---|
| 47 | PUBLIC lim_sbc_init_2 ! called by ice_init_2 |
|---|
| 48 | PUBLIC lim_sbc_flx_2 ! called by sbc_ice_lim_2 |
|---|
| 49 | PUBLIC lim_sbc_tau_2 ! called by sbc_ice_lim_2 |
|---|
| 50 | |
|---|
| 51 | REAL(wp) :: r1_rdtice ! = 1. / rdt_ice |
|---|
| 52 | REAL(wp) :: epsi16 = 1.e-16_wp ! constant values |
|---|
| 53 | REAL(wp) :: rzero = 0._wp ! - - |
|---|
| 54 | REAL(wp) :: rone = 1._wp ! - - |
|---|
| 55 | ! |
|---|
| 56 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: soce_0, sice_0 ! constant SSS and ice salinity used in levitating sea-ice case |
|---|
| 57 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: utau_oce, vtau_oce ! air-ocean surface i- & j-stress [N/m2] |
|---|
| 58 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: tmod_io ! modulus of the ice-ocean relative velocity [m/s] |
|---|
| 59 | |
|---|
| 60 | !! * Substitutions |
|---|
| 61 | # include "vectopt_loop_substitute.h90" |
|---|
| 62 | # include "domzgr_substitute.h90" |
|---|
| 63 | !!---------------------------------------------------------------------- |
|---|
| 64 | !! NEMO/LIM2 4.0 , UCL - NEMO Consortium (2011) |
|---|
| 65 | !! $Id$ |
|---|
| 66 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 67 | !!---------------------------------------------------------------------- |
|---|
| 68 | CONTAINS |
|---|
| 69 | |
|---|
| 70 | INTEGER FUNCTION lim_sbc_alloc_2() |
|---|
| 71 | !!------------------------------------------------------------------- |
|---|
| 72 | !! *** ROUTINE lim_sbc_alloc_2 *** |
|---|
| 73 | !!------------------------------------------------------------------- |
|---|
| 74 | ALLOCATE( soce_0(jpi,jpj) , utau_oce(jpi,jpj) , & |
|---|
| 75 | & sice_0(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=lim_sbc_alloc_2) |
|---|
| 76 | ! |
|---|
| 77 | IF( lk_mpp ) CALL mpp_sum( lim_sbc_alloc_2 ) |
|---|
| 78 | IF( lim_sbc_alloc_2 /= 0 ) CALL ctl_warn('lim_sbc_alloc_2: failed to allocate arrays.') |
|---|
| 79 | ! |
|---|
| 80 | END FUNCTION lim_sbc_alloc_2 |
|---|
| 81 | |
|---|
| 82 | |
|---|
| 83 | SUBROUTINE lim_sbc_flx_2( kt ) |
|---|
| 84 | !!------------------------------------------------------------------- |
|---|
| 85 | !! *** ROUTINE lim_sbc_2 *** |
|---|
| 86 | !! |
|---|
| 87 | !! ** Purpose : Update surface ocean boundary condition over areas |
|---|
| 88 | !! that are at least partially covered by sea-ice |
|---|
| 89 | !! |
|---|
| 90 | !! ** Action : - comput. of the momentum, heat and freshwater/salt |
|---|
| 91 | !! fluxes at the ice-ocean interface. |
|---|
| 92 | !! - Update the fluxes provided to the ocean |
|---|
| 93 | !! |
|---|
| 94 | !! ** Outputs : - qsr : sea heat flux : solar |
|---|
| 95 | !! - qns : sea heat flux : non solar (including heat content of the mass flux) |
|---|
| 96 | !! - emp : freshwater budget: mass flux |
|---|
| 97 | !! - sfx : freshwater budget: salt flux due to Freezing/Melting |
|---|
| 98 | !! - utau : sea surface i-stress (ocean referential) |
|---|
| 99 | !! - vtau : sea surface j-stress (ocean referential) |
|---|
| 100 | !! - fr_i : ice fraction |
|---|
| 101 | !! - tn_ice : sea-ice surface temperature |
|---|
| 102 | !! - alb_ice : sea-ice alberdo (lk_cpl=T) |
|---|
| 103 | !! |
|---|
| 104 | !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90. |
|---|
| 105 | !! Tartinville et al. 2001 Ocean Modelling, 3, 95-108. |
|---|
| 106 | !!--------------------------------------------------------------------- |
|---|
| 107 | INTEGER, INTENT(in) :: kt ! number of iteration |
|---|
| 108 | !! |
|---|
| 109 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 110 | INTEGER :: ii0, ii1, ij0, ij1 ! local integers |
|---|
| 111 | INTEGER :: ifvt, i1mfr, idfr, iflt ! - - |
|---|
| 112 | INTEGER :: ial, iadv, ifral, ifrdv ! - - |
|---|
| 113 | REAL(wp) :: zqsr, zqns, zfmm ! local scalars |
|---|
| 114 | REAL(wp) :: zinda, zfsalt, zemp ! - - |
|---|
| 115 | REAL(wp) :: zemp_snw, zqhc, zcd ! - - |
|---|
| 116 | REAL(wp) :: zswitch ! - - |
|---|
| 117 | REAL(wp), POINTER, DIMENSION(:,:) :: zqnsoce ! 2D workspace |
|---|
| 118 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb, zalbp ! 2D/3D workspace |
|---|
| 119 | !!--------------------------------------------------------------------- |
|---|
| 120 | |
|---|
| 121 | CALL wrk_alloc( jpi, jpj, zqnsoce ) |
|---|
| 122 | CALL wrk_alloc( jpi, jpj, 1, zalb, zalbp ) |
|---|
| 123 | |
|---|
| 124 | SELECT CASE( nn_ice_embd ) ! levitating or embedded sea-ice option |
|---|
| 125 | CASE( 0 ) ; zswitch = 1 ! (0) standard levitating sea-ice : salt exchange only |
|---|
| 126 | CASE( 1, 2 ) ; zswitch = 0 ! (1) levitating sea-ice: salt and volume exchange but no pressure effect |
|---|
| 127 | ! (2) embedded sea-ice : salt and volume fluxes and pressure |
|---|
| 128 | END SELECT ! |
|---|
| 129 | |
|---|
| 130 | !------------------------------------------! |
|---|
| 131 | ! heat flux at the ocean surface ! |
|---|
| 132 | !------------------------------------------! |
|---|
| 133 | |
|---|
| 134 | zqnsoce(:,:) = qns(:,:) |
|---|
| 135 | DO jj = 1, jpj |
|---|
| 136 | DO ji = 1, jpi |
|---|
| 137 | zinda = 1.0 - MAX( rzero , SIGN( rone, - ( 1.0 - pfrld(ji,jj) ) ) ) |
|---|
| 138 | ifvt = zinda * MAX( rzero , SIGN( rone, - phicif(ji,jj) ) ) |
|---|
| 139 | i1mfr = 1.0 - MAX( rzero , SIGN( rone, - ( 1.0 - frld(ji,jj) ) ) ) |
|---|
| 140 | idfr = 1.0 - MAX( rzero , SIGN( rone, frld(ji,jj) - pfrld(ji,jj) ) ) |
|---|
| 141 | iflt = zinda * (1 - i1mfr) * (1 - ifvt ) |
|---|
| 142 | ial = ifvt * i1mfr + ( 1 - ifvt ) * idfr |
|---|
| 143 | iadv = ( 1 - i1mfr ) * zinda |
|---|
| 144 | ifral = ( 1 - i1mfr * ( 1 - ial ) ) |
|---|
| 145 | ifrdv = ( 1 - ifral * ( 1 - ial ) ) * iadv |
|---|
| 146 | |
|---|
| 147 | !!$ attempt to explain the tricky flags set above.... |
|---|
| 148 | !!$ zinda = 1.0 - AINT( pfrld(ji,jj) ) ! = 0. if ice-free ocean else 1. (after ice adv, but before ice thermo) |
|---|
| 149 | !!$ i1mfr = 1.0 - AINT( frld(ji,jj) ) ! = 0. if ice-free ocean else 1. (after ice thermo) |
|---|
| 150 | !!$ |
|---|
| 151 | !!$ IF( phicif(ji,jj) <= 0. ) THEN ; ifvt = zinda ! = zinda if previous thermodynamic step overmelted the ice??? |
|---|
| 152 | !!$ ELSE ; ifvt = 0. ! |
|---|
| 153 | !!$ ENDIF |
|---|
| 154 | !!$ |
|---|
| 155 | !!$ IF( frld(ji,jj) >= pfrld(ji,jj) ) THEN ; idfr = 0. ! = 0. if lead fraction increases due to ice thermodynamics |
|---|
| 156 | !!$ ELSE ; idfr = 1. |
|---|
| 157 | !!$ ENDIF |
|---|
| 158 | !!$ |
|---|
| 159 | !!$ iflt = zinda * (1 - i1mfr) * (1 - ifvt ) ! = 1. if ice (not only snow) at previous time and ice-free ocean currently |
|---|
| 160 | !!$ |
|---|
| 161 | !!$ ial = ifvt * i1mfr + ( 1 - ifvt ) * idfr |
|---|
| 162 | !!$ = i1mfr if ifvt = 1 i.e. |
|---|
| 163 | !!$ = idfr if ifvt = 0 |
|---|
| 164 | !!$! snow no ice ice ice or nothing lead fraction increases |
|---|
| 165 | !!$! at previous now at previous |
|---|
| 166 | !!$! -> ice area increases ??? -> ice area decreases ??? |
|---|
| 167 | !!$ |
|---|
| 168 | !!$ iadv = ( 1 - i1mfr ) * zinda |
|---|
| 169 | !!$! pure ocean ice at |
|---|
| 170 | !!$! at current previous |
|---|
| 171 | !!$! -> = 1. if ice disapear between previous and current |
|---|
| 172 | !!$ |
|---|
| 173 | !!$ ifral = ( 1 - i1mfr * ( 1 - ial ) ) |
|---|
| 174 | !!$! ice at ??? |
|---|
| 175 | !!$! current |
|---|
| 176 | !!$! -> ??? |
|---|
| 177 | !!$ |
|---|
| 178 | !!$ ifrdv = ( 1 - ifral * ( 1 - ial ) ) * iadv |
|---|
| 179 | !!$! ice disapear |
|---|
| 180 | !!$ |
|---|
| 181 | !!$ |
|---|
| 182 | |
|---|
| 183 | ! computation the solar flux at ocean surface |
|---|
| 184 | #if defined key_coupled |
|---|
| 185 | zqsr = qsr_tot(ji,jj) + ( fstric(ji,jj) - qsr_ice(ji,jj,1) ) * ( 1.0 - pfrld(ji,jj) ) |
|---|
| 186 | #else |
|---|
| 187 | zqsr = pfrld(ji,jj) * qsr(ji,jj) + ( 1. - pfrld(ji,jj) ) * fstric(ji,jj) |
|---|
| 188 | #endif |
|---|
| 189 | ! computation the non solar heat flux at ocean surface |
|---|
| 190 | zqns = - ( 1. - thcm(ji,jj) ) * zqsr & ! part of the solar energy used in leads |
|---|
| 191 | & + iflt * ( fscmbq(ji,jj) + ffltbif(ji,jj) ) & |
|---|
| 192 | & + ifral * ( ial * qcmif(ji,jj) + (1 - ial) * qldif(ji,jj) ) * r1_rdtice & |
|---|
| 193 | & + ifrdv * ( qfvbq(ji,jj) + qdtcn(ji,jj) ) * r1_rdtice |
|---|
| 194 | |
|---|
| 195 | fsbbq(ji,jj) = ( 1.0 - ( ifvt + iflt ) ) * fscmbq(ji,jj) ! store residual heat flux (to put into the ocean at the next time-step) |
|---|
| 196 | zqhc = ( rdq_snw(ji,jj) & |
|---|
| 197 | & + rdq_ice(ji,jj) * ( 1.- zswitch) ) * r1_rdtice ! heat flux due to snow ( & ice heat content, |
|---|
| 198 | ! ! if ice/ocean mass exchange active) |
|---|
| 199 | qsr (ji,jj) = zqsr ! solar heat flux |
|---|
| 200 | qns (ji,jj) = zqns - fdtcn(ji,jj) + zqhc ! non solar heat flux |
|---|
| 201 | ! |
|---|
| 202 | ! !------------------------------------------! |
|---|
| 203 | ! ! mass and salt flux at the ocean surface ! |
|---|
| 204 | ! !------------------------------------------! |
|---|
| 205 | ! |
|---|
| 206 | ! mass flux at the ocean-atmosphere interface (open ocean fraction = leads area) |
|---|
| 207 | #if defined key_coupled |
|---|
| 208 | ! ! coupled mode: |
|---|
| 209 | zemp = + emp_tot(ji,jj) & ! net mass flux over the grid cell (ice+ocean area) |
|---|
| 210 | & - emp_ice(ji,jj) * ( 1. - pfrld(ji,jj) ) ! minus the mass flux intercepted by sea-ice |
|---|
| 211 | #else |
|---|
| 212 | ! ! forced mode: |
|---|
| 213 | zemp = + emp(ji,jj) * frld(ji,jj) & ! mass flux over open ocean fraction |
|---|
| 214 | & - tprecip(ji,jj) * ( 1. - frld(ji,jj) ) & ! liquid precip. over ice reaches directly the ocean |
|---|
| 215 | & + sprecip(ji,jj) * ( 1. - pfrld(ji,jj) ) ! snow is intercepted by sea-ice (previous frld) |
|---|
| 216 | #endif |
|---|
| 217 | ! |
|---|
| 218 | ! mass flux at the ocean/ice interface (sea ice fraction) |
|---|
| 219 | zemp_snw = rdm_snw(ji,jj) * r1_rdtice ! snow melting = pure water that enters the ocean |
|---|
| 220 | zfmm = rdm_ice(ji,jj) * r1_rdtice ! Freezing minus Melting (F-M) |
|---|
| 221 | |
|---|
| 222 | fmmflx(ji,jj) = zfmm ! F/M mass flux save at least for biogeochemical model |
|---|
| 223 | |
|---|
| 224 | ! salt flux at the ice/ocean interface (sea ice fraction) [PSU*kg/m2/s] |
|---|
| 225 | zfsalt = - sice_0(ji,jj) * zfmm ! F-M salt exchange |
|---|
| 226 | zcd = soce_0(ji,jj) * zfmm ! concentration/dilution term due to F-M |
|---|
| 227 | ! |
|---|
| 228 | ! salt flux only : add concentration dilution term in salt flux and no F-M term in volume flux |
|---|
| 229 | ! salt and mass fluxes : non concentration dilution term in salt flux and add F-M term in volume flux |
|---|
| 230 | sfx (ji,jj) = zfsalt + zswitch * zcd ! salt flux (+ C/D if no ice/ocean mass exchange) |
|---|
| 231 | emp (ji,jj) = zemp + zemp_snw + ( 1.- zswitch) * zfmm ! mass flux (+ F/M mass flux if ice/ocean mass exchange) |
|---|
| 232 | ! |
|---|
| 233 | END DO |
|---|
| 234 | END DO |
|---|
| 235 | ! !------------------------------------------! |
|---|
| 236 | ! ! mass of snow and ice per unit area ! |
|---|
| 237 | ! !------------------------------------------! |
|---|
| 238 | IF( nn_ice_embd /= 0 ) THEN ! embedded sea-ice (mass required) |
|---|
| 239 | snwice_mass_b(:,:) = snwice_mass(:,:) ! save mass from the previous ice time step |
|---|
| 240 | ! ! new mass per unit area |
|---|
| 241 | snwice_mass (:,:) = tms(:,:) * ( rhosn * hsnif(:,:) + rhoic * hicif(:,:) ) * ( 1.0 - frld(:,:) ) |
|---|
| 242 | ! ! time evolution of snow+ice mass |
|---|
| 243 | snwice_fmass (:,:) = ( snwice_mass(:,:) - snwice_mass_b(:,:) ) / rdt_ice |
|---|
| 244 | ENDIF |
|---|
| 245 | |
|---|
| 246 | CALL iom_put( 'hflx_ice_cea', - fdtcn(:,:) ) |
|---|
| 247 | CALL iom_put( 'qns_io_cea', qns(:,:) - zqnsoce(:,:) * pfrld(:,:) ) |
|---|
| 248 | CALL iom_put( 'qsr_io_cea', fstric(:,:) * (1.e0 - pfrld(:,:)) ) |
|---|
| 249 | |
|---|
| 250 | IF( lk_diaar5 ) THEN ! AR5 diagnostics |
|---|
| 251 | CALL iom_put( 'isnwmlt_cea' , rdm_snw(:,:) * r1_rdtice ) |
|---|
| 252 | CALL iom_put( 'fsal_virt_cea', soce_0(:,:) * rdm_ice(:,:) * r1_rdtice ) |
|---|
| 253 | CALL iom_put( 'fsal_real_cea', - sice_0(:,:) * rdm_ice(:,:) * r1_rdtice ) |
|---|
| 254 | ENDIF |
|---|
| 255 | |
|---|
| 256 | !-----------------------------------------------! |
|---|
| 257 | ! Coupling variables ! |
|---|
| 258 | !-----------------------------------------------! |
|---|
| 259 | |
|---|
| 260 | #if defined key_coupled |
|---|
| 261 | tn_ice(:,:,1) = sist(:,:) ! sea-ice surface temperature |
|---|
| 262 | ht_i(:,:,1) = hicif(:,:) |
|---|
| 263 | ht_s(:,:,1) = hsnif(:,:) |
|---|
| 264 | a_i(:,:,1) = fr_i(:,:) |
|---|
| 265 | ! ! Computation of snow/ice and ocean albedo |
|---|
| 266 | CALL albedo_ice( tn_ice, ht_i, ht_s, zalbp, zalb ) |
|---|
| 267 | alb_ice(:,:,1) = 0.5 * ( zalbp(:,:,1) + zalb (:,:,1) ) ! Ice albedo (mean clear and overcast skys) |
|---|
| 268 | CALL iom_put( "icealb_cea", alb_ice(:,:,1) * fr_i(:,:) ) ! ice albedo |
|---|
| 269 | #endif |
|---|
| 270 | |
|---|
| 271 | IF(ln_ctl) THEN ! control print |
|---|
| 272 | CALL prt_ctl(tab2d_1=qsr , clinfo1=' lim_sbc: qsr : ', tab2d_2=qns , clinfo2=' qns : ') |
|---|
| 273 | CALL prt_ctl(tab2d_1=emp , clinfo1=' lim_sbc: emp : ', tab2d_2=sfx , clinfo2=' sfx : ') |
|---|
| 274 | CALL prt_ctl(tab2d_1=utau , clinfo1=' lim_sbc: utau : ', mask1=umask, & |
|---|
| 275 | & tab2d_2=vtau , clinfo2=' vtau : ' , mask2=vmask ) |
|---|
| 276 | CALL prt_ctl(tab2d_1=fr_i , clinfo1=' lim_sbc: fr_i : ', tab2d_2=tn_ice(:,:,1), clinfo2=' tn_ice : ') |
|---|
| 277 | ENDIF |
|---|
| 278 | ! |
|---|
| 279 | CALL wrk_dealloc( jpi, jpj, zqnsoce ) |
|---|
| 280 | CALL wrk_dealloc( jpi, jpj, 1, zalb, zalbp ) |
|---|
| 281 | ! |
|---|
| 282 | END SUBROUTINE lim_sbc_flx_2 |
|---|
| 283 | |
|---|
| 284 | |
|---|
| 285 | SUBROUTINE lim_sbc_tau_2( kt , pu_oce, pv_oce ) |
|---|
| 286 | !!------------------------------------------------------------------- |
|---|
| 287 | !! *** ROUTINE lim_sbc_tau_2 *** |
|---|
| 288 | !! |
|---|
| 289 | !! ** Purpose : Update the ocean surface stresses due to the ice |
|---|
| 290 | !! |
|---|
| 291 | !! ** Action : * at each ice time step (every nn_fsbc time step): |
|---|
| 292 | !! - compute the modulus of ice-ocean relative velocity |
|---|
| 293 | !! at T-point (C-grid) or I-point (B-grid) |
|---|
| 294 | !! tmod_io = rhoco * | U_ice-U_oce | |
|---|
| 295 | !! - update the modulus of stress at ocean surface |
|---|
| 296 | !! taum = frld * taum + (1-frld) * tmod_io * | U_ice-U_oce | |
|---|
| 297 | !! * at each ocean time step (each kt): |
|---|
| 298 | !! compute linearized ice-ocean stresses as |
|---|
| 299 | !! Utau = tmod_io * | U_ice - pU_oce | |
|---|
| 300 | !! using instantaneous current ocean velocity (usually before) |
|---|
| 301 | !! |
|---|
| 302 | !! NB: - the averaging operator used depends on the ice dynamics grid (cp_ice_msh='I' or 'C') |
|---|
| 303 | !! - ice-ocean rotation angle only allowed in cp_ice_msh='I' case |
|---|
| 304 | !! - here we make an approximation: taum is only computed every ice time step |
|---|
| 305 | !! This avoids mutiple average to pass from T -> U,V grids and next from U,V grids |
|---|
| 306 | !! to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximation... |
|---|
| 307 | !! |
|---|
| 308 | !! ** Outputs : - utau, vtau : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes |
|---|
| 309 | !! - taum : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes |
|---|
| 310 | !!--------------------------------------------------------------------- |
|---|
| 311 | INTEGER , INTENT(in) :: kt ! ocean time-step index |
|---|
| 312 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pu_oce, pv_oce ! surface ocean currents |
|---|
| 313 | !! |
|---|
| 314 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 315 | REAL(wp) :: zfrldu, zat_u, zu_i, zutau_ice, zu_t, zmodt ! local scalar |
|---|
| 316 | REAL(wp) :: zfrldv, zat_v, zv_i, zvtau_ice, zv_t, zmodi ! - - |
|---|
| 317 | REAL(wp) :: zsang, zumt ! - - |
|---|
| 318 | REAL(wp), POINTER, DIMENSION(:,:) :: ztio_u, ztio_v ! ocean stress below sea-ice |
|---|
| 319 | !!--------------------------------------------------------------------- |
|---|
| 320 | ! |
|---|
| 321 | CALL wrk_alloc( jpi, jpj, ztio_u, ztio_v ) |
|---|
| 322 | ! |
|---|
| 323 | SELECT CASE( cp_ice_msh ) |
|---|
| 324 | ! !-----------------------! |
|---|
| 325 | CASE( 'I' ) ! B-grid ice dynamics ! I-point (i.e. F-point with sea-ice indexation) |
|---|
| 326 | ! !--=--------------------! |
|---|
| 327 | ! |
|---|
| 328 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN !== Ice time-step only ==! (i.e. surface module time-step) |
|---|
| 329 | !CDIR NOVERRCHK |
|---|
| 330 | DO jj = 1, jpj !* modulus of ice-ocean relative velocity at I-point |
|---|
| 331 | !CDIR NOVERRCHK |
|---|
| 332 | DO ji = 1, jpi |
|---|
| 333 | zu_i = u_ice(ji,jj) - u_oce(ji,jj) ! ice-ocean relative velocity at I-point |
|---|
| 334 | zv_i = v_ice(ji,jj) - v_oce(ji,jj) |
|---|
| 335 | tmod_io(ji,jj) = SQRT( zu_i * zu_i + zv_i * zv_i ) ! modulus of this velocity (at I-point) |
|---|
| 336 | END DO |
|---|
| 337 | END DO |
|---|
| 338 | !CDIR NOVERRCHK |
|---|
| 339 | DO jj = 1, jpjm1 !* update the modulus of stress at ocean surface (T-point) |
|---|
| 340 | !CDIR NOVERRCHK |
|---|
| 341 | DO ji = 1, jpim1 ! NO vector opt. |
|---|
| 342 | ! ! modulus of U_ice-U_oce at T-point |
|---|
| 343 | zumt = 0.25_wp * ( tmod_io(ji+1,jj) + tmod_io(ji ,jj ) & |
|---|
| 344 | & + tmod_io(ji,jj+1) + tmod_io(ji+1,jj+1) ) |
|---|
| 345 | ! ! update the modulus of stress at ocean surface |
|---|
| 346 | taum(ji,jj) = frld(ji,jj) * taum(ji,jj) + ( 1._wp - frld(ji,jj) ) * rhoco * zumt * zumt |
|---|
| 347 | END DO |
|---|
| 348 | END DO |
|---|
| 349 | CALL lbc_lnk( taum, 'T', 1. ) |
|---|
| 350 | ! |
|---|
| 351 | utau_oce(:,:) = utau(:,:) !* save the air-ocean stresses at ice time-step |
|---|
| 352 | vtau_oce(:,:) = vtau(:,:) |
|---|
| 353 | ! |
|---|
| 354 | ENDIF |
|---|
| 355 | ! |
|---|
| 356 | ! !== at each ocean time-step ==! |
|---|
| 357 | ! |
|---|
| 358 | ! !* ice/ocean stress WITH a ice-ocean rotation angle at I-point |
|---|
| 359 | DO jj = 2, jpj |
|---|
| 360 | zsang = SIGN( 1._wp, gphif(1,jj) ) * sangvg ! change the cosine angle sign in the SH |
|---|
| 361 | DO ji = 2, jpi ! NO vect. opt. possible |
|---|
| 362 | ! ... ice-ocean relative velocity at I-point using instantaneous surface ocean current at u- & v-pts |
|---|
| 363 | zu_i = u_ice(ji,jj) - 0.5_wp * ( pu_oce(ji-1,jj ) + pu_oce(ji-1,jj-1) ) * tmu(ji,jj) |
|---|
| 364 | zv_i = v_ice(ji,jj) - 0.5_wp * ( pv_oce(ji ,jj-1) + pv_oce(ji-1,jj-1) ) * tmu(ji,jj) |
|---|
| 365 | ! ... components of stress with a ice-ocean rotation angle |
|---|
| 366 | zmodi = rhoco * tmod_io(ji,jj) |
|---|
| 367 | ztio_u(ji,jj) = zmodi * ( cangvg * zu_i - zsang * zv_i ) |
|---|
| 368 | ztio_v(ji,jj) = zmodi * ( cangvg * zv_i + zsang * zu_i ) |
|---|
| 369 | END DO |
|---|
| 370 | END DO |
|---|
| 371 | ! !* surface ocean stresses at u- and v-points |
|---|
| 372 | DO jj = 2, jpjm1 |
|---|
| 373 | DO ji = 2, jpim1 ! NO vector opt. |
|---|
| 374 | ! ! ice-ocean stress at U and V-points (from I-point values) |
|---|
| 375 | zutau_ice = 0.5_wp * ( ztio_u(ji+1,jj) + ztio_u(ji+1,jj+1) ) |
|---|
| 376 | zvtau_ice = 0.5_wp * ( ztio_v(ji,jj+1) + ztio_v(ji+1,jj+1) ) |
|---|
| 377 | ! ! open-ocean (lead) fraction at U- & V-points (from T-point values) |
|---|
| 378 | zfrldu = 0.5_wp * ( frld(ji,jj) + frld(ji+1,jj) ) |
|---|
| 379 | zfrldv = 0.5_wp * ( frld(ji,jj) + frld(ji,jj+1) ) |
|---|
| 380 | ! ! update the surface ocean stress (ice-cover wheighted) |
|---|
| 381 | utau(ji,jj) = zfrldu * utau_oce(ji,jj) + ( 1._wp - zfrldu ) * zutau_ice |
|---|
| 382 | vtau(ji,jj) = zfrldv * vtau_oce(ji,jj) + ( 1._wp - zfrldv ) * zvtau_ice |
|---|
| 383 | END DO |
|---|
| 384 | END DO |
|---|
| 385 | CALL lbc_lnk( utau, 'U', -1. ) ; CALL lbc_lnk( vtau, 'V', -1. ) ! lateral boundary condition |
|---|
| 386 | ! |
|---|
| 387 | ! |
|---|
| 388 | ! !-----------------------! |
|---|
| 389 | CASE( 'C' ) ! C-grid ice dynamics ! U & V-points (same as in the ocean) |
|---|
| 390 | ! !--=--------------------! |
|---|
| 391 | ! |
|---|
| 392 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN !== Ice time-step only ==! (i.e. surface module time-step) |
|---|
| 393 | !CDIR NOVERRCHK |
|---|
| 394 | DO jj = 2, jpjm1 !* modulus of the ice-ocean velocity at T-point |
|---|
| 395 | !CDIR NOVERRCHK |
|---|
| 396 | DO ji = fs_2, fs_jpim1 |
|---|
| 397 | zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj) ! 2*(U_ice-U_oce) at T-point |
|---|
| 398 | zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) |
|---|
| 399 | zmodt = 0.25_wp * ( zu_t * zu_t + zv_t * zv_t ) ! |U_ice-U_oce|^2 |
|---|
| 400 | ! ! update the modulus of stress at ocean surface |
|---|
| 401 | taum (ji,jj) = frld(ji,jj) * taum(ji,jj) + ( 1._wp - frld(ji,jj) ) * rhoco * zmodt |
|---|
| 402 | tmod_io(ji,jj) = SQRT( zmodt ) * rhoco ! rhoco*|Uice-Uoce| |
|---|
| 403 | END DO |
|---|
| 404 | END DO |
|---|
| 405 | CALL lbc_lnk( taum, 'T', 1. ) ; CALL lbc_lnk( tmod_io, 'T', 1. ) |
|---|
| 406 | ! |
|---|
| 407 | utau_oce(:,:) = utau(:,:) !* save the air-ocean stresses at ice time-step |
|---|
| 408 | vtau_oce(:,:) = vtau(:,:) |
|---|
| 409 | ! |
|---|
| 410 | ENDIF |
|---|
| 411 | ! |
|---|
| 412 | ! !== at each ocean time-step ==! |
|---|
| 413 | ! |
|---|
| 414 | DO jj = 2, jpjm1 !* ice stress over ocean WITHOUT a ice-ocean rotation angle |
|---|
| 415 | DO ji = fs_2, fs_jpim1 |
|---|
| 416 | ! ! ocean area at u- & v-points |
|---|
| 417 | zfrldu = 0.5_wp * ( frld(ji,jj) + frld(ji+1,jj) ) |
|---|
| 418 | zfrldv = 0.5_wp * ( frld(ji,jj) + frld(ji,jj+1) ) |
|---|
| 419 | ! ! quadratic drag formulation without rotation |
|---|
| 420 | ! ! using instantaneous surface ocean current |
|---|
| 421 | zutau_ice = 0.5 * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) ) |
|---|
| 422 | zvtau_ice = 0.5 * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) ) |
|---|
| 423 | ! ! update the surface ocean stress (ice-cover wheighted) |
|---|
| 424 | utau(ji,jj) = zfrldu * utau_oce(ji,jj) + ( 1._wp - zfrldu ) * zutau_ice |
|---|
| 425 | vtau(ji,jj) = zfrldv * vtau_oce(ji,jj) + ( 1._wp - zfrldv ) * zvtau_ice |
|---|
| 426 | END DO |
|---|
| 427 | END DO |
|---|
| 428 | CALL lbc_lnk( utau, 'U', -1. ) ; CALL lbc_lnk( vtau, 'V', -1. ) ! lateral boundary condition |
|---|
| 429 | ! |
|---|
| 430 | END SELECT |
|---|
| 431 | |
|---|
| 432 | IF(ln_ctl) CALL prt_ctl( tab2d_1=utau, clinfo1=' lim_sbc: utau : ', mask1=umask, & |
|---|
| 433 | & tab2d_2=vtau, clinfo2=' vtau : ' , mask2=vmask ) |
|---|
| 434 | ! |
|---|
| 435 | CALL wrk_dealloc( jpi, jpj, ztio_u, ztio_v ) |
|---|
| 436 | ! |
|---|
| 437 | END SUBROUTINE lim_sbc_tau_2 |
|---|
| 438 | |
|---|
| 439 | |
|---|
| 440 | SUBROUTINE lim_sbc_init_2 |
|---|
| 441 | !!------------------------------------------------------------------- |
|---|
| 442 | !! *** ROUTINE lim_sbc_init *** |
|---|
| 443 | !! |
|---|
| 444 | !! ** Purpose : Preparation of the file ice_evolu for the output of |
|---|
| 445 | !! the temporal evolution of key variables |
|---|
| 446 | !! |
|---|
| 447 | !! ** input : Namelist namicedia |
|---|
| 448 | !!------------------------------------------------------------------- |
|---|
| 449 | ! |
|---|
| 450 | INTEGER :: jk ! local integer |
|---|
| 451 | ! |
|---|
| 452 | IF(lwp) WRITE(numout,*) |
|---|
| 453 | IF(lwp) WRITE(numout,*) 'lim_sbc_init_2 : LIM-2 sea-ice - surface boundary condition' |
|---|
| 454 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~ ' |
|---|
| 455 | |
|---|
| 456 | ! ! allocate lim_sbc arrays |
|---|
| 457 | IF( lim_sbc_alloc_2() /= 0 ) CALL ctl_stop( 'STOP', 'lim_sbc_flx_2 : unable to allocate arrays' ) |
|---|
| 458 | ! |
|---|
| 459 | r1_rdtice = 1._wp / rdt_ice |
|---|
| 460 | ! |
|---|
| 461 | soce_0(:,:) = soce ! constant SSS and ice salinity used in levitating sea-ice case |
|---|
| 462 | sice_0(:,:) = sice |
|---|
| 463 | ! |
|---|
| 464 | IF( cp_cfg == "orca" ) THEN ! decrease ocean & ice reference salinities in the Baltic sea |
|---|
| 465 | WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND. & |
|---|
| 466 | & 54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp ) |
|---|
| 467 | soce_0(:,:) = 4._wp |
|---|
| 468 | sice_0(:,:) = 2._wp |
|---|
| 469 | END WHERE |
|---|
| 470 | ENDIF |
|---|
| 471 | ! ! embedded sea ice |
|---|
| 472 | IF( nn_ice_embd /= 0 ) THEN ! mass exchanges between ice and ocean (case 1 or 2) set the snow+ice mass |
|---|
| 473 | snwice_mass (:,:) = tms(:,:) * ( rhosn * hsnif(:,:) + rhoic * hicif(:,:) ) * ( 1.0 - frld(:,:) ) |
|---|
| 474 | snwice_mass_b(:,:) = snwice_mass(:,:) |
|---|
| 475 | ELSE |
|---|
| 476 | snwice_mass (:,:) = 0.e0 ! no mass exchanges |
|---|
| 477 | snwice_mass_b(:,:) = 0.e0 ! no mass exchanges |
|---|
| 478 | snwice_fmass (:,:) = 0.e0 ! no mass exchanges |
|---|
| 479 | ENDIF |
|---|
| 480 | IF( nn_ice_embd == 2 .AND. & ! full embedment (case 2) & no restart : |
|---|
| 481 | & .NOT.ln_rstart ) THEN ! deplete the initial ssh below sea-ice area |
|---|
| 482 | sshn(:,:) = sshn(:,:) - snwice_mass(:,:) * r1_rau0 |
|---|
| 483 | sshb(:,:) = sshb(:,:) - snwice_mass(:,:) * r1_rau0 |
|---|
| 484 | do jk = 1,jpkm1 ! adjust initial vertical scale factors |
|---|
| 485 | fse3t_n(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshn(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) ) |
|---|
| 486 | fse3t_b(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshb(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) ) |
|---|
| 487 | end do |
|---|
| 488 | fse3t_a(:,:,:) = fse3t_b(:,:,:) |
|---|
| 489 | ! Reconstruction of all vertical scale factors at now and before time steps |
|---|
| 490 | ! ============================================================================= |
|---|
| 491 | ! Horizontal scale factor interpolations |
|---|
| 492 | ! -------------------------------------- |
|---|
| 493 | CALL dom_vvl_interpol( fse3t_b(:,:,:), fse3u_b(:,:,:), 'U' ) |
|---|
| 494 | CALL dom_vvl_interpol( fse3t_b(:,:,:), fse3v_b(:,:,:), 'V' ) |
|---|
| 495 | CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3u_n(:,:,:), 'U' ) |
|---|
| 496 | CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3v_n(:,:,:), 'V' ) |
|---|
| 497 | CALL dom_vvl_interpol( fse3u_n(:,:,:), fse3f_n(:,:,:), 'F' ) |
|---|
| 498 | ! Vertical scale factor interpolations |
|---|
| 499 | ! ------------------------------------ |
|---|
| 500 | CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3w_n (:,:,:), 'W' ) |
|---|
| 501 | CALL dom_vvl_interpol( fse3u_n(:,:,:), fse3uw_n(:,:,:), 'UW' ) |
|---|
| 502 | CALL dom_vvl_interpol( fse3v_n(:,:,:), fse3vw_n(:,:,:), 'VW' ) |
|---|
| 503 | CALL dom_vvl_interpol( fse3u_b(:,:,:), fse3uw_b(:,:,:), 'UW' ) |
|---|
| 504 | CALL dom_vvl_interpol( fse3v_b(:,:,:), fse3vw_b(:,:,:), 'VW' ) |
|---|
| 505 | ! t- and w- points depth |
|---|
| 506 | ! ---------------------- |
|---|
| 507 | fsdept_n(:,:,1) = 0.5_wp * fse3w_n(:,:,1) |
|---|
| 508 | fsdepw_n(:,:,1) = 0.0_wp |
|---|
| 509 | fsde3w_n(:,:,1) = fsdept_n(:,:,1) - sshn(:,:) |
|---|
| 510 | DO jk = 2, jpk |
|---|
| 511 | fsdept_n(:,:,jk) = fsdept_n(:,:,jk-1) + fse3w_n(:,:,jk) |
|---|
| 512 | fsdepw_n(:,:,jk) = fsdepw_n(:,:,jk-1) + fse3t_n(:,:,jk-1) |
|---|
| 513 | fsde3w_n(:,:,jk) = fsdept_n(:,:,jk ) - sshn (:,:) |
|---|
| 514 | END DO |
|---|
| 515 | ENDIF |
|---|
| 516 | ! |
|---|
| 517 | END SUBROUTINE lim_sbc_init_2 |
|---|
| 518 | |
|---|
| 519 | #else |
|---|
| 520 | !!---------------------------------------------------------------------- |
|---|
| 521 | !! Default option Empty module NO LIM 2.0 sea-ice model |
|---|
| 522 | !!---------------------------------------------------------------------- |
|---|
| 523 | #endif |
|---|
| 524 | |
|---|
| 525 | !!====================================================================== |
|---|
| 526 | END MODULE limsbc_2 |
|---|
