New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_bilap.F90 in branches/2013/dev_MERGE_2013/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2013/dev_MERGE_2013/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_bilap.F90 @ 4328

Last change on this file since 4328 was 4292, checked in by cetlod, 10 years ago

dev_MERGE_2013 : 1st step of the merge, see ticket #1185
  • Property svn:keywords set to Id
File size: 9.3 KB
Line 
1MODULE traldf_bilap
2   !!==============================================================================
3   !!                   ***  MODULE  traldf_bilap  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6   !! History :  OPA  !  1991-11  (G. Madec)  Original code
7   !!                 !  1993-03  (M. Guyon)  symetrical conditions
8   !!                 !  1995-11  (G. Madec)  suppress volumetric scale factors
9   !!                 !  1996-01  (G. Madec)  statement function for e3
10   !!                 !  1996-01  (M. Imbard)  mpp exchange
11   !!                 !  1997-07  (G. Madec)  optimization, and ahtt
12   !!            8.5  !  2002-08  (G. Madec)  F90: Free form and module
13   !!   NEMO     1.0  !  2004-08  (C. Talandier) New trends organization
14   !!             -   !  2005-11  (G. Madec)  zps or sco as default option
15   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
16   !!==============================================================================
17
18   !!----------------------------------------------------------------------
19   !!   tra_ldf_bilap : update the tracer trend with the horizontal diffusion
20   !!                   using a iso-level biharmonic operator
21   !!----------------------------------------------------------------------
22   USE oce             ! ocean dynamics and active tracers
23   USE dom_oce         ! ocean space and time domain
24   USE ldftra_oce      ! ocean tracer   lateral physics
25   USE in_out_manager  ! I/O manager
26   USE ldfslp          ! iso-neutral slopes
27   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
28   USE diaptr          ! poleward transport diagnostics
29   USE trc_oce         ! share passive tracers/Ocean variables
30   USE lib_mpp         ! MPP library
31   USE wrk_nemo       ! Memory Allocation
32   USE timing         ! Timing
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   tra_ldf_bilap   ! routine called by step.F90
38
39   !! * Substitutions
40#  include "domzgr_substitute.h90"
41#  include "ldftra_substitute.h90"
42#  include "ldfeiv_substitute.h90"
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50 
51   SUBROUTINE tra_ldf_bilap( kt, kit000, cdtype, pgu, pgv,      &
52      &                                  ptb, pta, kjpt ) 
53      !!----------------------------------------------------------------------
54      !!                  ***  ROUTINE tra_ldf_bilap  ***
55      !!
56      !! ** Purpose :   Compute the before horizontal tracer diffusive
57      !!      trend and add it to the general trend of tracer equation.
58      !!
59      !! ** Method  :   4th order diffusive operator along model level surfaces
60      !!      evaluated using before fields (forward time scheme). The hor.
61      !!      diffusive trends  is given by:
62      !!      Laplacian of tb:
63      !!         zlt   = 1/(e1t*e2t*e3t) {  di-1[ e2u*e3u/e1u di(tb) ]
64      !!                                  + dj-1[ e1v*e3v/e2v dj(tb) ]  }
65      !!      Multiply by the eddy diffusivity coef. and insure lateral bc:
66      !!        zlt   = ahtt * zlt
67      !!        call to lbc_lnk
68      !!      Bilaplacian (laplacian of zlt):
69      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ e2u*e3u/e1u di(zlt) ]
70      !!                                  + dj-1[ e1v*e3v/e2v dj(zlt) ]  }
71      !!
72      !!      Add this trend to the general trend
73      !!         (pta) = (pta) + ( difft )
74      !!
75      !! ** Action : - Update pta arrays with the before iso-level
76      !!               biharmonic mixing trend.
77      !!----------------------------------------------------------------------
78      USE oce     , ONLY:   ztu  => ua       , ztv  => va                           ! (ua,va) used as workspace
79      !!
80      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
81      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
82      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
83      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
84      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
85      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
86      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
87      !!
88      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
89      REAL(wp) ::  zbtr, ztra       ! local scalars
90      REAL(wp), POINTER, DIMENSION(:,:) ::  zeeu, zeev, zlt
91      !!----------------------------------------------------------------------
92      !
93      IF( nn_timing == 1 )  CALL timing_start( 'tra_ldf_bilap')
94      !
95      CALL wrk_alloc( jpi, jpj, zeeu, zeev, zlt ) 
96      !
97
98      IF( kt == kit000 )  THEN
99         IF(lwp) WRITE(numout,*)
100         IF(lwp) WRITE(numout,*) 'tra_ldf_bilap : iso-level biharmonic operator on ', cdtype
101         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~'
102      ENDIF
103      !                                                          ! ===========
104      DO jn = 1, kjpt                                            ! tracer loop
105         !                                                       ! ===========
106         !                                               
107         DO jk = 1, jpkm1                                        ! Horizontal slab
108            !                                             
109            !                          !==  Initialization of metric arrays (for z- or s-coordinates)  ==!
110            DO jj = 1, jpjm1
111               DO ji = 1, fs_jpim1   ! vector opt.
112                  zeeu(ji,jj) = re2u_e1u(ji,jj) * fse3u_n(ji,jj,jk) * umask(ji,jj,jk)
113                  zeev(ji,jj) = re1v_e2v(ji,jj) * fse3v_n(ji,jj,jk) * vmask(ji,jj,jk)
114               END DO
115            END DO
116
117            !                          !==  Laplacian  ==!
118            !
119            DO jj = 1, jpjm1                 ! First derivative (gradient)
120               DO ji = 1, fs_jpim1   ! vector opt.
121                  ztu(ji,jj,jk) = zeeu(ji,jj) * ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) )
122                  ztv(ji,jj,jk) = zeev(ji,jj) * ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
123               END DO
124            END DO
125            IF( ln_zps ) THEN                ! set gradient at partial step level (last ocean level)
126               DO jj = 1, jpjm1
127                  DO ji = 1, jpim1
128                     IF( mbku(ji,jj) == jk )  ztu(ji,jj,jk) = zeeu(ji,jj) * pgu(ji,jj,jn)
129                     IF( mbkv(ji,jj) == jk )  ztv(ji,jj,jk) = zeev(ji,jj) * pgv(ji,jj,jn)
130                  END DO
131               END DO
132            ENDIF
133            DO jj = 2, jpjm1                 ! Second derivative (divergence) time the eddy diffusivity coefficient
134               DO ji = fs_2, fs_jpim1   ! vector opt.
135                  zbtr = 1.0 / ( e12t(ji,jj) * fse3t_n(ji,jj,jk) )
136                  zlt(ji,jj) = fsahtt(ji,jj,jk) * zbtr * (   ztu(ji,jj,jk) - ztu(ji-1,jj,jk)   &
137                     &                                     + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)   )
138               END DO
139            END DO
140            CALL lbc_lnk( zlt, 'T', 1. )     ! Lateral boundary conditions (unchanged sgn)
141
142            !                          !==  Bilaplacian  ==!
143            !
144            DO jj = 1, jpjm1                 ! third derivative (gradient)
145               DO ji = 1, fs_jpim1   ! vector opt.
146                  ztu(ji,jj,jk) = zeeu(ji,jj) * ( zlt(ji+1,jj  ) - zlt(ji,jj) )
147                  ztv(ji,jj,jk) = zeev(ji,jj) * ( zlt(ji  ,jj+1) - zlt(ji,jj) )
148               END DO
149            END DO
150            DO jj = 2, jpjm1                 ! fourth derivative (divergence) and add to the general tracer trend
151               DO ji = fs_2, fs_jpim1   ! vector opt.
152                  ! horizontal diffusive trends
153                  zbtr = 1.0 / ( e12t(ji,jj) * fse3t_n(ji,jj,jk) )
154                  ztra = zbtr * (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk) + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  )
155                  ! add it to the general tracer trends
156                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
157               END DO
158            END DO
159            !                                             
160         END DO                                           ! Horizontal slab
161         !                                               
162         ! "zonal" mean lateral diffusive heat and salt transport
163         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
164           IF( jn == jp_tem )  htr_ldf(:) = ptr_vj( ztv(:,:,:) )
165           IF( jn == jp_sal )  str_ldf(:) = ptr_vj( ztv(:,:,:) )
166         ENDIF
167         !                                                ! ===========
168      END DO                                              ! tracer loop
169      !                                                   ! ===========
170      IF( nn_timing == 1 )  CALL timing_stop( 'tra_ldf_bilap')
171      !
172      CALL wrk_dealloc( jpi, jpj, zeeu, zeev, zlt ) 
173      !
174   END SUBROUTINE tra_ldf_bilap
175
176   !!==============================================================================
177END MODULE traldf_bilap
Note: See TracBrowser for help on using the repository browser.