New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd_lac.F90 in branches/2013/dev_r4028_CNRS_LIM3/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2013/dev_r4028_CNRS_LIM3/NEMOGCM/NEMO/LIM_SRC_3/limthd_lac.F90 @ 4649

Last change on this file since 4649 was 4649, checked in by clem, 10 years ago

finalizing LIM3 heat budget conservation + multiple minor bugs corrections
  • Property svn:keywords set to Id
File size: 26.5 KB
Line 
1MODULE limthd_lac
2   !!======================================================================
3   !!                       ***  MODULE limthd_lac   ***
4   !!                lateral thermodynamic growth of the ice
5   !!======================================================================
6   !! History :  LIM  ! 2005-12 (M. Vancoppenolle)  Original code
7   !!             -   ! 2006-01 (M. Vancoppenolle)  add ITD
8   !!            3.0  ! 2007-07 (M. Vancoppenolle)  Mass and energy conservation tested
9   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
10   !!----------------------------------------------------------------------
11#if defined key_lim3
12   !!----------------------------------------------------------------------
13   !!   'key_lim3'                                      LIM3 sea-ice model
14   !!----------------------------------------------------------------------
15   !!   lim_lat_acr   : lateral accretion of ice
16   !!----------------------------------------------------------------------
17   USE par_oce        ! ocean parameters
18   USE dom_oce        ! domain variables
19   USE phycst         ! physical constants
20   USE sbc_oce        ! Surface boundary condition: ocean fields
21   USE sbc_ice        ! Surface boundary condition: ice fields
22   USE thd_ice        ! LIM thermodynamics
23   USE dom_ice        ! LIM domain
24   USE par_ice        ! LIM parameters
25   USE ice            ! LIM variables
26   USE limtab         ! LIM 2D <==> 1D
27   USE limcons        ! LIM conservation
28   USE in_out_manager ! I/O manager
29   USE lib_mpp        ! MPP library
30   USE wrk_nemo       ! work arrays
31   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
32   USE limthd_ent
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC lim_thd_lac     ! called by lim_thd
38
39   REAL(wp) ::   epsi10 = 1.e-10_wp   !
40   REAL(wp) ::   epsi20 = 1.e-20_wp   !
41
42   !!----------------------------------------------------------------------
43   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE lim_thd_lac
50      !!-------------------------------------------------------------------
51      !!               ***   ROUTINE lim_thd_lac  ***
52      !! 
53      !! ** Purpose : Computation of the evolution of the ice thickness and
54      !!      concentration as a function of the heat balance in the leads.
55      !!      It is only used for lateral accretion
56      !!       
57      !! ** Method  : Ice is formed in the open water when ocean lose heat
58      !!      (heat budget of open water Bl is negative) .
59      !!      Computation of the increase of 1-A (ice concentration) fol-
60      !!      lowing the law :
61      !!      (dA/dt)acc = F[ (1-A)/(1-a) ] * [ Bl / (Li*h0) ]
62      !!       where - h0 is the thickness of ice created in the lead
63      !!             - a is a minimum fraction for leads
64      !!             - F is a monotonic non-increasing function defined as:
65      !!                  F(X)=( 1 - X**exld )**(1.0/exld)
66      !!             - exld is the exponent closure rate (=2 default val.)
67      !!
68      !! ** Action : - Adjustment of snow and ice thicknesses and heat
69      !!                content in brine pockets
70      !!             - Updating ice internal temperature
71      !!             - Computation of variation of ice volume and mass
72      !!             - Computation of frldb after lateral accretion and
73      !!               update ht_s_b, ht_i_b and tbif_1d(:,:)     
74      !!------------------------------------------------------------------------
75      INTEGER ::   ji,jj,jk,jl,jm   ! dummy loop indices
76      INTEGER ::   layer, nbpac     ! local integers
77      INTEGER ::   ii, ij, iter   !   -       -
78      REAL(wp)  ::   ztmelts, zdv, zfrazb, zweight, zindb, zinda, zde  ! local scalars
79      REAL(wp) ::   zgamafr, zvfrx, zvgx, ztaux, ztwogp, zf , zhicol_new        !   -      -
80      REAL(wp) ::   ztenagm, zvfry, zvgy, ztauy, zvrel2, zfp, zsqcd , zhicrit   !   -      -
81      LOGICAL  ::   iterate_frazil   ! iterate frazil ice collection thickness
82      CHARACTER (len = 15) :: fieldid
83
84      REAL(wp) ::   zQm          ! enthalpy exchanged with the ocean (J/m2, >0 towards ocean)
85      REAL(wp) ::   zEi          ! sea ice specific enthalpy (J/kg)
86      REAL(wp) ::   zEw          ! seawater specific enthalpy (J/kg)
87      REAL(wp) ::   zfmdt        ! mass flux x time step (kg/m2, >0 towards ocean)
88     
89      REAL(wp) ::   zv_newfra
90 
91      INTEGER , POINTER, DIMENSION(:) ::   jcat      ! indexes of categories where new ice grows
92      REAL(wp), POINTER, DIMENSION(:) ::   zswinew     ! switch for new ice or not
93
94      REAL(wp), POINTER, DIMENSION(:) ::   zv_newice   ! volume of accreted ice
95      REAL(wp), POINTER, DIMENSION(:) ::   za_newice   ! fractional area of accreted ice
96      REAL(wp), POINTER, DIMENSION(:) ::   zh_newice   ! thickness of accreted ice
97      REAL(wp), POINTER, DIMENSION(:) ::   ze_newice   ! heat content of accreted ice
98      REAL(wp), POINTER, DIMENSION(:) ::   zs_newice   ! salinity of accreted ice
99      REAL(wp), POINTER, DIMENSION(:) ::   zo_newice   ! age of accreted ice
100      REAL(wp), POINTER, DIMENSION(:) ::   zdv_res     ! residual volume in case of excessive heat budget
101      REAL(wp), POINTER, DIMENSION(:) ::   zda_res     ! residual area in case of excessive heat budget
102      REAL(wp), POINTER, DIMENSION(:) ::   zat_i_1d    ! total ice fraction   
103      REAL(wp), POINTER, DIMENSION(:) ::   zat_i_lev   ! total ice fraction for level ice only (type 1)   
104      REAL(wp), POINTER, DIMENSION(:) ::   zv_frazb   ! accretion of frazil ice at the ice bottom
105      REAL(wp), POINTER, DIMENSION(:) ::   zvrel_1d    ! relative ice / frazil velocity (1D vector)
106
107      REAL(wp), POINTER, DIMENSION(:,:) ::   zv_old      ! old volume of ice in category jl
108      REAL(wp), POINTER, DIMENSION(:,:) ::   za_old      ! old area of ice in category jl
109      REAL(wp), POINTER, DIMENSION(:,:) ::   za_i_1d     ! 1-D version of a_i
110      REAL(wp), POINTER, DIMENSION(:,:) ::   zv_i_1d     ! 1-D version of v_i
111      REAL(wp), POINTER, DIMENSION(:,:) ::   zoa_i_1d    ! 1-D version of oa_i
112      REAL(wp), POINTER, DIMENSION(:,:) ::   zsmv_i_1d   ! 1-D version of smv_i
113
114      REAL(wp), POINTER, DIMENSION(:,:,:) ::   ze_i_1d   !: 1-D version of e_i
115
116      REAL(wp), POINTER, DIMENSION(:,:) ::   zvrel                   ! relative ice / frazil velocity
117      !!-----------------------------------------------------------------------!
118
119      CALL wrk_alloc( jpij, jcat )   ! integer
120      CALL wrk_alloc( jpij, zswinew, zv_newice, za_newice, zh_newice, ze_newice, zs_newice, zo_newice )
121      CALL wrk_alloc( jpij, zdv_res, zda_res, zat_i_1d, zat_i_lev, zv_frazb, zvrel_1d )
122      CALL wrk_alloc( jpij,jpl, zv_old, za_old, za_i_1d, zv_i_1d, zoa_i_1d, zsmv_i_1d )
123      CALL wrk_alloc( jpij,jkmax,jpl, ze_i_1d )
124      CALL wrk_alloc( jpi,jpj, zvrel )
125
126      !------------------------------------------------------------------------------|
127      ! 2) Convert units for ice internal energy
128      !------------------------------------------------------------------------------|
129      DO jl = 1, jpl
130         DO jk = 1, nlay_i
131            DO jj = 1, jpj
132               DO ji = 1, jpi
133                  !Energy of melting q(S,T) [J.m-3]
134                  zindb = 1._wp - MAX(  0._wp , SIGN( 1._wp , -v_i(ji,jj,jl) + epsi10 )  )   !0 if no ice and 1 if yes
135                  e_i(ji,jj,jk,jl) = zindb * e_i(ji,jj,jk,jl) / ( area(ji,jj) * MAX( v_i(ji,jj,jl) ,  epsi10 ) ) * REAL( nlay_i )
136                  e_i(ji,jj,jk,jl) = e_i(ji,jj,jk,jl) * unit_fac
137               END DO
138            END DO
139         END DO
140      END DO
141
142      !------------------------------------------------------------------------------!
143      ! 3) Collection thickness of ice formed in leads and polynyas
144      !------------------------------------------------------------------------------!   
145      ! hicol is the thickness of new ice formed in open water
146      ! hicol can be either prescribed (frazswi = 0)
147      ! or computed (frazswi = 1)
148      ! Frazil ice forms in open water, is transported by wind
149      ! accumulates at the edge of the consolidated ice edge
150      ! where it forms aggregates of a specific thickness called
151      ! collection thickness.
152
153      ! Note : the following algorithm currently breaks vectorization
154      !
155
156      zvrel(:,:) = 0._wp
157
158      ! Default new ice thickness
159      hicol(:,:) = hiccrit(1)
160
161      IF( fraz_swi == 1._wp ) THEN
162
163         !--------------------
164         ! Physical constants
165         !--------------------
166         hicol(:,:) = 0._wp
167
168         zhicrit = 0.04 ! frazil ice thickness
169         ztwogp  = 2. * rau0 / ( grav * 0.3 * ( rau0 - rhoic ) ) ! reduced grav
170         zsqcd   = 1.0 / SQRT( 1.3 * cai ) ! 1/SQRT(airdensity*drag)
171         zgamafr = 0.03
172
173         DO jj = 1, jpj
174            DO ji = 1, jpi
175
176               IF ( qlead(ji,jj) < 0._wp ) THEN
177                  !-------------
178                  ! Wind stress
179                  !-------------
180                  ! C-grid wind stress components
181                  ztaux         = ( utau_ice(ji-1,jj  ) * tmu(ji-1,jj  )   &
182                     &          +   utau_ice(ji  ,jj  ) * tmu(ji  ,jj  ) ) * 0.5_wp
183                  ztauy         = ( vtau_ice(ji  ,jj-1) * tmv(ji  ,jj-1)   &
184                     &          +   vtau_ice(ji  ,jj  ) * tmv(ji  ,jj  ) ) * 0.5_wp
185                  ! Square root of wind stress
186                  ztenagm       =  SQRT( SQRT( ztaux**2 + ztauy**2 ) )
187
188                  !---------------------
189                  ! Frazil ice velocity
190                  !---------------------
191                  zindb = MAX( 0._wp, SIGN( 1._wp , ztenagm - epsi10 ) )
192                  zvfrx = zindb * zgamafr * zsqcd * ztaux / MAX( ztenagm, epsi10 )
193                  zvfry = zindb * zgamafr * zsqcd * ztauy / MAX( ztenagm, epsi10 )
194
195                  !-------------------
196                  ! Pack ice velocity
197                  !-------------------
198                  ! C-grid ice velocity
199                  zindb = MAX(  0._wp, SIGN( 1._wp , at_i(ji,jj) )  )
200                  zvgx  = zindb * (  u_ice(ji-1,jj  ) * tmu(ji-1,jj  )    &
201                     &             + u_ice(ji,jj    ) * tmu(ji  ,jj  )  ) * 0.5_wp
202                  zvgy  = zindb * (  v_ice(ji  ,jj-1) * tmv(ji  ,jj-1)    &
203                     &             + v_ice(ji,jj    ) * tmv(ji  ,jj  )  ) * 0.5_wp
204
205                  !-----------------------------------
206                  ! Relative frazil/pack ice velocity
207                  !-----------------------------------
208                  ! absolute relative velocity
209                  zvrel2 = MAX(  ( zvfrx - zvgx ) * ( zvfrx - zvgx )   &
210                     &         + ( zvfry - zvgy ) * ( zvfry - zvgy ) , 0.15 * 0.15 )
211                  zvrel(ji,jj)  = SQRT( zvrel2 )
212
213                  !---------------------
214                  ! Iterative procedure
215                  !---------------------
216                  hicol(ji,jj) = zhicrit + 0.1 
217                  hicol(ji,jj) = zhicrit +   hicol(ji,jj)    &
218                     &                   / ( hicol(ji,jj) * hicol(ji,jj) -  zhicrit * zhicrit ) * ztwogp * zvrel2
219
220!!gm better coding: above: hicol(ji,jj) * hicol(ji,jj) = (zhicrit + 0.1)*(zhicrit + 0.1)
221!!gm                                                   = zhicrit**2 + 0.2*zhicrit +0.01
222!!gm                therefore the 2 lines with hicol can be replaced by 1 line:
223!!gm              hicol(ji,jj) = zhicrit + (zhicrit + 0.1) / ( 0.2 * zhicrit + 0.01 ) * ztwogp * zvrel2
224!!gm further more (zhicrit + 0.1)/(0.2 * zhicrit + 0.01 )*ztwogp can be computed one for all outside the DO loop
225
226                  iter = 1
227                  iterate_frazil = .true.
228
229                  DO WHILE ( iter .LT. 100 .AND. iterate_frazil ) 
230                     zf = ( hicol(ji,jj) - zhicrit ) * ( hicol(ji,jj)**2 - zhicrit**2 ) &
231                        - hicol(ji,jj) * zhicrit * ztwogp * zvrel2
232                     zfp = ( hicol(ji,jj) - zhicrit ) * ( 3.0*hicol(ji,jj) + zhicrit ) &
233                        - zhicrit * ztwogp * zvrel2
234                     zhicol_new = hicol(ji,jj) - zf/zfp
235                     hicol(ji,jj)   = zhicol_new
236
237                     iter = iter + 1
238
239                  END DO ! do while
240
241               ENDIF ! end of selection of pixels where ice forms
242
243            END DO ! loop on ji ends
244         END DO ! loop on jj ends
245
246      ENDIF ! End of computation of frazil ice collection thickness
247
248      !------------------------------------------------------------------------------!
249      ! 4) Identify grid points where new ice forms
250      !------------------------------------------------------------------------------!
251
252      !-------------------------------------
253      ! Select points for new ice formation
254      !-------------------------------------
255      ! This occurs if open water energy budget is negative
256      nbpac = 0
257      DO jj = 1, jpj
258         DO ji = 1, jpi
259            IF ( qlead(ji,jj)  <  0._wp ) THEN
260               nbpac = nbpac + 1
261               npac( nbpac ) = (jj - 1) * jpi + ji
262            ENDIF
263         END DO
264      END DO
265
266      ! debug point to follow
267      jiindex_1d = 0
268      IF( ln_nicep ) THEN
269         DO ji = mi0(jiindx), mi1(jiindx)
270            DO jj = mj0(jjindx), mj1(jjindx)
271               IF ( qlead(ji,jj)  <  0._wp ) THEN
272                  jiindex_1d = (jj - 1) * jpi + ji
273               ENDIF
274            END DO
275         END DO
276      ENDIF
277   
278      IF( ln_nicep ) WRITE(numout,*) 'lim_thd_lac : nbpac = ', nbpac
279
280      !------------------------------
281      ! Move from 2-D to 1-D vectors
282      !------------------------------
283      ! If ocean gains heat do nothing
284      ! 0therwise compute new ice formation
285
286      IF ( nbpac > 0 ) THEN
287
288         CALL tab_2d_1d( nbpac, zat_i_1d  (1:nbpac)     , at_i         , jpi, jpj, npac(1:nbpac) )
289         DO jl = 1, jpl
290            CALL tab_2d_1d( nbpac, za_i_1d  (1:nbpac,jl), a_i  (:,:,jl), jpi, jpj, npac(1:nbpac) )
291            CALL tab_2d_1d( nbpac, zv_i_1d  (1:nbpac,jl), v_i  (:,:,jl), jpi, jpj, npac(1:nbpac) )
292            CALL tab_2d_1d( nbpac, zoa_i_1d (1:nbpac,jl), oa_i (:,:,jl), jpi, jpj, npac(1:nbpac) )
293            CALL tab_2d_1d( nbpac, zsmv_i_1d(1:nbpac,jl), smv_i(:,:,jl), jpi, jpj, npac(1:nbpac) )
294            DO jk = 1, nlay_i
295               CALL tab_2d_1d( nbpac, ze_i_1d(1:nbpac,jk,jl), e_i(:,:,jk,jl) , jpi, jpj, npac(1:nbpac) )
296            END DO ! jk
297         END DO ! jl
298
299         CALL tab_2d_1d( nbpac, qlead_1d  (1:nbpac)     , qlead  , jpi, jpj, npac(1:nbpac) )
300         CALL tab_2d_1d( nbpac, t_bo_b    (1:nbpac)     , t_bo   , jpi, jpj, npac(1:nbpac) )
301         CALL tab_2d_1d( nbpac, sfx_opw_1d(1:nbpac)     , sfx_opw, jpi, jpj, npac(1:nbpac) )
302         CALL tab_2d_1d( nbpac, wfx_opw_1d(1:nbpac)     , wfx_opw, jpi, jpj, npac(1:nbpac) )
303         CALL tab_2d_1d( nbpac, wfx_opw_1d(1:nbpac)     , wfx_opw, jpi, jpj, npac(1:nbpac) )
304         CALL tab_2d_1d( nbpac, hicol_b   (1:nbpac)     , hicol  , jpi, jpj, npac(1:nbpac) )
305         CALL tab_2d_1d( nbpac, zvrel_1d  (1:nbpac)     , zvrel  , jpi, jpj, npac(1:nbpac) )
306
307         CALL tab_2d_1d( nbpac, hfx_thd_1d(1:nbpac)     , hfx_thd, jpi, jpj, npac(1:nbpac) )
308         CALL tab_2d_1d( nbpac, hfx_opw_1d(1:nbpac)     , hfx_opw, jpi, jpj, npac(1:nbpac) )
309
310         !------------------------------------------------------------------------------!
311         ! 5) Compute thickness, salinity, enthalpy, age, area and volume of new ice
312         !------------------------------------------------------------------------------!
313
314         !-----------------------------------------
315         ! Keep old ice areas and volume in memory
316         !-----------------------------------------
317         zv_old(:,:) = zv_i_1d(:,:) 
318         za_old(:,:) = za_i_1d(:,:)
319
320         !----------------------
321         ! Thickness of new ice
322         !----------------------
323         DO ji = 1, nbpac
324            zh_newice(ji) = hiccrit(1)
325         END DO
326         IF( fraz_swi == 1.0 ) zh_newice(:) = hicol_b(:)
327
328         !----------------------
329         ! Salinity of new ice
330         !----------------------
331
332         SELECT CASE ( num_sal )
333         CASE ( 1 )                    ! Sice = constant
334            zs_newice(:) = bulk_sal
335         CASE ( 2 )                    ! Sice = F(z,t) [Vancoppenolle et al (2005)]
336            DO ji = 1, nbpac
337               ii =   MOD( npac(ji) - 1 , jpi ) + 1
338               ij =      ( npac(ji) - 1 ) / jpi + 1
339               zs_newice(ji) = MIN(  4.606 + 0.91 / zh_newice(ji) , s_i_max , 0.5 * sss_m(ii,ij)  )
340            END DO
341         CASE ( 3 )                    ! Sice = F(z) [multiyear ice]
342            zs_newice(:) =   2.3
343         END SELECT
344
345
346         !-------------------------
347         ! Heat content of new ice
348         !-------------------------
349         ! We assume that new ice is formed at the seawater freezing point
350         DO ji = 1, nbpac
351            ztmelts       = - tmut * zs_newice(ji) + rtt                  ! Melting point (K)
352            ze_newice(ji) =   rhoic * (  cpic * ( ztmelts - t_bo_b(ji) )                             &
353               &                       + lfus * ( 1.0 - ( ztmelts - rtt ) / MIN( t_bo_b(ji) - rtt, -epsi10 ) )   &
354               &                       - rcp  *         ( ztmelts - rtt )  )
355         END DO ! ji
356         !----------------
357         ! Age of new ice
358         !----------------
359         DO ji = 1, nbpac
360            zo_newice(ji) = 0._wp
361         END DO ! ji
362
363         !-------------------
364         ! Volume of new ice
365         !-------------------
366         DO ji = 1, nbpac
367
368            zEi           = - ze_newice(ji) / rhoic                ! specific enthalpy of forming ice [J/kg]
369
370            zEw           = rcp * ( t_bo_b(ji) - rt0 )             ! specific enthalpy of seawater at t_bo_b [J/kg]
371                                                                   ! clem: we suppose we are already at the freezing point (condition qlead<0 is satisfyied)
372                                                                   
373            zdE           = zEi - zEw                              ! specific enthalpy difference [J/kg]
374                                             
375            zfmdt         = - qlead_1d(ji) / zdE                   ! Fm.dt [kg/m2] (<0)
376                                                                   ! clem: we use qlead instead of zqld (limthd) because we suppose we are at the freezing point   
377            zv_newice(ji) = - zfmdt / rhoic
378
379            zQm           = zfmdt * zEw                            ! heat to the ocean >0 associated with mass flux 
380
381            ! Contribution to heat flux to the ocean [W.m-2], >0 
382            hfx_thd_1d(ji) = hfx_thd_1d(ji) + zfmdt * zEw * r1_rdtice
383            ! Total heat flux used in this process [W.m-2] 
384            hfx_opw_1d(ji) = hfx_opw_1d(ji) - zfmdt * zdE * r1_rdtice
385            ! mass flux
386            wfx_opw_1d(ji) = wfx_opw_1d(ji) - zv_newice(ji) * rhoic * r1_rdtice
387            ! salt flux
388            sfx_opw_1d(ji) = sfx_opw_1d(ji) - zv_newice(ji) * rhoic * zs_newice(ji) * r1_rdtice
389
390            ! A fraction zfrazb of frazil ice is accreted at the ice bottom
391            zinda         = 1._wp - MAX( 0._wp, SIGN( 1._wp , - zat_i_1d(ji) ) )
392            zfrazb        = zinda * ( TANH ( Cfrazb * ( zvrel_1d(ji) - vfrazb ) ) + 1.0 ) * 0.5 * maxfrazb
393            zv_frazb(ji)  =         zfrazb   * zv_newice(ji)
394            zv_newice(ji) = ( 1.0 - zfrazb ) * zv_newice(ji)
395         END DO
396
397
398         !-----------------
399         ! Area of new ice
400         !-----------------
401         DO ji = 1, nbpac
402            za_newice(ji) = zv_newice(ji) / zh_newice(ji)
403         END DO
404
405         !------------------------------------------------------------------------------!
406         ! 6) Redistribute new ice area and volume into ice categories                  !
407         !------------------------------------------------------------------------------!
408
409         !-------------------------------------------
410         ! Compute excessive new ice area and volume
411         !-------------------------------------------
412         ! If lateral ice growth gives an ice concentration gt 1, then
413         ! we keep the excessive volume in memory and attribute it later to bottom accretion
414         DO ji = 1, nbpac
415            IF ( za_newice(ji) >  ( amax - zat_i_1d(ji) ) ) THEN
416               zda_res(ji)   = za_newice(ji) - ( amax - zat_i_1d(ji) )
417               zdv_res(ji)   = zda_res  (ji) * zh_newice(ji) 
418               za_newice(ji) = za_newice(ji) - zda_res  (ji)
419               zv_newice(ji) = zv_newice(ji) - zdv_res  (ji)
420            ELSE
421               zda_res(ji) = 0._wp
422               zdv_res(ji) = 0._wp
423            ENDIF
424         END DO ! ji
425
426         !------------------------------------------------
427         ! Laterally redistribute new ice volume and area
428         !------------------------------------------------
429         zat_i_1d(:) = 0._wp
430         DO jl = 1, jpl
431            DO ji = 1, nbpac
432               IF( zh_newice(ji) > hi_max(jl-1) .AND. zh_newice(ji) <= hi_max(jl) ) THEN
433                  za_i_1d (ji,jl) = za_i_1d (ji,jl) + za_newice(ji)
434                  zv_i_1d (ji,jl) = zv_i_1d (ji,jl) + zv_newice(ji)
435                  jcat  (ji)    = jl
436               ENDIF
437               zat_i_1d(ji) = zat_i_1d(ji) + za_i_1d  (ji,jl)
438            END DO
439         END DO
440
441         !----------------------------------
442         ! Heat content - lateral accretion
443         !----------------------------------
444         DO ji = 1, nbpac
445            jl = jcat(ji)                                                  ! categroy in which new ice is put
446            zswinew  (ji) = MAX( 0._wp , SIGN( 1._wp , - za_old(ji,jl) ) )   ! 0 if old ice
447         END DO
448
449         DO jk = 1, nlay_i
450            DO ji = 1, nbpac
451               jl = jcat(ji)
452               zinda = MAX( 0._wp, SIGN( 1._wp , zv_i_1d(ji,jl) - epsi20 ) )
453               ze_i_1d(ji,jk,jl) = zswinew(ji)   *   ze_newice(ji) +                                                      &
454                  &        ( 1.0 - zswinew(ji) ) * ( ze_newice(ji) * zv_newice(ji) + ze_i_1d(ji,jk,jl) * zv_old(ji,jl) )  &
455                  &        * zinda / MAX( zv_i_1d(ji,jl), epsi20 )
456            END DO
457         END DO
458
459         !-----------------------------------------------
460         ! Add excessive volume of new ice at the bottom
461         !-----------------------------------------------
462         DO jl = 1, jpl
463            h_i_old (1:nbpac,0:nlay_i+1) = 0._wp
464            qh_i_old(1:nbpac,0:nlay_i+1) = 0._wp
465
466            DO jk = 1, nlay_i
467               DO ji = 1, nbpac
468                  h_i_old (ji,jk) = zv_i_1d(ji,jl) / REAL( nlay_i )
469                  qh_i_old(ji,jk) = ze_i_1d(ji,jk,jl) * h_i_old(ji,jk)
470               END DO
471            END DO
472
473            DO ji = 1, nbpac
474               zinda          = MAX( 0._wp, SIGN( 1._wp , zat_i_1d(ji) - epsi20 ) )
475               zv_newfra      = zinda * ( zdv_res(ji) + zv_frazb(ji) ) * za_i_1d(ji,jl) / MAX( zat_i_1d(ji) , epsi20 )
476               za_i_1d(ji,jl) = zinda * za_i_1d(ji,jl)               
477
478               h_i_old (ji,nlay_i+1) = zv_newfra
479               qh_i_old(ji,nlay_i+1) = ze_newice(ji) * zv_newfra
480
481               zv_i_1d(ji,jl) = zv_i_1d(ji,jl) + zv_newfra
482            ENDDO
483
484            ! --- Ice enthalpy remapping --- !
485            CALL lim_thd_ent( 1, nbpac, jl, ze_i_1d(1:nbpac,:,jl) ) 
486
487         ENDDO
488
489         !------------
490         ! Update age
491         !------------
492         DO jl = 1, jpl
493            DO ji = 1, nbpac
494               zindb = 1._wp - MAX( 0._wp , SIGN( 1._wp , - za_i_1d(ji,jl) + epsi20 ) )  ! 0 if no ice and 1 if yes
495               zoa_i_1d(ji,jl)  = za_old(ji,jl) * zoa_i_1d(ji,jl) / MAX( za_i_1d(ji,jl) , epsi20 ) * zindb   
496            END DO
497         END DO   
498
499         !-----------------
500         ! Update salinity
501         !-----------------
502         !clem IF(  num_sal == 2  ) THEN
503            DO jl = 1, jpl
504               DO ji = 1, nbpac
505                  zdv   = zv_i_1d(ji,jl) - zv_old(ji,jl)
506                  zsmv_i_1d(ji,jl) = zsmv_i_1d(ji,jl) + zdv * zs_newice(ji)
507               END DO
508            END DO   
509         !clem ENDIF
510
511         !------------------------------------------------------------------------------!
512         ! 8) Change 2D vectors to 1D vectors
513         !------------------------------------------------------------------------------!
514         DO jl = 1, jpl
515            CALL tab_1d_2d( nbpac, a_i (:,:,jl), npac(1:nbpac), za_i_1d (1:nbpac,jl), jpi, jpj )
516            CALL tab_1d_2d( nbpac, v_i (:,:,jl), npac(1:nbpac), zv_i_1d (1:nbpac,jl), jpi, jpj )
517            CALL tab_1d_2d( nbpac, oa_i(:,:,jl), npac(1:nbpac), zoa_i_1d(1:nbpac,jl), jpi, jpj )
518            CALL tab_1d_2d( nbpac, smv_i (:,:,jl), npac(1:nbpac), zsmv_i_1d(1:nbpac,jl) , jpi, jpj )
519            DO jk = 1, nlay_i
520               CALL tab_1d_2d( nbpac, e_i(:,:,jk,jl), npac(1:nbpac), ze_i_1d(1:nbpac,jk,jl), jpi, jpj )
521            END DO
522         END DO
523         CALL tab_1d_2d( nbpac, sfx_opw, npac(1:nbpac), sfx_opw_1d(1:nbpac), jpi, jpj )
524         CALL tab_1d_2d( nbpac, wfx_opw, npac(1:nbpac), wfx_opw_1d(1:nbpac), jpi, jpj )
525         CALL tab_1d_2d( nbpac, wfx_opw, npac(1:nbpac), wfx_opw_1d(1:nbpac), jpi, jpj )
526
527         CALL tab_1d_2d( nbpac, hfx_thd, npac(1:nbpac), hfx_thd_1d(1:nbpac), jpi, jpj )
528         CALL tab_1d_2d( nbpac, hfx_opw, npac(1:nbpac), hfx_opw_1d(1:nbpac), jpi, jpj )
529         !
530      ENDIF ! nbpac > 0
531
532      !------------------------------------------------------------------------------!
533      ! 9) Change units for e_i
534      !------------------------------------------------------------------------------!   
535      DO jl = 1, jpl
536         DO jk = 1, nlay_i
537            DO jj = 1, jpj
538               DO ji = 1, jpi
539                  ! heat content in Joules
540                  e_i(ji,jj,jk,jl) = e_i(ji,jj,jk,jl) * area(ji,jj) * v_i(ji,jj,jl) / ( REAL( nlay_i ) * unit_fac ) 
541               END DO
542            END DO
543         END DO
544      END DO
545
546      !
547      CALL wrk_dealloc( jpij, jcat )   ! integer
548      CALL wrk_dealloc( jpij, zswinew, zv_newice, za_newice, zh_newice, ze_newice, zs_newice, zo_newice )
549      CALL wrk_dealloc( jpij, zdv_res, zda_res, zat_i_1d, zat_i_lev, zv_frazb, zvrel_1d )
550      CALL wrk_dealloc( jpij,jpl, zv_old, za_old, za_i_1d, zv_i_1d, zoa_i_1d, zsmv_i_1d )
551      CALL wrk_dealloc( jpij,jkmax,jpl, ze_i_1d )
552      CALL wrk_dealloc( jpi,jpj, zvrel )
553      !
554   END SUBROUTINE lim_thd_lac
555
556#else
557   !!----------------------------------------------------------------------
558   !!   Default option                               NO  LIM3 sea-ice model
559   !!----------------------------------------------------------------------
560CONTAINS
561   SUBROUTINE lim_thd_lac           ! Empty routine
562   END SUBROUTINE lim_thd_lac
563#endif
564
565   !!======================================================================
566END MODULE limthd_lac
Note: See TracBrowser for help on using the repository browser.