| 1 | MODULE limsbc |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE limsbc *** |
|---|
| 4 | !! computation of the flux at the sea ice/ocean interface |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : - ! 2006-07 (M. Vancoppelle) LIM3 original code |
|---|
| 7 | !! 3.0 ! 2008-03 (C. Tallandier) surface module |
|---|
| 8 | !! - ! 2008-04 (C. Tallandier) split in 2 + new ice-ocean coupling |
|---|
| 9 | !! 3.3 ! 2010-05 (G. Madec) decrease ocean & ice reference salinities in the Baltic sea |
|---|
| 10 | !! ! + simplification of the ice-ocean stress calculation |
|---|
| 11 | !! 3.4 ! 2011-02 (G. Madec) dynamical allocation |
|---|
| 12 | !! - ! 2012 (D. Iovino) salt flux change |
|---|
| 13 | !! - ! 2012-05 (C. Rousset) add penetration solar flux |
|---|
| 14 | !! 3.5 ! 2012-10 (A. Coward, G. Madec) salt fluxes ; ice+snow mass |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | #if defined key_lim3 |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | !! 'key_lim3' LIM 3.0 sea-ice model |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | !! lim_sbc_alloc : allocate the limsbc arrays |
|---|
| 21 | !! lim_sbc_init : initialisation |
|---|
| 22 | !! lim_sbc_flx : updates mass, heat and salt fluxes at the ocean surface |
|---|
| 23 | !! lim_sbc_tau : update i- and j-stresses, and its modulus at the ocean surface |
|---|
| 24 | !!---------------------------------------------------------------------- |
|---|
| 25 | USE par_oce ! ocean parameters |
|---|
| 26 | USE phycst ! physical constants |
|---|
| 27 | USE par_ice ! ice parameters |
|---|
| 28 | USE dom_oce ! ocean domain |
|---|
| 29 | USE dom_ice, ONLY : tms, area |
|---|
| 30 | USE ice ! LIM sea-ice variables |
|---|
| 31 | USE sbc_ice ! Surface boundary condition: sea-ice fields |
|---|
| 32 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 33 | USE sbccpl |
|---|
| 34 | USE oce , ONLY : iatte, oatte, sshn, sshb, snwice_mass, snwice_mass_b, snwice_fmass |
|---|
| 35 | USE albedo ! albedo parameters |
|---|
| 36 | USE lbclnk ! ocean lateral boundary condition - MPP exchanges |
|---|
| 37 | USE lib_mpp ! MPP library |
|---|
| 38 | USE wrk_nemo ! work arrays |
|---|
| 39 | USE in_out_manager ! I/O manager |
|---|
| 40 | USE prtctl ! Print control |
|---|
| 41 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 42 | USE traqsr ! clem: add penetration of solar flux into the calculation of heat budget |
|---|
| 43 | USE iom |
|---|
| 44 | USE domvvl ! Variable volume |
|---|
| 45 | |
|---|
| 46 | IMPLICIT NONE |
|---|
| 47 | PRIVATE |
|---|
| 48 | |
|---|
| 49 | PUBLIC lim_sbc_init ! called by ice_init |
|---|
| 50 | PUBLIC lim_sbc_flx ! called by sbc_ice_lim |
|---|
| 51 | PUBLIC lim_sbc_tau ! called by sbc_ice_lim |
|---|
| 52 | |
|---|
| 53 | REAL(wp) :: epsi10 = 1.e-10 ! |
|---|
| 54 | REAL(wp) :: epsi20 = 1.e-20 ! |
|---|
| 55 | |
|---|
| 56 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: utau_oce, vtau_oce ! air-ocean surface i- & j-stress [N/m2] |
|---|
| 57 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: tmod_io ! modulus of the ice-ocean velocity [m/s] |
|---|
| 58 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: soce_0 , sice_0 ! cst SSS and ice salinity (levitating sea-ice) |
|---|
| 59 | |
|---|
| 60 | !! * Substitutions |
|---|
| 61 | # include "vectopt_loop_substitute.h90" |
|---|
| 62 | # include "domzgr_substitute.h90" |
|---|
| 63 | !!---------------------------------------------------------------------- |
|---|
| 64 | !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011) |
|---|
| 65 | !! $Id$ |
|---|
| 66 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 67 | !!---------------------------------------------------------------------- |
|---|
| 68 | CONTAINS |
|---|
| 69 | |
|---|
| 70 | INTEGER FUNCTION lim_sbc_alloc() |
|---|
| 71 | !!------------------------------------------------------------------- |
|---|
| 72 | !! *** ROUTINE lim_sbc_alloc *** |
|---|
| 73 | !!------------------------------------------------------------------- |
|---|
| 74 | ALLOCATE( soce_0(jpi,jpj) , utau_oce(jpi,jpj) , & |
|---|
| 75 | & sice_0(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=lim_sbc_alloc) |
|---|
| 76 | ! |
|---|
| 77 | IF( lk_mpp ) CALL mpp_sum( lim_sbc_alloc ) |
|---|
| 78 | IF( lim_sbc_alloc /= 0 ) CALL ctl_warn('lim_sbc_alloc: failed to allocate arrays') |
|---|
| 79 | END FUNCTION lim_sbc_alloc |
|---|
| 80 | |
|---|
| 81 | |
|---|
| 82 | SUBROUTINE lim_sbc_flx( kt ) |
|---|
| 83 | !!------------------------------------------------------------------- |
|---|
| 84 | !! *** ROUTINE lim_sbc_flx *** |
|---|
| 85 | !! |
|---|
| 86 | !! ** Purpose : Update the surface ocean boundary condition for heat |
|---|
| 87 | !! salt and mass over areas where sea-ice is non-zero |
|---|
| 88 | !! |
|---|
| 89 | !! ** Action : - computes the heat and freshwater/salt fluxes |
|---|
| 90 | !! at the ice-ocean interface. |
|---|
| 91 | !! - Update the ocean sbc |
|---|
| 92 | !! |
|---|
| 93 | !! ** Outputs : - qsr : sea heat flux: solar |
|---|
| 94 | !! - qns : sea heat flux: non solar |
|---|
| 95 | !! - emp : freshwater budget: volume flux |
|---|
| 96 | !! - sfx : salt flux |
|---|
| 97 | !! - fr_i : ice fraction |
|---|
| 98 | !! - tn_ice : sea-ice surface temperature |
|---|
| 99 | !! - alb_ice : sea-ice albedo (lk_cpl=T) |
|---|
| 100 | !! |
|---|
| 101 | !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90. |
|---|
| 102 | !! Tartinville et al. 2001 Ocean Modelling, 3, 95-108. |
|---|
| 103 | !! These refs are now obsolete since everything has been revised |
|---|
| 104 | !! The ref should be Rousset et al., 2015? |
|---|
| 105 | !!--------------------------------------------------------------------- |
|---|
| 106 | INTEGER, INTENT(in) :: kt ! number of iteration |
|---|
| 107 | ! |
|---|
| 108 | INTEGER :: ji, jj, jl, jk ! dummy loop indices |
|---|
| 109 | ! |
|---|
| 110 | REAL(wp) :: zinda, zemp ! local scalars |
|---|
| 111 | REAL(wp) :: zf_mass ! Heat flux associated with mass exchange ice->ocean (W.m-2) |
|---|
| 112 | REAL(wp) :: zfcm1 ! New solar flux received by the ocean |
|---|
| 113 | ! |
|---|
| 114 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_cs, zalb_os ! 2D/3D workspace |
|---|
| 115 | !!--------------------------------------------------------------------- |
|---|
| 116 | |
|---|
| 117 | ! make calls for heat fluxes before it is modified |
|---|
| 118 | CALL iom_put( "qsr_oce" , qsr(:,:) * pfrld(:,:) ) ! solar flux at ocean surface |
|---|
| 119 | CALL iom_put( "qns_oce" , qns(:,:) * pfrld(:,:) ) ! non-solar flux at ocean surface |
|---|
| 120 | CALL iom_put( "qsr_ice" , SUM( qsr_ice(:,:,:) * old_a_i(:,:,:), dim=3 ) ) ! solar flux at ice surface |
|---|
| 121 | CALL iom_put( "qns_ice" , SUM( qns_ice(:,:,:) * old_a_i(:,:,:), dim=3 ) ) ! non-solar flux at ice surface |
|---|
| 122 | CALL iom_put( "qtr_ice" , SUM( ftr_ice(:,:,:) * old_a_i(:,:,:), dim=3 ) ) ! solar flux transmitted thru ice |
|---|
| 123 | CALL iom_put( "qt_oce" , ( qsr(:,:) + qns(:,:) ) * pfrld(:,:) ) |
|---|
| 124 | CALL iom_put( "qt_ice" , SUM( ( qns_ice(:,:,:) + qsr_ice(:,:,:) ) * old_a_i(:,:,:), dim=3 ) ) |
|---|
| 125 | |
|---|
| 126 | ! pfrld is the lead fraction at the previous time step (actually between TRP and THD) |
|---|
| 127 | DO jj = 1, jpj |
|---|
| 128 | DO ji = 1, jpi |
|---|
| 129 | |
|---|
| 130 | !------------------------------------------! |
|---|
| 131 | ! heat flux at the ocean surface ! |
|---|
| 132 | !------------------------------------------! |
|---|
| 133 | zinda = 1._wp - MAX( 0._wp , SIGN( 1._wp , - ( 1._wp - pfrld(ji,jj) ) ) ) ! 1 if ice |
|---|
| 134 | |
|---|
| 135 | ! Solar heat flux reaching the ocean = zfcm1 (W.m-2) |
|---|
| 136 | !--------------------------------------------------- |
|---|
| 137 | IF( lk_cpl ) THEN |
|---|
| 138 | !!! LIM2 version zqsr = qsr_tot(ji,jj) + ( fstric(ji,jj) - qsr_ice(ji,jj,1) ) * ( 1.0 - pfrld(ji,jj) ) |
|---|
| 139 | zfcm1 = qsr_tot(ji,jj) |
|---|
| 140 | DO jl = 1, jpl |
|---|
| 141 | zfcm1 = zfcm1 + ( ftr_ice(ji,jj,jl) - qsr_ice(ji,jj,jl) ) * old_a_i(ji,jj,jl) |
|---|
| 142 | END DO |
|---|
| 143 | ELSE |
|---|
| 144 | !!! LIM2 version zqsr = pfrld(ji,jj) * qsr(ji,jj) + ( 1. - pfrld(ji,jj) ) * fstric(ji,jj) |
|---|
| 145 | zfcm1 = pfrld(ji,jj) * qsr(ji,jj) |
|---|
| 146 | DO jl = 1, jpl |
|---|
| 147 | zfcm1 = zfcm1 + old_a_i(ji,jj,jl) * ftr_ice(ji,jj,jl) |
|---|
| 148 | END DO |
|---|
| 149 | ENDIF |
|---|
| 150 | |
|---|
| 151 | ! Total heat flux reaching the ocean = hfx_out (W.m-2) |
|---|
| 152 | !--------------------------------------------------- |
|---|
| 153 | zf_mass = hfx_thd(ji,jj) + hfx_dyn(ji,jj) + hfx_res(ji,jj) ! heat flux from snow is 0 (T=0 degC) |
|---|
| 154 | hfx_out(ji,jj) = hfx_out(ji,jj) + zf_mass + zfcm1 |
|---|
| 155 | |
|---|
| 156 | ! New qsr and qns used to compute the oceanic heat flux at the next time step |
|---|
| 157 | !--------------------------------------------------- |
|---|
| 158 | qsr(ji,jj) = zfcm1 |
|---|
| 159 | qns(ji,jj) = hfx_out(ji,jj) - zfcm1 |
|---|
| 160 | |
|---|
| 161 | !------------------------------------------! |
|---|
| 162 | ! mass flux at the ocean surface ! |
|---|
| 163 | !------------------------------------------! |
|---|
| 164 | ! case of realistic freshwater flux (Tartinville et al., 2001) (presently ACTIVATED) |
|---|
| 165 | ! ------------------------------------------------------------------------------------- |
|---|
| 166 | ! The idea of this approach is that the system that we consider is the ICE-OCEAN system |
|---|
| 167 | ! Thus FW flux = External ( E-P+snow melt) |
|---|
| 168 | ! Salt flux = Exchanges in the ice-ocean system then converted into FW |
|---|
| 169 | ! Associated to Ice formation AND Ice melting |
|---|
| 170 | ! Even if i see Ice melting as a FW and SALT flux |
|---|
| 171 | ! |
|---|
| 172 | ! computing freshwater exchanges at the ice/ocean interface |
|---|
| 173 | IF( lk_cpl ) THEN |
|---|
| 174 | zemp = - emp_tot(ji,jj) + emp_ice(ji,jj) * ( 1. - pfrld(ji,jj) ) & ! |
|---|
| 175 | & + wfx_snw(ji,jj) |
|---|
| 176 | ELSE |
|---|
| 177 | zemp = emp(ji,jj) * pfrld(ji,jj) & ! evaporation over oceanic fraction |
|---|
| 178 | & - tprecip(ji,jj) * ( 1._wp - pfrld(ji,jj) ) & ! all precipitation reach the ocean |
|---|
| 179 | & + sprecip(ji,jj) * ( 1._wp - pfrld(ji,jj)**betas ) ! except solid precip intercepted by sea-ice |
|---|
| 180 | ENDIF |
|---|
| 181 | |
|---|
| 182 | ! mass flux from ice/ocean |
|---|
| 183 | wfx_ice(ji,jj) = wfx_bog(ji,jj) + wfx_bom(ji,jj) + wfx_sum(ji,jj) + wfx_sni(ji,jj) + wfx_opw(ji,jj) + wfx_dyn(ji,jj) + wfx_res(ji,jj) |
|---|
| 184 | |
|---|
| 185 | ! mass flux at the ocean/ice interface |
|---|
| 186 | fmmflx(ji,jj) = - wfx_ice(ji,jj) * rdt_ice ! F/M mass flux save at least for biogeochemical model |
|---|
| 187 | emp(ji,jj) = zemp - wfx_ice(ji,jj) - wfx_snw(ji,jj) - wfx_sub(ji,jj) ! mass flux + F/M mass flux (always ice/ocean mass exchange) |
|---|
| 188 | |
|---|
| 189 | END DO |
|---|
| 190 | END DO |
|---|
| 191 | |
|---|
| 192 | !------------------------------------------! |
|---|
| 193 | ! salt flux at the ocean surface ! |
|---|
| 194 | !------------------------------------------! |
|---|
| 195 | sfx(:,:) = sfx_bog(:,:) + sfx_bom(:,:) + sfx_sum(:,:) + sfx_sni(:,:) + sfx_opw(:,:) + sfx_res(:,:) + sfx_dyn(:,:) + sfx_bri(:,:) |
|---|
| 196 | |
|---|
| 197 | !-------------------------------------------------------------! |
|---|
| 198 | ! mass of snow and ice per unit area for embedded sea-ice ! |
|---|
| 199 | !-------------------------------------------------------------! |
|---|
| 200 | IF( nn_ice_embd /= 0 ) THEN |
|---|
| 201 | ! save mass from the previous ice time step |
|---|
| 202 | snwice_mass_b(:,:) = snwice_mass(:,:) |
|---|
| 203 | ! new mass per unit area |
|---|
| 204 | snwice_mass (:,:) = tms(:,:) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:) ) |
|---|
| 205 | ! time evolution of snow+ice mass |
|---|
| 206 | snwice_fmass (:,:) = ( snwice_mass(:,:) - snwice_mass_b(:,:) ) * r1_rdtice |
|---|
| 207 | ENDIF |
|---|
| 208 | |
|---|
| 209 | !-----------------------------------------------! |
|---|
| 210 | ! Storing the transmitted variables ! |
|---|
| 211 | !-----------------------------------------------! |
|---|
| 212 | fr_i (:,:) = at_i(:,:) ! Sea-ice fraction |
|---|
| 213 | tn_ice(:,:,:) = t_su(:,:,:) ! Ice surface temperature |
|---|
| 214 | |
|---|
| 215 | !------------------------------------------------! |
|---|
| 216 | ! Snow/ice albedo (only if sent to coupler) ! |
|---|
| 217 | !------------------------------------------------! |
|---|
| 218 | IF( lk_cpl ) THEN ! coupled case |
|---|
| 219 | |
|---|
| 220 | CALL wrk_alloc( jpi, jpj, jpl, zalb_cs, zalb_os ) |
|---|
| 221 | |
|---|
| 222 | CALL albedo_ice( t_su, ht_i, ht_s, zalb_cs, zalb_os ) ! cloud-sky and overcast-sky ice albedos |
|---|
| 223 | |
|---|
| 224 | alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:) |
|---|
| 225 | |
|---|
| 226 | CALL wrk_dealloc( jpi, jpj, jpl, zalb_cs, zalb_os ) |
|---|
| 227 | |
|---|
| 228 | ENDIF |
|---|
| 229 | |
|---|
| 230 | |
|---|
| 231 | IF(ln_ctl) THEN |
|---|
| 232 | CALL prt_ctl( tab2d_1=qsr , clinfo1=' lim_sbc: qsr : ', tab2d_2=qns , clinfo2=' qns : ' ) |
|---|
| 233 | CALL prt_ctl( tab2d_1=emp , clinfo1=' lim_sbc: emp : ', tab2d_2=sfx , clinfo2=' sfx : ' ) |
|---|
| 234 | CALL prt_ctl( tab2d_1=fr_i , clinfo1=' lim_sbc: fr_i : ' ) |
|---|
| 235 | CALL prt_ctl( tab3d_1=tn_ice, clinfo1=' lim_sbc: tn_ice : ', kdim=jpl ) |
|---|
| 236 | ENDIF |
|---|
| 237 | |
|---|
| 238 | END SUBROUTINE lim_sbc_flx |
|---|
| 239 | |
|---|
| 240 | |
|---|
| 241 | SUBROUTINE lim_sbc_tau( kt , pu_oce, pv_oce ) |
|---|
| 242 | !!------------------------------------------------------------------- |
|---|
| 243 | !! *** ROUTINE lim_sbc_tau *** |
|---|
| 244 | !! |
|---|
| 245 | !! ** Purpose : Update the ocean surface stresses due to the ice |
|---|
| 246 | !! |
|---|
| 247 | !! ** Action : * at each ice time step (every nn_fsbc time step): |
|---|
| 248 | !! - compute the modulus of ice-ocean relative velocity |
|---|
| 249 | !! (*rho*Cd) at T-point (C-grid) or I-point (B-grid) |
|---|
| 250 | !! tmod_io = rhoco * | U_ice-U_oce | |
|---|
| 251 | !! - update the modulus of stress at ocean surface |
|---|
| 252 | !! taum = frld * taum + (1-frld) * tmod_io * | U_ice-U_oce | |
|---|
| 253 | !! * at each ocean time step (every kt): |
|---|
| 254 | !! compute linearized ice-ocean stresses as |
|---|
| 255 | !! Utau = tmod_io * | U_ice - pU_oce | |
|---|
| 256 | !! using instantaneous current ocean velocity (usually before) |
|---|
| 257 | !! |
|---|
| 258 | !! NB: - ice-ocean rotation angle no more allowed |
|---|
| 259 | !! - here we make an approximation: taum is only computed every ice time step |
|---|
| 260 | !! This avoids mutiple average to pass from T -> U,V grids and next from U,V grids |
|---|
| 261 | !! to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton... |
|---|
| 262 | !! |
|---|
| 263 | !! ** Outputs : - utau, vtau : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes |
|---|
| 264 | !! - taum : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes |
|---|
| 265 | !!--------------------------------------------------------------------- |
|---|
| 266 | INTEGER , INTENT(in) :: kt ! ocean time-step index |
|---|
| 267 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pu_oce, pv_oce ! surface ocean currents |
|---|
| 268 | !! |
|---|
| 269 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 270 | REAL(wp) :: zat_u, zutau_ice, zu_t, zmodt ! local scalar |
|---|
| 271 | REAL(wp) :: zat_v, zvtau_ice, zv_t ! - - |
|---|
| 272 | !!--------------------------------------------------------------------- |
|---|
| 273 | ! |
|---|
| 274 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN !== Ice time-step only ==! (i.e. surface module time-step) |
|---|
| 275 | !CDIR NOVERRCHK |
|---|
| 276 | DO jj = 2, jpjm1 !* update the modulus of stress at ocean surface (T-point) |
|---|
| 277 | !CDIR NOVERRCHK |
|---|
| 278 | DO ji = fs_2, fs_jpim1 |
|---|
| 279 | ! ! 2*(U_ice-U_oce) at T-point |
|---|
| 280 | zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj) |
|---|
| 281 | zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) |
|---|
| 282 | ! ! |U_ice-U_oce|^2 |
|---|
| 283 | zmodt = 0.25_wp * ( zu_t * zu_t + zv_t * zv_t ) |
|---|
| 284 | ! ! update the ocean stress modulus |
|---|
| 285 | taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * rhoco * zmodt |
|---|
| 286 | tmod_io(ji,jj) = rhoco * SQRT( zmodt ) ! rhoco * |U_ice-U_oce| at T-point |
|---|
| 287 | END DO |
|---|
| 288 | END DO |
|---|
| 289 | CALL lbc_lnk( taum, 'T', 1. ) ; CALL lbc_lnk( tmod_io, 'T', 1. ) |
|---|
| 290 | ! |
|---|
| 291 | utau_oce(:,:) = utau(:,:) !* save the air-ocean stresses at ice time-step |
|---|
| 292 | vtau_oce(:,:) = vtau(:,:) |
|---|
| 293 | ! |
|---|
| 294 | ENDIF |
|---|
| 295 | ! |
|---|
| 296 | ! !== every ocean time-step ==! |
|---|
| 297 | ! |
|---|
| 298 | DO jj = 2, jpjm1 !* update the stress WITHOUT a ice-ocean rotation angle |
|---|
| 299 | DO ji = fs_2, fs_jpim1 ! Vect. Opt. |
|---|
| 300 | zat_u = ( at_i(ji,jj) + at_i(ji+1,jj) ) * 0.5_wp ! ice area at u and V-points |
|---|
| 301 | zat_v = ( at_i(ji,jj) + at_i(ji,jj+1) ) * 0.5_wp |
|---|
| 302 | ! ! linearized quadratic drag formulation |
|---|
| 303 | zutau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) ) |
|---|
| 304 | zvtau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) ) |
|---|
| 305 | ! ! stresses at the ocean surface |
|---|
| 306 | utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice |
|---|
| 307 | vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice |
|---|
| 308 | END DO |
|---|
| 309 | END DO |
|---|
| 310 | CALL lbc_lnk( utau, 'U', -1. ) ; CALL lbc_lnk( vtau, 'V', -1. ) ! lateral boundary condition |
|---|
| 311 | ! |
|---|
| 312 | IF(ln_ctl) CALL prt_ctl( tab2d_1=utau, clinfo1=' lim_sbc: utau : ', mask1=umask, & |
|---|
| 313 | & tab2d_2=vtau, clinfo2=' vtau : ' , mask2=vmask ) |
|---|
| 314 | ! |
|---|
| 315 | END SUBROUTINE lim_sbc_tau |
|---|
| 316 | |
|---|
| 317 | |
|---|
| 318 | SUBROUTINE lim_sbc_init |
|---|
| 319 | !!------------------------------------------------------------------- |
|---|
| 320 | !! *** ROUTINE lim_sbc_init *** |
|---|
| 321 | !! |
|---|
| 322 | !! ** Purpose : Preparation of the file ice_evolu for the output of |
|---|
| 323 | !! the temporal evolution of key variables |
|---|
| 324 | !! |
|---|
| 325 | !! ** input : Namelist namicedia |
|---|
| 326 | !!------------------------------------------------------------------- |
|---|
| 327 | REAL(wp) :: zsum, zarea |
|---|
| 328 | ! |
|---|
| 329 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 330 | REAL(wp) :: zcoefu, zcoefv, zcoeff ! local scalar |
|---|
| 331 | IF(lwp) WRITE(numout,*) |
|---|
| 332 | IF(lwp) WRITE(numout,*) 'lim_sbc_init : LIM-3 sea-ice - surface boundary condition' |
|---|
| 333 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~ ' |
|---|
| 334 | |
|---|
| 335 | ! ! allocate lim_sbc array |
|---|
| 336 | IF( lim_sbc_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'lim_sbc_init : unable to allocate standard arrays' ) |
|---|
| 337 | ! |
|---|
| 338 | soce_0(:,:) = soce ! constant SSS and ice salinity used in levitating sea-ice case |
|---|
| 339 | sice_0(:,:) = sice |
|---|
| 340 | ! |
|---|
| 341 | IF( cp_cfg == "orca" ) THEN ! decrease ocean & ice reference salinities in the Baltic sea |
|---|
| 342 | WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND. & |
|---|
| 343 | & 54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp ) |
|---|
| 344 | soce_0(:,:) = 4._wp |
|---|
| 345 | sice_0(:,:) = 2._wp |
|---|
| 346 | END WHERE |
|---|
| 347 | ENDIF |
|---|
| 348 | ! clem modif |
|---|
| 349 | IF( .NOT. ln_rstart ) THEN |
|---|
| 350 | iatte(:,:) = 1._wp |
|---|
| 351 | oatte(:,:) = 1._wp |
|---|
| 352 | ENDIF |
|---|
| 353 | ! |
|---|
| 354 | ! clem: snwice_mass in the restart file now |
|---|
| 355 | IF( .NOT. ln_rstart ) THEN |
|---|
| 356 | ! ! embedded sea ice |
|---|
| 357 | IF( nn_ice_embd /= 0 ) THEN ! mass exchanges between ice and ocean (case 1 or 2) set the snow+ice mass |
|---|
| 358 | snwice_mass (:,:) = tms(:,:) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:) ) |
|---|
| 359 | snwice_mass_b(:,:) = snwice_mass(:,:) |
|---|
| 360 | ELSE |
|---|
| 361 | snwice_mass (:,:) = 0.0_wp ! no mass exchanges |
|---|
| 362 | snwice_mass_b(:,:) = 0.0_wp ! no mass exchanges |
|---|
| 363 | ENDIF |
|---|
| 364 | IF( nn_ice_embd == 2 ) THEN ! full embedment (case 2) deplete the initial ssh below sea-ice area |
|---|
| 365 | sshn(:,:) = sshn(:,:) - snwice_mass(:,:) * r1_rau0 |
|---|
| 366 | sshb(:,:) = sshb(:,:) - snwice_mass(:,:) * r1_rau0 |
|---|
| 367 | #if defined key_vvl |
|---|
| 368 | ! key_vvl necessary? clem: yes for compilation purpose |
|---|
| 369 | DO jk = 1,jpkm1 ! adjust initial vertical scale factors |
|---|
| 370 | fse3t_n(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshn(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) ) |
|---|
| 371 | fse3t_b(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshb(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) ) |
|---|
| 372 | ENDDO |
|---|
| 373 | fse3t_a(:,:,:) = fse3t_b(:,:,:) |
|---|
| 374 | ! Reconstruction of all vertical scale factors at now and before time |
|---|
| 375 | ! steps |
|---|
| 376 | ! ============================================================================= |
|---|
| 377 | ! Horizontal scale factor interpolations |
|---|
| 378 | ! -------------------------------------- |
|---|
| 379 | CALL dom_vvl_interpol( fse3t_b(:,:,:), fse3u_b(:,:,:), 'U' ) |
|---|
| 380 | CALL dom_vvl_interpol( fse3t_b(:,:,:), fse3v_b(:,:,:), 'V' ) |
|---|
| 381 | CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3u_n(:,:,:), 'U' ) |
|---|
| 382 | CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3v_n(:,:,:), 'V' ) |
|---|
| 383 | CALL dom_vvl_interpol( fse3u_n(:,:,:), fse3f_n(:,:,:), 'F' ) |
|---|
| 384 | ! Vertical scale factor interpolations |
|---|
| 385 | ! ------------------------------------ |
|---|
| 386 | CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3w_n (:,:,:), 'W' ) |
|---|
| 387 | CALL dom_vvl_interpol( fse3u_n(:,:,:), fse3uw_n(:,:,:), 'UW' ) |
|---|
| 388 | CALL dom_vvl_interpol( fse3v_n(:,:,:), fse3vw_n(:,:,:), 'VW' ) |
|---|
| 389 | CALL dom_vvl_interpol( fse3u_b(:,:,:), fse3uw_b(:,:,:), 'UW' ) |
|---|
| 390 | CALL dom_vvl_interpol( fse3v_b(:,:,:), fse3vw_b(:,:,:), 'VW' ) |
|---|
| 391 | ! t- and w- points depth |
|---|
| 392 | ! ---------------------- |
|---|
| 393 | fsdept_n(:,:,1) = 0.5_wp * fse3w_n(:,:,1) |
|---|
| 394 | fsdepw_n(:,:,1) = 0.0_wp |
|---|
| 395 | fsde3w_n(:,:,1) = fsdept_n(:,:,1) - sshn(:,:) |
|---|
| 396 | DO jk = 2, jpk |
|---|
| 397 | fsdept_n(:,:,jk) = fsdept_n(:,:,jk-1) + fse3w_n(:,:,jk) |
|---|
| 398 | fsdepw_n(:,:,jk) = fsdepw_n(:,:,jk-1) + fse3t_n(:,:,jk-1) |
|---|
| 399 | fsde3w_n(:,:,jk) = fsdept_n(:,:,jk ) - sshn (:,:) |
|---|
| 400 | END DO |
|---|
| 401 | #endif |
|---|
| 402 | ENDIF |
|---|
| 403 | ENDIF ! .NOT. ln_rstart |
|---|
| 404 | ! |
|---|
| 405 | |
|---|
| 406 | END SUBROUTINE lim_sbc_init |
|---|
| 407 | |
|---|
| 408 | #else |
|---|
| 409 | !!---------------------------------------------------------------------- |
|---|
| 410 | !! Default option : Dummy module NO LIM 3.0 sea-ice model |
|---|
| 411 | !!---------------------------------------------------------------------- |
|---|
| 412 | CONTAINS |
|---|
| 413 | SUBROUTINE lim_sbc ! Dummy routine |
|---|
| 414 | END SUBROUTINE lim_sbc |
|---|
| 415 | #endif |
|---|
| 416 | |
|---|
| 417 | !!====================================================================== |
|---|
| 418 | END MODULE limsbc |
|---|
