New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in branches/2013/dev_r3411_CNRS4_IOCRS/NEMOGCM/CONFIG/ORCA2_LIM_CRS/MY_SRC – NEMO

Context Navigation

source: branches/2013/dev_r3411_CNRS4_IOCRS/NEMOGCM/CONFIG/ORCA2_LIM_CRS/MY_SRC/nemogcm.F90 @ 3864

Last change on this file since 3864 was 3864, checked in by cetlod, 11 years ago
2013/dev_r3411_CNRS4_IOCRS : minor improvments
File size: 36.4 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) LIM sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!! 3.4 ! 2011-11 (C. Harris) decomposition changes for running with CICE
31	!! ! 2012-05 (J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32	!! ! 2012-07 - Add calls to crs_dia_wri
33	!!----------------------------------------------------------------------
34
35	!!----------------------------------------------------------------------
36	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
37	!! nemo_init : initialization of the NEMO system
38	!! nemo_ctl : initialisation of the contol print
39	!! nemo_closefile : close remaining open files
40	!! nemo_alloc : dynamical allocation
41	!! nemo_partition : calculate MPP domain decomposition
42	!! factorise : calculate the factors of the no. of MPI processes
43	!!----------------------------------------------------------------------
44	USE step_oce ! module used in the ocean time stepping module
45	USE sbc_oce ! surface boundary condition: ocean
46	USE cla ! cross land advection (tra_cla routine)
47	USE domcfg ! domain configuration (dom_cfg routine)
48	USE mppini ! shared/distributed memory setting (mpp_init routine)
49	USE domain ! domain initialization (dom_init routine)
50	USE obcini ! open boundary cond. initialization (obc_ini routine)
51	USE bdyini ! open boundary cond. initialization (bdy_init routine)
52	USE bdydta ! open boundary cond. initialization (bdy_dta_init routine)
53	USE bdytides ! open boundary cond. initialization (tide_init routine)
54	USE istate ! initial state setting (istate_init routine)
55	USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine)
56	USE ldftra ! lateral diffusivity setting (ldftra_init routine)
57	USE zdfini ! vertical physics setting (zdf_init routine)
58	USE phycst ! physical constant (par_cst routine)
59	USE trdmod ! momentum/tracers trends (trd_mod_init routine)
60	USE asmtrj ! writing out state trajectory
61	USE diaptr ! poleward transports (dia_ptr_init routine)
62	USE diadct ! sections transports (dia_dct_init routine)
63	USE diaobs ! Observation diagnostics (dia_obs_init routine)
64	USE step ! NEMO time-stepping (stp routine)
65	#if defined key_oasis3
66	USE cpl_oasis3 ! OASIS3 coupling
67	#elif defined key_oasis4
68	USE cpl_oasis4 ! OASIS4 coupling (not working)
69	#endif
70	USE c1d ! 1D configuration
71	USE step_c1d ! Time stepping loop for the 1D configuration
72	#if defined key_top
73	USE trcini ! passive tracer initialisation
74	#endif
75	USE lib_mpp ! distributed memory computing
76	#if defined key_iomput
77	USE mod_ioclient
78	#endif
79	USE crsini ! initialise grid coarsening utility
80
81	IMPLICIT NONE
82	PRIVATE
83
84	PUBLIC nemo_gcm ! called by model.F90
85	PUBLIC nemo_init ! needed by AGRIF
86
87	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
88
89	!!----------------------------------------------------------------------
90	!! NEMO/OPA 4.0 , NEMO Consortium (2011)
91	!! $Id: nemogcm.F90 3352 2012-04-11 12:56:01Z rblod $
92	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
93	!!----------------------------------------------------------------------
94	CONTAINS
95
96	SUBROUTINE nemo_gcm
97	!!----------------------------------------------------------------------
98	!! * ROUTINE nemo_gcm *
99	!!
100	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
101	!! curvilinear mesh on the sphere.
102	!!
103	!! ** Method : - model general initialization
104	!! - launch the time-stepping (stp routine)
105	!! - finalize the run by closing files and communications
106	!!
107	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
108	!! Madec, 2008, internal report, IPSL.
109	!!----------------------------------------------------------------------
110	INTEGER :: istp ! time step index
111	!!----------------------------------------------------------------------
112	!
113	#if defined key_agrif
114	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
115	#endif
116
117	! !-----------------------!
118	CALL nemo_init !== Initialisations ==!
119	! !-----------------------!
120	#if defined key_agrif
121	CALL Agrif_Declare_Var ! AGRIF: set the meshes
122	# if defined key_top
123	CALL Agrif_Declare_Var_Top ! AGRIF: set the meshes
124	# endif
125	#endif
126	! check that all process are still there... If some process have an error,
127	! they will never enter in step and other processes will wait until the end of the cpu time!
128	IF( lk_mpp ) CALL mpp_max( nstop )
129
130	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
131
132	! !-----------------------!
133	! !== time stepping ==!
134	! !-----------------------!
135	istp = nit000
136	#if defined key_c1d
137	DO WHILE ( istp <= nitend .AND. nstop == 0 )
138	CALL stp_c1d( istp )
139	istp = istp + 1
140	END DO
141	#else
142	IF( lk_asminc ) THEN
143	IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 ) ! Output background fields
144	IF( ln_trjwri ) CALL asm_trj_wri( nit000 - 1 ) ! Output trajectory fields
145	IF( ln_asmdin ) THEN ! Direct initialization
146	IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 ) ! Tracers
147	IF( ln_dyninc ) THEN
148	CALL dyn_asm_inc( nit000 - 1 ) ! Dynamics
149	IF ( ln_asmdin ) CALL ssh_wzv ( nit000 - 1 ) ! update vertical velocity
150	ENDIF
151	IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 ) ! SSH
152	ENDIF
153	ENDIF
154
155	DO WHILE ( istp <= nitend .AND. nstop == 0 )
156	#if defined key_agrif
157	CALL Agrif_Step( stp ) ! AGRIF: time stepping
158	#else
159	CALL stp( istp ) ! standard time stepping
160	#endif
161	istp = istp + 1
162	IF( lk_mpp ) CALL mpp_max( nstop )
163	END DO
164	#endif
165
166	IF( lk_diaobs ) CALL dia_obs_wri
167
168	! !------------------------!
169	! !== finalize the run ==!
170	! !------------------------!
171	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
172	!
173	IF( nstop /= 0 .AND. lwp ) THEN ! error print
174	WRITE(numout,cform_err)
175	WRITE(numout,*) nstop, ' error have been found'
176	ENDIF
177	!
178	#if defined key_agrif
179	CALL Agrif_ParentGrid_To_ChildGrid()
180	IF( lk_diaobs ) CALL dia_obs_wri
181	IF( nn_timing == 1 ) CALL timing_finalize
182	CALL Agrif_ChildGrid_To_ParentGrid()
183	#endif
184	IF( nn_timing == 1 ) CALL timing_finalize
185	!
186	CALL nemo_closefile
187	#if defined key_oasis3 \|\| defined key_oasis4
188	CALL cpl_prism_finalize ! end coupling and mpp communications with OASIS
189	#else
190	IF( lk_mpp ) CALL mppstop ! end mpp communications
191	#endif
192	!
193	END SUBROUTINE nemo_gcm
194
195
196	SUBROUTINE nemo_init
197	!!----------------------------------------------------------------------
198	!! * ROUTINE nemo_init *
199	!!
200	!! ** Purpose : initialization of the NEMO GCM
201	!!----------------------------------------------------------------------
202	INTEGER :: ji ! dummy loop indices
203	INTEGER :: ilocal_comm ! local integer
204	CHARACTER(len=80), DIMENSION(16) :: cltxt
205	!!
206	NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, &
207	& nn_isplt, nn_jsplt, nn_jctls, nn_jctle, &
208	& nn_bench, nn_timing
209	!!----------------------------------------------------------------------
210	!
211	!
212	cltxt = ''
213	!
214	! ! open Namelist file
215	CALL ctl_opn( numnam, 'namelist', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
216	!
217	READ( numnam, namctl ) ! Namelist namctl : Control prints & Benchmark
218	!
219	! !--------------------------------------------!
220	! ! set communicator & select the local node !
221	! !--------------------------------------------!
222	#if defined key_iomput
223	IF( Agrif_Root() ) THEN
224	# if defined key_oasis3 \|\| defined key_oasis4
225	CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis
226	# endif
227	CALL init_ioclient( ilocal_comm ) ! exchange io_server nemo local communicator with the io_server
228	ENDIF
229	narea = mynode( cltxt, numnam, nstop, ilocal_comm ) ! Nodes selection
230	#else
231	# if defined key_oasis3 \|\| defined key_oasis4
232	IF( Agrif_Root() ) THEN
233	CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis
234	ENDIF
235	narea = mynode( cltxt, numnam, nstop, ilocal_comm ) ! Nodes selection (control print return in cltxt)
236	# else
237	ilocal_comm = 0
238	narea = mynode( cltxt, numnam, nstop ) ! Nodes selection (control print return in cltxt)
239	# endif
240	#endif
241	narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 )
242
243	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
244
245	! If dimensions of processor grid weren't specified in the namelist file
246	! then we calculate them here now that we have our communicator size
247	IF( (jpni < 1) .OR. (jpnj < 1) )THEN
248	#if defined key_mpp_mpi
249	IF( Agrif_Root() ) CALL nemo_partition(mppsize)
250	#else
251	jpni = 1
252	jpnj = 1
253	jpnij = jpni*jpnj
254	#endif
255	END IF
256
257	! Calculate domain dimensions given calculated jpni and jpnj
258	! This used to be done in par_oce.F90 when they were parameters rather
259	! than variables
260	IF( Agrif_Root() ) THEN
261	jpi = ( jpiglo-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
262	#if defined key_nemocice_decomp
263	jpj = ( jpjglo+1-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
264	#else
265	jpj = ( jpjglo-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
266	#endif
267	jpk = jpkdta ! third dim
268	jpim1 = jpi-1 ! inner domain indices
269	jpjm1 = jpj-1 ! " "
270	jpkm1 = jpk-1 ! " "
271	jpij = jpi*jpj ! jpi x j
272	ENDIF
273
274	IF(lwp) THEN ! open listing units
275	!
276	CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
277	!
278	WRITE(numout,*)
279	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
280	WRITE(numout,*) ' NEMO team'
281	WRITE(numout,*) ' Ocean General Circulation Model'
282	WRITE(numout,*) ' version 3.4 (2011) '
283	WRITE(numout,*)
284	WRITE(numout,*)
285	DO ji = 1, SIZE(cltxt)
286	IF( TRIM(cltxt(ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode
287	END DO
288	WRITE(numout,cform_aaa) ! Flag AAAAAAA
289	!
290	ENDIF
291
292	! Now we know the dimensions of the grid and numout has been set we can
293	! allocate arrays
294	CALL nemo_alloc()
295
296	! !-------------------------------!
297	! ! NEMO general initialization !
298	! !-------------------------------!
299
300	CALL nemo_ctl ! Control prints & Benchmark
301
302	! ! Domain decomposition
303	IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out
304	ELSE ; CALL mpp_init2 ! eliminate land processors
305	ENDIF
306
307
308	!
309	IF( nn_timing == 1 ) CALL timing_init
310	!
311	! ! General initialization
312	CALL phy_cst ! Physical constants
313	CALL eos_init ! Equation of state
314	CALL dom_cfg ! Domain configuration
315	CALL dom_init ! Domain
316
317	IF( ln_nnogather ) CALL nemo_northcomms ! Initialise the northfold neighbour lists (must be done after the masks are defined)
318
319	IF( ln_ctl ) CALL prt_ctl_init ! Print control
320
321	IF( lk_obc ) CALL obc_init ! Open boundaries
322	IF( lk_bdy ) CALL bdy_init ! Open boundaries initialisation
323	IF( lk_bdy ) CALL bdy_dta_init ! Open boundaries initialisation of external data arrays
324	IF( lk_bdy ) CALL tide_init ! Open boundaries initialisation of tidal harmonic forcing
325
326	CALL flush(numout)
327	CALL dyn_nept_init ! simplified form of Neptune effect
328	CALL flush(numout)
329
330	CALL istate_init ! ocean initial state (Dynamics and tracers)
331
332	! ! Grid coarsening
333	IF( ln_crs ) CALL crs_init ! Domain initialization of coarsened grid
334	! Ocean physics
335	CALL sbc_init ! Forcings : surface module
336
337	! ! Vertical physics
338	CALL zdf_init ! namelist read
339	CALL zdf_bfr_init ! bottom friction
340	IF( lk_zdfric ) CALL zdf_ric_init ! Richardson number dependent Kz
341	IF( lk_zdftke ) CALL zdf_tke_init ! TKE closure scheme
342	IF( lk_zdfgls ) CALL zdf_gls_init ! GLS closure scheme
343	IF( lk_zdfkpp ) CALL zdf_kpp_init ! KPP closure scheme
344	IF( lk_zdftmx ) CALL zdf_tmx_init ! tidal vertical mixing
345	IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) &
346	& CALL zdf_ddm_init ! double diffusive mixing
347	! ! Lateral physics
348	CALL ldf_tra_init ! Lateral ocean tracer physics
349	CALL ldf_dyn_init ! Lateral ocean momentum physics
350	IF( lk_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
351	!jes IF( lk_ldfslp .AND. ln_crs ) CALL ldf_slp_init( ld_crs = .TRUE. ) ! slope of lateral mixing
352
353	! ! Active tracers
354	CALL tra_qsr_init ! penetrative solar radiation qsr
355	CALL tra_bbc_init ! bottom heat flux
356	IF( lk_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
357	IF( ln_tradmp ) CALL tra_dmp_init ! internal damping trends
358	CALL tra_adv_init ! horizontal & vertical advection
359	CALL tra_ldf_init ! lateral mixing
360	CALL tra_zdf_init ! vertical mixing and after tracer fields
361
362	! ! Dynamics
363	CALL dyn_adv_init ! advection (vector or flux form)
364	CALL dyn_vor_init ! vorticity term including Coriolis
365	CALL dyn_ldf_init ! lateral mixing
366	CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure
367	CALL dyn_zdf_init ! vertical diffusion
368	CALL dyn_spg_init ! surface pressure gradient
369	! ! Misc. options
370	IF( nn_cla == 1 ) CALL cla_init ! Cross Land Advection
371
372	#if defined key_top
373	! ! Passive tracers
374	CALL trc_init
375	#endif
376	! ! Diagnostics
377	IF( lk_floats ) CALL flo_init ! drifting Floats
378	CALL iom_init ! iom_put initialization
379	IF( lk_diaar5 ) CALL dia_ar5_init ! ar5 diag
380	CALL dia_ptr_init ! Poleward TRansports initialization
381	IF( lk_diadct ) CALL dia_dct_init ! Sections tranports
382	CALL dia_hsb_init ! heat content, salt content and volume budgets
383	CALL trd_mod_init ! Mixed-layer/Vorticity/Integral constraints trends
384	IF( lk_diaobs ) THEN ! Observation & model comparison
385	CALL dia_obs_init ! Initialize observational data
386	CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
387	ENDIF
388	! ! Assimilation increments
389	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
390	IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
391	!
392	END SUBROUTINE nemo_init
393
394
395	SUBROUTINE nemo_ctl
396	!!----------------------------------------------------------------------
397	!! * ROUTINE nemo_ctl *
398	!!
399	!! ** Purpose : control print setting
400	!!
401	!! ** Method : - print namctl information and check some consistencies
402	!!----------------------------------------------------------------------
403	!
404	IF(lwp) THEN ! control print
405	WRITE(numout,*)
406	WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
407	WRITE(numout,*) '~~~~~~~ '
408	WRITE(numout,*) ' Namelist namctl'
409	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
410	WRITE(numout,*) ' level of print nn_print = ', nn_print
411	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
412	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
413	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
414	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
415	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
416	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
417	WRITE(numout,*) ' benchmark parameter (0/1) nn_bench = ', nn_bench
418	WRITE(numout,*) ' timing activated (0/1) nn_timing = ', nn_timing
419	ENDIF
420	!
421	nprint = nn_print ! convert DOCTOR namelist names into OLD names
422	nictls = nn_ictls
423	nictle = nn_ictle
424	njctls = nn_jctls
425	njctle = nn_jctle
426	isplt = nn_isplt
427	jsplt = nn_jsplt
428	nbench = nn_bench
429	! ! Parameter control
430	!
431	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
432	IF( lk_mpp .AND. jpnij > 1 ) THEN
433	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
434	ELSE
435	IF( isplt == 1 .AND. jsplt == 1 ) THEN
436	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
437	& ' - the print control will be done over the whole domain' )
438	ENDIF
439	ijsplt = isplt * jsplt ! total number of processors ijsplt
440	ENDIF
441	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
442	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
443	!
444	! ! indices used for the SUM control
445	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
446	lsp_area = .FALSE.
447	ELSE ! print control done over a specific area
448	lsp_area = .TRUE.
449	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
450	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
451	nictls = 1
452	ENDIF
453	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
454	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
455	nictle = jpiglo
456	ENDIF
457	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
458	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
459	njctls = 1
460	ENDIF
461	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
462	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
463	njctle = jpjglo
464	ENDIF
465	ENDIF
466	ENDIF
467	!
468	IF( nbench == 1 ) THEN ! Benchmark
469	SELECT CASE ( cp_cfg )
470	CASE ( 'gyre' ) ; CALL ctl_warn( ' The Benchmark is activated ' )
471	CASE DEFAULT ; CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:', &
472	& ' key_gyre must be used or set nbench = 0' )
473	END SELECT
474	ENDIF
475	!
476	IF( lk_c1d .AND. .NOT.lk_iomput ) CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ', &
477	& 'with the IOM Input/Output manager. ' , &
478	& 'Compile with key_iomput enabled' )
479	!
480	END SUBROUTINE nemo_ctl
481
482
483	SUBROUTINE nemo_closefile
484	!!----------------------------------------------------------------------
485	!! * ROUTINE nemo_closefile *
486	!!
487	!! ** Purpose : Close the files
488	!!----------------------------------------------------------------------
489	!
490	IF( lk_mpp ) CALL mppsync
491	!
492	CALL iom_close ! close all input/output files managed by iom_*
493	!
494	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
495	IF( numsol /= -1 ) CLOSE( numsol ) ! solver file
496	IF( numnam /= -1 ) CLOSE( numnam ) ! oce namelist
497	IF( numnam_ice /= -1 ) CLOSE( numnam_ice ) ! ice namelist
498	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
499	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
500	IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports
501	IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports
502	IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports
503
504	!
505	numout = 6 ! redefine numout in case it is used after this point...
506	!
507	END SUBROUTINE nemo_closefile
508
509
510	SUBROUTINE nemo_alloc
511	!!----------------------------------------------------------------------
512	!! * ROUTINE nemo_alloc *
513	!!
514	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
515	!!
516	!! ** Method :
517	!!----------------------------------------------------------------------
518	USE diawri , ONLY: dia_wri_alloc
519	USE dom_oce , ONLY: dom_oce_alloc
520	USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
521	USE ldftra_oce, ONLY: ldftra_oce_alloc
522	USE trc_oce , ONLY: trc_oce_alloc
523	!
524	INTEGER :: ierr
525	!!----------------------------------------------------------------------
526	!
527	ierr = oce_alloc () ! ocean
528	ierr = ierr + dia_wri_alloc ()
529	ierr = ierr + dom_oce_alloc () ! ocean domain
530	ierr = ierr + ldfdyn_oce_alloc() ! ocean lateral physics : dynamics
531	ierr = ierr + ldftra_oce_alloc() ! ocean lateral physics : tracers
532	ierr = ierr + zdf_oce_alloc () ! ocean vertical physics
533	!
534	ierr = ierr + trc_oce_alloc () ! shared TRC / TRA arrays
535	!
536	IF( lk_mpp ) CALL mpp_sum( ierr )
537	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
538	!
539	END SUBROUTINE nemo_alloc
540
541
542	SUBROUTINE nemo_partition( num_pes )
543	!!----------------------------------------------------------------------
544	!! * ROUTINE nemo_partition *
545	!!
546	!! ** Purpose :
547	!!
548	!! ** Method :
549	!!----------------------------------------------------------------------
550	INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
551	!
552	INTEGER, PARAMETER :: nfactmax = 20
553	INTEGER :: nfact ! The no. of factors returned
554	INTEGER :: ierr ! Error flag
555	INTEGER :: ji
556	INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
557	INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
558	!!----------------------------------------------------------------------
559
560	ierr = 0
561
562	CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
563
564	IF( nfact <= 1 ) THEN
565	WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
566	WRITE (numout, *) ' : using grid of ',num_pes,' x 1'
567	jpnj = 1
568	jpni = num_pes
569	ELSE
570	! Search through factors for the pair that are closest in value
571	mindiff = 1000000
572	imin = 1
573	DO ji = 1, nfact-1, 2
574	idiff = ABS( ifact(ji) - ifact(ji+1) )
575	IF( idiff < mindiff ) THEN
576	mindiff = idiff
577	imin = ji
578	ENDIF
579	END DO
580	jpnj = ifact(imin)
581	jpni = ifact(imin + 1)
582	ENDIF
583	!
584	jpnij = jpni*jpnj
585	!
586	END SUBROUTINE nemo_partition
587
588
589	SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
590	!!----------------------------------------------------------------------
591	!! * ROUTINE factorise *
592	!!
593	!! ** Purpose : return the prime factors of n.
594	!! knfax factors are returned in array kfax which is of
595	!! maximum dimension kmaxfax.
596	!! ** Method :
597	!!----------------------------------------------------------------------
598	INTEGER , INTENT(in ) :: kn, kmaxfax
599	INTEGER , INTENT( out) :: kerr, knfax
600	INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax
601	!
602	INTEGER :: ifac, jl, inu
603	INTEGER, PARAMETER :: ntest = 14
604	INTEGER :: ilfax(ntest)
605
606	! lfax contains the set of allowed factors.
607	data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256, &
608	& 128, 64, 32, 16, 8, 4, 2 /
609	!!----------------------------------------------------------------------
610
611	! Clear the error flag and initialise output vars
612	kerr = 0
613	kfax = 1
614	knfax = 0
615
616	! Find the factors of n.
617	IF( kn == 1 ) GOTO 20
618
619	! nu holds the unfactorised part of the number.
620	! knfax holds the number of factors found.
621	! l points to the allowed factor list.
622	! ifac holds the current factor.
623
624	inu = kn
625	knfax = 0
626
627	DO jl = ntest, 1, -1
628	!
629	ifac = ilfax(jl)
630	IF( ifac > inu ) CYCLE
631
632	! Test whether the factor will divide.
633
634	IF( MOD(inu,ifac) == 0 ) THEN
635	!
636	knfax = knfax + 1 ! Add the factor to the list
637	IF( knfax > kmaxfax ) THEN
638	kerr = 6
639	write (,) 'FACTOR: insufficient space in factor array ', knfax
640	return
641	ENDIF
642	kfax(knfax) = ifac
643	! Store the other factor that goes with this one
644	knfax = knfax + 1
645	kfax(knfax) = inu / ifac
646	!WRITE (,) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
647	ENDIF
648	!
649	END DO
650
651	20 CONTINUE ! Label 20 is the exit point from the factor search loop.
652	!
653	END SUBROUTINE factorise
654
655	#if defined key_mpp_mpi
656	SUBROUTINE nemo_northcomms
657	!!======================================================================
658	!! * ROUTINE nemo_northcomms *
659	!! nemo_northcomms : Setup for north fold exchanges with explicit peer to peer messaging
660	!!=====================================================================
661	!!----------------------------------------------------------------------
662	!!
663	!! ** Purpose : Initialization of the northern neighbours lists.
664	!!----------------------------------------------------------------------
665	!! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE)
666	!!----------------------------------------------------------------------
667
668	INTEGER :: ji, jj, jk, ij, jtyp ! dummy loop indices
669	INTEGER :: ijpj ! number of rows involved in north-fold exchange
670	INTEGER :: northcomms_alloc ! allocate return status
671	REAL(wp), ALLOCATABLE, DIMENSION ( :,: ) :: znnbrs ! workspace
672	LOGICAL, ALLOCATABLE, DIMENSION ( : ) :: lrankset ! workspace
673
674	IF(lwp) WRITE(numout,*)
675	IF(lwp) WRITE(numout,*) 'nemo_northcomms : Initialization of the northern neighbours lists'
676	IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
677
678	!!----------------------------------------------------------------------
679	ALLOCATE( znnbrs(jpi,jpj), stat = northcomms_alloc )
680	ALLOCATE( lrankset(jpnij), stat = northcomms_alloc )
681	IF( northcomms_alloc /= 0 ) THEN
682	WRITE(numout,cform_war)
683	WRITE(numout,*) 'northcomms_alloc : failed to allocate arrays'
684	CALL ctl_stop( 'STOP', 'nemo_northcomms : unable to allocate temporary arrays' )
685	ENDIF
686	nsndto = 0
687	isendto = -1
688	ijpj = 4
689	!
690	! This routine has been called because ln_nnogather has been set true ( nammpp )
691	! However, these first few exchanges have to use the mpi_allgather method to
692	! establish the neighbour lists to use in subsequent peer to peer exchanges.
693	! Consequently, set l_north_nogather to be false here and set it true only after
694	! the lists have been established.
695	!
696	l_north_nogather = .FALSE.
697	!
698	! Exchange and store ranks on northern rows
699
700	DO jtyp = 1,4
701
702	lrankset = .FALSE.
703	znnbrs = narea
704	SELECT CASE (jtyp)
705	CASE(1)
706	CALL lbc_lnk( znnbrs, 'T', 1. ) ! Type 1: T,W-points
707	CASE(2)
708	CALL lbc_lnk( znnbrs, 'U', 1. ) ! Type 2: U-point
709	CASE(3)
710	CALL lbc_lnk( znnbrs, 'V', 1. ) ! Type 3: V-point
711	CASE(4)
712	CALL lbc_lnk( znnbrs, 'F', 1. ) ! Type 4: F-point
713	END SELECT
714
715	IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
716	DO jj = nlcj-ijpj+1, nlcj
717	ij = jj - nlcj + ijpj
718	DO ji = 1,jpi
719	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
720	& lrankset(INT(znnbrs(ji,jj))) = .true.
721	END DO
722	END DO
723
724	DO jj = 1,jpnij
725	IF ( lrankset(jj) ) THEN
726	nsndto(jtyp) = nsndto(jtyp) + 1
727	IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
728	CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
729	& ' jpmaxngh will need to be increased ')
730	ENDIF
731	isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank
732	ENDIF
733	END DO
734	ENDIF
735
736	END DO
737
738	!
739	! Type 5: I-point
740	!
741	! ICE point exchanges may involve some averaging. The neighbours list is
742	! built up using two exchanges to ensure that the whole stencil is covered.
743	! lrankset should not be reset between these 'J' and 'K' point exchanges
744
745	jtyp = 5
746	lrankset = .FALSE.
747	znnbrs = narea
748	CALL lbc_lnk( znnbrs, 'J', 1. ) ! first ice U-V point
749
750	IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
751	DO jj = nlcj-ijpj+1, nlcj
752	ij = jj - nlcj + ijpj
753	DO ji = 1,jpi
754	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
755	& lrankset(INT(znnbrs(ji,jj))) = .true.
756	END DO
757	END DO
758	ENDIF
759
760	znnbrs = narea
761	CALL lbc_lnk( znnbrs, 'K', 1. ) ! second ice U-V point
762
763	IF ( njmppt(narea) .EQ. MAXVAL( njmppt )) THEN
764	DO jj = nlcj-ijpj+1, nlcj
765	ij = jj - nlcj + ijpj
766	DO ji = 1,jpi
767	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
768	& lrankset( INT(znnbrs(ji,jj))) = .true.
769	END DO
770	END DO
771
772	DO jj = 1,jpnij
773	IF ( lrankset(jj) ) THEN
774	nsndto(jtyp) = nsndto(jtyp) + 1
775	IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
776	CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
777	& ' jpmaxngh will need to be increased ')
778	ENDIF
779	isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank
780	ENDIF
781	END DO
782	!
783	! For northern row areas, set l_north_nogather so that all subsequent exchanges
784	! can use peer to peer communications at the north fold
785	!
786	l_north_nogather = .TRUE.
787	!
788	ENDIF
789	DEALLOCATE( znnbrs )
790	DEALLOCATE( lrankset )
791
792	END SUBROUTINE nemo_northcomms
793	#else
794	SUBROUTINE nemo_northcomms ! Dummy routine
795	WRITE(,) 'nemo_northcomms: You should not have seen this print! error?'
796	END SUBROUTINE nemo_northcomms
797	#endif
798	!!======================================================================
799	END MODULE nemogcm

Note: See TracBrowser for help on using the repository browser.

Download in other formats: