New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdylib.F90 in branches/2013/dev_r3987_METO1_MERCATOR6_OBC_BDY_merge/NEMOGCM/NEMO/OPA_SRC/BDY – NEMO

source: branches/2013/dev_r3987_METO1_MERCATOR6_OBC_BDY_merge/NEMOGCM/NEMO/OPA_SRC/BDY/bdylib.F90 @ 4033

Last change on this file since 4033 was 4033, checked in by davestorkey, 11 years ago

Bug fixes for Orlanski routines:

  1. Correct formulation of relaxation term.
  2. Add spatial scale factors to calculation of radiation term.
File size: 19.4 KB
Line 
1MODULE bdylib
2   !!======================================================================
3   !!                       ***  MODULE  bdylib  ***
4   !! Unstructured Open Boundary Cond. :  Library module of generic boundary algorithms.
5   !!======================================================================
6   !! History :  3.6  !  2013     (D. Storkey) new module
7   !!----------------------------------------------------------------------
8#if defined key_bdy 
9   !!----------------------------------------------------------------------
10   !!   'key_bdy' :                    Unstructured Open Boundary Condition
11   !!----------------------------------------------------------------------
12   !!   bdy_orlanski_2d
13   !!   bdy_orlanski_3d
14   !!----------------------------------------------------------------------
15   USE timing          ! Timing
16   USE oce             ! ocean dynamics and tracers
17   USE dom_oce         ! ocean space and time domain
18   USE bdy_oce         ! ocean open boundary conditions
19   USE phycst          ! physical constants
20   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
21   USE in_out_manager  !
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   bdy_orlanski_2d     ! routine called where?
27   PUBLIC   bdy_orlanski_3d     ! routine called where?
28
29   !!----------------------------------------------------------------------
30   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
31   !! $Id: bdydyn.F90 2528 2010-12-27 17:33:53Z rblod $
32   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
33   !!----------------------------------------------------------------------
34CONTAINS
35
36   SUBROUTINE bdy_orlanski_2d( idx, igrd, phib, phia, phi_ext, ll_npo )
37      !!----------------------------------------------------------------------
38      !!                 ***  SUBROUTINE bdy_orlanski_2d  ***
39      !!             
40      !!              - Apply Orlanski radiation condition adaptively to 2D fields:
41      !!                  - radiation plus weak nudging at outflow points
42      !!                  - no radiation and strong nudging at inflow points
43      !!
44      !!
45      !! References:  Marchesiello, McWilliams and Shchepetkin, Ocean Modelling vol. 3 (2001)   
46      !!----------------------------------------------------------------------
47      TYPE(OBC_INDEX),            INTENT(in)     ::   idx      ! BDY indices
48      INTEGER,                    INTENT(in)     ::   igrd     ! grid index
49      REAL(wp), DIMENSION(:,:),   INTENT(in)     ::   phib     ! model before 2D field
50      REAL(wp), DIMENSION(:,:),   INTENT(inout)  ::   phia     ! model after 2D field (to be updated)
51      REAL(wp), DIMENSION(:),     INTENT(in)     ::   phi_ext  ! external forcing data
52      LOGICAL,                    INTENT(in)     ::   ll_npo   ! switch for NPO version
53
54      INTEGER  ::   jb                                     ! dummy loop indices
55      INTEGER  ::   ii, ij, iibm1, iibm2, ijbm1, ijbm2     ! 2D addresses
56      INTEGER  ::   iijm1, iijp1, ijjm1, ijjp1             ! 2D addresses
57      INTEGER  ::   iibm1jp1, iibm1jm1, ijbm1jp1, ijbm1jm1 ! 2D addresses
58      INTEGER  ::   ii_offset, ij_offset                   ! offsets for mask indices
59      INTEGER  ::   flagu, flagv                           ! short cuts
60      REAL(wp) ::   zmask_x, zmask_y1, zmask_y2
61      REAL(wp) ::   zex, zey, zey1, zey2
62      REAL(wp) ::   zdt, zdx, zdy, znor2, zrx, zry         ! intermediate calculations
63      REAL(wp) ::   zout, zwgt, zdy_centred
64      REAL(wp) ::   zdy_1, zdy_2, zsign_ups
65      REAL(wp), PARAMETER :: zepsilon = 1.e-30                 ! local small value
66      REAL(wp), POINTER, DIMENSION(:,:)          :: pmask      ! land/sea mask for field
67      REAL(wp), POINTER, DIMENSION(:,:)          :: pmask_xdif ! land/sea mask for x-derivatives
68      REAL(wp), POINTER, DIMENSION(:,:)          :: pmask_ydif ! land/sea mask for y-derivatives
69      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_xdif    ! scale factors for x-derivatives
70      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_ydif    ! scale factors for y-derivatives
71      !!----------------------------------------------------------------------
72
73      IF( nn_timing == 1 ) CALL timing_start('bdy_orlanski_2d')
74
75      ! ----------------------------------!
76      ! Orlanski boundary conditions     :!
77      ! ----------------------------------!
78     
79      SELECT CASE(igrd)
80         CASE(1)
81            pmask => tmask(:,:,1)
82            pmask_xdif => umask(:,:,1)
83            pmask_ydif => vmask(:,:,1)
84            pe_xdif => e1u(:,:)
85            pe_ydif => e2v(:,:)
86            ii_offset = 0
87            ij_offset = 0
88         CASE(2)
89            pmask => umask(:,:,1)
90            pmask_xdif => tmask(:,:,1)
91            pmask_ydif => fmask(:,:,1)
92            pe_xdif => e1t(:,:)
93            pe_ydif => e2f(:,:)
94            ii_offset = 1
95            ij_offset = 0
96         CASE(3)
97            pmask => vmask(:,:,1)
98            pmask_xdif => fmask(:,:,1)
99            pmask_ydif => tmask(:,:,1)
100            pe_xdif => e1f(:,:)
101            pe_ydif => e2t(:,:)
102            ii_offset = 0
103            ij_offset = 1
104         CASE DEFAULT ;   CALL ctl_stop( 'unrecognised value for igrd in bdy_orlanksi_2d' )
105      END SELECT
106      !
107      DO jb = 1, idx%nblenrim(igrd)
108         ii  = idx%nbi(jb,igrd)
109         ij  = idx%nbj(jb,igrd) 
110         flagu = int( idx%flagu(jb,igrd) )
111         flagv = int( idx%flagv(jb,igrd) )
112         !
113         ! Calculate positions of b-1 and b-2 points for this rim point
114         ! also (b-1,j-1) and (b-1,j+1) points
115         iibm1 = ii + flagu ; iibm2 = ii + 2*flagu 
116         ijbm1 = ij + flagv ; ijbm2 = ij + 2*flagv
117          !
118         iijm1 = ii - abs(flagv) ; iijp1 = ii + abs(flagv) 
119         ijjm1 = ij - abs(flagu) ; ijjp1 = ij + abs(flagu)
120         !
121         iibm1jm1 = ii + flagu - abs(flagv) ; iibm1jp1 = ii + flagu + abs(flagv) 
122         ijbm1jm1 = ij + flagv - abs(flagu) ; ijbm1jp1 = ij + flagv + abs(flagu) 
123         !
124         ! Calculate scale factors for calculation of spatial derivatives.       
125         zex = ( abs(iibm1-iibm2) * pe_xdif(iibm2+ii_offset,ijbm2          )         &
126        &      + abs(ijbm1-ijbm2) * pe_ydif(iibm2          ,ijbm2+ij_offset) ) 
127         zey1 = ( (iibm1-iibm1jm1) * pe_xdif(iibm1jm1+ii_offset,ijbm1jm1          )  & 
128        &      +  (ijbm1-ijbm1jm1) * pe_ydif(iibm1jm1          ,ijbm1jm1+ij_offset) ) 
129         zey2 = ( (iibm1jp1-iibm1) * pe_xdif(iibm1+ii_offset,ijbm1)                  &
130        &      +  (ijbm1jp1-ijbm1) * pe_ydif(iibm1          ,ijbm1+ij_offset) ) 
131         ! make sure scale factors are nonzero
132         if( zey1 .lt. rsmall ) zey1 = zey2
133         if( zey2 .lt. rsmall ) zey2 = zey1
134         zex = max(zex,rsmall); zey1 = max(zey1,rsmall); zey2 = max(zey2,rsmall); 
135         !
136         ! Calculate masks for calculation of spatial derivatives.       
137         zmask_x = ( abs(iibm1-iibm2) * pmask_xdif(iibm2+ii_offset,ijbm2          )         &
138        &          + abs(ijbm1-ijbm2) * pmask_ydif(iibm2          ,ijbm2+ij_offset) ) 
139         zmask_y1 = ( (iibm1-iibm1jm1) * pmask_xdif(iibm1jm1+ii_offset,ijbm1jm1          )  & 
140        &          +  (ijbm1-ijbm1jm1) * pmask_ydif(iibm1jm1          ,ijbm1jm1+ij_offset) ) 
141         zmask_y2 = ( (iibm1jp1-iibm1) * pmask_xdif(iibm1+ii_offset,ijbm1)                  &
142        &          +  (ijbm1jp1-ijbm1) * pmask_ydif(iibm1          ,ijbm1+ij_offset) ) 
143
144         ! Calculation of terms required for both versions of the scheme.
145         ! Mask derivatives to ensure correct land boundary conditions for each variable.
146         ! Centred derivative is calculated as average of "left" and "right" derivatives for
147         ! this reason.
148         ! Note no rdt factor in expression for zdt because it cancels in the expressions for
149         ! zrx and zry.
150         zdt = phia(iibm1,ijbm1) - phib(iibm1,ijbm1)
151         zdx = ( ( phia(iibm1,ijbm1) - phia(iibm2,ijbm2) ) / zex ) * zmask_x 
152         zdy_1 = ( ( phib(iibm1   ,ijbm1   ) - phib(iibm1jm1,ijbm1jm1) ) / zey1 ) * zmask_y1   
153         zdy_2 = ( ( phib(iibm1jp1,ijbm1jp1) - phib(iibm1   ,ijbm1)    ) / zey2 ) * zmask_y2 
154         zdy_centred = 0.5 * ( zdy_1 + zdy_2 )
155!!$         zdy_centred = phib(iibm1jp1,ijbm1jp1) - phib(iibm1jm1,ijbm1jm1)
156         ! upstream differencing for tangential derivatives
157         zsign_ups = sign( 1., zdt * zdy_centred )
158         zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
159         zdy = zsign_ups * zdy_1 + (1. - zsign_ups) * zdy_2
160         znor2 = zdx * zdx + zdy * zdy
161         znor2 = max(znor2,zepsilon)
162         !
163         zrx = zdt * zdx / ( zex * znor2 ) 
164         zrx = min(zrx,2.0_wp)
165         zout = sign( 1., zrx )
166         zout = 0.5*( zout + abs(zout) )
167         zwgt = 2.*rdt*( (1.-zout) * idx%nbd(jb,igrd) + zout * idx%nbdout(jb,igrd) )
168         ! only apply radiation on outflow points
169         if( ll_npo ) then     !! NPO version !!
170            phia(ii,ij) = (1.-zout) * ( phib(ii,ij) + zwgt * ( phi_ext(jb) - phib(ii,ij) ) )        &
171           &            + zout      * ( phib(ii,ij) + zrx*phia(iibm1,ijbm1)                         &
172           &                            + zwgt * ( phi_ext(jb) - phib(ii,ij) ) ) / ( 1. + zrx ) 
173         else                  !! full oblique radiation !!
174            zsign_ups = sign( 1., zdt * zdy )
175            zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
176            zey = zsign_ups * zey1 + (1.-zsign_ups) * zey2 
177            zry = zdt * zdy / ( zey * znor2 ) 
178            phia(ii,ij) = (1.-zout) * ( phib(ii,ij) + zwgt * ( phi_ext(jb) - phib(ii,ij) ) )        &
179           &            + zout      * ( phib(ii,ij) + zrx*phia(iibm1,ijbm1)                         &
180           &                    - zsign_ups      * zry * ( phib(ii   ,ij   ) - phib(iijm1,ijjm1 ) ) &
181           &                    - (1.-zsign_ups) * zry * ( phib(iijp1,ijjp1) - phib(ii   ,ij    ) ) &
182           &                    + zwgt * ( phi_ext(jb) - phib(ii,ij) ) ) / ( 1. + zrx ) 
183         end if
184         phia(ii,ij) = phia(ii,ij) * pmask(ii,ij)
185      END DO
186      !
187      IF( nn_timing == 1 ) CALL timing_stop('bdy_orlanski_2d')
188
189   END SUBROUTINE bdy_orlanski_2d
190
191
192   SUBROUTINE bdy_orlanski_3d( idx, igrd, phib, phia, phi_ext, ll_npo )
193      !!----------------------------------------------------------------------
194      !!                 ***  SUBROUTINE bdy_orlanski_3d  ***
195      !!             
196      !!              - Apply Orlanski radiation condition adaptively to 3D fields:
197      !!                  - radiation plus weak nudging at outflow points
198      !!                  - no radiation and strong nudging at inflow points
199      !!
200      !!
201      !! References:  Marchesiello, McWilliams and Shchepetkin, Ocean Modelling vol. 3 (2001)   
202      !!----------------------------------------------------------------------
203      TYPE(OBC_INDEX),            INTENT(in)     ::   idx      ! BDY indices
204      INTEGER,                    INTENT(in)     ::   igrd     ! grid index
205      REAL(wp), DIMENSION(:,:,:), INTENT(in)     ::   phib     ! model before 3D field
206      REAL(wp), DIMENSION(:,:,:), INTENT(inout)  ::   phia     ! model after 3D field (to be updated)
207      REAL(wp), DIMENSION(:,:),   INTENT(in)     ::   phi_ext  ! external forcing data
208      LOGICAL,                    INTENT(in)     ::   ll_npo   ! switch for NPO version
209
210      INTEGER  ::   jb, jk                                 ! dummy loop indices
211      INTEGER  ::   ii, ij, iibm1, iibm2, ijbm1, ijbm2     ! 2D addresses
212      INTEGER  ::   iijm1, iijp1, ijjm1, ijjp1             ! 2D addresses
213      INTEGER  ::   iibm1jp1, iibm1jm1, ijbm1jp1, ijbm1jm1 ! 2D addresses
214      INTEGER  ::   ii_offset, ij_offset                   ! offsets for mask indices
215      INTEGER  ::   flagu, flagv                           ! short cuts
216      REAL(wp) ::   zmask_x, zmask_y1, zmask_y2
217      REAL(wp) ::   zex, zey, zey1, zey2
218      REAL(wp) ::   zdt, zdx, zdy, znor2, zrx, zry         ! intermediate calculations
219      REAL(wp) ::   zout, zwgt, zdy_centred
220      REAL(wp) ::   zdy_1, zdy_2,  zsign_ups
221      REAL(wp), PARAMETER :: zepsilon = 1.e-30                 ! local small value
222      REAL(wp), POINTER, DIMENSION(:,:,:)        :: pmask      ! land/sea mask for field
223      REAL(wp), POINTER, DIMENSION(:,:,:)        :: pmask_xdif ! land/sea mask for x-derivatives
224      REAL(wp), POINTER, DIMENSION(:,:,:)        :: pmask_ydif ! land/sea mask for y-derivatives
225      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_xdif    ! scale factors for x-derivatives
226      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_ydif    ! scale factors for y-derivatives
227      !!----------------------------------------------------------------------
228
229      IF( nn_timing == 1 ) CALL timing_start('bdy_orlanski_3d')
230
231      ! ----------------------------------!
232      ! Orlanski boundary conditions     :!
233      ! ----------------------------------!
234     
235      SELECT CASE(igrd)
236         CASE(1)
237            pmask => tmask(:,:,:)
238            pmask_xdif => umask(:,:,:)
239            pmask_ydif => vmask(:,:,:)
240            pe_xdif => e1u(:,:)
241            pe_ydif => e2v(:,:)
242            ii_offset = 0
243            ij_offset = 0
244         CASE(2)
245            pmask => umask(:,:,:)
246            pmask_xdif => tmask(:,:,:)
247            pmask_ydif => fmask(:,:,:)
248            pe_xdif => e1t(:,:)
249            pe_ydif => e2f(:,:)
250            ii_offset = 1
251            ij_offset = 0
252         CASE(3)
253            pmask => vmask(:,:,:)
254            pmask_xdif => fmask(:,:,:)
255            pmask_ydif => tmask(:,:,:)
256            pe_xdif => e1f(:,:)
257            pe_ydif => e2t(:,:)
258            ii_offset = 0
259            ij_offset = 1
260         CASE DEFAULT ;   CALL ctl_stop( 'unrecognised value for igrd in bdy_orlanksi_2d' )
261      END SELECT
262
263      DO jk = 1, jpk
264         !           
265         DO jb = 1, idx%nblenrim(igrd)
266            ii  = idx%nbi(jb,igrd)
267            ij  = idx%nbj(jb,igrd) 
268            flagu = int( idx%flagu(jb,igrd) )
269            flagv = int( idx%flagv(jb,igrd) )
270            !
271            ! calculate positions of b-1 and b-2 points for this rim point
272            ! also (b-1,j-1) and (b-1,j+1) points
273            iibm1 = ii + flagu ; iibm2 = ii + 2*flagu 
274            ijbm1 = ij + flagv ; ijbm2 = ij + 2*flagv
275            !
276            iijm1 = ii - abs(flagv) ; iijp1 = ii + abs(flagv) 
277            ijjm1 = ij - abs(flagu) ; ijjp1 = ij + abs(flagu)
278            !
279            iibm1jm1 = ii + flagu - abs(flagv) ; iibm1jp1 = ii + flagu + abs(flagv) 
280            ijbm1jm1 = ij + flagv - abs(flagu) ; ijbm1jp1 = ij + flagv + abs(flagu) 
281            !
282            ! Calculate scale factors for calculation of spatial derivatives.       
283            zex = ( abs(iibm1-iibm2) * pe_xdif(iibm2+ii_offset,ijbm2          )         &
284           &      + abs(ijbm1-ijbm2) * pe_ydif(iibm2          ,ijbm2+ij_offset) ) 
285            zey1 = ( (iibm1-iibm1jm1) * pe_xdif(iibm1jm1+ii_offset,ijbm1jm1          )  & 
286           &      +  (ijbm1-ijbm1jm1) * pe_ydif(iibm1jm1          ,ijbm1jm1+ij_offset) ) 
287            zey2 = ( (iibm1jp1-iibm1) * pe_xdif(iibm1+ii_offset,ijbm1)                  &
288           &      +  (ijbm1jp1-ijbm1) * pe_ydif(iibm1          ,ijbm1+ij_offset) ) 
289            ! make sure scale factors are nonzero
290            if( zey1 .lt. rsmall ) zey1 = zey2
291            if( zey2 .lt. rsmall ) zey2 = zey1
292            zex = max(zex,rsmall); zey1 = max(zey1,rsmall); zey2 = max(zey2,rsmall); 
293            !
294            ! Calculate masks for calculation of spatial derivatives.       
295            zmask_x = ( abs(iibm1-iibm2) * pmask_xdif(iibm2+ii_offset,ijbm2          ,jk)          &
296           &          + abs(ijbm1-ijbm2) * pmask_ydif(iibm2          ,ijbm2+ij_offset,jk) ) 
297            zmask_y1 = ( (iibm1-iibm1jm1) * pmask_xdif(iibm1jm1+ii_offset,ijbm1jm1          ,jk)   & 
298           &          +  (ijbm1-ijbm1jm1) * pmask_ydif(iibm1jm1          ,ijbm1jm1+ij_offset,jk) ) 
299            zmask_y2 = ( (iibm1jp1-iibm1) * pmask_xdif(iibm1+ii_offset,ijbm1          ,jk)         &
300           &          +  (ijbm1jp1-ijbm1) * pmask_ydif(iibm1          ,ijbm1+ij_offset,jk) ) 
301            !
302            ! Calculate normal (zrx) and tangential (zry) components of radiation velocities.
303            ! Mask derivatives to ensure correct land boundary conditions for each variable.
304            ! Centred derivative is calculated as average of "left" and "right" derivatives for
305            ! this reason.
306            zdt = phia(iibm1,ijbm1,jk) - phib(iibm1,ijbm1,jk)
307            zdx = ( ( phia(iibm1,ijbm1,jk) - phia(iibm2,ijbm2,jk) ) / zex ) * zmask_x                 
308            zdy_1 = ( ( phib(iibm1   ,ijbm1   ,jk) - phib(iibm1jm1,ijbm1jm1,jk) ) / zey1 ) * zmask_y1 
309            zdy_2 = ( ( phib(iibm1jp1,ijbm1jp1,jk) - phib(iibm1   ,ijbm1   ,jk) ) / zey2 ) * zmask_y2     
310            zdy_centred = 0.5 * ( zdy_1 + zdy_2 )
311!!$            zdy_centred = phib(iibm1jp1,ijbm1jp1,jk) - phib(iibm1jm1,ijbm1jm1,jk)
312            ! upstream differencing for tangential derivatives
313            zsign_ups = sign( 1., zdt * zdy_centred )
314            zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
315            zdy = zsign_ups * zdy_1 + (1. - zsign_ups) * zdy_2
316            znor2 = zdx * zdx + zdy * zdy
317            znor2 = max(znor2,zepsilon)
318            !
319            ! update boundary value:
320            zrx = zdt * zdx / ( zex * znor2 )
321            zrx = min(zrx,2.0_wp)
322            zout = sign( 1., zrx )
323            zout = 0.5*( zout + abs(zout) )
324            zwgt = 2.*rdt*( (1.-zout) * idx%nbd(jb,igrd) + zout * idx%nbdout(jb,igrd) )
325            ! only apply radiation on outflow points
326            if( ll_npo ) then     !! NPO version !!
327               phia(ii,ij,jk) = (1.-zout) * ( phib(ii,ij,jk) + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) &
328              &               + zout      * ( phib(ii,ij,jk) + zrx*phia(iibm1,ijbm1,jk)                     &
329              &                            + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) / ( 1. + zrx ) 
330            else                  !! full oblique radiation !!
331               zsign_ups = sign( 1., zdt * zdy )
332               zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
333               zey = zsign_ups * zey1 + (1.-zsign_ups) * zey2 
334               zry = zdt * zdy / ( zey * znor2 ) 
335               phia(ii,ij,jk) = (1.-zout) * ( phib(ii,ij,jk) + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) )    &
336              &               + zout      * ( phib(ii,ij,jk) + zrx*phia(iibm1,ijbm1,jk)                        &
337              &                       - zsign_ups      * zry * ( phib(ii   ,ij   ,jk) - phib(iijm1,ijjm1,jk) ) &
338              &                       - (1.-zsign_ups) * zry * ( phib(iijp1,ijjp1,jk) - phib(ii   ,ij   ,jk) ) &
339              &                       + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) / ( 1. + zrx ) 
340            end if
341            phia(ii,ij,jk) = phia(ii,ij,jk) * pmask(ii,ij,jk)
342         END DO
343         !
344      END DO
345
346      IF( nn_timing == 1 ) CALL timing_stop('bdy_orlanski_3d')
347
348   END SUBROUTINE bdy_orlanski_3d
349
350
351#else
352   !!----------------------------------------------------------------------
353   !!   Dummy module                   NO Unstruct Open Boundary Conditions
354   !!----------------------------------------------------------------------
355CONTAINS
356   SUBROUTINE bdy_orlanski_2d( idx, igrd, phib, phia, phi_ext  )      ! Empty routine
357      WRITE(*,*) 'bdy_orlanski_2d: You should not have seen this print! error?', kt
358   END SUBROUTINE bdy_orlanski_2d
359   SUBROUTINE bdy_orlanski_3d( idx, igrd, phib, phia, phi_ext  )      ! Empty routine
360      WRITE(*,*) 'bdy_orlanski_3d: You should not have seen this print! error?', kt
361   END SUBROUTINE bdy_orlanski_3d
362#endif
363
364   !!======================================================================
365END MODULE bdylib
Note: See TracBrowser for help on using the repository browser.