New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diaptr.F90 in branches/2013/dev_r3858_NOC_ZTC/NEMOGCM/NEMO/OPA_SRC/DIA – NEMO

source: branches/2013/dev_r3858_NOC_ZTC/NEMOGCM/NEMO/OPA_SRC/DIA/diaptr.F90 @ 3865

Last change on this file since 3865 was 3865, checked in by acc, 11 years ago

Branch 2013/dev_r3858_NOC_ZTC, #863. Nearly complete port of 2011/dev_r2739_LOCEAN8_ZTC development branch into v3.5aplha base. Compiles and runs but currently unstable after 8 timesteps with ORCA2_LIM reference configuration.
  • Property svn:keywords set to Id
File size: 43.2 KB
Line 
1MODULE diaptr
2   !!======================================================================
3   !!                       ***  MODULE  diaptr  ***
4   !! Ocean physics:  Computes meridonal transports and zonal means
5   !!=====================================================================
6   !! History :  1.0  ! 2003-09  (C. Talandier, G. Madec)  Original code
7   !!            2.0  ! 2006-01  (A. Biastoch)  Allow sub-basins computation
8   !!            3.2  ! 2010-03  (O. Marti, S. Flavoni) Add fields
9   !!            3.3  ! 2010-10  (G. Madec)  dynamical allocation
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   dia_ptr      : Poleward Transport Diagnostics module
14   !!   dia_ptr_init : Initialization, namelist read
15   !!   dia_ptr_wri  : Output of poleward fluxes
16   !!   ptr_vjk      : "zonal" sum computation of a "meridional" flux array
17   !!   ptr_tjk      : "zonal" mean computation of a tracer field
18   !!   ptr_vj       : "zonal" and vertical sum computation of a "meridional" flux array
19   !!                   (Generic interface to ptr_vj_3d, ptr_vj_2d)
20   !!----------------------------------------------------------------------
21   USE oce              ! ocean dynamics and active tracers
22   USE dom_oce          ! ocean space and time domain
23   USE phycst           ! physical constants
24   USE ldftra_oce       ! ocean active tracers: lateral physics
25   USE dianam           !
26   USE iom              ! IOM library
27   USE ioipsl           ! IO-IPSL library
28   USE in_out_manager   ! I/O manager
29   USE lib_mpp          ! MPP library
30   USE lbclnk           ! lateral boundary condition - processor exchanges
31   USE timing           ! preformance summary
32   USE wrk_nemo         ! working arrays
33
34   IMPLICIT NONE
35   PRIVATE
36
37   INTERFACE ptr_vj
38      MODULE PROCEDURE ptr_vj_3d, ptr_vj_2d
39   END INTERFACE
40
41   PUBLIC   dia_ptr_init   ! call in opa module
42   PUBLIC   dia_ptr        ! call in step module
43   PUBLIC   ptr_vj         ! call by tra_ldf & tra_adv routines
44   PUBLIC   ptr_vjk        ! call by tra_ldf & tra_adv routines
45
46   !                                           !!** namelist  namptr  **
47   LOGICAL , PUBLIC ::   ln_diaptr  = .FALSE.   !: Poleward transport flag (T) or not (F)
48   LOGICAL , PUBLIC ::   ln_subbas  = .FALSE.   !: Atlantic/Pacific/Indian basins calculation
49   LOGICAL , PUBLIC ::   ln_diaznl  = .FALSE.   !: Add zonal means and meridional stream functions
50   LOGICAL , PUBLIC ::   ln_ptrcomp = .FALSE.   !: Add decomposition : overturning (and gyre, soon ...)
51   INTEGER , PUBLIC ::   nn_fptr    = 15        !: frequency of ptr computation  [time step]
52   INTEGER , PUBLIC ::   nn_fwri    = 15        !: frequency of ptr outputs      [time step]
53
54   REAL(wp), ALLOCATABLE, SAVE, PUBLIC, DIMENSION(:) ::   htr_adv, htr_ldf, htr_ove   !: Heat TRansports (adv, diff, overturn.)
55   REAL(wp), ALLOCATABLE, SAVE, PUBLIC, DIMENSION(:) ::   str_adv, str_ldf, str_ove   !: Salt TRansports (adv, diff, overturn.)
56   
57   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   btmsk                  ! T-point basin interior masks
58   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   btm30                  ! mask out Southern Ocean (=0 south of 30°S)
59   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   htr  , str             ! adv heat and salt transports (approx)
60   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   tn_jk, sn_jk , v_msf   ! i-mean T and S, j-Stream-Function
61   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sjk  , r1_sjk          ! i-mean i-k-surface and its inverse       
62   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   htr_eiv, str_eiv       ! bolus adv heat ans salt transports ('key_diaeiv')
63   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   v_msf_eiv              ! bolus j-streamfuction              ('key_diaeiv')
64
65
66   INTEGER ::   niter       !
67   INTEGER ::   nidom_ptr   !
68   INTEGER ::   numptr      ! logical unit for Poleward TRansports
69   INTEGER ::   nptr        ! = 1 (ln_subbas=F) or = 5 (glo, atl, pac, ind, ipc) (ln_subbas=T)
70
71   REAL(wp) ::   rc_sv    = 1.e-6_wp   ! conversion from m3/s to Sverdrup
72   REAL(wp) ::   rc_pwatt = 1.e-15_wp  ! conversion from W    to PW (further x rau0 x Cp)
73   REAL(wp) ::   rc_ggram = 1.e-6_wp   ! conversion from g    to Pg
74
75   REAL(wp), TARGET, DIMENSION(:),   ALLOCATABLE, SAVE :: p_fval1d
76   REAL(wp), TARGET, DIMENSION(:,:), ALLOCATABLE, SAVE :: p_fval2d
77
78   !! Integer, 1D workspace arrays. Not common enough to be implemented in
79   !! wrk_nemo module.
80   INTEGER, ALLOCATABLE, SAVE, DIMENSION(:) :: ndex  , ndex_atl     , ndex_pac     , ndex_ind     , ndex_ipc
81   INTEGER, ALLOCATABLE, SAVE, DIMENSION(:) ::         ndex_atl_30  , ndex_pac_30  , ndex_ind_30  , ndex_ipc_30
82   INTEGER, ALLOCATABLE, SAVE, DIMENSION(:) :: ndex_h, ndex_h_atl_30, ndex_h_pac_30, ndex_h_ind_30, ndex_h_ipc_30
83
84   !! * Substitutions
85#  include "domzgr_substitute.h90"
86#  include "vectopt_loop_substitute.h90"
87   !!----------------------------------------------------------------------
88   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
89   !! $Id$
90   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
91   !!----------------------------------------------------------------------
92CONTAINS
93
94   FUNCTION dia_ptr_alloc()
95      !!----------------------------------------------------------------------
96      !!                    ***  ROUTINE dia_ptr_alloc  ***
97      !!----------------------------------------------------------------------
98      INTEGER               ::   dia_ptr_alloc   ! return value
99      INTEGER, DIMENSION(6) ::   ierr
100      !!----------------------------------------------------------------------
101      ierr(:) = 0
102      !
103      ALLOCATE( btmsk(jpi,jpj,nptr) ,           &
104         &      htr_adv(jpj) , str_adv(jpj) ,   &
105         &      htr_ldf(jpj) , str_ldf(jpj) ,   &
106         &      htr_ove(jpj) , str_ove(jpj),    &
107         &      htr(jpj,nptr) , str(jpj,nptr) , &
108         &      tn_jk(jpj,jpk,nptr) , sn_jk (jpj,jpk,nptr) , v_msf(jpj,jpk,nptr) , &
109         &      sjk  (jpj,jpk,nptr) , r1_sjk(jpj,jpk,nptr) , STAT=ierr(1)  )
110         !
111#if defined key_diaeiv
112      ALLOCATE( htr_eiv(jpj,nptr) , str_eiv(jpj,nptr) , &
113         &      v_msf_eiv(jpj,jpk,nptr) , STAT=ierr(2) )
114#endif
115      ALLOCATE( p_fval1d(jpj), p_fval2d(jpj,jpk), Stat=ierr(3))
116      !
117      ALLOCATE(ndex(jpj*jpk),        ndex_atl(jpj*jpk), ndex_pac(jpj*jpk), &
118         &     ndex_ind(jpj*jpk),    ndex_ipc(jpj*jpk),                    &
119         &     ndex_atl_30(jpj*jpk), ndex_pac_30(jpj*jpk), Stat=ierr(4))
120
121      ALLOCATE(ndex_ind_30(jpj*jpk), ndex_ipc_30(jpj*jpk),                   &
122         &     ndex_h(jpj),          ndex_h_atl_30(jpj), ndex_h_pac_30(jpj), &
123         &     ndex_h_ind_30(jpj),   ndex_h_ipc_30(jpj), Stat=ierr(5) )
124         !
125     ALLOCATE( btm30(jpi,jpj) , STAT=ierr(6)  )
126         !
127      dia_ptr_alloc = MAXVAL( ierr )
128      IF(lk_mpp)   CALL mpp_sum( dia_ptr_alloc )
129      !
130   END FUNCTION dia_ptr_alloc
131
132
133   FUNCTION ptr_vj_3d( pva )   RESULT ( p_fval )
134      !!----------------------------------------------------------------------
135      !!                    ***  ROUTINE ptr_vj_3d  ***
136      !!
137      !! ** Purpose :   i-k sum computation of a j-flux array
138      !!
139      !! ** Method  : - i-k sum of pva using the interior 2D vmask (vmask_i).
140      !!              pva is supposed to be a masked flux (i.e. * vmask*e1v*e3v)
141      !!
142      !! ** Action  : - p_fval: i-k-mean poleward flux of pva
143      !!----------------------------------------------------------------------
144      REAL(wp) , INTENT(in), DIMENSION(jpi,jpj,jpk) ::   pva   ! mask flux array at V-point
145      !!
146      INTEGER                  ::   ji, jj, jk   ! dummy loop arguments
147      INTEGER                  ::   ijpj         ! ???
148      REAL(wp), POINTER, DIMENSION(:) :: p_fval  ! function value
149      !!--------------------------------------------------------------------
150      !
151      p_fval => p_fval1d
152
153      ijpj = jpj
154      p_fval(:) = 0._wp
155      DO jk = 1, jpkm1
156         DO jj = 2, jpjm1
157            DO ji = fs_2, fs_jpim1   ! Vector opt.
158               p_fval(jj) = p_fval(jj) + pva(ji,jj,jk) * tmask_i(ji,jj) 
159            END DO
160         END DO
161      END DO
162#if defined key_mpp_mpi
163      IF(lk_mpp)   CALL mpp_sum( p_fval, ijpj, ncomm_znl)
164#endif
165      !
166   END FUNCTION ptr_vj_3d
167
168
169   FUNCTION ptr_vj_2d( pva )   RESULT ( p_fval )
170      !!----------------------------------------------------------------------
171      !!                    ***  ROUTINE ptr_vj_2d  ***
172      !!
173      !! ** Purpose :   "zonal" and vertical sum computation of a i-flux array
174      !!
175      !! ** Method  : - i-k sum of pva using the interior 2D vmask (vmask_i).
176      !!      pva is supposed to be a masked flux (i.e. * vmask*e1v*e3v)
177      !!
178      !! ** Action  : - p_fval: i-k-mean poleward flux of pva
179      !!----------------------------------------------------------------------
180      IMPLICIT none
181      REAL(wp) , INTENT(in), DIMENSION(jpi,jpj) ::   pva   ! mask flux array at V-point
182      !!
183      INTEGER                  ::   ji,jj       ! dummy loop arguments
184      INTEGER                  ::   ijpj        ! ???
185      REAL(wp), POINTER, DIMENSION(:) :: p_fval ! function value
186      !!--------------------------------------------------------------------
187      !
188      p_fval => p_fval1d
189
190      ijpj = jpj
191      p_fval(:) = 0._wp
192      DO jj = 2, jpjm1
193         DO ji = nldi, nlei   ! No vector optimisation here. Better use a mask ?
194            p_fval(jj) = p_fval(jj) + pva(ji,jj) * tmask_i(ji,jj)
195         END DO
196      END DO
197#if defined key_mpp_mpi
198      CALL mpp_sum( p_fval, ijpj, ncomm_znl )
199#endif
200      !
201   END FUNCTION ptr_vj_2d
202
203
204   FUNCTION ptr_vjk( pva, pmsk )   RESULT ( p_fval )
205      !!----------------------------------------------------------------------
206      !!                    ***  ROUTINE ptr_vjk  ***
207      !!
208      !! ** Purpose :   i-sum computation of a j-velocity array
209      !!
210      !! ** Method  : - i-sum of pva using the interior 2D vmask (vmask_i).
211      !!              pva is supposed to be a masked flux (i.e. * vmask)
212      !!
213      !! ** Action  : - p_fval: i-mean poleward flux of pva
214      !!----------------------------------------------------------------------
215      !!
216      IMPLICIT none
217      REAL(wp) , INTENT(in), DIMENSION(jpi,jpj,jpk)           ::   pva    ! mask flux array at V-point
218      REAL(wp) , INTENT(in), DIMENSION(jpi,jpj)    , OPTIONAL ::   pmsk   ! Optional 2D basin mask
219      !!
220      INTEGER                           :: ji, jj, jk ! dummy loop arguments
221      REAL(wp), POINTER, DIMENSION(:,:) :: p_fval     ! return function value
222#if defined key_mpp_mpi
223      INTEGER, DIMENSION(1) ::   ish
224      INTEGER, DIMENSION(2) ::   ish2
225      INTEGER               ::   ijpjjpk
226#endif
227#if defined key_mpp_mpi
228      REAL(wp), POINTER, DIMENSION(:) ::   zwork    ! mask flux array at V-point
229#endif
230      !!--------------------------------------------------------------------
231      !
232#if defined key_mpp_mpi
233      ijpjjpk = jpj*jpk
234      CALL wrk_alloc( jpj*jpk, zwork )
235#endif
236
237      p_fval => p_fval2d
238
239      p_fval(:,:) = 0._wp
240      !
241      IF( PRESENT( pmsk ) ) THEN
242         DO jk = 1, jpkm1
243            DO jj = 2, jpjm1
244!!gm here, use of tmask_i  ==> no need of loop over nldi, nlei....
245               DO ji =  nldi, nlei   ! No vector optimisation here. Better use a mask ?
246                  p_fval(jj,jk) = p_fval(jj,jk) + pva(ji,jj,jk) * e1v(ji,jj) * fse3v(ji,jj,jk) * pmsk(ji,jj)
247               END DO
248            END DO
249         END DO
250      ELSE
251         DO jk = 1, jpkm1
252            DO jj = 2, jpjm1
253               DO ji =  nldi, nlei   ! No vector optimisation here. Better use a mask ?
254                  p_fval(jj,jk) = p_fval(jj,jk) + pva(ji,jj,jk) * e1v(ji,jj) * fse3v(ji,jj,jk) * tmask_i(ji,jj)
255               END DO
256            END DO
257         END DO
258      END IF
259      !
260#if defined key_mpp_mpi
261      ijpjjpk = jpj*jpk
262      ish(1) = ijpjjpk  ;   ish2(1) = jpj   ;   ish2(2) = jpk
263      zwork(1:ijpjjpk) = RESHAPE( p_fval, ish )
264      CALL mpp_sum( zwork, ijpjjpk, ncomm_znl )
265      p_fval(:,:) = RESHAPE( zwork, ish2 )
266#endif
267      !
268#if defined key_mpp_mpi
269      CALL wrk_dealloc( jpj*jpk, zwork )
270#endif
271      !
272   END FUNCTION ptr_vjk
273
274
275   FUNCTION ptr_tjk( pta, pmsk )   RESULT ( p_fval )
276      !!----------------------------------------------------------------------
277      !!                    ***  ROUTINE ptr_tjk  ***
278      !!
279      !! ** Purpose :   i-sum computation of e1t*e3t * a tracer field
280      !!
281      !! ** Method  : - i-sum of mj(pta) using tmask
282      !!
283      !! ** Action  : - p_fval: i-sum of e1t*e3t*pta
284      !!----------------------------------------------------------------------
285      !!
286      REAL(wp) , INTENT(in), DIMENSION(jpi,jpj,jpk) ::   pta    ! tracer flux array at T-point
287      REAL(wp) , INTENT(in), DIMENSION(jpi,jpj)     ::   pmsk   ! Optional 2D basin mask
288      !!
289      INTEGER                           :: ji, jj, jk   ! dummy loop arguments
290      REAL(wp), POINTER, DIMENSION(:,:) :: p_fval       ! return function value
291#if defined key_mpp_mpi
292      INTEGER, DIMENSION(1) ::   ish
293      INTEGER, DIMENSION(2) ::   ish2
294      INTEGER               ::   ijpjjpk
295#endif
296#if defined key_mpp_mpi
297      REAL(wp), POINTER, DIMENSION(:) ::   zwork    ! mask flux array at V-point
298#endif
299      !!--------------------------------------------------------------------
300      !
301#if defined key_mpp_mpi
302      ijpjjpk = jpj*jpk
303      CALL wrk_alloc( jpj*jpk, zwork )
304#endif
305
306      p_fval => p_fval2d
307
308      p_fval(:,:) = 0._wp
309      DO jk = 1, jpkm1
310         DO jj = 2, jpjm1
311            DO ji =  nldi, nlei   ! No vector optimisation here. Better use a mask ?
312               p_fval(jj,jk) = p_fval(jj,jk) + pta(ji,jj,jk) * e1t(ji,jj) * fse3t(ji,jj,jk) * pmsk(ji,jj)
313            END DO
314         END DO
315      END DO
316#if defined key_mpp_mpi
317      ijpjjpk = jpj*jpk
318      ish(1) = jpj*jpk   ;   ish2(1) = jpj   ;   ish2(2) = jpk
319      zwork(1:ijpjjpk)= RESHAPE( p_fval, ish )
320      CALL mpp_sum( zwork, ijpjjpk, ncomm_znl )
321      p_fval(:,:)= RESHAPE( zwork, ish2 )
322#endif
323      !
324#if defined key_mpp_mpi
325      CALL wrk_dealloc( jpj*jpk, zwork )
326#endif
327      !   
328   END FUNCTION ptr_tjk
329
330
331   SUBROUTINE dia_ptr( kt )
332      !!----------------------------------------------------------------------
333      !!                  ***  ROUTINE dia_ptr  ***
334      !!----------------------------------------------------------------------
335      USE oce,     vt  =>   ua   ! use ua as workspace
336      USE oce,     vs  =>   va   ! use va as workspace
337      IMPLICIT none
338      !!
339      INTEGER, INTENT(in) ::   kt   ! ocean time step index
340      !
341      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
342      REAL(wp) ::   zv               ! local scalar
343      !!----------------------------------------------------------------------
344      !
345      IF( nn_timing == 1 )   CALL timing_start('dia_ptr')
346      !
347      IF( kt == nit000 .OR. MOD( kt, nn_fptr ) == 0 )   THEN
348         !
349         IF( MOD( kt, nn_fptr ) == 0 ) THEN 
350            !
351            IF( ln_diaznl ) THEN               ! i-mean temperature and salinity
352               DO jn = 1, nptr
353                  tn_jk(:,:,jn) = ptr_tjk( tsn(:,:,:,jp_tem), btmsk(:,:,jn) ) * r1_sjk(:,:,jn)
354               END DO
355            ENDIF
356            !
357            !                          ! horizontal integral and vertical dz
358            !                                ! eulerian velocity
359            v_msf(:,:,1) = ptr_vjk( vn(:,:,:) ) 
360            DO jn = 2, nptr
361               v_msf(:,:,jn) = ptr_vjk( vn(:,:,:), btmsk(:,:,jn)*btm30(:,:) ) 
362            END DO
363#if defined key_diaeiv
364            DO jn = 1, nptr                  ! bolus velocity
365               v_msf_eiv(:,:,jn) = ptr_vjk( v_eiv(:,:,:), btmsk(:,:,jn) )   ! here no btm30 for MSFeiv
366            END DO
367            !                                ! add bolus stream-function to the eulerian one
368            v_msf(:,:,:) = v_msf(:,:,:) + v_msf_eiv(:,:,:)
369#endif
370            !
371            !                          ! Transports
372            !                                ! local heat & salt transports at T-points  ( tsn*mj[vn+v_eiv] )
373            vt(:,:,jpk) = 0._wp   ;   vs(:,:,jpk) = 0._wp
374            DO jk= 1, jpkm1
375               DO jj = 2, jpj
376                  DO ji = 1, jpi
377#if defined key_diaeiv 
378                     zv = ( vn(ji,jj,jk) + vn(ji,jj-1,jk) + v_eiv(ji,jj,jk) + v_eiv(ji,jj-1,jk) ) * 0.5_wp
379#else
380                     zv = ( vn(ji,jj,jk) + vn(ji,jj-1,jk) ) * 0.5_wp
381#endif
382                     vt(ji,jj,jk) = zv * tsn(ji,jj,jk,jp_tem)
383                     vs(ji,jj,jk) = zv * tsn(ji,jj,jk,jp_sal)
384                  END DO
385               END DO
386            END DO
387!!gm useless as overlap areas are not used in ptr_vjk
388            CALL lbc_lnk( vs, 'V', -1. )   ;   CALL lbc_lnk( vt, 'V', -1. )
389!!gm
390            !                                ! heat & salt advective transports (approximation)
391            htr(:,1) = SUM( ptr_vjk( vt(:,:,:) ) , 2 ) * rc_pwatt   ! SUM over jk + conversion
392            str(:,1) = SUM( ptr_vjk( vs(:,:,:) ) , 2 ) * rc_ggram
393            DO jn = 2, nptr 
394               htr(:,jn) = SUM( ptr_vjk( vt(:,:,:), btmsk(:,:,jn)*btm30(:,:) ) , 2 ) * rc_pwatt   ! mask Southern Ocean
395               str(:,jn) = SUM( ptr_vjk( vs(:,:,:), btmsk(:,:,jn)*btm30(:,:) ) , 2 ) * rc_ggram   ! mask Southern Ocean
396            END DO
397
398            IF( ln_ptrcomp ) THEN            ! overturning transport
399               htr_ove(:) = SUM( v_msf(:,:,1) * tn_jk(:,:,1), 2 ) * rc_pwatt   ! SUM over jk + conversion
400               str_ove(:) = SUM( v_msf(:,:,1) * sn_jk(:,:,1), 2 ) * rc_ggram
401            END IF
402            !                                ! Advective and diffusive transport
403            htr_adv(:) = htr_adv(:) * rc_pwatt        ! these are computed in tra_adv... and tra_ldf... routines
404            htr_ldf(:) = htr_ldf(:) * rc_pwatt        ! here just the conversion in PW and Gg
405            str_adv(:) = str_adv(:) * rc_ggram
406            str_ldf(:) = str_ldf(:) * rc_ggram
407
408#if defined key_diaeiv
409            DO jn = 1, nptr                  ! Bolus component
410               htr_eiv(:,jn) = SUM( v_msf_eiv(:,:,jn) * tn_jk(:,:,jn), 2 ) * rc_pwatt   ! SUM over jk
411               str_eiv(:,jn) = SUM( v_msf_eiv(:,:,jn) * sn_jk(:,:,jn), 2 ) * rc_ggram   ! SUM over jk
412            END DO
413#endif
414            !                                ! "Meridional" Stream-Function
415            DO jn = 1, nptr
416               DO jk = 2, jpk 
417                  v_msf    (:,jk,jn) = v_msf    (:,jk-1,jn) + v_msf    (:,jk,jn)       ! Eulerian j-Stream-Function
418#if defined key_diaeiv
419                  v_msf_eiv(:,jk,jn) = v_msf_eiv(:,jk-1,jn) + v_msf_eiv(:,jk,jn)       ! Bolus    j-Stream-Function
420
421#endif
422               END DO
423            END DO
424            v_msf    (:,:,:) = v_msf    (:,:,:) * rc_sv       ! converte in Sverdrups
425#if defined key_diaeiv
426            v_msf_eiv(:,:,:) = v_msf_eiv(:,:,:) * rc_sv
427#endif
428         ENDIF
429         !
430         CALL dia_ptr_wri( kt )                        ! outputs
431         !
432      ENDIF
433      !
434#if defined key_mpp_mpi
435      IF( kt == nitend .AND. l_znl_root )   CALL histclo( numptr )      ! Close the file
436#else
437      IF( kt == nitend )                    CALL histclo( numptr )      ! Close the file
438#endif
439      !
440      IF( nn_timing == 1 )   CALL timing_stop('dia_ptr')
441      !
442   END SUBROUTINE dia_ptr
443
444
445   SUBROUTINE dia_ptr_init
446      !!----------------------------------------------------------------------
447      !!                  ***  ROUTINE dia_ptr_init  ***
448      !!                   
449      !! ** Purpose :   Initialization, namelist read
450      !!----------------------------------------------------------------------
451      INTEGER ::   jn           ! dummy loop indices
452      INTEGER ::   inum, ierr   ! local integers
453#if defined key_mpp_mpi
454      INTEGER, DIMENSION(1) :: iglo, iloc, iabsf, iabsl, ihals, ihale, idid
455#endif
456      !!
457      NAMELIST/namptr/ ln_diaptr, ln_diaznl, ln_subbas, ln_ptrcomp, nn_fptr, nn_fwri
458      !!----------------------------------------------------------------------
459
460      REWIND( numnam )                 ! Read Namelist namptr : poleward transport parameters
461      READ  ( numnam, namptr )
462
463      IF(lwp) THEN                     ! Control print
464         WRITE(numout,*)
465         WRITE(numout,*) 'dia_ptr_init : poleward transport and msf initialization'
466         WRITE(numout,*) '~~~~~~~~~~~~'
467         WRITE(numout,*) '   Namelist namptr : set ptr parameters'
468         WRITE(numout,*) '      Poleward heat & salt transport (T) or not (F)      ln_diaptr  = ', ln_diaptr
469         WRITE(numout,*) '      Overturning heat & salt transport                  ln_ptrcomp = ', ln_ptrcomp
470         WRITE(numout,*) '      T & S zonal mean and meridional stream function    ln_diaznl  = ', ln_diaznl 
471         WRITE(numout,*) '      Global (F) or glo/Atl/Pac/Ind/Indo-Pac basins      ln_subbas  = ', ln_subbas
472         WRITE(numout,*) '      Frequency of computation                           nn_fptr    = ', nn_fptr
473         WRITE(numout,*) '      Frequency of outputs                               nn_fwri    = ', nn_fwri
474      ENDIF
475     
476      IF( ln_diaptr) THEN 
477     
478         IF( nn_timing == 1 )   CALL timing_start('dia_ptr_init')
479     
480         IF( ln_subbas ) THEN   ;   nptr = 5       ! Global, Atlantic, Pacific, Indian, Indo-Pacific
481         ELSE                   ;   nptr = 1       ! Global only
482         ENDIF
483
484         !                                      ! allocate dia_ptr arrays
485         IF( dia_ptr_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'dia_ptr_init : unable to allocate arrays' )
486
487         rc_pwatt = rc_pwatt * rau0 * rcp          ! conversion from K.s-1 to PetaWatt
488
489         IF( lk_mpp )   CALL mpp_ini_znl( numout )     ! Define MPI communicator for zonal sum
490
491         IF( ln_subbas ) THEN                ! load sub-basin mask
492            CALL iom_open( 'subbasins', inum )
493            CALL iom_get( inum, jpdom_data, 'atlmsk', btmsk(:,:,2) )   ! Atlantic basin
494            CALL iom_get( inum, jpdom_data, 'pacmsk', btmsk(:,:,3) )   ! Pacific  basin
495            CALL iom_get( inum, jpdom_data, 'indmsk', btmsk(:,:,4) )   ! Indian   basin
496            CALL iom_close( inum )
497            btmsk(:,:,5) = MAX ( btmsk(:,:,3), btmsk(:,:,4) )          ! Indo-Pacific basin
498            WHERE( gphit(:,:) < -30._wp)   ;   btm30(:,:) = 0._wp      ! mask out Southern Ocean
499            ELSE WHERE                     ;   btm30(:,:) = tmask(:,:,1)
500            END WHERE
501         ENDIF
502         btmsk(:,:,1) = tmask_i(:,:)                                   ! global ocean
503     
504         DO jn = 1, nptr
505            btmsk(:,:,jn) = btmsk(:,:,jn) * tmask_i(:,:)               ! interior domain only
506         END DO
507     
508         IF( lk_vvl )   CALL ctl_stop( 'diaptr: error in vvl case as constant i-mean surface is used' )
509
510         !                                   ! i-sum of e1v*e3v surface and its inverse
511         DO jn = 1, nptr
512            sjk(:,:,jn) = ptr_tjk( tmask(:,:,:), btmsk(:,:,jn) )
513            r1_sjk(:,:,jn) = 0._wp
514            WHERE( sjk(:,:,jn) /= 0._wp )   r1_sjk(:,:,jn) = 1._wp / sjk(:,:,jn)
515         END DO
516
517      ! Initialise arrays to zero because diatpr is called before they are first calculated
518      ! Note that this means diagnostics will not be exactly correct when model run is restarted.
519      htr_adv(:) = 0._wp ; str_adv(:) =  0._wp ;  htr_ldf(:) = 0._wp ; str_ldf(:) =  0._wp
520
521#if defined key_mpp_mpi 
522         iglo (1) = jpjglo                   ! MPP case using MPI  ('key_mpp_mpi')
523         iloc (1) = nlcj
524         iabsf(1) = njmppt(narea)
525         iabsl(:) = iabsf(:) + iloc(:) - 1
526         ihals(1) = nldj - 1
527         ihale(1) = nlcj - nlej
528         idid (1) = 2
529         CALL flio_dom_set( jpnj, nproc/jpni, idid, iglo, iloc, iabsf, iabsl, ihals, ihale, 'BOX', nidom_ptr )
530#else
531         nidom_ptr = FLIO_DOM_NONE
532#endif
533      IF( nn_timing == 1 )   CALL timing_stop('dia_ptr_init')
534      !
535      ENDIF 
536      !
537   END SUBROUTINE dia_ptr_init
538
539
540   SUBROUTINE dia_ptr_wri( kt )
541      !!---------------------------------------------------------------------
542      !!                ***  ROUTINE dia_ptr_wri  ***
543      !!
544      !! ** Purpose :   output of poleward fluxes
545      !!
546      !! ** Method  :   NetCDF file
547      !!----------------------------------------------------------------------
548      !!
549      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
550      !!
551      INTEGER, SAVE ::   nhoridz, ndepidzt, ndepidzw
552      INTEGER, SAVE ::   ndim  , ndim_atl     , ndim_pac     , ndim_ind     , ndim_ipc
553      INTEGER, SAVE ::           ndim_atl_30  , ndim_pac_30  , ndim_ind_30  , ndim_ipc_30
554      INTEGER, SAVE ::   ndim_h, ndim_h_atl_30, ndim_h_pac_30, ndim_h_ind_30, ndim_h_ipc_30
555      !!
556      CHARACTER (len=40) ::   clhstnam, clop, clop_once, cl_comment   ! temporary names
557      INTEGER            ::   iline, it, itmod, ji, jj, jk            !
558#if defined key_iomput
559      INTEGER            ::   inum                                    ! temporary logical unit
560#endif
561      REAL(wp)           ::   zsto, zout, zdt, zjulian                ! temporary scalars
562      !!
563      REAL(wp), POINTER, DIMENSION(:)   ::   zphi, zfoo    ! 1D workspace
564      REAL(wp), POINTER, DIMENSION(:,:) ::   z_1           ! 2D workspace
565      !!--------------------------------------------------------------------
566      !
567      CALL wrk_alloc( jpi      , zphi , zfoo )
568      CALL wrk_alloc( jpi , jpk, z_1 )
569
570      ! define time axis
571      it    = kt / nn_fptr
572      itmod = kt - nit000 + 1
573     
574      ! Initialization
575      ! --------------
576      IF( kt == nit000 ) THEN
577         niter = ( nit000 - 1 ) / nn_fptr
578         zdt = rdt
579         IF( nacc == 1 )   zdt = rdtmin
580         !
581         IF(lwp) THEN
582            WRITE(numout,*)
583            WRITE(numout,*) 'dia_ptr_wri : poleward transport and msf writing: initialization , niter = ', niter
584            WRITE(numout,*) '~~~~~~~~~~~~'
585         ENDIF
586
587         ! Reference latitude (used in plots)
588         ! ------------------
589         !                                           ! =======================
590         IF( cp_cfg == "orca" ) THEN                 !   ORCA configurations
591            !                                        ! =======================
592            IF( jp_cfg == 05  )   iline = 192   ! i-line that passes near the North Pole
593            IF( jp_cfg == 025 )   iline = 384   ! i-line that passes near the North Pole
594            IF( jp_cfg == 1   )   iline =  96   ! i-line that passes near the North Pole
595            IF( jp_cfg == 2   )   iline =  48   ! i-line that passes near the North Pole
596            IF( jp_cfg == 4   )   iline =  24   ! i-line that passes near the North Pole
597            zphi(1:jpj) = 0._wp
598            DO ji = mi0(iline), mi1(iline) 
599               zphi(1:jpj) = gphiv(ji,:)         ! if iline is in the local domain
600               ! Correct highest latitude for some configurations - will work if domain is parallelized in J ?
601               IF( jp_cfg == 05 ) THEN
602                  DO jj = mj0(jpjdta), mj1(jpjdta) 
603                     zphi( jj ) = zphi(mj0(jpjdta-1)) + ( zphi(mj0(jpjdta-1))-zphi(mj0(jpjdta-2)) ) * 0.5_wp
604                     zphi( jj ) = MIN( zphi(jj), 90._wp )
605                  END DO
606               END IF
607               IF( jp_cfg == 1 .OR. jp_cfg == 2 .OR. jp_cfg == 4 ) THEN
608                  DO jj = mj0(jpjdta-1), mj1(jpjdta-1) 
609                     zphi( jj ) = 88.5_wp
610                  END DO
611                  DO jj = mj0(jpjdta  ), mj1(jpjdta  ) 
612                     zphi( jj ) = 89.5_wp
613                  END DO
614               END IF
615            END DO
616            ! provide the correct zphi to all local domains
617#if defined key_mpp_mpi
618            CALL mpp_sum( zphi, jpj, ncomm_znl )       
619#endif
620            !                                        ! =======================
621         ELSE                                        !   OTHER configurations
622            !                                        ! =======================
623            zphi(1:jpj) = gphiv(1,:)             ! assume lat/lon coordinate, select the first i-line
624            !
625         ENDIF
626         !
627         ! Work only on westmost processor (will not work if mppini2 is used)
628#if defined key_mpp_mpi
629         IF( l_znl_root ) THEN 
630#endif
631            !
632            ! OPEN netcdf file
633            ! ----------------
634            ! Define frequency of output and means
635            zsto = nn_fptr * zdt
636            IF( ln_mskland )   THEN    ! put 1.e+20 on land (very expensive!!)
637               clop      = "ave(only(x))"
638               clop_once = "once(only(x))"
639            ELSE                       ! no use of the mask value (require less cpu time)
640               clop      = "ave(x)"       
641               clop_once = "once"
642            ENDIF
643
644            zout = nn_fwri * zdt
645            zfoo(1:jpj) = 0._wp
646
647            CALL ymds2ju( nyear, nmonth, nday, rdt, zjulian )  ! Compute julian date from starting date of the run
648            zjulian = zjulian - adatrj                         ! set calendar origin to the beginning of the experiment
649
650#if defined key_iomput
651            ! Requested by IPSL people, use by their postpro...
652            IF(lwp) THEN
653               CALL dia_nam( clhstnam, nn_fwri,' ' )
654               CALL ctl_opn( inum, 'date.file', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
655               WRITE(inum,*) clhstnam
656               CLOSE(inum)
657            ENDIF
658#endif
659
660            CALL dia_nam( clhstnam, nn_fwri, 'diaptr' )
661            IF(lwp)WRITE( numout,*)" Name of diaptr NETCDF file : ", clhstnam
662
663            ! Horizontal grid : zphi()
664            CALL histbeg(clhstnam, 1, zfoo, jpj, zphi,   &
665               1, 1, 1, jpj, niter, zjulian, zdt*nn_fptr, nhoridz, numptr, domain_id=nidom_ptr)
666            ! Vertical grids : gdept_1d, gdepw_1d
667            CALL histvert( numptr, "deptht", "Vertical T levels",   &
668               &                   "m", jpk, gdept_1d, ndepidzt, "down" )
669            CALL histvert( numptr, "depthw", "Vertical W levels",   &
670               &                   "m", jpk, gdepw_1d, ndepidzw, "down" )
671            !
672            CALL wheneq ( jpj*jpk, MIN(sjk(:,:,1), 1._wp), 1, 1., ndex  , ndim  )      ! Lat-Depth
673            CALL wheneq ( jpj    , MIN(sjk(:,1,1), 1._wp), 1, 1., ndex_h, ndim_h )     ! Lat
674
675            IF( ln_subbas ) THEN
676               z_1(:,1) = 1._wp
677               WHERE ( gphit(jpi/2,:) < -30._wp )   z_1(:,1) = 0._wp
678               DO jk = 2, jpk
679                  z_1(:,jk) = z_1(:,1)
680               END DO
681               !                       ! Atlantic (jn=2)
682               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,2)         , 1._wp), 1, 1., ndex_atl     , ndim_atl      ) ! Lat-Depth
683               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,2)*z_1(:,:), 1._wp), 1, 1., ndex_atl_30  , ndim_atl_30   ) ! Lat-Depth
684               CALL wheneq ( jpj    , MIN(sjk(:,1,2)*z_1(:,1), 1._wp), 1, 1., ndex_h_atl_30, ndim_h_atl_30 ) ! Lat
685               !                       ! Pacific (jn=3)
686               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,3)         , 1._wp), 1, 1., ndex_pac     , ndim_pac      ) ! Lat-Depth
687               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,3)*z_1(:,:), 1._wp), 1, 1., ndex_pac_30  , ndim_pac_30   ) ! Lat-Depth
688               CALL wheneq ( jpj    , MIN(sjk(:,1,3)*z_1(:,1), 1._wp), 1, 1., ndex_h_pac_30, ndim_h_pac_30 ) ! Lat
689               !                       ! Indian (jn=4)
690               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,4)         , 1._wp), 1, 1., ndex_ind     , ndim_ind      ) ! Lat-Depth
691               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,4)*z_1(:,:), 1._wp), 1, 1., ndex_ind_30  , ndim_ind_30   ) ! Lat-Depth
692               CALL wheneq ( jpj    , MIN(sjk(:,1,4)*z_1(:,1), 1._wp), 1, 1., ndex_h_ind_30, ndim_h_ind_30 ) ! Lat
693               !                       ! Indo-Pacific (jn=5)
694               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,5)         , 1._wp), 1, 1., ndex_ipc     , ndim_ipc      ) ! Lat-Depth
695               CALL wheneq ( jpj*jpk, MIN(sjk(:,:,5)*z_1(:,:), 1._wp), 1, 1., ndex_ipc_30  , ndim_ipc_30   ) ! Lat-Depth
696               CALL wheneq ( jpj    , MIN(sjk(:,1,5)*z_1(:,1), 1._wp), 1, 1., ndex_h_ipc_30, ndim_h_ipc_30 ) ! Lat
697            ENDIF
698            !
699#if defined key_diaeiv
700            cl_comment = ' (Bolus part included)'
701#else
702            cl_comment = '                      '
703#endif
704            IF( ln_diaznl ) THEN             !  Zonal mean T and S
705               CALL histdef( numptr, "zotemglo", "Zonal Mean Temperature","C" ,   &
706                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
707               CALL histdef( numptr, "zosalglo", "Zonal Mean Salinity","PSU"  ,   &
708                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
709
710               CALL histdef( numptr, "zosrfglo", "Zonal Mean Surface","m^2"   ,   &
711                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop_once, zsto, zout )
712               !
713               IF (ln_subbas) THEN
714                  CALL histdef( numptr, "zotematl", "Zonal Mean Temperature: Atlantic","C" ,   &
715                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
716                  CALL histdef( numptr, "zosalatl", "Zonal Mean Salinity: Atlantic","PSU"  ,   &
717                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
718                  CALL histdef( numptr, "zosrfatl", "Zonal Mean Surface: Atlantic","m^2"   ,   &
719                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop_once, zsto, zout )
720
721                  CALL histdef( numptr, "zotempac", "Zonal Mean Temperature: Pacific","C"  ,   &
722                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
723                  CALL histdef( numptr, "zosalpac", "Zonal Mean Salinity: Pacific","PSU"   ,   &
724                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
725                  CALL histdef( numptr, "zosrfpac", "Zonal Mean Surface: Pacific","m^2"    ,   &
726                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop_once, zsto, zout )
727
728                  CALL histdef( numptr, "zotemind", "Zonal Mean Temperature: Indian","C"   ,   &
729                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
730                  CALL histdef( numptr, "zosalind", "Zonal Mean Salinity: Indian","PSU"    ,   &
731                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
732                  CALL histdef( numptr, "zosrfind", "Zonal Mean Surface: Indian","m^2"     ,   &
733                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop_once, zsto, zout )
734
735                  CALL histdef( numptr, "zotemipc", "Zonal Mean Temperature: Pacific+Indian","C" ,   &
736                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
737                  CALL histdef( numptr, "zosalipc", "Zonal Mean Salinity: Pacific+Indian","PSU"  ,   &
738                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop, zsto, zout )
739                  CALL histdef( numptr, "zosrfipc", "Zonal Mean Surface: Pacific+Indian","m^2"   ,   &
740                     1, jpj, nhoridz, jpk, 1, jpk, ndepidzt, 32, clop_once, zsto, zout )
741               ENDIF
742            ENDIF
743            !
744            !  Meridional Stream-Function (Eulerian and Bolus)
745            CALL histdef( numptr, "zomsfglo", "Meridional Stream-Function: Global"//TRIM(cl_comment),"Sv" ,   &
746               1, jpj, nhoridz, jpk, 1, jpk, ndepidzw, 32, clop, zsto, zout )
747            IF( ln_subbas .AND. ln_diaznl ) THEN
748               CALL histdef( numptr, "zomsfatl", "Meridional Stream-Function: Atlantic"//TRIM(cl_comment),"Sv" ,   &
749                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzw, 32, clop, zsto, zout )
750               CALL histdef( numptr, "zomsfpac", "Meridional Stream-Function: Pacific"//TRIM(cl_comment),"Sv"  ,   &
751                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzw, 32, clop, zsto, zout )
752               CALL histdef( numptr, "zomsfind", "Meridional Stream-Function: Indian"//TRIM(cl_comment),"Sv"   ,   &
753                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzw, 32, clop, zsto, zout )
754               CALL histdef( numptr, "zomsfipc", "Meridional Stream-Function: Indo-Pacific"//TRIM(cl_comment),"Sv" ,&
755                  1, jpj, nhoridz, jpk, 1, jpk, ndepidzw, 32, clop, zsto, zout )
756            ENDIF
757            !
758            !  Heat transport
759            CALL histdef( numptr, "sophtadv", "Advective Heat Transport"      ,   &
760               "PW", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
761            CALL histdef( numptr, "sophtldf", "Diffusive Heat Transport"      ,   &
762               "PW",1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
763            IF ( ln_ptrcomp ) THEN
764               CALL histdef( numptr, "sophtove", "Overturning Heat Transport"    ,   &
765                  "PW",1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
766            END IF
767            IF( ln_subbas ) THEN
768               CALL histdef( numptr, "sohtatl", "Heat Transport Atlantic"//TRIM(cl_comment),  &
769                  "PW", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
770               CALL histdef( numptr, "sohtpac", "Heat Transport Pacific"//TRIM(cl_comment) ,  &
771                  "PW", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
772               CALL histdef( numptr, "sohtind", "Heat Transport Indian"//TRIM(cl_comment)  ,  &
773                  "PW", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
774               CALL histdef( numptr, "sohtipc", "Heat Transport Pacific+Indian"//TRIM(cl_comment), &
775                  "PW", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
776            ENDIF
777            !
778            !  Salt transport
779            CALL histdef( numptr, "sopstadv", "Advective Salt Transport"      ,   &
780               "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
781            CALL histdef( numptr, "sopstldf", "Diffusive Salt Transport"      ,   &
782               "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
783            IF ( ln_ptrcomp ) THEN
784               CALL histdef( numptr, "sopstove", "Overturning Salt Transport"    ,   &
785                  "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
786            END IF
787#if defined key_diaeiv
788            ! Eddy induced velocity
789            CALL histdef( numptr, "zomsfeiv", "Bolus Meridional Stream-Function: global",   &
790               "Sv"      , 1, jpj, nhoridz, jpk, 1, jpk, ndepidzw, 32, clop, zsto, zout )
791            CALL histdef( numptr, "sophteiv", "Bolus Advective Heat Transport",   &
792               "PW"      , 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
793            CALL histdef( numptr, "sopsteiv", "Bolus Advective Salt Transport",   &
794               "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
795#endif
796            IF( ln_subbas ) THEN
797               CALL histdef( numptr, "sostatl", "Salt Transport Atlantic"//TRIM(cl_comment)      ,  &
798                  "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
799               CALL histdef( numptr, "sostpac", "Salt Transport Pacific"//TRIM(cl_comment)      ,   &
800                  "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
801               CALL histdef( numptr, "sostind", "Salt Transport Indian"//TRIM(cl_comment)      ,    &
802                  "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
803               CALL histdef( numptr, "sostipc", "Salt Transport Pacific+Indian"//TRIM(cl_comment),  &
804                  "Giga g/s", 1, jpj, nhoridz, 1, 1, 1, -99, 32, clop, zsto, zout )
805            ENDIF
806            !
807            CALL histend( numptr )
808            !
809         END IF
810#if defined key_mpp_mpi
811      END IF
812#endif
813
814#if defined key_mpp_mpi
815      IF( MOD( itmod, nn_fptr ) == 0 .AND. l_znl_root ) THEN
816#else
817      IF( MOD( itmod, nn_fptr ) == 0  ) THEN
818#endif
819         niter = niter + 1
820
821         IF( ln_diaznl ) THEN
822            CALL histwrite( numptr, "zosrfglo", niter, sjk  (:,:,1) , ndim, ndex )
823            CALL histwrite( numptr, "zotemglo", niter, tn_jk(:,:,1)  , ndim, ndex )
824            CALL histwrite( numptr, "zosalglo", niter, sn_jk(:,:,1)  , ndim, ndex )
825
826            IF (ln_subbas) THEN
827               CALL histwrite( numptr, "zosrfatl", niter, sjk(:,:,2), ndim_atl, ndex_atl )
828               CALL histwrite( numptr, "zosrfpac", niter, sjk(:,:,3), ndim_pac, ndex_pac )
829               CALL histwrite( numptr, "zosrfind", niter, sjk(:,:,4), ndim_ind, ndex_ind )
830               CALL histwrite( numptr, "zosrfipc", niter, sjk(:,:,5), ndim_ipc, ndex_ipc )
831
832               CALL histwrite( numptr, "zotematl", niter, tn_jk(:,:,2)  , ndim_atl, ndex_atl )
833               CALL histwrite( numptr, "zosalatl", niter, sn_jk(:,:,2)  , ndim_atl, ndex_atl )
834               CALL histwrite( numptr, "zotempac", niter, tn_jk(:,:,3)  , ndim_pac, ndex_pac )
835               CALL histwrite( numptr, "zosalpac", niter, sn_jk(:,:,3)  , ndim_pac, ndex_pac )
836               CALL histwrite( numptr, "zotemind", niter, tn_jk(:,:,4)  , ndim_ind, ndex_ind )
837               CALL histwrite( numptr, "zosalind", niter, sn_jk(:,:,4)  , ndim_ind, ndex_ind )
838               CALL histwrite( numptr, "zotemipc", niter, tn_jk(:,:,5)  , ndim_ipc, ndex_ipc )
839               CALL histwrite( numptr, "zosalipc", niter, sn_jk(:,:,5)  , ndim_ipc, ndex_ipc )
840            END IF
841         ENDIF
842
843         ! overturning outputs:
844         CALL histwrite( numptr, "zomsfglo", niter, v_msf(:,:,1), ndim, ndex )
845         IF( ln_subbas .AND. ln_diaznl ) THEN
846            CALL histwrite( numptr, "zomsfatl", niter, v_msf(:,:,2) , ndim_atl_30, ndex_atl_30 )
847            CALL histwrite( numptr, "zomsfpac", niter, v_msf(:,:,3) , ndim_pac_30, ndex_pac_30 )
848            CALL histwrite( numptr, "zomsfind", niter, v_msf(:,:,4) , ndim_ind_30, ndex_ind_30 )
849            CALL histwrite( numptr, "zomsfipc", niter, v_msf(:,:,5) , ndim_ipc_30, ndex_ipc_30 )
850         ENDIF
851#if defined key_diaeiv
852         CALL histwrite( numptr, "zomsfeiv", niter, v_msf_eiv(:,:,1), ndim  , ndex   )
853#endif
854
855         ! heat transport outputs:
856         IF( ln_subbas ) THEN
857            CALL histwrite( numptr, "sohtatl", niter, htr(:,2)  , ndim_h_atl_30, ndex_h_atl_30 )
858            CALL histwrite( numptr, "sohtpac", niter, htr(:,3)  , ndim_h_pac_30, ndex_h_pac_30 )
859            CALL histwrite( numptr, "sohtind", niter, htr(:,4)  , ndim_h_ind_30, ndex_h_ind_30 )
860            CALL histwrite( numptr, "sohtipc", niter, htr(:,5)  , ndim_h_ipc_30, ndex_h_ipc_30 )
861            CALL histwrite( numptr, "sostatl", niter, str(:,2)  , ndim_h_atl_30, ndex_h_atl_30 )
862            CALL histwrite( numptr, "sostpac", niter, str(:,3)  , ndim_h_pac_30, ndex_h_pac_30 )
863            CALL histwrite( numptr, "sostind", niter, str(:,4)  , ndim_h_ind_30, ndex_h_ind_30 )
864            CALL histwrite( numptr, "sostipc", niter, str(:,5)  , ndim_h_ipc_30, ndex_h_ipc_30 )
865         ENDIF
866
867         CALL histwrite( numptr, "sophtadv", niter, htr_adv     , ndim_h, ndex_h )
868         CALL histwrite( numptr, "sophtldf", niter, htr_ldf     , ndim_h, ndex_h )
869         CALL histwrite( numptr, "sopstadv", niter, str_adv     , ndim_h, ndex_h )
870         CALL histwrite( numptr, "sopstldf", niter, str_ldf     , ndim_h, ndex_h )
871         IF( ln_ptrcomp ) THEN
872            CALL histwrite( numptr, "sopstove", niter, str_ove(:) , ndim_h, ndex_h )
873            CALL histwrite( numptr, "sophtove", niter, htr_ove(:) , ndim_h, ndex_h )
874         ENDIF
875#if defined key_diaeiv
876         CALL histwrite( numptr, "sophteiv", niter, htr_eiv(:,1)  , ndim_h, ndex_h )
877         CALL histwrite( numptr, "sopsteiv", niter, str_eiv(:,1)  , ndim_h, ndex_h )
878#endif
879         !
880      ENDIF
881      !
882      CALL wrk_dealloc( jpi      , zphi , zfoo )
883      CALL wrk_dealloc( jpi , jpk, z_1 )
884      !
885  END SUBROUTINE dia_ptr_wri
886
887   !!======================================================================
888END MODULE diaptr
Note: See TracBrowser for help on using the repository browser.