| 1 | MODULE limsbc |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE limsbc *** |
|---|
| 4 | !! computation of the flux at the sea ice/ocean interface |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : - ! 2006-07 (M. Vancoppelle) LIM3 original code |
|---|
| 7 | !! 3.0 ! 2008-03 (C. Tallandier) surface module |
|---|
| 8 | !! - ! 2008-04 (C. Tallandier) split in 2 + new ice-ocean coupling |
|---|
| 9 | !! 3.3 ! 2010-05 (G. Madec) decrease ocean & ice reference salinities in the Baltic sea |
|---|
| 10 | !! ! + simplification of the ice-ocean stress calculation |
|---|
| 11 | !! 3.4 ! 2011-02 (G. Madec) dynamical allocation |
|---|
| 12 | !! - ! 2012 (D. Iovino) salt flux change |
|---|
| 13 | !! - ! 2012-05 (C. Rousset) add penetration solar flux |
|---|
| 14 | !! 3.5 ! 2012-10 (A. Coward, G. Madec) salt fluxes ; ice+snow mass |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | #if defined key_lim3 |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | !! 'key_lim3' LIM 3.0 sea-ice model |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | !! lim_sbc_alloc : allocate the limsbc arrays |
|---|
| 21 | !! lim_sbc_init : initialisation |
|---|
| 22 | !! lim_sbc_flx : updates mass, heat and salt fluxes at the ocean surface |
|---|
| 23 | !! lim_sbc_tau : update i- and j-stresses, and its modulus at the ocean surface |
|---|
| 24 | !!---------------------------------------------------------------------- |
|---|
| 25 | USE par_oce ! ocean parameters |
|---|
| 26 | USE phycst ! physical constants |
|---|
| 27 | USE par_ice ! ice parameters |
|---|
| 28 | USE dom_oce ! ocean domain |
|---|
| 29 | USE dom_ice, ONLY : tms, area |
|---|
| 30 | USE ice ! LIM sea-ice variables |
|---|
| 31 | USE sbc_ice ! Surface boundary condition: sea-ice fields |
|---|
| 32 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 33 | USE sbccpl |
|---|
| 34 | USE cpl_oasis3, ONLY : lk_cpl |
|---|
| 35 | USE oce , ONLY : iatte, oatte, sshn, sshb, snwice_mass, snwice_mass_b, snwice_fmass |
|---|
| 36 | USE albedo ! albedo parameters |
|---|
| 37 | USE lbclnk ! ocean lateral boundary condition - MPP exchanges |
|---|
| 38 | USE lib_mpp ! MPP library |
|---|
| 39 | USE wrk_nemo ! work arrays |
|---|
| 40 | USE in_out_manager ! I/O manager |
|---|
| 41 | USE prtctl ! Print control |
|---|
| 42 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 43 | USE traqsr ! clem: add penetration of solar flux into the calculation of heat budget |
|---|
| 44 | USE iom |
|---|
| 45 | USE domvvl ! Variable volume |
|---|
| 46 | |
|---|
| 47 | IMPLICIT NONE |
|---|
| 48 | PRIVATE |
|---|
| 49 | |
|---|
| 50 | PUBLIC lim_sbc_init ! called by ice_init |
|---|
| 51 | PUBLIC lim_sbc_flx ! called by sbc_ice_lim |
|---|
| 52 | PUBLIC lim_sbc_tau ! called by sbc_ice_lim |
|---|
| 53 | |
|---|
| 54 | REAL(wp) :: epsi10 = 1.e-10 ! |
|---|
| 55 | REAL(wp) :: epsi20 = 1.e-20 ! |
|---|
| 56 | |
|---|
| 57 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: utau_oce, vtau_oce ! air-ocean surface i- & j-stress [N/m2] |
|---|
| 58 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: tmod_io ! modulus of the ice-ocean velocity [m/s] |
|---|
| 59 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: soce_0 , sice_0 ! cst SSS and ice salinity (levitating sea-ice) |
|---|
| 60 | |
|---|
| 61 | !! * Substitutions |
|---|
| 62 | # include "vectopt_loop_substitute.h90" |
|---|
| 63 | # include "domzgr_substitute.h90" |
|---|
| 64 | !!---------------------------------------------------------------------- |
|---|
| 65 | !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011) |
|---|
| 66 | !! $Id$ |
|---|
| 67 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 68 | !!---------------------------------------------------------------------- |
|---|
| 69 | CONTAINS |
|---|
| 70 | |
|---|
| 71 | INTEGER FUNCTION lim_sbc_alloc() |
|---|
| 72 | !!------------------------------------------------------------------- |
|---|
| 73 | !! *** ROUTINE lim_sbc_alloc *** |
|---|
| 74 | !!------------------------------------------------------------------- |
|---|
| 75 | ALLOCATE( soce_0(jpi,jpj) , utau_oce(jpi,jpj) , & |
|---|
| 76 | & sice_0(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=lim_sbc_alloc) |
|---|
| 77 | ! |
|---|
| 78 | IF( lk_mpp ) CALL mpp_sum( lim_sbc_alloc ) |
|---|
| 79 | IF( lim_sbc_alloc /= 0 ) CALL ctl_warn('lim_sbc_alloc: failed to allocate arrays') |
|---|
| 80 | END FUNCTION lim_sbc_alloc |
|---|
| 81 | |
|---|
| 82 | |
|---|
| 83 | SUBROUTINE lim_sbc_flx( kt ) |
|---|
| 84 | !!------------------------------------------------------------------- |
|---|
| 85 | !! *** ROUTINE lim_sbc_flx *** |
|---|
| 86 | !! |
|---|
| 87 | !! ** Purpose : Update the surface ocean boundary condition for heat |
|---|
| 88 | !! salt and mass over areas where sea-ice is non-zero |
|---|
| 89 | !! |
|---|
| 90 | !! ** Action : - computes the heat and freshwater/salt fluxes |
|---|
| 91 | !! at the ice-ocean interface. |
|---|
| 92 | !! - Update the ocean sbc |
|---|
| 93 | !! |
|---|
| 94 | !! ** Outputs : - qsr : sea heat flux: solar |
|---|
| 95 | !! - qns : sea heat flux: non solar |
|---|
| 96 | !! - emp : freshwater budget: volume flux |
|---|
| 97 | !! - sfx : salt flux |
|---|
| 98 | !! - fr_i : ice fraction |
|---|
| 99 | !! - tn_ice : sea-ice surface temperature |
|---|
| 100 | !! - alb_ice : sea-ice alberdo (lk_cpl=T) |
|---|
| 101 | !! |
|---|
| 102 | !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90. |
|---|
| 103 | !! Tartinville et al. 2001 Ocean Modelling, 3, 95-108. |
|---|
| 104 | !! These refs are now obsolete since everything has been revised |
|---|
| 105 | !! The ref should be Rousset et al., 2015? |
|---|
| 106 | !!--------------------------------------------------------------------- |
|---|
| 107 | INTEGER, INTENT(in) :: kt ! number of iteration |
|---|
| 108 | ! |
|---|
| 109 | INTEGER :: ji, jj, jl, jk ! dummy loop indices |
|---|
| 110 | ! |
|---|
| 111 | REAL(wp) :: zinda, zemp ! local scalars |
|---|
| 112 | REAL(wp) :: zf_mass ! Heat flux associated with mass exchange ice->ocean (W.m-2) |
|---|
| 113 | REAL(wp) :: zfcm1 ! New solar flux received by the ocean |
|---|
| 114 | ! |
|---|
| 115 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_cs, zalb_os ! 2D/3D workspace |
|---|
| 116 | !!--------------------------------------------------------------------- |
|---|
| 117 | |
|---|
| 118 | ! make calls for heat fluxes before it is modified |
|---|
| 119 | CALL iom_put( "qsr_oce" , qsr(:,:) * pfrld(:,:) ) ! solar flux at ocean surface |
|---|
| 120 | CALL iom_put( "qns_oce" , qns(:,:) * pfrld(:,:) ) ! non-solar flux at ocean surface |
|---|
| 121 | CALL iom_put( "qsr_ice" , SUM( qsr_ice(:,:,:) * old_a_i(:,:,:), dim=3 ) ) ! solar flux at ice surface |
|---|
| 122 | CALL iom_put( "qns_ice" , SUM( qns_ice(:,:,:) * old_a_i(:,:,:), dim=3 ) ) ! non-solar flux at ice surface |
|---|
| 123 | CALL iom_put( "qtr_ice" , SUM( ftr_ice(:,:,:) * old_a_i(:,:,:), dim=3 ) ) ! solar flux transmitted thru ice |
|---|
| 124 | CALL iom_put( "qt_oce" , ( qsr(:,:) + qns(:,:) ) * pfrld(:,:) ) |
|---|
| 125 | CALL iom_put( "qt_ice" , SUM( ( qns_ice(:,:,:) + qsr_ice(:,:,:) ) * old_a_i(:,:,:), dim=3 ) ) |
|---|
| 126 | |
|---|
| 127 | ! pfrld is the lead fraction at the previous time step (actually between TRP and THD) |
|---|
| 128 | DO jj = 1, jpj |
|---|
| 129 | DO ji = 1, jpi |
|---|
| 130 | |
|---|
| 131 | !------------------------------------------! |
|---|
| 132 | ! heat flux at the ocean surface ! |
|---|
| 133 | !------------------------------------------! |
|---|
| 134 | zinda = 1._wp - MAX( 0._wp , SIGN( 1._wp , - ( 1._wp - pfrld(ji,jj) ) ) ) ! 1 if ice |
|---|
| 135 | |
|---|
| 136 | ! Solar heat flux reaching the ocean = zfcm1 (W.m-2) |
|---|
| 137 | !--------------------------------------------------- |
|---|
| 138 | IF( lk_cpl ) THEN ! be careful: not been tested yet |
|---|
| 139 | ! original line |
|---|
| 140 | zfcm1 = qsr_tot(ji,jj) |
|---|
| 141 | !!! LIM2 version zqsr = qsr_tot(ji,jj) + ( fstric(ji,jj) - qsr_ice(ji,jj,1) ) * ( 1.0 - pfrld(ji,jj) ) |
|---|
| 142 | DO jl = 1, jpl |
|---|
| 143 | zfcm1 = zfcm1 + ( ftr_ice(ji,jj,jl) - qsr_ice(ji,jj,jl) ) * old_a_i(ji,jj,jl) |
|---|
| 144 | END DO |
|---|
| 145 | ELSE |
|---|
| 146 | !!! LIM2 version zqsr = pfrld(ji,jj) * qsr(ji,jj) + ( 1. - pfrld(ji,jj) ) * fstric(ji,jj) |
|---|
| 147 | zfcm1 = pfrld(ji,jj) * qsr(ji,jj) |
|---|
| 148 | DO jl = 1, jpl |
|---|
| 149 | zfcm1 = zfcm1 + old_a_i(ji,jj,jl) * ftr_ice(ji,jj,jl) |
|---|
| 150 | END DO |
|---|
| 151 | ENDIF |
|---|
| 152 | |
|---|
| 153 | ! Total heat flux reaching the ocean = hfx_out (W.m-2) |
|---|
| 154 | !--------------------------------------------------- |
|---|
| 155 | zf_mass = hfx_thd(ji,jj) + hfx_dyn(ji,jj) + hfx_res(ji,jj) ! heat flux from snow is 0 (T=0 degC) |
|---|
| 156 | hfx_out(ji,jj) = hfx_out(ji,jj) + zf_mass + zfcm1 |
|---|
| 157 | |
|---|
| 158 | ! New qsr and qns used to compute the oceanic heat flux at the next time step |
|---|
| 159 | !--------------------------------------------------- |
|---|
| 160 | qsr(ji,jj) = zfcm1 |
|---|
| 161 | qns(ji,jj) = hfx_out(ji,jj) - zfcm1 |
|---|
| 162 | |
|---|
| 163 | !------------------------------------------! |
|---|
| 164 | ! mass flux at the ocean surface ! |
|---|
| 165 | !------------------------------------------! |
|---|
| 166 | ! case of realistic freshwater flux (Tartinville et al., 2001) (presently ACTIVATED) |
|---|
| 167 | ! ------------------------------------------------------------------------------------- |
|---|
| 168 | ! The idea of this approach is that the system that we consider is the ICE-OCEAN system |
|---|
| 169 | ! Thus FW flux = External ( E-P+snow melt) |
|---|
| 170 | ! Salt flux = Exchanges in the ice-ocean system then converted into FW |
|---|
| 171 | ! Associated to Ice formation AND Ice melting |
|---|
| 172 | ! Even if i see Ice melting as a FW and SALT flux |
|---|
| 173 | ! |
|---|
| 174 | ! computing freshwater exchanges at the ice/ocean interface |
|---|
| 175 | IF( lk_cpl ) THEN |
|---|
| 176 | zemp = - emp_tot(ji,jj) + emp_ice(ji,jj) * ( 1. - pfrld(ji,jj) ) & ! |
|---|
| 177 | & + wfx_snw(ji,jj) |
|---|
| 178 | ELSE |
|---|
| 179 | zemp = emp(ji,jj) * pfrld(ji,jj) & ! evaporation over oceanic fraction |
|---|
| 180 | & - tprecip(ji,jj) * ( 1._wp - pfrld(ji,jj) ) & ! all precipitation reach the ocean |
|---|
| 181 | & + sprecip(ji,jj) * ( 1._wp - pfrld(ji,jj)**betas ) ! except solid precip intercepted by sea-ice |
|---|
| 182 | ENDIF |
|---|
| 183 | |
|---|
| 184 | ! mass flux from ice/ocean |
|---|
| 185 | wfx_ice(ji,jj) = wfx_bog(ji,jj) + wfx_bom(ji,jj) + wfx_sum(ji,jj) + wfx_sni(ji,jj) + wfx_opw(ji,jj) + wfx_dyn(ji,jj) + wfx_res(ji,jj) |
|---|
| 186 | |
|---|
| 187 | ! mass flux at the ocean/ice interface |
|---|
| 188 | fmmflx(ji,jj) = - wfx_ice(ji,jj) * rdt_ice ! F/M mass flux save at least for biogeochemical model |
|---|
| 189 | emp(ji,jj) = zemp - wfx_ice(ji,jj) - wfx_snw(ji,jj) - wfx_sub(ji,jj) ! mass flux + F/M mass flux (always ice/ocean mass exchange) |
|---|
| 190 | |
|---|
| 191 | END DO |
|---|
| 192 | END DO |
|---|
| 193 | |
|---|
| 194 | !------------------------------------------! |
|---|
| 195 | ! salt flux at the ocean surface ! |
|---|
| 196 | !------------------------------------------! |
|---|
| 197 | sfx(:,:) = sfx_bog(:,:) + sfx_bom(:,:) + sfx_sum(:,:) + sfx_sni(:,:) + sfx_opw(:,:) + sfx_res(:,:) + sfx_dyn(:,:) + sfx_bri(:,:) |
|---|
| 198 | |
|---|
| 199 | !-------------------------------------------------------------! |
|---|
| 200 | ! mass of snow and ice per unit area for embedded sea-ice ! |
|---|
| 201 | !-------------------------------------------------------------! |
|---|
| 202 | IF( nn_ice_embd /= 0 ) THEN |
|---|
| 203 | ! save mass from the previous ice time step |
|---|
| 204 | snwice_mass_b(:,:) = snwice_mass(:,:) |
|---|
| 205 | ! new mass per unit area |
|---|
| 206 | snwice_mass (:,:) = tms(:,:) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:) ) |
|---|
| 207 | ! time evolution of snow+ice mass |
|---|
| 208 | snwice_fmass (:,:) = ( snwice_mass(:,:) - snwice_mass_b(:,:) ) * r1_rdtice |
|---|
| 209 | ENDIF |
|---|
| 210 | |
|---|
| 211 | !-----------------------------------------------! |
|---|
| 212 | ! Storing the transmitted variables ! |
|---|
| 213 | !-----------------------------------------------! |
|---|
| 214 | fr_i (:,:) = at_i(:,:) ! Sea-ice fraction |
|---|
| 215 | tn_ice(:,:,:) = t_su(:,:,:) ! Ice surface temperature |
|---|
| 216 | |
|---|
| 217 | !------------------------------------------------! |
|---|
| 218 | ! Snow/ice albedo (only if sent to coupler) ! |
|---|
| 219 | !------------------------------------------------! |
|---|
| 220 | IF( lk_cpl ) THEN ! coupled case |
|---|
| 221 | |
|---|
| 222 | CALL wrk_alloc( jpi, jpj, jpl, zalb_cs, zalb_os ) |
|---|
| 223 | |
|---|
| 224 | CALL albedo_ice( t_su, ht_i, ht_s, zalb_cs, zalb_os ) ! cloud-sky and overcast-sky ice albedos |
|---|
| 225 | |
|---|
| 226 | alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:) |
|---|
| 227 | |
|---|
| 228 | CALL wrk_dealloc( jpi, jpj, jpl, zalb_cs, zalb_os ) |
|---|
| 229 | |
|---|
| 230 | ENDIF |
|---|
| 231 | |
|---|
| 232 | |
|---|
| 233 | IF(ln_ctl) THEN |
|---|
| 234 | CALL prt_ctl( tab2d_1=qsr , clinfo1=' lim_sbc: qsr : ', tab2d_2=qns , clinfo2=' qns : ' ) |
|---|
| 235 | CALL prt_ctl( tab2d_1=emp , clinfo1=' lim_sbc: emp : ', tab2d_2=sfx , clinfo2=' sfx : ' ) |
|---|
| 236 | CALL prt_ctl( tab2d_1=fr_i , clinfo1=' lim_sbc: fr_i : ' ) |
|---|
| 237 | CALL prt_ctl( tab3d_1=tn_ice, clinfo1=' lim_sbc: tn_ice : ', kdim=jpl ) |
|---|
| 238 | ENDIF |
|---|
| 239 | |
|---|
| 240 | END SUBROUTINE lim_sbc_flx |
|---|
| 241 | |
|---|
| 242 | |
|---|
| 243 | SUBROUTINE lim_sbc_tau( kt , pu_oce, pv_oce ) |
|---|
| 244 | !!------------------------------------------------------------------- |
|---|
| 245 | !! *** ROUTINE lim_sbc_tau *** |
|---|
| 246 | !! |
|---|
| 247 | !! ** Purpose : Update the ocean surface stresses due to the ice |
|---|
| 248 | !! |
|---|
| 249 | !! ** Action : * at each ice time step (every nn_fsbc time step): |
|---|
| 250 | !! - compute the modulus of ice-ocean relative velocity |
|---|
| 251 | !! (*rho*Cd) at T-point (C-grid) or I-point (B-grid) |
|---|
| 252 | !! tmod_io = rhoco * | U_ice-U_oce | |
|---|
| 253 | !! - update the modulus of stress at ocean surface |
|---|
| 254 | !! taum = frld * taum + (1-frld) * tmod_io * | U_ice-U_oce | |
|---|
| 255 | !! * at each ocean time step (every kt): |
|---|
| 256 | !! compute linearized ice-ocean stresses as |
|---|
| 257 | !! Utau = tmod_io * | U_ice - pU_oce | |
|---|
| 258 | !! using instantaneous current ocean velocity (usually before) |
|---|
| 259 | !! |
|---|
| 260 | !! NB: - ice-ocean rotation angle no more allowed |
|---|
| 261 | !! - here we make an approximation: taum is only computed every ice time step |
|---|
| 262 | !! This avoids mutiple average to pass from T -> U,V grids and next from U,V grids |
|---|
| 263 | !! to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton... |
|---|
| 264 | !! |
|---|
| 265 | !! ** Outputs : - utau, vtau : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes |
|---|
| 266 | !! - taum : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes |
|---|
| 267 | !!--------------------------------------------------------------------- |
|---|
| 268 | INTEGER , INTENT(in) :: kt ! ocean time-step index |
|---|
| 269 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pu_oce, pv_oce ! surface ocean currents |
|---|
| 270 | !! |
|---|
| 271 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 272 | REAL(wp) :: zat_u, zutau_ice, zu_t, zmodt ! local scalar |
|---|
| 273 | REAL(wp) :: zat_v, zvtau_ice, zv_t ! - - |
|---|
| 274 | !!--------------------------------------------------------------------- |
|---|
| 275 | ! |
|---|
| 276 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN !== Ice time-step only ==! (i.e. surface module time-step) |
|---|
| 277 | !CDIR NOVERRCHK |
|---|
| 278 | DO jj = 2, jpjm1 !* update the modulus of stress at ocean surface (T-point) |
|---|
| 279 | !CDIR NOVERRCHK |
|---|
| 280 | DO ji = fs_2, fs_jpim1 |
|---|
| 281 | ! ! 2*(U_ice-U_oce) at T-point |
|---|
| 282 | zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj) |
|---|
| 283 | zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) |
|---|
| 284 | ! ! |U_ice-U_oce|^2 |
|---|
| 285 | zmodt = 0.25_wp * ( zu_t * zu_t + zv_t * zv_t ) |
|---|
| 286 | ! ! update the ocean stress modulus |
|---|
| 287 | taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * rhoco * zmodt |
|---|
| 288 | tmod_io(ji,jj) = rhoco * SQRT( zmodt ) ! rhoco * |U_ice-U_oce| at T-point |
|---|
| 289 | END DO |
|---|
| 290 | END DO |
|---|
| 291 | CALL lbc_lnk( taum, 'T', 1. ) ; CALL lbc_lnk( tmod_io, 'T', 1. ) |
|---|
| 292 | ! |
|---|
| 293 | utau_oce(:,:) = utau(:,:) !* save the air-ocean stresses at ice time-step |
|---|
| 294 | vtau_oce(:,:) = vtau(:,:) |
|---|
| 295 | ! |
|---|
| 296 | ENDIF |
|---|
| 297 | ! |
|---|
| 298 | ! !== every ocean time-step ==! |
|---|
| 299 | ! |
|---|
| 300 | DO jj = 2, jpjm1 !* update the stress WITHOUT a ice-ocean rotation angle |
|---|
| 301 | DO ji = fs_2, fs_jpim1 ! Vect. Opt. |
|---|
| 302 | zat_u = ( at_i(ji,jj) + at_i(ji+1,jj) ) * 0.5_wp ! ice area at u and V-points |
|---|
| 303 | zat_v = ( at_i(ji,jj) + at_i(ji,jj+1) ) * 0.5_wp |
|---|
| 304 | ! ! linearized quadratic drag formulation |
|---|
| 305 | zutau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) ) |
|---|
| 306 | zvtau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) ) |
|---|
| 307 | ! ! stresses at the ocean surface |
|---|
| 308 | utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice |
|---|
| 309 | vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice |
|---|
| 310 | END DO |
|---|
| 311 | END DO |
|---|
| 312 | CALL lbc_lnk( utau, 'U', -1. ) ; CALL lbc_lnk( vtau, 'V', -1. ) ! lateral boundary condition |
|---|
| 313 | ! |
|---|
| 314 | IF(ln_ctl) CALL prt_ctl( tab2d_1=utau, clinfo1=' lim_sbc: utau : ', mask1=umask, & |
|---|
| 315 | & tab2d_2=vtau, clinfo2=' vtau : ' , mask2=vmask ) |
|---|
| 316 | ! |
|---|
| 317 | END SUBROUTINE lim_sbc_tau |
|---|
| 318 | |
|---|
| 319 | |
|---|
| 320 | SUBROUTINE lim_sbc_init |
|---|
| 321 | !!------------------------------------------------------------------- |
|---|
| 322 | !! *** ROUTINE lim_sbc_init *** |
|---|
| 323 | !! |
|---|
| 324 | !! ** Purpose : Preparation of the file ice_evolu for the output of |
|---|
| 325 | !! the temporal evolution of key variables |
|---|
| 326 | !! |
|---|
| 327 | !! ** input : Namelist namicedia |
|---|
| 328 | !!------------------------------------------------------------------- |
|---|
| 329 | REAL(wp) :: zsum, zarea |
|---|
| 330 | ! |
|---|
| 331 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 332 | REAL(wp) :: zcoefu, zcoefv, zcoeff ! local scalar |
|---|
| 333 | IF(lwp) WRITE(numout,*) |
|---|
| 334 | IF(lwp) WRITE(numout,*) 'lim_sbc_init : LIM-3 sea-ice - surface boundary condition' |
|---|
| 335 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~ ' |
|---|
| 336 | |
|---|
| 337 | ! ! allocate lim_sbc array |
|---|
| 338 | IF( lim_sbc_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'lim_sbc_init : unable to allocate standard arrays' ) |
|---|
| 339 | ! |
|---|
| 340 | soce_0(:,:) = soce ! constant SSS and ice salinity used in levitating sea-ice case |
|---|
| 341 | sice_0(:,:) = sice |
|---|
| 342 | ! |
|---|
| 343 | IF( cp_cfg == "orca" ) THEN ! decrease ocean & ice reference salinities in the Baltic sea |
|---|
| 344 | WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND. & |
|---|
| 345 | & 54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp ) |
|---|
| 346 | soce_0(:,:) = 4._wp |
|---|
| 347 | sice_0(:,:) = 2._wp |
|---|
| 348 | END WHERE |
|---|
| 349 | ENDIF |
|---|
| 350 | ! clem modif |
|---|
| 351 | IF( .NOT. ln_rstart ) THEN |
|---|
| 352 | iatte(:,:) = 1._wp |
|---|
| 353 | oatte(:,:) = 1._wp |
|---|
| 354 | ENDIF |
|---|
| 355 | ! |
|---|
| 356 | ! clem: snwice_mass in the restart file now |
|---|
| 357 | IF( .NOT. ln_rstart ) THEN |
|---|
| 358 | ! ! embedded sea ice |
|---|
| 359 | IF( nn_ice_embd /= 0 ) THEN ! mass exchanges between ice and ocean (case 1 or 2) set the snow+ice mass |
|---|
| 360 | snwice_mass (:,:) = tms(:,:) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:) ) |
|---|
| 361 | snwice_mass_b(:,:) = snwice_mass(:,:) |
|---|
| 362 | ELSE |
|---|
| 363 | snwice_mass (:,:) = 0.0_wp ! no mass exchanges |
|---|
| 364 | snwice_mass_b(:,:) = 0.0_wp ! no mass exchanges |
|---|
| 365 | ENDIF |
|---|
| 366 | IF( nn_ice_embd == 2 ) THEN ! full embedment (case 2) deplete the initial ssh below sea-ice area |
|---|
| 367 | sshn(:,:) = sshn(:,:) - snwice_mass(:,:) * r1_rau0 |
|---|
| 368 | sshb(:,:) = sshb(:,:) - snwice_mass(:,:) * r1_rau0 |
|---|
| 369 | #if defined key_vvl |
|---|
| 370 | ! key_vvl necessary? clem: yes for compilation purpose |
|---|
| 371 | DO jk = 1,jpkm1 ! adjust initial vertical scale factors |
|---|
| 372 | fse3t_n(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshn(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) ) |
|---|
| 373 | fse3t_b(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshb(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) ) |
|---|
| 374 | ENDDO |
|---|
| 375 | fse3t_a(:,:,:) = fse3t_b(:,:,:) |
|---|
| 376 | ! Reconstruction of all vertical scale factors at now and before time |
|---|
| 377 | ! steps |
|---|
| 378 | ! ============================================================================= |
|---|
| 379 | ! Horizontal scale factor interpolations |
|---|
| 380 | ! -------------------------------------- |
|---|
| 381 | CALL dom_vvl_interpol( fse3t_b(:,:,:), fse3u_b(:,:,:), 'U' ) |
|---|
| 382 | CALL dom_vvl_interpol( fse3t_b(:,:,:), fse3v_b(:,:,:), 'V' ) |
|---|
| 383 | CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3u_n(:,:,:), 'U' ) |
|---|
| 384 | CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3v_n(:,:,:), 'V' ) |
|---|
| 385 | CALL dom_vvl_interpol( fse3u_n(:,:,:), fse3f_n(:,:,:), 'F' ) |
|---|
| 386 | ! Vertical scale factor interpolations |
|---|
| 387 | ! ------------------------------------ |
|---|
| 388 | CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3w_n (:,:,:), 'W' ) |
|---|
| 389 | CALL dom_vvl_interpol( fse3u_n(:,:,:), fse3uw_n(:,:,:), 'UW' ) |
|---|
| 390 | CALL dom_vvl_interpol( fse3v_n(:,:,:), fse3vw_n(:,:,:), 'VW' ) |
|---|
| 391 | CALL dom_vvl_interpol( fse3u_b(:,:,:), fse3uw_b(:,:,:), 'UW' ) |
|---|
| 392 | CALL dom_vvl_interpol( fse3v_b(:,:,:), fse3vw_b(:,:,:), 'VW' ) |
|---|
| 393 | ! t- and w- points depth |
|---|
| 394 | ! ---------------------- |
|---|
| 395 | fsdept_n(:,:,1) = 0.5_wp * fse3w_n(:,:,1) |
|---|
| 396 | fsdepw_n(:,:,1) = 0.0_wp |
|---|
| 397 | fsde3w_n(:,:,1) = fsdept_n(:,:,1) - sshn(:,:) |
|---|
| 398 | DO jk = 2, jpk |
|---|
| 399 | fsdept_n(:,:,jk) = fsdept_n(:,:,jk-1) + fse3w_n(:,:,jk) |
|---|
| 400 | fsdepw_n(:,:,jk) = fsdepw_n(:,:,jk-1) + fse3t_n(:,:,jk-1) |
|---|
| 401 | fsde3w_n(:,:,jk) = fsdept_n(:,:,jk ) - sshn (:,:) |
|---|
| 402 | END DO |
|---|
| 403 | #endif |
|---|
| 404 | ENDIF |
|---|
| 405 | ENDIF ! .NOT. ln_rstart |
|---|
| 406 | ! |
|---|
| 407 | |
|---|
| 408 | END SUBROUTINE lim_sbc_init |
|---|
| 409 | |
|---|
| 410 | #else |
|---|
| 411 | !!---------------------------------------------------------------------- |
|---|
| 412 | !! Default option : Dummy module NO LIM 3.0 sea-ice model |
|---|
| 413 | !!---------------------------------------------------------------------- |
|---|
| 414 | CONTAINS |
|---|
| 415 | SUBROUTINE lim_sbc ! Dummy routine |
|---|
| 416 | END SUBROUTINE lim_sbc |
|---|
| 417 | #endif |
|---|
| 418 | |
|---|
| 419 | !!====================================================================== |
|---|
| 420 | END MODULE limsbc |
|---|
