| 1 | MODULE limsbc |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE limsbc *** |
|---|
| 4 | !! computation of the flux at the sea ice/ocean interface |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : - ! 2006-07 (M. Vancoppelle) LIM3 original code |
|---|
| 7 | !! 3.0 ! 2008-03 (C. Tallandier) surface module |
|---|
| 8 | !! - ! 2008-04 (C. Tallandier) split in 2 + new ice-ocean coupling |
|---|
| 9 | !! 3.3 ! 2010-05 (G. Madec) decrease ocean & ice reference salinities in the Baltic sea |
|---|
| 10 | !! ! + simplification of the ice-ocean stress calculation |
|---|
| 11 | !! 3.4 ! 2011-02 (G. Madec) dynamical allocation |
|---|
| 12 | !! - ! 2012 (D. Iovino) salt flux change |
|---|
| 13 | !! - ! 2012-05 (C. Rousset) add penetration solar flux |
|---|
| 14 | !! 3.5 ! 2012-10 (A. Coward, G. Madec) salt fluxes ; ice+snow mass |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | #if defined key_lim3 |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | !! 'key_lim3' LIM 3.0 sea-ice model |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | !! lim_sbc_alloc : allocate the limsbc arrays |
|---|
| 21 | !! lim_sbc_init : initialisation |
|---|
| 22 | !! lim_sbc_flx : updates mass, heat and salt fluxes at the ocean surface |
|---|
| 23 | !! lim_sbc_tau : update i- and j-stresses, and its modulus at the ocean surface |
|---|
| 24 | !!---------------------------------------------------------------------- |
|---|
| 25 | USE par_oce ! ocean parameters |
|---|
| 26 | USE phycst ! physical constants |
|---|
| 27 | USE par_ice ! ice parameters |
|---|
| 28 | USE dom_oce ! ocean domain |
|---|
| 29 | USE dom_ice, ONLY : tms |
|---|
| 30 | USE ice ! LIM sea-ice variables |
|---|
| 31 | USE sbc_ice ! Surface boundary condition: sea-ice fields |
|---|
| 32 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 33 | USE sbccpl |
|---|
| 34 | USE cpl_oasis3, ONLY : lk_cpl |
|---|
| 35 | USE oce , ONLY : iatte, oatte, sshn, sshb, snwice_mass, snwice_mass_b, snwice_fmass, sshu_b, sshv_b, sshu_n, sshv_n, sshf_n |
|---|
| 36 | USE albedo ! albedo parameters |
|---|
| 37 | USE lbclnk ! ocean lateral boundary condition - MPP exchanges |
|---|
| 38 | USE lib_mpp ! MPP library |
|---|
| 39 | USE wrk_nemo ! work arrays |
|---|
| 40 | USE in_out_manager ! I/O manager |
|---|
| 41 | USE prtctl ! Print control |
|---|
| 42 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 43 | USE traqsr ! clem: add penetration of solar flux into the calculation of heat budget |
|---|
| 44 | |
|---|
| 45 | IMPLICIT NONE |
|---|
| 46 | PRIVATE |
|---|
| 47 | |
|---|
| 48 | PUBLIC lim_sbc_init ! called by ice_init |
|---|
| 49 | PUBLIC lim_sbc_flx ! called by sbc_ice_lim |
|---|
| 50 | PUBLIC lim_sbc_tau ! called by sbc_ice_lim |
|---|
| 51 | |
|---|
| 52 | REAL(wp) :: rzero = 0._wp |
|---|
| 53 | REAL(wp) :: rone = 1._wp |
|---|
| 54 | |
|---|
| 55 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: utau_oce, vtau_oce ! air-ocean surface i- & j-stress [N/m2] |
|---|
| 56 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: tmod_io ! modulus of the ice-ocean velocity [m/s] |
|---|
| 57 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: soce_0 , sice_0 ! cst SSS and ice salinity (levitating sea-ice) |
|---|
| 58 | |
|---|
| 59 | !! * Substitutions |
|---|
| 60 | # include "vectopt_loop_substitute.h90" |
|---|
| 61 | !!---------------------------------------------------------------------- |
|---|
| 62 | !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011) |
|---|
| 63 | !! $Id$ |
|---|
| 64 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 65 | !!---------------------------------------------------------------------- |
|---|
| 66 | CONTAINS |
|---|
| 67 | |
|---|
| 68 | INTEGER FUNCTION lim_sbc_alloc() |
|---|
| 69 | !!------------------------------------------------------------------- |
|---|
| 70 | !! *** ROUTINE lim_sbc_alloc *** |
|---|
| 71 | !!------------------------------------------------------------------- |
|---|
| 72 | ALLOCATE( soce_0(jpi,jpj) , utau_oce(jpi,jpj) , & |
|---|
| 73 | & sice_0(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=lim_sbc_alloc) |
|---|
| 74 | ! |
|---|
| 75 | IF( lk_mpp ) CALL mpp_sum( lim_sbc_alloc ) |
|---|
| 76 | IF( lim_sbc_alloc /= 0 ) CALL ctl_warn('lim_sbc_alloc: failed to allocate arrays') |
|---|
| 77 | END FUNCTION lim_sbc_alloc |
|---|
| 78 | |
|---|
| 79 | |
|---|
| 80 | SUBROUTINE lim_sbc_flx( kt ) |
|---|
| 81 | !!------------------------------------------------------------------- |
|---|
| 82 | !! *** ROUTINE lim_sbc_flx *** |
|---|
| 83 | !! |
|---|
| 84 | !! ** Purpose : Update the surface ocean boundary condition for heat |
|---|
| 85 | !! salt and mass over areas where sea-ice is non-zero |
|---|
| 86 | !! |
|---|
| 87 | !! ** Action : - computes the heat and freshwater/salt fluxes |
|---|
| 88 | !! at the ice-ocean interface. |
|---|
| 89 | !! - Update the ocean sbc |
|---|
| 90 | !! |
|---|
| 91 | !! ** Outputs : - qsr : sea heat flux: solar |
|---|
| 92 | !! - qns : sea heat flux: non solar |
|---|
| 93 | !! - emp : freshwater budget: volume flux |
|---|
| 94 | !! - sfx : salt flux |
|---|
| 95 | !! - fr_i : ice fraction |
|---|
| 96 | !! - tn_ice : sea-ice surface temperature |
|---|
| 97 | !! - alb_ice : sea-ice alberdo (lk_cpl=T) |
|---|
| 98 | !! |
|---|
| 99 | !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90. |
|---|
| 100 | !! Tartinville et al. 2001 Ocean Modelling, 3, 95-108. |
|---|
| 101 | !!--------------------------------------------------------------------- |
|---|
| 102 | INTEGER, INTENT(in) :: kt ! number of iteration |
|---|
| 103 | ! |
|---|
| 104 | INTEGER :: ji, jj, jl ! dummy loop indices |
|---|
| 105 | INTEGER :: ierr, ifvt, i1mfr, idfr ! local integer |
|---|
| 106 | INTEGER :: iflt, ial , iadv , ifral, ifrdv ! - - |
|---|
| 107 | REAL(wp) :: zinda, zemp, zemp_snow, zfmm ! local scalars |
|---|
| 108 | REAL(wp) :: zemp_snw ! - - |
|---|
| 109 | REAL(wp) :: zfcm1 , zfcm2 ! - - |
|---|
| 110 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb, zalbp ! 2D/3D workspace |
|---|
| 111 | REAL(wp) :: zzfcm1, zfscmbq ! clem: for light penetration |
|---|
| 112 | !!--------------------------------------------------------------------- |
|---|
| 113 | |
|---|
| 114 | IF( lk_cpl ) CALL wrk_alloc( jpi, jpj, jpl, zalb, zalbp ) |
|---|
| 115 | |
|---|
| 116 | !------------------------------------------! |
|---|
| 117 | ! heat flux at the ocean surface ! |
|---|
| 118 | !------------------------------------------! |
|---|
| 119 | ! pfrld is the lead fraction at the previous time step (actually between TRP and THD) |
|---|
| 120 | ! changed to old_frld and old ht_i |
|---|
| 121 | |
|---|
| 122 | DO jj = 1, jpj |
|---|
| 123 | DO ji = 1, jpi |
|---|
| 124 | zinda = 1.0 - MAX( rzero , SIGN( rone , - ( 1.0 - pfrld(ji,jj) ) ) ) |
|---|
| 125 | ifvt = zinda * MAX( rzero , SIGN( rone, - phicif(ji,jj) ) ) !subscripts are bad here |
|---|
| 126 | i1mfr = 1.0 - MAX( rzero , SIGN( rone , - at_i(ji,jj) ) ) |
|---|
| 127 | idfr = 1.0 - MAX( rzero , SIGN( rone , ( 1.0 - at_i(ji,jj) ) - pfrld(ji,jj) ) ) |
|---|
| 128 | iflt = zinda * (1 - i1mfr) * (1 - ifvt ) |
|---|
| 129 | ial = ifvt * i1mfr + ( 1 - ifvt ) * idfr |
|---|
| 130 | iadv = ( 1 - i1mfr ) * zinda |
|---|
| 131 | ifral = ( 1 - i1mfr * ( 1 - ial ) ) |
|---|
| 132 | ifrdv = ( 1 - ifral * ( 1 - ial ) ) * iadv |
|---|
| 133 | |
|---|
| 134 | ! switch --- 1.0 ---------------- 0.0 -------------------- |
|---|
| 135 | ! ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ |
|---|
| 136 | ! zinda | if pfrld = 1 | if pfrld < 1 | |
|---|
| 137 | ! -> ifvt| if pfrld old_ht_i |
|---|
| 138 | ! i1mfr | if frld = 1 | if frld < 1 | |
|---|
| 139 | ! idfr | if frld <= pfrld | if frld > pfrld | |
|---|
| 140 | ! iflt | |
|---|
| 141 | ! ial | |
|---|
| 142 | ! iadv | |
|---|
| 143 | ! ifral |
|---|
| 144 | ! ifrdv |
|---|
| 145 | |
|---|
| 146 | ! computation the solar flux at ocean surface |
|---|
| 147 | IF (lk_cpl) THEN ! be carfeful: not been tested yet |
|---|
| 148 | ! original line |
|---|
| 149 | !zfcm1 = qsr_tot(ji,jj) + fstric(ji,jj) * at_i(ji,jj) |
|---|
| 150 | ! new line to include solar penetration (not tested) |
|---|
| 151 | zfcm1 = qsr_tot(ji,jj) + fstric(ji,jj) * at_i(ji,jj) / ( 1.0 - zinda + zinda * iatte(ji,jj) ) |
|---|
| 152 | DO jl = 1, jpl |
|---|
| 153 | zfcm1 = zfcm1 - qsr_ice(ji,jj,jl) * a_i(ji,jj,jl) |
|---|
| 154 | END DO |
|---|
| 155 | ELSE |
|---|
| 156 | zfcm1 = pfrld(ji,jj) * qsr(ji,jj) + & |
|---|
| 157 | & ( 1._wp - pfrld(ji,jj) ) * fstric(ji,jj) / ( 1.0 - zinda + zinda * iatte(ji,jj) ) |
|---|
| 158 | ENDIF |
|---|
| 159 | ! fstric Solar flux transmitted trough the ice |
|---|
| 160 | ! qsr Net short wave heat flux on free ocean |
|---|
| 161 | ! new line |
|---|
| 162 | fscmbq(ji,jj) = ( 1.0 - pfrld(ji,jj) ) * fstric(ji,jj) / ( 1.0 - zinda + zinda * iatte(ji,jj) ) |
|---|
| 163 | |
|---|
| 164 | ! solar flux and fscmbq with light penetration (clem) |
|---|
| 165 | zzfcm1 = pfrld(ji,jj) * qsr(ji,jj) * oatte(ji,jj) + ( 1. - pfrld(ji,jj) ) * fstric(ji,jj) |
|---|
| 166 | zfscmbq = ( 1.0 - pfrld(ji,jj) ) * fstric(ji,jj) |
|---|
| 167 | |
|---|
| 168 | ! computation the non solar heat flux at ocean surface |
|---|
| 169 | zfcm2 = - zzfcm1 & ! |
|---|
| 170 | & + iflt * zfscmbq & ! total ablation: heat given to the ocean |
|---|
| 171 | & + ifral * ( ial * qcmif(ji,jj) + (1 - ial) * qldif(ji,jj) ) * r1_rdtice & |
|---|
| 172 | & + ifrdv * ( qfvbq(ji,jj) + qdtcn(ji,jj) ) * r1_rdtice & |
|---|
| 173 | & + fhmec(ji,jj) & ! snow melt when ridging |
|---|
| 174 | & + fheat_mec(ji,jj) & ! ridge formation |
|---|
| 175 | & + fheat_res(ji,jj) ! residual heat flux |
|---|
| 176 | ! qcmif Energy needed to bring the ocean surface layer until its freezing (ok) |
|---|
| 177 | ! qldif heat balance of the lead (or of the open ocean) |
|---|
| 178 | ! qfvbq latent heat uptake/release after accretion/ablation |
|---|
| 179 | ! qdtcn Energy from the turbulent oceanic heat flux heat flux coming in the lead |
|---|
| 180 | |
|---|
| 181 | IF( num_sal == 2 ) zfcm2 = zfcm2 + fhbri(ji,jj) ! add contribution due to brine drainage |
|---|
| 182 | |
|---|
| 183 | ! bottom radiative component is sent to the computation of the oceanic heat flux |
|---|
| 184 | fsbbq(ji,jj) = ( 1._wp - ( ifvt + iflt ) ) * fscmbq(ji,jj) |
|---|
| 185 | |
|---|
| 186 | ! used to compute the oceanic heat flux at the next time step |
|---|
| 187 | qsr(ji,jj) = zfcm1 ! solar heat flux |
|---|
| 188 | qns(ji,jj) = zfcm2 - fdtcn(ji,jj) ! non solar heat flux |
|---|
| 189 | ! ! fdtcn : turbulent oceanic heat flux |
|---|
| 190 | END DO |
|---|
| 191 | END DO |
|---|
| 192 | |
|---|
| 193 | !------------------------------------------! |
|---|
| 194 | ! mass flux at the ocean surface ! |
|---|
| 195 | !------------------------------------------! |
|---|
| 196 | |
|---|
| 197 | !!gm optimisation: this loop have to be merged with the previous one |
|---|
| 198 | DO jj = 1, jpj |
|---|
| 199 | DO ji = 1, jpi |
|---|
| 200 | ! case of realistic freshwater flux (Tartinville et al., 2001) (presently ACTIVATED) |
|---|
| 201 | ! ------------------------------------------------------------------------------------- |
|---|
| 202 | ! The idea of this approach is that the system that we consider is the ICE-OCEAN system |
|---|
| 203 | ! Thus FW flux = External ( E-P+snow melt) |
|---|
| 204 | ! Salt flux = Exchanges in the ice-ocean system then converted into FW |
|---|
| 205 | ! Associated to Ice formation AND Ice melting |
|---|
| 206 | ! Even if i see Ice melting as a FW and SALT flux |
|---|
| 207 | ! |
|---|
| 208 | |
|---|
| 209 | ! computing freshwater exchanges at the ice/ocean interface |
|---|
| 210 | IF (lk_cpl) THEN |
|---|
| 211 | zemp = - emp_tot(ji,jj) + emp_ice(ji,jj) * ( 1. - pfrld(ji,jj) ) & ! |
|---|
| 212 | & - rdm_snw(ji,jj) / rdt_ice |
|---|
| 213 | ELSE |
|---|
| 214 | zemp = emp(ji,jj) * ( 1.0 - at_i(ji,jj) ) & ! evaporation over oceanic fraction |
|---|
| 215 | & - tprecip(ji,jj) * at_i(ji,jj) & ! all precipitation reach the ocean |
|---|
| 216 | & + sprecip(ji,jj) * ( 1. - (pfrld(ji,jj)**betas) ) & ! except solid precip intercepted by sea-ice |
|---|
| 217 | & - fmmec(ji,jj) ! snow falling when ridging |
|---|
| 218 | ENDIF |
|---|
| 219 | |
|---|
| 220 | ! mass flux at the ocean/ice interface (sea ice fraction) |
|---|
| 221 | zemp_snw = rdm_snw(ji,jj) * r1_rdtice ! snow melting = pure water that enters the ocean |
|---|
| 222 | zfmm = rdm_ice(ji,jj) * r1_rdtice ! Freezing minus melting |
|---|
| 223 | |
|---|
| 224 | fmmflx(ji,jj) = zfmm ! F/M mass flux save at least for biogeochemical model |
|---|
| 225 | |
|---|
| 226 | emp(ji,jj) = zemp + zemp_snw + zfmm ! mass flux + F/M mass flux (always ice/ocean mass exchange) |
|---|
| 227 | |
|---|
| 228 | ! correcting brine salt fluxes (zinda = 1 if pfrld=1 , =0 otherwise) |
|---|
| 229 | zinda = 1.0 - MAX( rzero , SIGN( rone , - ( 1.0 - pfrld(ji,jj) ) ) ) |
|---|
| 230 | sfx_bri(ji,jj) = zinda * sfx_bri(ji,jj) |
|---|
| 231 | END DO |
|---|
| 232 | END DO |
|---|
| 233 | |
|---|
| 234 | !------------------------------------------! |
|---|
| 235 | ! salt flux at the ocean surface ! |
|---|
| 236 | !------------------------------------------! |
|---|
| 237 | |
|---|
| 238 | IF( num_sal == 2 ) THEN ! variable ice salinity: brine drainage included in the salt flux |
|---|
| 239 | sfx(:,:) = sfx_thd(:,:) + sfx_res(:,:) + sfx_mec(:,:) + sfx_bri(:,:) |
|---|
| 240 | ELSE ! constant ice salinity: |
|---|
| 241 | sfx(:,:) = sfx_thd(:,:) + sfx_res(:,:) + sfx_mec(:,:) |
|---|
| 242 | ENDIF |
|---|
| 243 | !-----------------------------------------------! |
|---|
| 244 | ! mass of snow and ice per unit area ! |
|---|
| 245 | !-----------------------------------------------! |
|---|
| 246 | IF( nn_ice_embd /= 0 ) THEN ! embedded sea-ice (mass required) |
|---|
| 247 | snwice_mass_b(:,:) = snwice_mass(:,:) ! save mass from the previous ice time step |
|---|
| 248 | ! ! new mass per unit area |
|---|
| 249 | snwice_mass (:,:) = tms(:,:) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:) ) |
|---|
| 250 | ! ! time evolution of snow+ice mass |
|---|
| 251 | snwice_fmass (:,:) = ( snwice_mass(:,:) - snwice_mass_b(:,:) ) * r1_rdtice |
|---|
| 252 | ENDIF |
|---|
| 253 | |
|---|
| 254 | !-----------------------------------------------! |
|---|
| 255 | ! Storing the transmitted variables ! |
|---|
| 256 | !-----------------------------------------------! |
|---|
| 257 | fr_i (:,:) = at_i(:,:) ! Sea-ice fraction |
|---|
| 258 | tn_ice(:,:,:) = t_su(:,:,:) ! Ice surface temperature |
|---|
| 259 | |
|---|
| 260 | !------------------------------------------------! |
|---|
| 261 | ! Computation of snow/ice and ocean albedo ! |
|---|
| 262 | !------------------------------------------------! |
|---|
| 263 | IF( lk_cpl ) THEN ! coupled case |
|---|
| 264 | CALL albedo_ice( t_su, ht_i, ht_s, zalbp, zalb ) ! snow/ice albedo |
|---|
| 265 | ! |
|---|
| 266 | alb_ice(:,:,:) = 0.5_wp * zalbp(:,:,:) + 0.5_wp * zalb (:,:,:) ! Ice albedo (mean clear and overcast skys) |
|---|
| 267 | ENDIF |
|---|
| 268 | |
|---|
| 269 | IF(ln_ctl) THEN |
|---|
| 270 | CALL prt_ctl( tab2d_1=qsr , clinfo1=' lim_sbc: qsr : ', tab2d_2=qns , clinfo2=' qns : ' ) |
|---|
| 271 | CALL prt_ctl( tab2d_1=emp , clinfo1=' lim_sbc: emp : ', tab2d_2=sfx , clinfo2=' sfx : ' ) |
|---|
| 272 | CALL prt_ctl( tab2d_1=fr_i , clinfo1=' lim_sbc: fr_i : ' ) |
|---|
| 273 | CALL prt_ctl( tab3d_1=tn_ice, clinfo1=' lim_sbc: tn_ice : ', kdim=jpl ) |
|---|
| 274 | ENDIF |
|---|
| 275 | ! |
|---|
| 276 | IF( lk_cpl ) CALL wrk_dealloc( jpi, jpj, jpl, zalb, zalbp ) |
|---|
| 277 | ! |
|---|
| 278 | END SUBROUTINE lim_sbc_flx |
|---|
| 279 | |
|---|
| 280 | |
|---|
| 281 | SUBROUTINE lim_sbc_tau( kt , pu_oce, pv_oce ) |
|---|
| 282 | !!------------------------------------------------------------------- |
|---|
| 283 | !! *** ROUTINE lim_sbc_tau *** |
|---|
| 284 | !! |
|---|
| 285 | !! ** Purpose : Update the ocean surface stresses due to the ice |
|---|
| 286 | !! |
|---|
| 287 | !! ** Action : * at each ice time step (every nn_fsbc time step): |
|---|
| 288 | !! - compute the modulus of ice-ocean relative velocity |
|---|
| 289 | !! (*rho*Cd) at T-point (C-grid) or I-point (B-grid) |
|---|
| 290 | !! tmod_io = rhoco * | U_ice-U_oce | |
|---|
| 291 | !! - update the modulus of stress at ocean surface |
|---|
| 292 | !! taum = frld * taum + (1-frld) * tmod_io * | U_ice-U_oce | |
|---|
| 293 | !! * at each ocean time step (every kt): |
|---|
| 294 | !! compute linearized ice-ocean stresses as |
|---|
| 295 | !! Utau = tmod_io * | U_ice - pU_oce | |
|---|
| 296 | !! using instantaneous current ocean velocity (usually before) |
|---|
| 297 | !! |
|---|
| 298 | !! NB: - ice-ocean rotation angle no more allowed |
|---|
| 299 | !! - here we make an approximation: taum is only computed every ice time step |
|---|
| 300 | !! This avoids mutiple average to pass from T -> U,V grids and next from U,V grids |
|---|
| 301 | !! to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton... |
|---|
| 302 | !! |
|---|
| 303 | !! ** Outputs : - utau, vtau : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes |
|---|
| 304 | !! - taum : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes |
|---|
| 305 | !!--------------------------------------------------------------------- |
|---|
| 306 | INTEGER , INTENT(in) :: kt ! ocean time-step index |
|---|
| 307 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pu_oce, pv_oce ! surface ocean currents |
|---|
| 308 | !! |
|---|
| 309 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 310 | REAL(wp) :: zat_u, zutau_ice, zu_t, zmodt ! local scalar |
|---|
| 311 | REAL(wp) :: zat_v, zvtau_ice, zv_t ! - - |
|---|
| 312 | !!--------------------------------------------------------------------- |
|---|
| 313 | ! |
|---|
| 314 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN !== Ice time-step only ==! (i.e. surface module time-step) |
|---|
| 315 | !CDIR NOVERRCHK |
|---|
| 316 | DO jj = 2, jpjm1 !* update the modulus of stress at ocean surface (T-point) |
|---|
| 317 | !CDIR NOVERRCHK |
|---|
| 318 | DO ji = fs_2, fs_jpim1 |
|---|
| 319 | ! ! 2*(U_ice-U_oce) at T-point |
|---|
| 320 | zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj) |
|---|
| 321 | zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) |
|---|
| 322 | ! ! |U_ice-U_oce|^2 |
|---|
| 323 | zmodt = 0.25_wp * ( zu_t * zu_t + zv_t * zv_t ) |
|---|
| 324 | ! ! update the ocean stress modulus |
|---|
| 325 | taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * rhoco * zmodt |
|---|
| 326 | tmod_io(ji,jj) = rhoco * SQRT( zmodt ) ! rhoco * |U_ice-U_oce| at T-point |
|---|
| 327 | END DO |
|---|
| 328 | END DO |
|---|
| 329 | CALL lbc_lnk( taum, 'T', 1. ) ; CALL lbc_lnk( tmod_io, 'T', 1. ) |
|---|
| 330 | ! |
|---|
| 331 | utau_oce(:,:) = utau(:,:) !* save the air-ocean stresses at ice time-step |
|---|
| 332 | vtau_oce(:,:) = vtau(:,:) |
|---|
| 333 | ! |
|---|
| 334 | ENDIF |
|---|
| 335 | ! |
|---|
| 336 | ! !== every ocean time-step ==! |
|---|
| 337 | ! |
|---|
| 338 | DO jj = 2, jpjm1 !* update the stress WITHOUT a ice-ocean rotation angle |
|---|
| 339 | DO ji = fs_2, fs_jpim1 ! Vect. Opt. |
|---|
| 340 | zat_u = ( at_i(ji,jj) + at_i(ji+1,jj) ) * 0.5_wp ! ice area at u and V-points |
|---|
| 341 | zat_v = ( at_i(ji,jj) + at_i(ji,jj+1) ) * 0.5_wp |
|---|
| 342 | ! ! linearized quadratic drag formulation |
|---|
| 343 | zutau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) ) |
|---|
| 344 | zvtau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) ) |
|---|
| 345 | ! ! stresses at the ocean surface |
|---|
| 346 | utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice |
|---|
| 347 | vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice |
|---|
| 348 | END DO |
|---|
| 349 | END DO |
|---|
| 350 | CALL lbc_lnk( utau, 'U', -1. ) ; CALL lbc_lnk( vtau, 'V', -1. ) ! lateral boundary condition |
|---|
| 351 | ! |
|---|
| 352 | IF(ln_ctl) CALL prt_ctl( tab2d_1=utau, clinfo1=' lim_sbc: utau : ', mask1=umask, & |
|---|
| 353 | & tab2d_2=vtau, clinfo2=' vtau : ' , mask2=vmask ) |
|---|
| 354 | ! |
|---|
| 355 | END SUBROUTINE lim_sbc_tau |
|---|
| 356 | |
|---|
| 357 | |
|---|
| 358 | SUBROUTINE lim_sbc_init |
|---|
| 359 | !!------------------------------------------------------------------- |
|---|
| 360 | !! *** ROUTINE lim_sbc_init *** |
|---|
| 361 | !! |
|---|
| 362 | !! ** Purpose : Preparation of the file ice_evolu for the output of |
|---|
| 363 | !! the temporal evolution of key variables |
|---|
| 364 | !! |
|---|
| 365 | !! ** input : Namelist namicedia |
|---|
| 366 | !!------------------------------------------------------------------- |
|---|
| 367 | REAL(wp) :: zsum, zarea |
|---|
| 368 | ! |
|---|
| 369 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 370 | REAL(wp) :: zcoefu, zcoefv, zcoeff ! local scalar |
|---|
| 371 | IF(lwp) WRITE(numout,*) |
|---|
| 372 | IF(lwp) WRITE(numout,*) 'lim_sbc_init : LIM-3 sea-ice - surface boundary condition' |
|---|
| 373 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~ ' |
|---|
| 374 | |
|---|
| 375 | ! ! allocate lim_sbc array |
|---|
| 376 | IF( lim_sbc_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'lim_sbc_init : unable to allocate standard arrays' ) |
|---|
| 377 | ! |
|---|
| 378 | soce_0(:,:) = soce ! constant SSS and ice salinity used in levitating sea-ice case |
|---|
| 379 | sice_0(:,:) = sice |
|---|
| 380 | ! |
|---|
| 381 | IF( cp_cfg == "orca" ) THEN ! decrease ocean & ice reference salinities in the Baltic sea |
|---|
| 382 | WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND. & |
|---|
| 383 | & 54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp ) |
|---|
| 384 | soce_0(:,:) = 4._wp |
|---|
| 385 | sice_0(:,:) = 2._wp |
|---|
| 386 | END WHERE |
|---|
| 387 | ENDIF |
|---|
| 388 | ! clem modif |
|---|
| 389 | IF( .NOT. ln_rstart ) THEN |
|---|
| 390 | iatte(:,:) = 1._wp |
|---|
| 391 | oatte(:,:) = 1._wp |
|---|
| 392 | ENDIF |
|---|
| 393 | ! |
|---|
| 394 | ! clem: snwice_mass in the restart file now |
|---|
| 395 | IF( .NOT. ln_rstart ) THEN |
|---|
| 396 | ! ! embedded sea ice |
|---|
| 397 | IF( nn_ice_embd /= 0 ) THEN ! mass exchanges between ice and ocean (case 1 or 2) set the snow+ice mass |
|---|
| 398 | snwice_mass (:,:) = tms(:,:) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:) ) |
|---|
| 399 | snwice_mass_b(:,:) = snwice_mass(:,:) |
|---|
| 400 | ELSE |
|---|
| 401 | snwice_mass (:,:) = 0.0_wp ! no mass exchanges |
|---|
| 402 | snwice_mass_b(:,:) = 0.0_wp ! no mass exchanges |
|---|
| 403 | ENDIF |
|---|
| 404 | IF( nn_ice_embd == 2 ) THEN ! full embedment (case 2) deplete the initial ssh below sea-ice area |
|---|
| 405 | sshn(:,:) = sshn(:,:) - snwice_mass(:,:) * r1_rau0 |
|---|
| 406 | sshb(:,:) = sshb(:,:) - snwice_mass(:,:) * r1_rau0 |
|---|
| 407 | ! |
|---|
| 408 | ! Note: Changed the initial values of sshb and sshn=> need to recompute ssh[u,v,f]_[b,n] |
|---|
| 409 | ! which were previously set in domvvl |
|---|
| 410 | IF ( lk_vvl ) THEN ! Is this necessary? embd 2 should be restricted to vvl only??? |
|---|
| 411 | DO jj = 1, jpjm1 |
|---|
| 412 | DO ji = 1, jpim1 ! caution: use of Vector Opt. not possible |
|---|
| 413 | zcoefu = 0.5 * umask(ji,jj,1) / ( e1u(ji,jj) * e2u(ji,jj) ) |
|---|
| 414 | zcoefv = 0.5 * vmask(ji,jj,1) / ( e1v(ji,jj) * e2v(ji,jj) ) |
|---|
| 415 | zcoeff = 0.25 * umask(ji,jj,1) * umask(ji,jj+1,1) |
|---|
| 416 | sshu_b(ji,jj) = zcoefu * ( e1t(ji ,jj) * e2t(ji ,jj) * sshb(ji ,jj) & |
|---|
| 417 | & + e1t(ji+1,jj) * e2t(ji+1,jj) * sshb(ji+1,jj) ) |
|---|
| 418 | sshv_b(ji,jj) = zcoefv * ( e1t(ji,jj ) * e2t(ji,jj ) * sshb(ji,jj ) & |
|---|
| 419 | & + e1t(ji,jj+1) * e2t(ji,jj+1) * sshb(ji,jj+1) ) |
|---|
| 420 | sshu_n(ji,jj) = zcoefu * ( e1t(ji ,jj) * e2t(ji ,jj) * sshn(ji ,jj) & |
|---|
| 421 | & + e1t(ji+1,jj) * e2t(ji+1,jj) * sshn(ji+1,jj) ) |
|---|
| 422 | sshv_n(ji,jj) = zcoefv * ( e1t(ji,jj ) * e2t(ji,jj ) * sshn(ji,jj ) & |
|---|
| 423 | & + e1t(ji,jj+1) * e2t(ji,jj+1) * sshn(ji,jj+1) ) |
|---|
| 424 | END DO |
|---|
| 425 | END DO |
|---|
| 426 | CALL lbc_lnk( sshu_b, 'U', 1. ) ; CALL lbc_lnk( sshu_n, 'U', 1. ) |
|---|
| 427 | CALL lbc_lnk( sshv_b, 'V', 1. ) ; CALL lbc_lnk( sshv_n, 'V', 1. ) |
|---|
| 428 | DO jj = 1, jpjm1 |
|---|
| 429 | DO ji = 1, jpim1 ! NO Vector Opt. |
|---|
| 430 | sshf_n(ji,jj) = 0.5 * umask(ji,jj,1) * umask(ji,jj+1,1) & |
|---|
| 431 | & / ( e1f(ji,jj ) * e2f(ji,jj ) ) & |
|---|
| 432 | & * ( e1u(ji,jj ) * e2u(ji,jj ) * sshu_n(ji,jj ) & |
|---|
| 433 | & + e1u(ji,jj+1) * e2u(ji,jj+1) * sshu_n(ji,jj+1) ) |
|---|
| 434 | END DO |
|---|
| 435 | END DO |
|---|
| 436 | CALL lbc_lnk( sshf_n, 'F', 1. ) |
|---|
| 437 | ENDIF |
|---|
| 438 | ENDIF |
|---|
| 439 | ENDIF ! .NOT. ln_rstart |
|---|
| 440 | ! |
|---|
| 441 | |
|---|
| 442 | END SUBROUTINE lim_sbc_init |
|---|
| 443 | |
|---|
| 444 | #else |
|---|
| 445 | !!---------------------------------------------------------------------- |
|---|
| 446 | !! Default option : Dummy module NO LIM 3.0 sea-ice model |
|---|
| 447 | !!---------------------------------------------------------------------- |
|---|
| 448 | CONTAINS |
|---|
| 449 | SUBROUTINE lim_sbc ! Dummy routine |
|---|
| 450 | END SUBROUTINE lim_sbc |
|---|
| 451 | #endif |
|---|
| 452 | |
|---|
| 453 | !!====================================================================== |
|---|
| 454 | END MODULE limsbc |
|---|
