New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv.F90 in branches/2013/dev_r3858_NOC_ZTC/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2013/dev_r3858_NOC_ZTC/NEMOGCM/NEMO/OPA_SRC/TRA/traadv.F90 @ 3865

Last change on this file since 3865 was 3865, checked in by acc, 11 years ago

Branch 2013/dev_r3858_NOC_ZTC, #863. Nearly complete port of 2011/dev_r2739_LOCEAN8_ZTC development branch into v3.5aplha base. Compiles and runs but currently unstable after 8 timesteps with ORCA2_LIM reference configuration.
  • Property svn:keywords set to Id
File size: 12.3 KB
Line 
1MODULE traadv
2   !!==============================================================================
3   !!                       ***  MODULE  traadv  ***
4   !! Ocean active tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-09  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   tra_adv      : compute ocean tracer advection trend
12   !!   tra_adv_ctl  : control the different options of advection scheme
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and active tracers
15   USE dom_oce         ! ocean space and time domain
16   USE domvvl          ! variable vertical scale factors
17   USE traadv_cen2     ! 2nd order centered scheme (tra_adv_cen2   routine)
18   USE traadv_tvd      ! TVD      scheme           (tra_adv_tvd    routine)
19   USE traadv_muscl    ! MUSCL    scheme           (tra_adv_muscl  routine)
20   USE traadv_muscl2   ! MUSCL2   scheme           (tra_adv_muscl2 routine)
21   USE traadv_ubs      ! UBS      scheme           (tra_adv_ubs    routine)
22   USE traadv_qck      ! QUICKEST scheme           (tra_adv_qck    routine)
23   USE traadv_eiv      ! eddy induced velocity     (tra_adv_eiv    routine)
24   USE cla             ! cross land advection      (cla_traadv     routine)
25   USE ldftra_oce      ! lateral diffusion coefficient on tracers
26   USE in_out_manager  ! I/O manager
27   USE iom             ! I/O module
28   USE prtctl          ! Print control
29   USE lib_mpp         ! MPP library
30   USE wrk_nemo        ! Memory Allocation
31   USE timing          ! Timing
32
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   tra_adv        ! routine called by step module
38   PUBLIC   tra_adv_init   ! routine called by opa module
39
40   !                                        !!* Namelist namtra_adv *
41   LOGICAL ::   ln_traadv_cen2   = .TRUE.    ! 2nd order centered scheme flag
42   LOGICAL ::   ln_traadv_tvd    = .FALSE.   ! TVD scheme flag
43   LOGICAL ::   ln_traadv_muscl  = .FALSE.   ! MUSCL scheme flag
44   LOGICAL ::   ln_traadv_muscl2 = .FALSE.   ! MUSCL2 scheme flag
45   LOGICAL ::   ln_traadv_ubs    = .FALSE.   ! UBS scheme flag
46   LOGICAL ::   ln_traadv_qck    = .FALSE.   ! QUICKEST scheme flag
47   LOGICAL ::   ln_traadv_msc_ups= .FALSE.   ! use upstream scheme within muscl
48
49
50   INTEGER ::   nadv   ! choice of the type of advection scheme
51
52   !! * Substitutions
53#  include "domzgr_substitute.h90"
54#  include "vectopt_loop_substitute.h90"
55   !!----------------------------------------------------------------------
56   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
57   !! $Id$
58   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
59   !!----------------------------------------------------------------------
60CONTAINS
61
62   SUBROUTINE tra_adv( kt )
63      !!----------------------------------------------------------------------
64      !!                  ***  ROUTINE tra_adv  ***
65      !!
66      !! ** Purpose :   compute the ocean tracer advection trend.
67      !!
68      !! ** Method  : - Update (ua,va) with the advection term following nadv
69      !!----------------------------------------------------------------------
70      !
71      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
72      !
73      INTEGER ::   jk   ! dummy loop index
74      REAL(wp), POINTER, DIMENSION(:,:,:) :: zun, zvn, zwn
75      !!----------------------------------------------------------------------
76      !
77      IF( nn_timing == 1 )  CALL timing_start('tra_adv')
78      !
79      CALL wrk_alloc( jpi, jpj, jpk, zun, zvn, zwn )
80      !                                          ! set time step
81      IF( neuler == 0 .AND. kt == nit000 ) THEN     ! at nit000
82         r2dtra(:) =  rdttra(:)                          ! = rdtra (restarting with Euler time stepping)
83      ELSEIF( kt <= nit000 + 1) THEN                ! at nit000 or nit000+1
84         r2dtra(:) = 2._wp * rdttra(:)                   ! = 2 rdttra (leapfrog)
85      ENDIF
86      !
87      IF( nn_cla == 1 )   CALL cla_traadv( kt )       !==  Cross Land Advection  ==! (hor. advection)
88      !
89      !                                               !==  effective transport  ==!
90      DO jk = 1, jpkm1
91         zun(:,:,jk) = e2u(:,:) * fse3u(:,:,jk) * un(:,:,jk)                  ! eulerian transport only
92         zvn(:,:,jk) = e1v(:,:) * fse3v(:,:,jk) * vn(:,:,jk)
93         zwn(:,:,jk) = e1t(:,:) * e2t(:,:)      * wn(:,:,jk)
94      END DO
95      !
96      IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN
97         zun(:,:,:) = zun(:,:,:) + un_td(:,:,:)
98         zvn(:,:,:) = zvn(:,:,:) + vn_td(:,:,:)
99      ENDIF
100      !
101      zun(:,:,jpk) = 0._wp                                                     ! no transport trough the bottom
102      zvn(:,:,jpk) = 0._wp                                                     ! no transport trough the bottom
103      zwn(:,:,jpk) = 0._wp                                                     ! no transport trough the bottom
104      !
105      IF( lk_traldf_eiv .AND. .NOT. ln_traldf_grif )   &
106         &              CALL tra_adv_eiv( kt, nit000, zun, zvn, zwn, 'TRA' )    ! add the eiv transport (if necessary)
107      !
108      CALL iom_put( "uocetr_eff", zun )                                         ! output effective transport     
109      CALL iom_put( "vocetr_eff", zvn )
110      CALL iom_put( "wocetr_eff", zwn )
111
112      SELECT CASE ( nadv )                            !==  compute advection trend and add it to general trend  ==!
113      CASE ( 1 )   ;    CALL tra_adv_cen2  ( kt, nit000, 'TRA',         zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  2nd order centered
114      CASE ( 2 )   ;    CALL tra_adv_tvd   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  TVD
115      CASE ( 3 )   ;    CALL tra_adv_muscl ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb,      tsa, jpts, ln_traadv_msc_ups )   !  MUSCL
116      CASE ( 4 )   ;    CALL tra_adv_muscl2( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  MUSCL2
117      CASE ( 5 )   ;    CALL tra_adv_ubs   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  UBS
118      CASE ( 6 )   ;    CALL tra_adv_qck   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  QUICKEST
119      !
120      CASE (-1 )                                      !==  esopa: test all possibility with control print  ==!
121         CALL tra_adv_cen2  ( kt, nit000, 'TRA',         zun, zvn, zwn, tsb, tsn, tsa, jpts )         
122         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv0 - Ta: ', mask1=tmask,               &
123            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
124         CALL tra_adv_tvd   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
125         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv1 - Ta: ', mask1=tmask,               &
126            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
127         CALL tra_adv_muscl ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb,      tsa, jpts, ln_traadv_msc_ups )         
128         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv3 - Ta: ', mask1=tmask,               &
129            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
130         CALL tra_adv_muscl2( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
131         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv4 - Ta: ', mask1=tmask,               &
132            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
133         CALL tra_adv_ubs   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
134         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv5 - Ta: ', mask1=tmask,               &
135            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
136         CALL tra_adv_qck   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
137         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv6 - Ta: ', mask1=tmask,               &
138            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
139      END SELECT
140      !
141      !                                              ! print mean trends (used for debugging)
142      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv  - Ta: ', mask1=tmask,               &
143         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
144      !
145      IF( nn_timing == 1 )  CALL timing_stop('tra_adv')
146      !
147      CALL wrk_dealloc( jpi, jpj, jpk, zun, zvn, zwn )
148      !                                         
149   END SUBROUTINE tra_adv
150
151
152   SUBROUTINE tra_adv_init
153      !!---------------------------------------------------------------------
154      !!                  ***  ROUTINE tra_adv_init  ***
155      !!               
156      !! ** Purpose :   Control the consistency between namelist options for
157      !!              tracer advection schemes and set nadv
158      !!----------------------------------------------------------------------
159      INTEGER ::   ioptio
160      !!
161      NAMELIST/namtra_adv/ ln_traadv_cen2 , ln_traadv_tvd,     &
162         &                 ln_traadv_muscl, ln_traadv_muscl2,  &
163         &                 ln_traadv_ubs  , ln_traadv_qck,     &
164         &                 ln_traadv_msc_ups
165      !!----------------------------------------------------------------------
166
167      REWIND( numnam )                ! Read Namelist namtra_adv : tracer advection scheme
168      READ  ( numnam, namtra_adv )
169
170      IF(lwp) THEN                    ! Namelist print
171         WRITE(numout,*)
172         WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
173         WRITE(numout,*) '~~~~~~~~~~~'
174         WRITE(numout,*) '   Namelist namtra_adv : chose a advection scheme for tracers'
175         WRITE(numout,*) '      2nd order advection scheme     ln_traadv_cen2    = ', ln_traadv_cen2
176         WRITE(numout,*) '      TVD advection scheme           ln_traadv_tvd     = ', ln_traadv_tvd
177         WRITE(numout,*) '      MUSCL  advection scheme        ln_traadv_muscl   = ', ln_traadv_muscl
178         WRITE(numout,*) '      MUSCL2 advection scheme        ln_traadv_muscl2  = ', ln_traadv_muscl2
179         WRITE(numout,*) '      UBS    advection scheme        ln_traadv_ubs     = ', ln_traadv_ubs
180         WRITE(numout,*) '      QUICKEST advection scheme      ln_traadv_qck     = ', ln_traadv_qck
181         WRITE(numout,*) '      upstream scheme within muscl   ln_traadv_msc_ups = ', ln_traadv_msc_ups
182      ENDIF
183
184      ioptio = 0                      ! Parameter control
185      IF( ln_traadv_cen2   )   ioptio = ioptio + 1
186      IF( ln_traadv_tvd    )   ioptio = ioptio + 1
187      IF( ln_traadv_muscl  )   ioptio = ioptio + 1
188      IF( ln_traadv_muscl2 )   ioptio = ioptio + 1
189      IF( ln_traadv_ubs    )   ioptio = ioptio + 1
190      IF( ln_traadv_qck    )   ioptio = ioptio + 1
191      IF( lk_esopa         )   ioptio =          1
192
193      IF( ioptio /= 1 )   CALL ctl_stop( 'Choose ONE advection scheme in namelist namtra_adv' )
194
195      !                              ! Set nadv
196      IF( ln_traadv_cen2   )   nadv =  1
197      IF( ln_traadv_tvd    )   nadv =  2
198      IF( ln_traadv_muscl  )   nadv =  3
199      IF( ln_traadv_muscl2 )   nadv =  4
200      IF( ln_traadv_ubs    )   nadv =  5
201      IF( ln_traadv_qck    )   nadv =  6
202      IF( lk_esopa         )   nadv = -1
203
204      IF(lwp) THEN                   ! Print the choice
205         WRITE(numout,*)
206         IF( nadv ==  1 )   WRITE(numout,*) '         2nd order scheme is used'
207         IF( nadv ==  2 )   WRITE(numout,*) '         TVD       scheme is used'
208         IF( nadv ==  3 )   WRITE(numout,*) '         MUSCL     scheme is used'
209         IF( nadv ==  4 )   WRITE(numout,*) '         MUSCL2    scheme is used'
210         IF( nadv ==  5 )   WRITE(numout,*) '         UBS       scheme is used'
211         IF( nadv ==  6 )   WRITE(numout,*) '         QUICKEST  scheme is used'
212         IF( nadv == -1 )   WRITE(numout,*) '         esopa test: use all advection scheme'
213      ENDIF
214      !
215   END SUBROUTINE tra_adv_init
216
217  !!======================================================================
218END MODULE traadv
Note: See TracBrowser for help on using the repository browser.