New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdydta.F90 in branches/2013/dev_r3987_METO1_MERCATOR6_OBC_BDY_merge/NEMOGCM/NEMO/OPA_SRC/BDY – NEMO

source: branches/2013/dev_r3987_METO1_MERCATOR6_OBC_BDY_merge/NEMOGCM/NEMO/OPA_SRC/BDY/bdydta.F90 @ 3991

Last change on this file since 3991 was 3991, checked in by davestorkey, 11 years ago

New branch from later branch point on trunk so you can do a clean
diff of all the changes. Copy in changes from dev_r3891_METO1_MERCATOR6_OBC_BDY_merge.
  • Property svn:keywords set to Id
File size: 35.7 KB
Line 
1MODULE bdydta
2   !!======================================================================
3   !!                       ***  MODULE bdydta  ***
4   !! Open boundary data : read the data for the unstructured open boundaries.
5   !!======================================================================
6   !! History :  1.0  !  2005-01  (J. Chanut, A. Sellar)  Original code
7   !!             -   !  2007-01  (D. Storkey) Update to use IOM module
8   !!             -   !  2007-07  (D. Storkey) add bdy_dta_fla
9   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
10   !!            3.3  !  2010-09  (E.O'Dea) modifications for Shelf configurations
11   !!            3.3  !  2010-09  (D.Storkey) add ice boundary conditions
12   !!            3.4  !  2011     (D. Storkey) rewrite in preparation for OBC-BDY merge
13   !!----------------------------------------------------------------------
14#if defined key_bdy
15   !!----------------------------------------------------------------------
16   !!   'key_bdy'                     Open Boundary Conditions
17   !!----------------------------------------------------------------------
18   !!    bdy_dta        : read external data along open boundaries from file
19   !!    bdy_dta_init   : initialise arrays etc for reading of external data
20   !!----------------------------------------------------------------------
21   USE wrk_nemo        ! Memory Allocation
22   USE timing          ! Timing
23   USE oce             ! ocean dynamics and tracers
24   USE dom_oce         ! ocean space and time domain
25   USE phycst          ! physical constants
26   USE bdy_oce         ! ocean open boundary conditions 
27   USE bdytides        ! tidal forcing at boundaries
28   USE fldread         ! read input fields
29   USE iom             ! IOM library
30   USE in_out_manager  ! I/O logical units
31#if defined key_lim2
32   USE ice_2
33#endif
34   USE sbcapr
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   bdy_dta          ! routine called by step.F90 and dynspg_ts.F90
40   PUBLIC   bdy_dta_init     ! routine called by nemogcm.F90
41
42   INTEGER, ALLOCATABLE, DIMENSION(:)   ::   nb_bdy_fld        ! Number of fields to update for each boundary set.
43   INTEGER                              ::   nb_bdy_fld_sum    ! Total number of fields to update for all boundary sets.
44
45   LOGICAL,           DIMENSION(jp_bdy) ::   ln_full_vel_array ! =T => full velocities in 3D boundary conditions
46                                                               ! =F => baroclinic velocities in 3D boundary conditions
47
48   TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:), TARGET ::   bf        ! structure of input fields (file informations, fields read)
49
50   TYPE(MAP_POINTER), ALLOCATABLE, DIMENSION(:) :: nbmap_ptr   ! array of pointers to nbmap
51
52#  include "domzgr_substitute.h90"
53   !!----------------------------------------------------------------------
54   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
55   !! $Id$
56   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
57   !!----------------------------------------------------------------------
58CONTAINS
59
60      SUBROUTINE bdy_dta( kt, jit, time_offset )
61      !!----------------------------------------------------------------------
62      !!                   ***  SUBROUTINE bdy_dta  ***
63      !!                   
64      !! ** Purpose :   Update external data for open boundary conditions
65      !!
66      !! ** Method  :   Use fldread.F90
67      !!               
68      !!----------------------------------------------------------------------
69      !!
70      INTEGER, INTENT( in )           ::   kt    ! ocean time-step index
71      INTEGER, INTENT( in ), OPTIONAL ::   jit   ! subcycle time-step index (for timesplitting option)
72      INTEGER, INTENT( in ), OPTIONAL ::   time_offset  ! time offset in units of timesteps. NB. if jit
73                                                        ! is present then units = subcycle timesteps.
74                                                        ! time_offset = 0 => get data at "now" time level
75                                                        ! time_offset = -1 => get data at "before" time level
76                                                        ! time_offset = +1 => get data at "after" time level
77                                                        ! etc.
78      !!
79      INTEGER     ::  ib_bdy, jfld, jstart, jend, ib, ii, ij, ik, igrd  ! local indices
80      INTEGER,          DIMENSION(jpbgrd) ::   ilen1 
81      INTEGER, POINTER, DIMENSION(:)      ::   nblen, nblenrim  ! short cuts
82      TYPE(OBC_DATA), POINTER             ::   dta              ! short cut
83      !!
84      !!---------------------------------------------------------------------------
85      !!
86      IF( nn_timing == 1 ) CALL timing_start('bdy_dta')
87
88      ! Initialise data arrays once for all from initial conditions where required
89      !---------------------------------------------------------------------------
90      IF( kt .eq. nit000 .and. .not. PRESENT(jit) ) THEN
91
92         ! Calculate depth-mean currents
93         !-----------------------------
94         CALL wrk_alloc(jpi,jpj,pun2d,pvn2d) 
95
96         pun2d(:,:) = 0.e0
97         pvn2d(:,:) = 0.e0
98         DO ik = 1, jpkm1   !! Vertically integrated momentum trends
99             pun2d(:,:) = pun2d(:,:) + fse3u(:,:,ik) * umask(:,:,ik) * un(:,:,ik)
100             pvn2d(:,:) = pvn2d(:,:) + fse3v(:,:,ik) * vmask(:,:,ik) * vn(:,:,ik)
101         END DO
102         pun2d(:,:) = pun2d(:,:) * hur(:,:)
103         pvn2d(:,:) = pvn2d(:,:) * hvr(:,:)
104         
105         DO ib_bdy = 1, nb_bdy
106
107            nblen => idx_bdy(ib_bdy)%nblen
108            nblenrim => idx_bdy(ib_bdy)%nblenrim
109            dta => dta_bdy(ib_bdy)
110
111            IF( nn_dyn2d_dta(ib_bdy) .eq. 0 ) THEN
112               ilen1(:) = nblen(:)
113               IF( dta%ll_ssh ) THEN
114                  igrd = 1
115                  DO ib = 1, ilen1(igrd)
116                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
117                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
118                     dta_bdy(ib_bdy)%ssh(ib) = sshn(ii,ij) * tmask(ii,ij,1)         
119                  END DO
120               END IF
121               IF( dta%ll_u2d ) THEN
122                  igrd = 2
123                  DO ib = 1, ilen1(igrd)
124                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
125                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
126                     dta_bdy(ib_bdy)%u2d(ib) = pun2d(ii,ij) * umask(ii,ij,1)         
127                  END DO
128               END IF
129               IF( dta%ll_v2d ) THEN
130                  igrd = 3
131                  DO ib = 1, ilen1(igrd)
132                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
133                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
134                     dta_bdy(ib_bdy)%v2d(ib) = pvn2d(ii,ij) * vmask(ii,ij,1)         
135                  END DO
136               END IF
137            ENDIF
138
139            IF( nn_dyn3d_dta(ib_bdy) .eq. 0 ) THEN
140               ilen1(:) = nblen(:)
141               IF( dta%ll_u3d ) THEN
142                  igrd = 2 
143                  DO ib = 1, ilen1(igrd)
144                     DO ik = 1, jpkm1
145                        ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
146                        ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
147                        dta_bdy(ib_bdy)%u3d(ib,ik) =  ( un(ii,ij,ik) - pun2d(ii,ij) ) * umask(ii,ij,ik)         
148                     END DO
149                  END DO
150               END IF
151               IF( dta%ll_v3d ) THEN
152                  igrd = 3 
153                  DO ib = 1, ilen1(igrd)
154                     DO ik = 1, jpkm1
155                        ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
156                        ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
157                        dta_bdy(ib_bdy)%v3d(ib,ik) =  ( vn(ii,ij,ik) - pvn2d(ii,ij) ) * vmask(ii,ij,ik)         
158                        END DO
159                  END DO
160               END IF
161            ENDIF
162
163            IF( nn_tra_dta(ib_bdy) .eq. 0 ) THEN
164               ilen1(:) = nblen(:)
165               IF( dta%ll_tem ) THEN
166                  igrd = 1 
167                  DO ib = 1, ilen1(igrd)
168                     DO ik = 1, jpkm1
169                        ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
170                        ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
171                        dta_bdy(ib_bdy)%tem(ib,ik) = tsn(ii,ij,ik,jp_tem) * tmask(ii,ij,ik)         
172                     END DO
173                  END DO
174               END IF
175               IF( dta%ll_sal ) THEN
176                  igrd = 1 
177                  DO ib = 1, ilen1(igrd)
178                     DO ik = 1, jpkm1
179                        ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
180                        ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
181                        dta_bdy(ib_bdy)%sal(ib,ik) = tsn(ii,ij,ik,jp_sal) * tmask(ii,ij,ik)         
182                     END DO
183                  END DO
184               END IF
185            ENDIF
186
187#if defined key_lim2
188            IF( nn_ice_lim2_dta(ib_bdy) .eq. 0 ) THEN
189               ilen1(:) = nblen(:)
190               IF( dta%ll_frld ) THEN
191                  igrd = 1 
192                  DO ib = 1, ilen1(igrd)
193                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
194                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
195                     dta_bdy(ib_bdy)%frld(ib) = frld(ii,ij) * tmask(ii,ij,1)         
196                  END DO
197               END IF
198               IF( dta%ll_hicif ) THEN
199                  igrd = 1 
200                  DO ib = 1, ilen1(igrd)
201                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
202                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
203                     dta_bdy(ib_bdy)%hicif(ib) = hicif(ii,ij) * tmask(ii,ij,1)         
204                  END DO
205               END IF
206               IF( dta%ll_hsnif ) THEN
207                  igrd = 1 
208                  DO ib = 1, ilen1(igrd)
209                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
210                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
211                     dta_bdy(ib_bdy)%hsnif(ib) = hsnif(ii,ij) * tmask(ii,ij,1)         
212                  END DO
213               END IF
214            ENDIF
215#endif
216
217         ENDDO ! ib_bdy
218
219         CALL wrk_dealloc(jpi,jpj,pun2d,pvn2d) 
220
221      ENDIF ! kt .eq. nit000
222
223      ! update external data from files
224      !--------------------------------
225     
226      jstart = 1
227      DO ib_bdy = 1, nb_bdy   
228         dta => dta_bdy(ib_bdy)
229         IF( nn_dta(ib_bdy) .eq. 1 ) THEN ! skip this bit if no external data required
230     
231            IF( PRESENT(jit) ) THEN
232               ! Update barotropic boundary conditions only
233               ! jit is optional argument for fld_read and bdytide_update
234               IF( cn_dyn2d(ib_bdy) /= 'none' ) THEN
235                  IF( nn_dyn2d_dta(ib_bdy) .eq. 2 ) THEN ! tidal harmonic forcing ONLY: initialise arrays
236                     IF( dta%ll_ssh ) dta%ssh(:) = 0.0
237                     IF( dta%ll_u2d ) dta%u2d(:) = 0.0
238                     IF( dta%ll_u3d ) dta%v2d(:) = 0.0
239                  ENDIF
240                  IF (cn_tra(ib_bdy) /= 'runoff') THEN
241                     IF( nn_dyn2d_dta(ib_bdy) .EQ. 1 .OR. nn_dyn2d_dta(ib_bdy) .EQ. 3 ) THEN
242
243                        jend = jstart + dta%nread(2) - 1
244                        CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), map=nbmap_ptr(jstart:jend),  &
245                                     & kit=jit, kt_offset=time_offset )
246
247                        ! If full velocities in boundary data then extract barotropic velocities from 3D fields
248                        IF( ln_full_vel_array(ib_bdy) .AND.                                             &
249                          &    ( nn_dyn2d_dta(ib_bdy) .EQ. 1 .OR. nn_dyn2d_dta(ib_bdy) .EQ. 3 .OR.  &
250                          &      nn_dyn3d_dta(ib_bdy) .EQ. 1 ) )THEN
251
252                           igrd = 2                      ! zonal velocity
253                           dta%u2d(:) = 0.0
254                           DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
255                              ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
256                              ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
257                              DO ik = 1, jpkm1
258                                 dta%u2d(ib) = dta%u2d(ib) &
259                       &                          + fse3u(ii,ij,ik) * umask(ii,ij,ik) * dta%u3d(ib,ik)
260                              END DO
261                              dta%u2d(ib) =  dta%u2d(ib) * hur(ii,ij)
262                           END DO
263                           igrd = 3                      ! meridional velocity
264                           dta%v2d(:) = 0.0
265                           DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
266                              ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
267                              ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
268                              DO ik = 1, jpkm1
269                                 dta%v2d(ib) = dta%v2d(ib) &
270                       &                       + fse3v(ii,ij,ik) * vmask(ii,ij,ik) * dta%v3d(ib,ik)
271                              END DO
272                              dta%v2d(ib) =  dta%v2d(ib) * hvr(ii,ij)
273                           END DO
274                        ENDIF                   
275                     ENDIF
276                     IF( nn_dyn2d_dta(ib_bdy) .ge. 2 ) THEN ! update tidal harmonic forcing
277                        CALL bdytide_update( kt=kt, idx=idx_bdy(ib_bdy), dta=dta, td=tides(ib_bdy),   & 
278                          &                 jit=jit, time_offset=time_offset )
279                     ENDIF
280                  ENDIF
281               ENDIF
282            ELSE
283               IF (cn_tra(ib_bdy) == 'runoff') then      ! runoff condition
284                  jend = nb_bdy_fld(ib_bdy)
285                  CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend),  &
286                               & map=nbmap_ptr(jstart:jend), kt_offset=time_offset )
287                  !
288                  igrd = 2                      ! zonal velocity
289                  DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
290                     ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
291                     ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
292                     dta%u2d(ib) = dta%u2d(ib) / ( e2u(ii,ij) * hu_0(ii,ij) )
293                  END DO
294                  !
295                  igrd = 3                      ! meridional velocity
296                  DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
297                     ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
298                     ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
299                     dta%v2d(ib) = dta%v2d(ib) / ( e1v(ii,ij) * hv_0(ii,ij) )
300                  END DO
301               ELSE
302                  IF( nn_dyn2d_dta(ib_bdy) .eq. 2 ) THEN ! tidal harmonic forcing ONLY: initialise arrays
303                     IF( dta%ll_ssh ) dta%ssh(:) = 0.0
304                     IF( dta%ll_u2d ) dta%u2d(:) = 0.0
305                     IF( dta%ll_v2d ) dta%v2d(:) = 0.0
306                  ENDIF
307                  IF( dta%nread(1) .gt. 0 ) THEN ! update external data
308                     jend = jstart + dta%nread(1) - 1
309                     CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), &
310                                  & map=nbmap_ptr(jstart:jend), kt_offset=time_offset )
311                  ENDIF
312                  ! If full velocities in boundary data then split into barotropic and baroclinic data
313                  IF( ln_full_vel_array(ib_bdy) .and.                                             &
314                    & ( nn_dyn2d_dta(ib_bdy) .EQ. 1 .OR. nn_dyn2d_dta(ib_bdy) .EQ. 3 .OR. &
315                    &   nn_dyn3d_dta(ib_bdy) .EQ. 1 ) ) THEN
316                     igrd = 2                      ! zonal velocity
317                     dta%u2d(:) = 0.0
318                     DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
319                        ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
320                        ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
321                        DO ik = 1, jpkm1
322                           dta%u2d(ib) = dta%u2d(ib) &
323                 &                       + fse3u(ii,ij,ik) * umask(ii,ij,ik) * dta%u3d(ib,ik)
324                        END DO
325                        dta%u2d(ib) =  dta%u2d(ib) * hur(ii,ij)
326                        DO ik = 1, jpkm1
327                           dta%u3d(ib,ik) = dta%u3d(ib,ik) - dta%u2d(ib)
328                        END DO
329                     END DO
330                     igrd = 3                      ! meridional velocity
331                     dta%v2d(:) = 0.0
332                     DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
333                        ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
334                        ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
335                        DO ik = 1, jpkm1
336                           dta%v2d(ib) = dta%v2d(ib) &
337                 &                       + fse3v(ii,ij,ik) * vmask(ii,ij,ik) * dta%v3d(ib,ik)
338                        END DO
339                        dta%v2d(ib) =  dta%v2d(ib) * hvr(ii,ij)
340                        DO ik = 1, jpkm1
341                           dta%v3d(ib,ik) = dta%v3d(ib,ik) - dta%v2d(ib)
342                        END DO
343                     END DO
344                  ENDIF
345                  IF( cn_dyn2d(ib_bdy) /= 'none' .and. nn_dyn2d_dta(ib_bdy) .ge. 2 ) THEN ! update tidal harmonic forcing
346                     CALL bdytide_update( kt=kt, idx=idx_bdy(ib_bdy), dta=dta,  &
347                                        & td=tides(ib_bdy), time_offset=time_offset )
348                  ENDIF
349               ENDIF
350            ENDIF
351            jstart = jstart + dta%nread(1)
352         END IF ! nn_dta(ib_bdy) = 1
353      END DO  ! ib_bdy
354
355      IF ( ln_apr_obc ) THEN
356         DO ib_bdy = 1, nb_bdy
357            IF (cn_tra(ib_bdy) /= 'runoff')THEN
358               igrd = 1                      ! meridional velocity
359               DO ib = 1, idx_bdy(ib_bdy)%nblenrim(igrd)
360                  ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
361                  ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
362                  dta_bdy(ib_bdy)%ssh(ib) = dta_bdy(ib_bdy)%ssh(ib) + ssh_ib(ii,ij)
363               ENDDO
364            ENDIF
365         ENDDO
366      ENDIF
367
368      IF( nn_timing == 1 ) CALL timing_stop('bdy_dta')
369
370      END SUBROUTINE bdy_dta
371
372
373      SUBROUTINE bdy_dta_init
374      !!----------------------------------------------------------------------
375      !!                   ***  SUBROUTINE bdy_dta_init  ***
376      !!                   
377      !! ** Purpose :   Initialise arrays for reading of external data
378      !!                for open boundary conditions
379      !!
380      !! ** Method  :   
381      !!               
382      !!----------------------------------------------------------------------
383      USE dynspg_oce, ONLY: lk_dynspg_ts
384      !!
385      INTEGER     ::  ib_bdy, jfld, jstart, jend, ierror  ! local indices
386      !!
387      CHARACTER(len=100)                     ::   cn_dir        ! Root directory for location of data files
388      CHARACTER(len=100), DIMENSION(nb_bdy)  ::   cn_dir_array  ! Root directory for location of data files
389      LOGICAL                                ::   ln_full_vel   ! =T => full velocities in 3D boundary data
390                                                                ! =F => baroclinic velocities in 3D boundary data
391      INTEGER                                ::   ilen_global   ! Max length required for global bdy dta arrays
392      INTEGER, ALLOCATABLE, DIMENSION(:)     ::   ilen1, ilen3  ! size of 1st and 3rd dimensions of local arrays
393      INTEGER, ALLOCATABLE, DIMENSION(:)     ::   ibdy           ! bdy set for a particular jfld
394      INTEGER, ALLOCATABLE, DIMENSION(:)     ::   igrid         ! index for grid type (1,2,3 = T,U,V)
395      INTEGER, POINTER, DIMENSION(:)         ::   nblen, nblenrim  ! short cuts
396      TYPE(OBC_DATA), POINTER                ::   dta           ! short cut
397      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::   blf_i         !  array of namelist information structures
398      TYPE(FLD_N) ::   bn_tem, bn_sal, bn_u3d, bn_v3d   !
399      TYPE(FLD_N) ::   bn_ssh, bn_u2d, bn_v2d           ! informations about the fields to be read
400#if defined key_lim2
401      TYPE(FLD_N) ::   bn_frld, bn_hicif, bn_hsnif      !
402#endif
403      NAMELIST/nambdy_dta/ cn_dir, bn_tem, bn_sal, bn_u3d, bn_v3d, bn_ssh, bn_u2d, bn_v2d 
404#if defined key_lim2
405      NAMELIST/nambdy_dta/ bn_frld, bn_hicif, bn_hsnif
406#endif
407      NAMELIST/nambdy_dta/ ln_full_vel
408      !!---------------------------------------------------------------------------
409
410      IF( nn_timing == 1 ) CALL timing_start('bdy_dta_init')
411
412      IF(lwp) WRITE(numout,*)
413      IF(lwp) WRITE(numout,*) 'bdy_dta_ini : initialization of data at the open boundaries'
414      IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
415      IF(lwp) WRITE(numout,*) ''
416
417      ! Set nn_dta
418      DO ib_bdy = 1, nb_bdy
419         nn_dta(ib_bdy) = MAX(  nn_dyn2d_dta(ib_bdy)       &
420                               ,nn_dyn3d_dta(ib_bdy)       &
421                               ,nn_tra_dta(ib_bdy)         &
422#if defined key_lim2
423                               ,nn_ice_lim2_dta(ib_bdy)    &
424#endif
425                              )
426         IF(nn_dta(ib_bdy) .gt. 1) nn_dta(ib_bdy) = 1
427      END DO
428
429      ! Work out upper bound of how many fields there are to read in and allocate arrays
430      ! ---------------------------------------------------------------------------
431      ALLOCATE( nb_bdy_fld(nb_bdy) )
432      nb_bdy_fld(:) = 0
433      DO ib_bdy = 1, nb_bdy         
434         IF( cn_dyn2d(ib_bdy) /= 'none' .and. ( nn_dyn2d_dta(ib_bdy) .eq. 1 .or. nn_dyn2d_dta(ib_bdy) .eq. 3 ) ) THEN
435            nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 3
436         ENDIF
437         IF( cn_dyn3d(ib_bdy) /= 'none' .and. nn_dyn3d_dta(ib_bdy) .eq. 1 ) THEN
438            nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 2
439         ENDIF
440         IF( cn_tra(ib_bdy) /= 'none' .and. nn_tra_dta(ib_bdy) .eq. 1  ) THEN
441            nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 2
442         ENDIF
443#if defined key_lim2
444         IF( cn_ice_lim2(ib_bdy) /= 'none' .and. nn_ice_lim2_dta(ib_bdy) .eq. 1  ) THEN
445            nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 3
446         ENDIF
447#endif               
448         IF(lwp) WRITE(numout,*) 'Maximum number of files to open =',nb_bdy_fld(ib_bdy)
449      ENDDO           
450
451      nb_bdy_fld_sum = SUM( nb_bdy_fld )
452
453      ALLOCATE( bf(nb_bdy_fld_sum), STAT=ierror )
454      IF( ierror > 0 ) THEN   
455         CALL ctl_stop( 'bdy_dta: unable to allocate bf structure' )   ;   RETURN 
456      ENDIF
457      ALLOCATE( blf_i(nb_bdy_fld_sum), STAT=ierror )
458      IF( ierror > 0 ) THEN   
459         CALL ctl_stop( 'bdy_dta: unable to allocate blf_i structure' )   ;   RETURN 
460      ENDIF
461      ALLOCATE( nbmap_ptr(nb_bdy_fld_sum), STAT=ierror )
462      IF( ierror > 0 ) THEN   
463         CALL ctl_stop( 'bdy_dta: unable to allocate nbmap_ptr structure' )   ;   RETURN 
464      ENDIF
465      ALLOCATE( ilen1(nb_bdy_fld_sum), ilen3(nb_bdy_fld_sum) ) 
466      ALLOCATE( ibdy(nb_bdy_fld_sum) ) 
467      ALLOCATE( igrid(nb_bdy_fld_sum) ) 
468
469      ! Read namelists
470      ! --------------
471      REWIND(numnam)
472      jfld = 0 
473      DO ib_bdy = 1, nb_bdy         
474         IF( nn_dta(ib_bdy) .eq. 1 ) THEN
475            ! set file information
476            cn_dir = './'        ! directory in which the model is executed
477            ln_full_vel = .false.
478            ! ... default values (NB: frequency positive => hours, negative => months)
479            !                    !  file       ! frequency !  variable   ! time intep !  clim   ! 'yearly' or ! weights  ! rotation  !
480            !                    !  name       ! hours !   name     !  (T/F)  !  (T/F)  !  'monthly'  ! filename ! pairs     !
481            bn_ssh     = FLD_N(  'bdy_ssh'     ,  24   , 'sossheig' , .false. , .false. ,   'yearly'  , ''       , ''        )
482            bn_u2d     = FLD_N(  'bdy_vel2d_u' ,  24   , 'vobtcrtx' , .false. , .false. ,   'yearly'  , ''       , ''        )
483            bn_v2d     = FLD_N(  'bdy_vel2d_v' ,  24   , 'vobtcrty' , .false. , .false. ,   'yearly'  , ''       , ''        )
484            bn_u3d     = FLD_N(  'bdy_vel3d_u' ,  24   , 'vozocrtx' , .false. , .false. ,   'yearly'  , ''       , ''        )
485            bn_v3d     = FLD_N(  'bdy_vel3d_v' ,  24   , 'vomecrty' , .false. , .false. ,   'yearly'  , ''       , ''        )
486            bn_tem     = FLD_N(  'bdy_tem'     ,  24   , 'votemper' , .false. , .false. ,   'yearly'  , ''       , ''        )
487            bn_sal     = FLD_N(  'bdy_sal'     ,  24   , 'vosaline' , .false. , .false. ,   'yearly'  , ''       , ''        )
488#if defined key_lim2
489            bn_frld    = FLD_N(  'bdy_frld'    ,  24   , 'ildsconc' , .false. , .false. ,   'yearly'  , ''       , ''        )
490            bn_hicif   = FLD_N(  'bdy_hicif'   ,  24   , 'iicethic' , .false. , .false. ,   'yearly'  , ''       , ''        )
491            bn_hsnif   = FLD_N(  'bdy_hsnif'   ,  24   , 'isnothic' , .false. , .false. ,   'yearly'  , ''       , ''        )
492#endif
493
494            ! Important NOT to rewind here.
495            READ( numnam, nambdy_dta )
496
497            cn_dir_array(ib_bdy) = cn_dir
498            ln_full_vel_array(ib_bdy) = ln_full_vel
499
500            nblen => idx_bdy(ib_bdy)%nblen
501            nblenrim => idx_bdy(ib_bdy)%nblenrim
502            dta => dta_bdy(ib_bdy)
503            dta%nread(2) = 0
504
505            ! Only read in necessary fields for this set.
506            ! Important that barotropic variables come first.
507            IF( nn_dyn2d_dta(ib_bdy) .eq. 1 .or. nn_dyn2d_dta(ib_bdy) .eq. 3 ) THEN
508
509               IF( dta%ll_ssh ) THEN
510                  if(lwp) write(numout,*) '++++++ reading in ssh field'
511                  jfld = jfld + 1
512                  blf_i(jfld) = bn_ssh
513                  ibdy(jfld) = ib_bdy
514                  igrid(jfld) = 1
515                  ilen1(jfld) = nblen(igrid(jfld))
516                  ilen3(jfld) = 1
517                  dta%nread(2) = dta%nread(2) + 1
518               ENDIF
519
520               IF( dta%ll_u2d .and. .not. ln_full_vel_array(ib_bdy) ) THEN
521                  if(lwp) write(numout,*) '++++++ reading in u2d field'
522                  jfld = jfld + 1
523                  blf_i(jfld) = bn_u2d
524                  ibdy(jfld) = ib_bdy
525                  igrid(jfld) = 2
526                  ilen1(jfld) = nblen(igrid(jfld))
527                  ilen3(jfld) = 1
528                  dta%nread(2) = dta%nread(2) + 1
529               ENDIF
530
531               IF( dta%ll_v2d .and. .not. ln_full_vel_array(ib_bdy) ) THEN
532                  if(lwp) write(numout,*) '++++++ reading in v2d field'
533                  jfld = jfld + 1
534                  blf_i(jfld) = bn_v2d
535                  ibdy(jfld) = ib_bdy
536                  igrid(jfld) = 3
537                  ilen1(jfld) = nblen(igrid(jfld))
538                  ilen3(jfld) = 1
539                  dta%nread(2) = dta%nread(2) + 1
540               ENDIF
541
542            ENDIF
543
544            ! read 3D velocities if baroclinic velocities require OR if
545            ! barotropic velocities required and ln_full_vel set to .true.
546            IF( nn_dyn3d_dta(ib_bdy) .eq. 1 .or. &
547           &  ( ln_full_vel_array(ib_bdy) .and. ( nn_dyn2d_dta(ib_bdy) .eq. 1 .or. nn_dyn2d_dta(ib_bdy) .eq. 3 ) ) ) THEN
548
549               IF( dta%ll_u3d .or. ( ln_full_vel_array(ib_bdy) .and. dta%ll_u2d ) ) THEN
550                  if(lwp) write(numout,*) '++++++ reading in u3d field'
551                  jfld = jfld + 1
552                  blf_i(jfld) = bn_u3d
553                  ibdy(jfld) = ib_bdy
554                  igrid(jfld) = 2
555                  ilen1(jfld) = nblen(igrid(jfld))
556                  ilen3(jfld) = jpk
557                  IF( ln_full_vel_array(ib_bdy) .and. dta%ll_u2d ) dta%nread(2) = dta%nread(2) + 1
558               ENDIF
559
560               IF( dta%ll_v3d .or. ( ln_full_vel_array(ib_bdy) .and. dta%ll_v2d ) ) THEN
561                  if(lwp) write(numout,*) '++++++ reading in v3d field'
562                  jfld = jfld + 1
563                  blf_i(jfld) = bn_v3d
564                  ibdy(jfld) = ib_bdy
565                  igrid(jfld) = 3
566                  ilen1(jfld) = nblen(igrid(jfld))
567                  ilen3(jfld) = jpk
568                  IF( ln_full_vel_array(ib_bdy) .and. dta%ll_v2d ) dta%nread(2) = dta%nread(2) + 1
569               ENDIF
570
571            ENDIF
572
573            ! temperature and salinity
574            IF( nn_tra_dta(ib_bdy) .eq. 1 ) THEN
575
576               IF( dta%ll_tem ) THEN
577                  if(lwp) write(numout,*) '++++++ reading in tem field'
578                  jfld = jfld + 1
579                  blf_i(jfld) = bn_tem
580                  ibdy(jfld) = ib_bdy
581                  igrid(jfld) = 1
582                  ilen1(jfld) = nblen(igrid(jfld))
583                  ilen3(jfld) = jpk
584               ENDIF
585
586               IF( dta%ll_sal ) THEN
587                  if(lwp) write(numout,*) '++++++ reading in sal field'
588                  jfld = jfld + 1
589                  blf_i(jfld) = bn_sal
590                  ibdy(jfld) = ib_bdy
591                  igrid(jfld) = 1
592                  ilen1(jfld) = nblen(igrid(jfld))
593                  ilen3(jfld) = jpk
594               ENDIF
595
596            ENDIF
597
598#if defined key_lim2
599            ! sea ice
600            IF( nn_ice_lim2_dta(ib_bdy) .eq. 1 ) THEN
601
602               IF( dta%ll_frld ) THEN
603                  jfld = jfld + 1
604                  blf_i(jfld) = bn_frld
605                  ibdy(jfld) = ib_bdy
606                  igrid(jfld) = 1
607                  ilen1(jfld) = nblen(igrid(jfld))
608                  ilen3(jfld) = 1
609               ENDIF
610
611               IF( dta%ll_hicif ) THEN
612                  jfld = jfld + 1
613                  blf_i(jfld) = bn_hicif
614                  ibdy(jfld) = ib_bdy
615                  igrid(jfld) = 1
616                  ilen1(jfld) = nblen(igrid(jfld))
617                  ilen3(jfld) = 1
618               ENDIF
619
620               IF( dta%ll_hsnif ) THEN
621                  jfld = jfld + 1
622                  blf_i(jfld) = bn_hsnif
623                  ibdy(jfld) = ib_bdy
624                  igrid(jfld) = 1
625                  ilen1(jfld) = nblen(igrid(jfld))
626                  ilen3(jfld) = 1
627               ENDIF
628
629            ENDIF
630#endif
631            ! Recalculate field counts
632            !-------------------------
633            IF( ib_bdy .eq. 1 ) THEN
634               nb_bdy_fld_sum = 0
635               nb_bdy_fld(ib_bdy) = jfld
636               nb_bdy_fld_sum     = jfld             
637            ELSE
638               nb_bdy_fld(ib_bdy) = jfld - nb_bdy_fld_sum
639               nb_bdy_fld_sum = nb_bdy_fld_sum + nb_bdy_fld(ib_bdy)
640            ENDIF
641
642            dta%nread(1) = nb_bdy_fld(ib_bdy)
643
644         ENDIF ! nn_dta .eq. 1
645      ENDDO ! ib_bdy
646
647      DO jfld = 1, nb_bdy_fld_sum
648         ALLOCATE( bf(jfld)%fnow(ilen1(jfld),1,ilen3(jfld)) )
649         IF( blf_i(jfld)%ln_tint ) ALLOCATE( bf(jfld)%fdta(ilen1(jfld),1,ilen3(jfld),2) )
650         nbmap_ptr(jfld)%ptr => idx_bdy(ibdy(jfld))%nbmap(:,igrid(jfld))
651      ENDDO
652
653      ! fill bf with blf_i and control print
654      !-------------------------------------
655      jstart = 1
656      DO ib_bdy = 1, nb_bdy
657         jend = nb_bdy_fld(ib_bdy) 
658         CALL fld_fill( bf(jstart:jend), blf_i(jstart:jend), cn_dir_array(ib_bdy), 'bdy_dta',   &
659         &              'open boundary conditions', 'nambdy_dta' )
660         jstart = jend + 1
661      ENDDO
662
663      ! Initialise local boundary data arrays
664      ! nn_xxx_dta=0 : allocate space - will be filled from initial conditions later
665      ! nn_xxx_dta=1 : point to "fnow" arrays
666      !-------------------------------------
667
668      jfld = 0
669      DO ib_bdy=1, nb_bdy
670
671         nblen => idx_bdy(ib_bdy)%nblen
672         dta => dta_bdy(ib_bdy)
673
674         if(lwp) then
675            write(numout,*) '++++++ dta%ll_ssh = ',dta%ll_ssh
676            write(numout,*) '++++++ dta%ll_u2d = ',dta%ll_u2d
677            write(numout,*) '++++++ dta%ll_v2d = ',dta%ll_v2d
678            write(numout,*) '++++++ dta%ll_u3d = ',dta%ll_u3d
679            write(numout,*) '++++++ dta%ll_v3d = ',dta%ll_v3d
680            write(numout,*) '++++++ dta%ll_tem = ',dta%ll_tem
681            write(numout,*) '++++++ dta%ll_sal = ',dta%ll_sal
682         endif
683
684         IF ( nn_dyn2d_dta(ib_bdy) .eq. 0 .or. nn_dyn2d_dta(ib_bdy) .eq. 2 ) THEN
685            if(lwp) write(numout,*) '++++++ dta%ssh/u2d/u3d allocated space'
686            IF( dta%ll_ssh ) ALLOCATE( dta%ssh(nblen(1)) )
687            IF( dta%ll_u2d ) ALLOCATE( dta%u2d(nblen(2)) )
688            IF( dta%ll_v2d ) ALLOCATE( dta%v2d(nblen(3)) )
689         ENDIF
690         IF ( nn_dyn2d_dta(ib_bdy) .eq. 1 .or. nn_dyn2d_dta(ib_bdy) .eq. 3 ) THEN
691            IF( dta%ll_ssh ) THEN
692               if(lwp) write(numout,*) '++++++ dta%ssh pointing to fnow'
693               jfld = jfld + 1
694               dta%ssh => bf(jfld)%fnow(:,1,1)
695            ENDIF
696            IF ( dta%ll_u2d ) THEN
697               IF ( ln_full_vel_array(ib_bdy) ) THEN
698                  if(lwp) write(numout,*) '++++++ dta%u2d allocated space'
699                  ALLOCATE( dta%u2d(nblen(2)) )
700               ELSE
701                  if(lwp) write(numout,*) '++++++ dta%u2d pointing to fnow'
702                  jfld = jfld + 1
703                  dta%u2d => bf(jfld)%fnow(:,1,1)
704               ENDIF
705            ENDIF
706            IF ( dta%ll_v2d ) THEN
707               IF ( ln_full_vel_array(ib_bdy) ) THEN
708                  if(lwp) write(numout,*) '++++++ dta%v2d allocated space'
709                  ALLOCATE( dta%v2d(nblen(3)) )
710               ELSE
711                  if(lwp) write(numout,*) '++++++ dta%v2d pointing to fnow'
712                  jfld = jfld + 1
713                  dta%v2d => bf(jfld)%fnow(:,1,1)
714               ENDIF
715            ENDIF
716         ENDIF
717
718         IF ( nn_dyn3d_dta(ib_bdy) .eq. 0 ) THEN
719            if(lwp) write(numout,*) '++++++ dta%u3d/v3d allocated space'
720            IF( dta%ll_u3d ) ALLOCATE( dta_bdy(ib_bdy)%u3d(nblen(2),jpk) )
721            IF( dta%ll_v3d ) ALLOCATE( dta_bdy(ib_bdy)%v3d(nblen(3),jpk) )
722         ENDIF
723         IF ( nn_dyn3d_dta(ib_bdy) .eq. 1 .or. &
724           &  ( ln_full_vel_array(ib_bdy) .and. ( nn_dyn2d_dta(ib_bdy) .eq. 1 .or. nn_dyn2d_dta(ib_bdy) .eq. 3 ) ) ) THEN
725            IF ( dta%ll_u3d .or. ( ln_full_vel_array(ib_bdy) .and. dta%ll_u2d ) ) THEN
726               if(lwp) write(numout,*) '++++++ dta%u3d pointing to fnow'
727               jfld = jfld + 1
728               dta_bdy(ib_bdy)%u3d => bf(jfld)%fnow(:,1,:)
729            ENDIF
730            IF ( dta%ll_v3d .or. ( ln_full_vel_array(ib_bdy) .and. dta%ll_v2d ) ) THEN
731               if(lwp) write(numout,*) '++++++ dta%v3d pointing to fnow'
732               jfld = jfld + 1
733               dta_bdy(ib_bdy)%v3d => bf(jfld)%fnow(:,1,:)
734            ENDIF
735         ENDIF
736
737         IF( nn_tra_dta(ib_bdy) .eq. 0 ) THEN
738            if(lwp) write(numout,*) '++++++ dta%tem/sal allocated space'
739            IF( dta%ll_tem ) ALLOCATE( dta_bdy(ib_bdy)%tem(nblen(1),jpk) )
740            IF( dta%ll_sal ) ALLOCATE( dta_bdy(ib_bdy)%sal(nblen(1),jpk) )
741         ELSE
742            IF( dta%ll_tem ) THEN
743               if(lwp) write(numout,*) '++++++ dta%tem pointing to fnow'
744               jfld = jfld + 1
745               dta_bdy(ib_bdy)%tem => bf(jfld)%fnow(:,1,:)
746            ENDIF
747            IF( dta%ll_sal ) THEN
748               if(lwp) write(numout,*) '++++++ dta%sal pointing to fnow'
749               jfld = jfld + 1
750               dta_bdy(ib_bdy)%sal => bf(jfld)%fnow(:,1,:)
751            ENDIF
752         ENDIF
753
754#if defined key_lim2
755         IF (nn_ice_lim2(ib_bdy) .gt. 0) THEN
756            IF( nn_ice_lim2_dta(ib_bdy) .eq. 0 ) THEN
757               ALLOCATE( dta_bdy(ib_bdy)%frld(nblen(1)) )
758               ALLOCATE( dta_bdy(ib_bdy)%hicif(nblen(1)) )
759               ALLOCATE( dta_bdy(ib_bdy)%hsnif(nblen(1)) )
760            ELSE
761               jfld = jfld + 1
762               dta_bdy(ib_bdy)%frld  => bf(jfld)%fnow(:,1,1)
763               jfld = jfld + 1
764               dta_bdy(ib_bdy)%hicif => bf(jfld)%fnow(:,1,1)
765               jfld = jfld + 1
766               dta_bdy(ib_bdy)%hsnif => bf(jfld)%fnow(:,1,1)
767            ENDIF
768         ENDIF
769#endif
770
771      ENDDO ! ib_bdy
772
773      IF( nn_timing == 1 ) CALL timing_stop('bdy_dta_init')
774
775      END SUBROUTINE bdy_dta_init
776
777#else
778   !!----------------------------------------------------------------------
779   !!   Dummy module                   NO Open Boundary Conditions
780   !!----------------------------------------------------------------------
781CONTAINS
782   SUBROUTINE bdy_dta( kt, jit, time_offset ) ! Empty routine
783      INTEGER, INTENT( in )           ::   kt   
784      INTEGER, INTENT( in ), OPTIONAL ::   jit   
785      INTEGER, INTENT( in ), OPTIONAL ::   time_offset
786      WRITE(*,*) 'bdy_dta: You should not have seen this print! error?', kt
787   END SUBROUTINE bdy_dta
788   SUBROUTINE bdy_dta_init()                  ! Empty routine
789      WRITE(*,*) 'bdy_dta_init: You should not have seen this print! error?'
790   END SUBROUTINE bdy_dta_init
791#endif
792
793   !!==============================================================================
794END MODULE bdydta
Note: See TracBrowser for help on using the repository browser.