| 1 | MODULE step |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE step *** |
|---|
| 4 | !! Time-stepping : manager of the ocean, tracer and ice time stepping |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1991-03 (G. Madec) Original code |
|---|
| 7 | !! - ! 1991-11 (G. Madec) |
|---|
| 8 | !! - ! 1992-06 (M. Imbard) add a first output record |
|---|
| 9 | !! - ! 1996-04 (G. Madec) introduction of dynspg |
|---|
| 10 | !! - ! 1996-04 (M.A. Foujols) introduction of passive tracer |
|---|
| 11 | !! 8.0 ! 1997-06 (G. Madec) new architecture of call |
|---|
| 12 | !! 8.2 ! 1997-06 (G. Madec, M. Imbard, G. Roullet) free surface |
|---|
| 13 | !! - ! 1999-02 (G. Madec, N. Grima) hpg implicit |
|---|
| 14 | !! - ! 2000-07 (J-M Molines, M. Imbard) Open Bondary Conditions |
|---|
| 15 | !! NEMO 1.0 ! 2002-06 (G. Madec) free form, suppress macro-tasking |
|---|
| 16 | !! - ! 2004-08 (C. Talandier) New trends organization |
|---|
| 17 | !! - ! 2005-01 (C. Ethe) Add the KPP closure scheme |
|---|
| 18 | !! - ! 2005-11 (G. Madec) Reorganisation of tra and dyn calls |
|---|
| 19 | !! - ! 2006-01 (L. Debreu, C. Mazauric) Agrif implementation |
|---|
| 20 | !! - ! 2006-07 (S. Masson) restart using iom |
|---|
| 21 | !! 3.2 ! 2009-02 (G. Madec, R. Benshila) reintroduicing z*-coordinate |
|---|
| 22 | !! - ! 2009-06 (S. Masson, G. Madec) TKE restart compatible with key_cpl |
|---|
| 23 | !! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface |
|---|
| 24 | !! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA |
|---|
| 25 | !! 3.4 ! 2011-04 (G. Madec, C. Ethe) Merge of dtatem and dtasal |
|---|
| 26 | !! ! 2012-07 (J. Simeon, G. Madec. C. Ethe) Online coarsening of outputs |
|---|
| 27 | !!---------------------------------------------------------------------- |
|---|
| 28 | |
|---|
| 29 | !!---------------------------------------------------------------------- |
|---|
| 30 | !! stp : OPA system time-stepping |
|---|
| 31 | !!---------------------------------------------------------------------- |
|---|
| 32 | USE step_oce ! time stepping definition modules |
|---|
| 33 | |
|---|
| 34 | IMPLICIT NONE |
|---|
| 35 | PRIVATE |
|---|
| 36 | |
|---|
| 37 | PUBLIC stp ! called by opa.F90 |
|---|
| 38 | |
|---|
| 39 | !! * Substitutions |
|---|
| 40 | # include "domzgr_substitute.h90" |
|---|
| 41 | # include "zdfddm_substitute.h90" |
|---|
| 42 | !!---------------------------------------------------------------------- |
|---|
| 43 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 44 | !! $Id$ |
|---|
| 45 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 46 | !!---------------------------------------------------------------------- |
|---|
| 47 | CONTAINS |
|---|
| 48 | |
|---|
| 49 | #if defined key_agrif |
|---|
| 50 | SUBROUTINE stp( ) |
|---|
| 51 | INTEGER :: kstp ! ocean time-step index |
|---|
| 52 | #else |
|---|
| 53 | SUBROUTINE stp( kstp ) |
|---|
| 54 | INTEGER, INTENT(in) :: kstp ! ocean time-step index |
|---|
| 55 | #endif |
|---|
| 56 | !!---------------------------------------------------------------------- |
|---|
| 57 | !! *** ROUTINE stp *** |
|---|
| 58 | !! |
|---|
| 59 | !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.) |
|---|
| 60 | !! - Time stepping of LIM (dynamic and thermodynamic eqs.) |
|---|
| 61 | !! - Tme stepping of TRC (passive tracer eqs.) |
|---|
| 62 | !! |
|---|
| 63 | !! ** Method : -1- Update forcings and data |
|---|
| 64 | !! -2- Update ocean physics |
|---|
| 65 | !! -3- Compute the t and s trends |
|---|
| 66 | !! -4- Update t and s |
|---|
| 67 | !! -5- Compute the momentum trends |
|---|
| 68 | !! -6- Update the horizontal velocity |
|---|
| 69 | !! -7- Compute the diagnostics variables (rd,N2, div,cur,w) |
|---|
| 70 | !! -8- Outputs and diagnostics |
|---|
| 71 | !!---------------------------------------------------------------------- |
|---|
| 72 | INTEGER :: jk ! dummy loop indice |
|---|
| 73 | INTEGER :: indic ! error indicator if < 0 |
|---|
| 74 | INTEGER :: kcall ! optional integer argument (dom_vvl_sf_nxt) |
|---|
| 75 | !! --------------------------------------------------------------------- |
|---|
| 76 | |
|---|
| 77 | #if defined key_agrif |
|---|
| 78 | kstp = nit000 + Agrif_Nb_Step() |
|---|
| 79 | ! IF ( Agrif_Root() .and. lwp) Write(*,*) '---' |
|---|
| 80 | ! IF (lwp) Write(*,*) 'Grid Number',Agrif_Fixed(),' time step ',kstp |
|---|
| 81 | # if defined key_iomput |
|---|
| 82 | IF( Agrif_Nbstepint() == 0 ) CALL iom_swap( "nemo" ) |
|---|
| 83 | # endif |
|---|
| 84 | #endif |
|---|
| 85 | indic = 0 ! reset to no error condition |
|---|
| 86 | IF( kstp == nit000 ) THEN |
|---|
| 87 | CALL iom_init( "nemo" ) ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS) |
|---|
| 88 | IF( ln_crs ) CALL iom_init( "nemo_crs" ) ! initialize context for coarse grid |
|---|
| 89 | ENDIF |
|---|
| 90 | |
|---|
| 91 | IF( kstp /= nit000 ) CALL day( kstp ) ! Calendar (day was already called at nit000 in day_init) |
|---|
| 92 | CALL iom_setkt( kstp - nit000 + 1, "nemo" ) ! say to iom that we are at time step kstp |
|---|
| 93 | IF( ln_crs ) CALL iom_setkt( kstp - nit000 + 1, "nemo_crs" ) ! say to iom that we are at time step kstp |
|---|
| 94 | |
|---|
| 95 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 96 | ! Update data, open boundaries, surface boundary condition (including sea-ice) |
|---|
| 97 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 98 | IF( lk_tide ) CALL sbc_tide( kstp ) |
|---|
| 99 | IF( lk_bdy ) CALL bdy_dta ( kstp, time_offset=+1 ) ! update dynamic & tracer data at open boundaries |
|---|
| 100 | |
|---|
| 101 | CALL sbc ( kstp ) ! Sea Boundary Condition (including sea-ice) |
|---|
| 102 | ! clem: moved here for bdy ice purpose |
|---|
| 103 | |
|---|
| 104 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 105 | ! Ocean physics update (ua, va, tsa used as workspace) |
|---|
| 106 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 107 | CALL bn2( tsb, rn2b ) ! before Brunt-Vaisala frequency |
|---|
| 108 | CALL bn2( tsn, rn2 ) ! now Brunt-Vaisala frequency |
|---|
| 109 | ! |
|---|
| 110 | ! VERTICAL PHYSICS |
|---|
| 111 | CALL zdf_bfr( kstp ) ! bottom friction (if quadratic) |
|---|
| 112 | ! ! Vertical eddy viscosity and diffusivity coefficients |
|---|
| 113 | IF( lk_zdfric ) CALL zdf_ric( kstp ) ! Richardson number dependent Kz |
|---|
| 114 | IF( lk_zdftke ) CALL zdf_tke( kstp ) ! TKE closure scheme for Kz |
|---|
| 115 | IF( lk_zdfgls ) CALL zdf_gls( kstp ) ! GLS closure scheme for Kz |
|---|
| 116 | IF( lk_zdfkpp ) CALL zdf_kpp( kstp ) ! KPP closure scheme for Kz |
|---|
| 117 | IF( lk_zdfcst ) THEN ! Constant Kz (reset avt, avm[uv] to the background value) |
|---|
| 118 | avt (:,:,:) = rn_avt0 * tmask(:,:,:) |
|---|
| 119 | avmu(:,:,:) = rn_avm0 * umask(:,:,:) |
|---|
| 120 | avmv(:,:,:) = rn_avm0 * vmask(:,:,:) |
|---|
| 121 | ENDIF |
|---|
| 122 | IF( ln_rnf_mouth ) THEN ! increase diffusivity at rivers mouths |
|---|
| 123 | DO jk = 2, nkrnf ; avt(:,:,jk) = avt(:,:,jk) + 2.e0 * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk) ; END DO |
|---|
| 124 | ENDIF |
|---|
| 125 | IF( ln_zdfevd ) CALL zdf_evd( kstp ) ! enhanced vertical eddy diffusivity |
|---|
| 126 | |
|---|
| 127 | IF( lk_zdftmx ) CALL zdf_tmx( kstp ) ! tidal vertical mixing |
|---|
| 128 | |
|---|
| 129 | IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) & |
|---|
| 130 | & CALL zdf_ddm( kstp ) ! double diffusive mixing |
|---|
| 131 | |
|---|
| 132 | CALL zdf_mxl( kstp ) ! mixed layer depth |
|---|
| 133 | |
|---|
| 134 | ! write TKE or GLS information in the restart file |
|---|
| 135 | IF( lrst_oce .AND. lk_zdftke ) CALL tke_rst( kstp, 'WRITE' ) |
|---|
| 136 | IF( lrst_oce .AND. lk_zdfgls ) CALL gls_rst( kstp, 'WRITE' ) |
|---|
| 137 | ! |
|---|
| 138 | ! LATERAL PHYSICS |
|---|
| 139 | ! |
|---|
| 140 | IF( lk_ldfslp ) THEN ! slope of lateral mixing |
|---|
| 141 | CALL eos( tsb, rhd, gdept_0(:,:,:) ) ! before in situ density |
|---|
| 142 | IF( ln_zps ) CALL zps_hde( kstp, jpts, tsb, gtsu, gtsv, & ! Partial steps: before horizontal gradient |
|---|
| 143 | & rhd, gru , grv ) ! of t, s, rd at the last ocean level |
|---|
| 144 | IF( ln_traldf_grif ) THEN ! before slope for Griffies operator |
|---|
| 145 | CALL ldf_slp_grif( kstp ) |
|---|
| 146 | ELSE |
|---|
| 147 | CALL ldf_slp( kstp, rhd, rn2b ) ! before slope for Madec operator |
|---|
| 148 | ENDIF |
|---|
| 149 | ENDIF |
|---|
| 150 | #if defined key_traldf_c2d |
|---|
| 151 | IF( lk_traldf_eiv ) CALL ldf_eiv( kstp ) ! eddy induced velocity coefficient |
|---|
| 152 | #endif |
|---|
| 153 | #if defined key_traldf_c3d && key_traldf_smag |
|---|
| 154 | CALL ldf_tra_smag( kstp ) ! eddy induced velocity coefficient |
|---|
| 155 | # endif |
|---|
| 156 | #if defined key_dynldf_c3d && key_dynldf_smag |
|---|
| 157 | CALL ldf_dyn_smag( kstp ) ! eddy induced velocity coefficient |
|---|
| 158 | # endif |
|---|
| 159 | |
|---|
| 160 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 161 | ! Ocean dynamics : hdiv, rot, ssh, e3, wn |
|---|
| 162 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 163 | CALL ssh_nxt ( kstp ) ! after ssh (includes call to div_cur) |
|---|
| 164 | |
|---|
| 165 | IF( lk_dynspg_ts ) THEN |
|---|
| 166 | IF( lk_vvl ) CALL dom_vvl_sf_nxt( kstp ) ! after vertical scale factors |
|---|
| 167 | CALL wzv ( kstp ) ! now cross-level velocity |
|---|
| 168 | ! In case the time splitting case, update almost all momentum trends here: |
|---|
| 169 | ! Note that the computation of vertical velocity above, hence "after" sea level |
|---|
| 170 | ! is necessary to compute momentum advection for the rhs of barotropic loop: |
|---|
| 171 | CALL eos ( tsn, rhd, rhop, fsdept_n(:,:,:) ) ! now in situ density for hpg computation |
|---|
| 172 | IF( ln_zps ) CALL zps_hde( kstp, jpts, tsn, gtsu, gtsv, & ! zps: now hor. derivative |
|---|
| 173 | & rhd, gru , grv ) ! of t, s, rd at the last ocean level |
|---|
| 174 | |
|---|
| 175 | ua(:,:,:) = 0.e0 ! set dynamics trends to zero |
|---|
| 176 | va(:,:,:) = 0.e0 |
|---|
| 177 | IF( ln_asmiau .AND. & |
|---|
| 178 | & ln_dyninc ) CALL dyn_asm_inc ( kstp ) ! apply dynamics assimilation increment |
|---|
| 179 | IF( ln_neptsimp ) CALL dyn_nept_cor ( kstp ) ! subtract Neptune velocities (simplified) |
|---|
| 180 | IF( lk_bdy ) CALL bdy_dyn3d_dmp( kstp ) ! bdy damping trends |
|---|
| 181 | CALL dyn_adv ( kstp ) ! advection (vector or flux form) |
|---|
| 182 | CALL dyn_vor ( kstp ) ! vorticity term including Coriolis |
|---|
| 183 | CALL dyn_ldf ( kstp ) ! lateral mixing |
|---|
| 184 | IF( ln_neptsimp ) CALL dyn_nept_cor ( kstp ) ! add Neptune velocities (simplified) |
|---|
| 185 | #if defined key_agrif |
|---|
| 186 | IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_dyn ! momentum sponge |
|---|
| 187 | #endif |
|---|
| 188 | CALL dyn_hpg( kstp ) ! horizontal gradient of Hydrostatic pressure |
|---|
| 189 | CALL dyn_spg( kstp, indic ) ! surface pressure gradient |
|---|
| 190 | |
|---|
| 191 | ua_sv(:,:,:) = ua(:,:,:) ! Save trends (barotropic trend has been fully updated at this stage) |
|---|
| 192 | va_sv(:,:,:) = va(:,:,:) |
|---|
| 193 | |
|---|
| 194 | CALL div_cur( kstp ) ! Horizontal divergence & Relative vorticity (2nd call in time-split case) |
|---|
| 195 | ENDIF |
|---|
| 196 | IF( lk_vvl ) CALL dom_vvl_sf_nxt( kstp, kcall=2 ) ! after vertical scale factors |
|---|
| 197 | CALL wzv ( kstp ) ! now cross-level velocity |
|---|
| 198 | |
|---|
| 199 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 200 | ! diagnostics and outputs (ua, va, tsa used as workspace) |
|---|
| 201 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 202 | IF( lk_floats ) CALL flo_stp( kstp ) ! drifting Floats |
|---|
| 203 | IF( lk_diahth ) CALL dia_hth( kstp ) ! Thermocline depth (20 degres isotherm depth) |
|---|
| 204 | IF( lk_diafwb ) CALL dia_fwb( kstp ) ! Fresh water budget diagnostics |
|---|
| 205 | IF( ln_diaptr ) CALL dia_ptr( kstp ) ! Poleward TRansports diagnostics |
|---|
| 206 | IF( lk_diadct ) CALL dia_dct( kstp ) ! Transports |
|---|
| 207 | IF( lk_diaar5 ) CALL dia_ar5( kstp ) ! ar5 diag |
|---|
| 208 | IF( lk_diaharm ) CALL dia_harm( kstp ) ! Tidal harmonic analysis |
|---|
| 209 | CALL dia_wri( kstp ) ! ocean model: outputs |
|---|
| 210 | ! |
|---|
| 211 | IF( ln_crs ) CALL crs_fld( kstp ) ! ocean model: online field coarsening & output |
|---|
| 212 | |
|---|
| 213 | |
|---|
| 214 | #if defined key_top |
|---|
| 215 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 216 | ! Passive Tracer Model |
|---|
| 217 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 218 | CALL trc_stp( kstp ) ! time-stepping |
|---|
| 219 | #endif |
|---|
| 220 | |
|---|
| 221 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 222 | ! Active tracers (ua, va used as workspace) |
|---|
| 223 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 224 | tsa(:,:,:,:) = 0.e0 ! set tracer trends to zero |
|---|
| 225 | |
|---|
| 226 | IF( ln_asmiau .AND. & |
|---|
| 227 | & ln_trainc ) CALL tra_asm_inc( kstp ) ! apply tracer assimilation increment |
|---|
| 228 | CALL tra_sbc ( kstp ) ! surface boundary condition |
|---|
| 229 | IF( ln_traqsr ) CALL tra_qsr ( kstp ) ! penetrative solar radiation qsr |
|---|
| 230 | IF( ln_trabbc ) CALL tra_bbc ( kstp ) ! bottom heat flux |
|---|
| 231 | IF( lk_trabbl ) CALL tra_bbl ( kstp ) ! advective (and/or diffusive) bottom boundary layer scheme |
|---|
| 232 | IF( ln_tradmp ) CALL tra_dmp ( kstp ) ! internal damping trends |
|---|
| 233 | IF( lk_bdy ) CALL bdy_tra_dmp( kstp ) ! bdy damping trends |
|---|
| 234 | CALL tra_adv ( kstp ) ! horizontal & vertical advection |
|---|
| 235 | IF( lk_zdfkpp ) CALL tra_kpp ( kstp ) ! KPP non-local tracer fluxes |
|---|
| 236 | CALL tra_ldf ( kstp ) ! lateral mixing |
|---|
| 237 | #if defined key_agrif |
|---|
| 238 | IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_tra ! tracers sponge |
|---|
| 239 | #endif |
|---|
| 240 | CALL tra_zdf ( kstp ) ! vertical mixing and after tracer fields |
|---|
| 241 | |
|---|
| 242 | IF( ln_dynhpg_imp ) THEN ! semi-implicit hpg (time stepping then eos) |
|---|
| 243 | IF( ln_zdfnpc ) CALL tra_npc( kstp ) ! update after fields by non-penetrative convection |
|---|
| 244 | CALL tra_nxt( kstp ) ! tracer fields at next time step |
|---|
| 245 | CALL eos ( tsa, rhd, rhop, fsdept_n(:,:,:) ) ! Time-filtered in situ density for hpg computation |
|---|
| 246 | IF( ln_zps ) CALL zps_hde( kstp, jpts, tsa, gtsu, gtsv, & ! zps: time filtered hor. derivative |
|---|
| 247 | & rhd, gru , grv ) ! of t, s, rd at the last ocean level |
|---|
| 248 | |
|---|
| 249 | ELSE ! centered hpg (eos then time stepping) |
|---|
| 250 | IF ( .NOT. lk_dynspg_ts ) THEN ! eos already called in time-split case |
|---|
| 251 | CALL eos ( tsn, rhd, rhop, fsdept_n(:,:,:) ) ! now in situ density for hpg computation |
|---|
| 252 | IF( ln_zps ) CALL zps_hde( kstp, jpts, tsn, gtsu, gtsv, & ! zps: now hor. derivative |
|---|
| 253 | & rhd, gru , grv ) ! of t, s, rd at the last ocean level |
|---|
| 254 | ENDIF |
|---|
| 255 | IF( ln_zdfnpc ) CALL tra_npc( kstp ) ! update after fields by non-penetrative convection |
|---|
| 256 | CALL tra_nxt( kstp ) ! tracer fields at next time step |
|---|
| 257 | ENDIF |
|---|
| 258 | |
|---|
| 259 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 260 | ! Dynamics (tsa used as workspace) |
|---|
| 261 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 262 | IF( lk_dynspg_ts ) THEN |
|---|
| 263 | ! revert to previously computed momentum tendencies |
|---|
| 264 | ! (not using ua, va as temporary arrays during tracers' update could avoid that) |
|---|
| 265 | ua(:,:,:) = ua_sv(:,:,:) |
|---|
| 266 | va(:,:,:) = va_sv(:,:,:) |
|---|
| 267 | ! Revert now divergence and rotational to previously computed ones |
|---|
| 268 | !(needed because of the time swap in div_cur, at the beginning of each time step) |
|---|
| 269 | hdivn(:,:,:) = hdivb(:,:,:) |
|---|
| 270 | rotn(:,:,:) = rotb(:,:,:) |
|---|
| 271 | |
|---|
| 272 | CALL dyn_bfr( kstp ) ! bottom friction |
|---|
| 273 | CALL dyn_zdf( kstp ) ! vertical diffusion |
|---|
| 274 | ELSE |
|---|
| 275 | ua(:,:,:) = 0.e0 ! set dynamics trends to zero |
|---|
| 276 | va(:,:,:) = 0.e0 |
|---|
| 277 | |
|---|
| 278 | IF( ln_asmiau .AND. & |
|---|
| 279 | & ln_dyninc ) CALL dyn_asm_inc( kstp ) ! apply dynamics assimilation increment |
|---|
| 280 | IF( ln_bkgwri ) CALL asm_bkg_wri( kstp ) ! output background fields |
|---|
| 281 | IF( ln_neptsimp ) CALL dyn_nept_cor( kstp ) ! subtract Neptune velocities (simplified) |
|---|
| 282 | IF( lk_bdy ) CALL bdy_dyn3d_dmp(kstp ) ! bdy damping trends |
|---|
| 283 | CALL dyn_adv( kstp ) ! advection (vector or flux form) |
|---|
| 284 | CALL dyn_vor( kstp ) ! vorticity term including Coriolis |
|---|
| 285 | CALL dyn_ldf( kstp ) ! lateral mixing |
|---|
| 286 | IF( ln_neptsimp ) CALL dyn_nept_cor( kstp ) ! add Neptune velocities (simplified) |
|---|
| 287 | #if defined key_agrif |
|---|
| 288 | IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_dyn ! momemtum sponge |
|---|
| 289 | #endif |
|---|
| 290 | CALL dyn_hpg( kstp ) ! horizontal gradient of Hydrostatic pressure |
|---|
| 291 | CALL dyn_bfr( kstp ) ! bottom friction |
|---|
| 292 | CALL dyn_zdf( kstp ) ! vertical diffusion |
|---|
| 293 | CALL dyn_spg( kstp, indic ) ! surface pressure gradient |
|---|
| 294 | ENDIF |
|---|
| 295 | CALL dyn_nxt( kstp ) ! lateral velocity at next time step |
|---|
| 296 | |
|---|
| 297 | CALL ssh_swp( kstp ) ! swap of sea surface height |
|---|
| 298 | IF( lk_vvl ) CALL dom_vvl_sf_swp( kstp ) ! swap of vertical scale factors |
|---|
| 299 | |
|---|
| 300 | IF( ln_diahsb ) CALL dia_hsb( kstp ) ! - ML - global conservation diagnostics |
|---|
| 301 | IF( lk_diaobs ) CALL dia_obs( kstp ) ! obs-minus-model (assimilation) diagnostics (call after dynamics update) |
|---|
| 302 | |
|---|
| 303 | IF( lrst_oce .AND. ln_diahsb ) CALL dia_hsb_rst( kstp, 'WRITE' ) |
|---|
| 304 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 305 | ! Control and restarts |
|---|
| 306 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 307 | CALL stp_ctl( kstp, indic ) |
|---|
| 308 | IF( indic < 0 ) THEN |
|---|
| 309 | CALL ctl_stop( 'step: indic < 0' ) |
|---|
| 310 | CALL dia_wri_state( 'output.abort', kstp ) |
|---|
| 311 | ENDIF |
|---|
| 312 | IF( kstp == nit000 ) THEN |
|---|
| 313 | CALL iom_close( numror ) ! close input ocean restart file |
|---|
| 314 | CALL FLUSH ( numond ) ! flush output namelist oce |
|---|
| 315 | CALL FLUSH ( numoni ) ! flush output namelist ice |
|---|
| 316 | ENDIF |
|---|
| 317 | IF( lrst_oce ) CALL rst_write ( kstp ) ! write output ocean restart file |
|---|
| 318 | |
|---|
| 319 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 320 | ! Trends (ua, va, tsa used as workspace) |
|---|
| 321 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 322 | IF( nstop == 0 ) THEN |
|---|
| 323 | IF( lk_trddyn ) CALL trd_dwr( kstp ) ! trends: dynamics |
|---|
| 324 | IF( lk_trdtra ) CALL trd_twr( kstp ) ! trends: active tracers |
|---|
| 325 | IF( lk_trdmld ) CALL trd_mld( kstp ) ! trends: Mixed-layer |
|---|
| 326 | IF( lk_trdvor ) CALL trd_vor( kstp ) ! trends: vorticity budget |
|---|
| 327 | ENDIF |
|---|
| 328 | |
|---|
| 329 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 330 | ! Coupled mode |
|---|
| 331 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 332 | IF( lk_cpl ) CALL sbc_cpl_snd( kstp ) ! coupled mode : field exchanges |
|---|
| 333 | ! |
|---|
| 334 | #if defined key_iomput |
|---|
| 335 | IF( kstp == nitend .OR. indic < 0 ) THEN |
|---|
| 336 | CALL iom_context_finalize( "nemo" ) ! needed for XIOS+AGRIF |
|---|
| 337 | IF( ln_crs ) CALL iom_context_finalize( "nemo_crs" ) ! |
|---|
| 338 | ENDIF |
|---|
| 339 | #endif |
|---|
| 340 | ! |
|---|
| 341 | IF( nn_timing == 1 .AND. kstp == nit000 ) CALL timing_reset |
|---|
| 342 | ! |
|---|
| 343 | END SUBROUTINE stp |
|---|
| 344 | |
|---|
| 345 | !!====================================================================== |
|---|
| 346 | END MODULE step |
|---|
