New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynadv_cen2.F90 in branches/2014/dev_CNRS0_NOC1_LDF/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2014/dev_CNRS0_NOC1_LDF/NEMOGCM/NEMO/OPA_SRC/DYN/dynadv_cen2.F90 @ 4616

Last change on this file since 4616 was 4616, checked in by gm, 10 years ago

#1260 : see the associated wiki page for explanation
  • Property svn:keywords set to Id
File size: 8.2 KB
Line 
1MODULE dynadv_cen2
2   !!======================================================================
3   !!                       ***  MODULE  dynadv  ***
4   !! Ocean dynamics: Update the momentum trend with the flux form advection
5   !!                 using a 2nd order centred scheme
6   !!======================================================================
7   !! History :  2.0  ! 2006-08  (G. Madec, S. Theetten)  Original code
8   !!            3.2  ! 2009-07  (R. Benshila)  Suppression of rigid-lid option
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   dyn_adv_cen2       : flux form momentum advection (ln_dynadv_cen2=T)
13   !!                        trends using a 2nd order centred scheme 
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE trdmod_oce     ! ocean variables trends
18   USE trdmod         ! ocean dynamics trends
19   USE in_out_manager ! I/O manager
20   USE lib_mpp        ! MPP library
21   USE prtctl         ! Print control
22   USE wrk_nemo        ! Memory Allocation
23   USE timing          ! Timing
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   dyn_adv_cen2   ! routine called by step.F90
29
30   !! * Substitutions
31#  include "domzgr_substitute.h90"
32#  include "vectopt_loop_substitute.h90"
33   !!----------------------------------------------------------------------
34   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
35   !! $Id$
36   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
37   !!----------------------------------------------------------------------
38CONTAINS
39
40   SUBROUTINE dyn_adv_cen2( kt )
41      !!----------------------------------------------------------------------
42      !!                  ***  ROUTINE dyn_adv_cen2  ***
43      !!
44      !! ** Purpose :   Compute the now momentum advection trend in flux form
45      !!              and the general trend of the momentum equation.
46      !!
47      !! ** Method  :   Trend evaluated using now fields (centered in time)
48      !!
49      !! ** Action  :   (ua,va) updated with the now vorticity term trend
50      !!----------------------------------------------------------------------
51      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
52      !
53      INTEGER  ::   ji, jj, jk   ! dummy loop indices
54      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zfu_t, zfv_t, zfu_f, zfv_f, zfu_uw, zfv_vw, zfw
55      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zfu, zfv
56      !!----------------------------------------------------------------------
57      !
58      IF( nn_timing == 1 )  CALL timing_start('dyn_adv_cen2')
59      !
60      CALL wrk_alloc( jpi, jpj, jpk, zfu_t, zfv_t, zfu_f, zfv_f, zfu_uw, zfv_vw, zfu, zfv, zfw )
61      !
62      IF( kt == nit000 .AND. lwp ) THEN
63         WRITE(numout,*)
64         WRITE(numout,*) 'dyn_adv_cen2 : 2nd order flux form momentum advection'
65         WRITE(numout,*) '~~~~~~~~~~~~'
66      ENDIF
67      !
68      IF( l_trddyn ) THEN           ! Save ua and va trends
69         zfu_uw(:,:,:) = ua(:,:,:)
70         zfv_vw(:,:,:) = va(:,:,:)
71      ENDIF
72
73      !                                      ! ====================== !
74      !                                      !  Horizontal advection  !
75      DO jk = 1, jpkm1                       ! ====================== !
76         !                                         ! horizontal volume fluxes
77         zfu(:,:,jk) = 0.25 * e2u(:,:) * fse3u(:,:,jk) * un(:,:,jk)
78         zfv(:,:,jk) = 0.25 * e1v(:,:) * fse3v(:,:,jk) * vn(:,:,jk)
79         !
80         DO jj = 1, jpjm1                          ! horizontal momentum fluxes at T- and F-point
81            DO ji = 1, fs_jpim1   ! vector opt.
82               zfu_t(ji+1,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji+1,jj  ,jk) )
83               zfv_f(ji  ,jj  ,jk) = ( zfv(ji,jj,jk) + zfv(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji  ,jj+1,jk) )
84               zfu_f(ji  ,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji+1,jj  ,jk) )
85               zfv_t(ji  ,jj+1,jk) = ( zfv(ji,jj,jk) + zfv(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji  ,jj+1,jk) )
86            END DO
87         END DO
88         DO jj = 2, jpjm1                          ! divergence of horizontal momentum fluxes
89            DO ji = fs_2, fs_jpim1   ! vector opt.
90               ua(ji,jj,jk) = ua(ji,jj,jk) - (  zfu_t(ji+1,jj  ,jk) - zfu_t(ji  ,jj  ,jk)    &
91                  &                           + zfv_f(ji  ,jj  ,jk) - zfv_f(ji  ,jj-1,jk)  ) / ( e1e2u(ji,jj) * fse3u(ji,jj,jk) )
92               va(ji,jj,jk) = va(ji,jj,jk) - (  zfu_f(ji  ,jj  ,jk) - zfu_f(ji-1,jj  ,jk)    &
93                  &                           + zfv_t(ji  ,jj+1,jk) - zfv_t(ji  ,jj  ,jk)  ) / ( e1e2v(ji,jj) * fse3v(ji,jj,jk) )
94            END DO
95         END DO
96      END DO
97      !
98      IF( l_trddyn ) THEN                          ! save the horizontal advection trend for diagnostic
99         zfu_uw(:,:,:) = ua(:,:,:) - zfu_uw(:,:,:)
100         zfv_vw(:,:,:) = va(:,:,:) - zfv_vw(:,:,:)
101         CALL trd_mod( zfu_uw, zfv_vw, jpdyn_trd_had, 'DYN', kt )
102         zfu_t(:,:,:) = ua(:,:,:)
103         zfv_t(:,:,:) = va(:,:,:)
104      ENDIF
105      !
106
107      !                                      ! ==================== !
108      !                                      !  Vertical advection  !
109      DO jk = 1, jpkm1                       ! ==================== !
110         !                                         ! Vertical volume fluxesÊ
111         zfw(:,:,jk) = 0.25 * e1e2t(:,:) * wn(:,:,jk)
112         !
113         IF( jk == 1 ) THEN                        ! surface/bottom advective fluxes                   
114            zfu_uw(:,:,jpk) = 0.e0                      ! Bottom  value : flux set to zero
115            zfv_vw(:,:,jpk) = 0.e0
116            !                                           ! Surface value :
117            IF( lk_vvl ) THEN                                ! variable volume : flux set to zero
118               zfu_uw(:,:, 1 ) = 0.e0   
119               zfv_vw(:,:, 1 ) = 0.e0
120            ELSE                                             ! constant volume : advection through the surface
121               DO jj = 2, jpjm1
122                  DO ji = fs_2, fs_jpim1
123                     zfu_uw(ji,jj, 1 ) = 2.e0 * ( zfw(ji,jj,1) + zfw(ji+1,jj  ,1) ) * un(ji,jj,1)
124                     zfv_vw(ji,jj, 1 ) = 2.e0 * ( zfw(ji,jj,1) + zfw(ji  ,jj+1,1) ) * vn(ji,jj,1)
125                  END DO
126               END DO
127            ENDIF
128         ELSE                                      ! interior fluxes
129            DO jj = 2, jpjm1
130               DO ji = fs_2, fs_jpim1   ! vector opt.
131                  zfu_uw(ji,jj,jk) = ( zfw(ji,jj,jk)+ zfw(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji,jj,jk-1) )
132                  zfv_vw(ji,jj,jk) = ( zfw(ji,jj,jk)+ zfw(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji,jj,jk-1) )
133               END DO
134            END DO
135         ENDIF
136      END DO
137      DO jk = 1, jpkm1                             ! divergence of vertical momentum flux divergence
138         DO jj = 2, jpjm1 
139            DO ji = fs_2, fs_jpim1   ! vector opt.
140               ua(ji,jj,jk) =  ua(ji,jj,jk) - ( zfu_uw(ji,jj,jk) - zfu_uw(ji,jj,jk+1) )    &
141                  &  / ( e1e2u(ji,jj) * fse3u(ji,jj,jk) )
142               va(ji,jj,jk) =  va(ji,jj,jk) - ( zfv_vw(ji,jj,jk) - zfv_vw(ji,jj,jk+1) )    &
143                  &  / ( e1e2v(ji,jj) * fse3v(ji,jj,jk) )
144            END DO
145         END DO
146      END DO
147      !
148      IF( l_trddyn ) THEN                          ! save the vertical advection trend for diagnostic
149         zfu_t(:,:,:) = ua(:,:,:) - zfu_t(:,:,:)
150         zfv_t(:,:,:) = va(:,:,:) - zfv_t(:,:,:)
151         CALL trd_mod( zfu_t, zfv_t, jpdyn_trd_zad, 'DYN', kt )
152      ENDIF
153      !                                            ! Control print
154      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' cen2 adv - Ua: ', mask1=umask,   &
155         &                       tab3d_2=va, clinfo2=           ' Va: ', mask2=vmask, clinfo3='dyn' )
156      !
157      CALL wrk_dealloc( jpi, jpj, jpk, zfu_t, zfv_t, zfu_f, zfv_f, zfu_uw, zfv_vw, zfu, zfv, zfw )
158      !
159      IF( nn_timing == 1 )  CALL timing_stop('dyn_adv_cen2')
160      !
161   END SUBROUTINE dyn_adv_cen2
162
163   !!==============================================================================
164END MODULE dynadv_cen2
Note: See TracBrowser for help on using the repository browser.