New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv.F90 in branches/2014/dev_CNRS0_NOC1_LDF/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2014/dev_CNRS0_NOC1_LDF/NEMOGCM/NEMO/OPA_SRC/TRA/traadv.F90 @ 4616

Last change on this file since 4616 was 4616, checked in by gm, 10 years ago

#1260 : see the associated wiki page for explanation
  • Property svn:keywords set to Id
File size: 13.0 KB
Line 
1MODULE traadv
2   !!==============================================================================
3   !!                       ***  MODULE  traadv  ***
4   !! Ocean active tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-09  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!            3.6  !  2011-06  (G. Madec)  Addition of Mixed Layer Eddy parameterisation
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   tra_adv      : compute ocean tracer advection trend
13   !!   tra_adv_ctl  : control the different options of advection scheme
14   !!----------------------------------------------------------------------
15   USE oce             ! ocean dynamics and active tracers
16   USE dom_oce         ! ocean space and time domain
17   USE domvvl          ! variable vertical scale factors
18   USE traadv_cen2     ! 2nd order centered scheme (tra_adv_cen2   routine)
19   USE traadv_tvd      ! TVD      scheme           (tra_adv_tvd    routine)
20   USE traadv_muscl    ! MUSCL    scheme           (tra_adv_muscl  routine)
21   USE traadv_muscl2   ! MUSCL2   scheme           (tra_adv_muscl2 routine)
22   USE traadv_ubs      ! UBS      scheme           (tra_adv_ubs    routine)
23   USE traadv_qck      ! QUICKEST scheme           (tra_adv_qck    routine)
24   USE traadv_mle      ! ML eddy induced velocity  (tra_adv_mle    routine)
25   USE cla             ! cross land advection      (cla_traadv     routine)
26   USE ldftra          ! lateral diffusion: eddy diffusivity & EIV coeff.
27   USE ldfslp          ! Lateral diffusion: slopes of neutral surfaces
28   USE in_out_manager  ! I/O manager
29   USE iom             ! I/O module
30   USE prtctl          ! Print control
31   USE lib_mpp         ! MPP library
32   USE wrk_nemo        ! Memory Allocation
33   USE timing          ! Timing
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   tra_adv        ! routine called by step module
39   PUBLIC   tra_adv_init   ! routine called by opa module
40
41   !                              !!* Namelist namtra_adv *
42   LOGICAL ::   ln_traadv_cen2     ! 2nd order centered scheme flag
43   LOGICAL ::   ln_traadv_tvd      ! TVD scheme flag
44   LOGICAL ::   ln_traadv_muscl    ! MUSCL scheme flag
45   LOGICAL ::   ln_traadv_muscl2   ! MUSCL2 scheme flag
46   LOGICAL ::   ln_traadv_ubs      ! UBS scheme flag
47   LOGICAL ::   ln_traadv_qck      ! QUICKEST scheme flag
48   LOGICAL ::   ln_traadv_msc_ups  ! use upstream scheme within muscl
49
50
51   INTEGER ::   nadv   ! choice of the type of advection scheme
52
53   !! * Substitutions
54#  include "domzgr_substitute.h90"
55#  include "vectopt_loop_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
58   !! $Id$
59   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE tra_adv( kt )
64      !!----------------------------------------------------------------------
65      !!                  ***  ROUTINE tra_adv  ***
66      !!
67      !! ** Purpose :   compute the ocean tracer advection trend.
68      !!
69      !! ** Method  : - Update (ua,va) with the advection term following nadv
70      !!----------------------------------------------------------------------
71      !
72      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
73      !
74      INTEGER ::   jk   ! dummy loop index
75      REAL(wp), POINTER, DIMENSION(:,:,:) :: zun, zvn, zwn
76      !!----------------------------------------------------------------------
77      !
78      IF( nn_timing == 1 )  CALL timing_start('tra_adv')
79      !
80      CALL wrk_alloc( jpi, jpj, jpk, zun, zvn, zwn )
81      !                                          ! set time step
82      IF( neuler == 0 .AND. kt == nit000 ) THEN     ! at nit000
83         r2dtra(:) =  rdttra(:)                          ! = rdtra (restarting with Euler time stepping)
84      ELSEIF( kt <= nit000 + 1) THEN                ! at nit000 or nit000+1
85         r2dtra(:) = 2._wp * rdttra(:)                   ! = 2 rdttra (leapfrog)
86      ENDIF
87      !
88      IF( nn_cla == 1 )   CALL cla_traadv( kt )       !==  Cross Land Advection  ==! (hor. advection)
89      !
90      !                                               !==  effective transport  ==!
91      DO jk = 1, jpkm1
92         zun(:,:,jk) = e2u  (:,:) * fse3u(:,:,jk) * un(:,:,jk)                  ! eulerian transport only
93         zvn(:,:,jk) = e1v  (:,:) * fse3v(:,:,jk) * vn(:,:,jk)
94         zwn(:,:,jk) = e1e2t(:,:)                 * wn(:,:,jk)
95      END DO
96      !
97      IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN
98         zun(:,:,:) = zun(:,:,:) + un_td(:,:,:)
99         zvn(:,:,:) = zvn(:,:,:) + vn_td(:,:,:)
100      ENDIF
101      !
102      zun(:,:,jpk) = 0._wp                                                     ! no transport trough the bottom
103      zvn(:,:,jpk) = 0._wp                                                     ! no transport trough the bottom
104      zwn(:,:,jpk) = 0._wp                                                     ! no transport trough the bottom
105      !
106      IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad )   &
107         &              CALL ldf_eiv_trp( kt, nit000, zun, zvn, zwn, 'TRA' )   ! add the eiv transport (if necessary)
108      !
109      IF( ln_mle    )   CALL tra_adv_mle( kt, nit000, zun, zvn, zwn, 'TRA' )    ! add the mle transport (if necessary)
110      CALL iom_put( "uocetr_eff", zun )                                         ! output effective transport     
111      CALL iom_put( "vocetr_eff", zvn )
112      CALL iom_put( "wocetr_eff", zwn )
113
114      SELECT CASE ( nadv )                            !==  compute advection trend and add it to general trend  ==!
115      CASE ( 1 )   ;    CALL tra_adv_cen2  ( kt, nit000, 'TRA',         zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  2nd order centered
116      CASE ( 2 )   ;    CALL tra_adv_tvd   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  TVD
117      CASE ( 3 )   ;    CALL tra_adv_muscl ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb,      tsa, jpts, ln_traadv_msc_ups )   !  MUSCL
118      CASE ( 4 )   ;    CALL tra_adv_muscl2( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  MUSCL2
119      CASE ( 5 )   ;    CALL tra_adv_ubs   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  UBS
120      CASE ( 6 )   ;    CALL tra_adv_qck   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  QUICKEST
121      !
122      CASE (-1 )                                      !==  esopa: test all possibility with control print  ==!
123         CALL tra_adv_cen2  ( kt, nit000, 'TRA',         zun, zvn, zwn, tsb, tsn, tsa, jpts )         
124         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv0 - Ta: ', mask1=tmask,               &
125            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
126         CALL tra_adv_tvd   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
127         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv1 - Ta: ', mask1=tmask,               &
128            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
129         CALL tra_adv_muscl ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb,      tsa, jpts, ln_traadv_msc_ups )         
130         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv3 - Ta: ', mask1=tmask,               &
131            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
132         CALL tra_adv_muscl2( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
133         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv4 - Ta: ', mask1=tmask,               &
134            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
135         CALL tra_adv_ubs   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
136         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv5 - Ta: ', mask1=tmask,               &
137            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
138         CALL tra_adv_qck   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
139         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv6 - Ta: ', mask1=tmask,               &
140            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
141      END SELECT
142      !
143      !                                              ! print mean trends (used for debugging)
144      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv  - Ta: ', mask1=tmask,               &
145         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
146      !
147      IF( nn_timing == 1 )  CALL timing_stop( 'tra_adv' )
148      !
149      CALL wrk_dealloc( jpi, jpj, jpk, zun, zvn, zwn )
150      !                                         
151   END SUBROUTINE tra_adv
152
153
154   SUBROUTINE tra_adv_init
155      !!---------------------------------------------------------------------
156      !!                  ***  ROUTINE tra_adv_init  ***
157      !!               
158      !! ** Purpose :   Control the consistency between namelist options for
159      !!              tracer advection schemes and set nadv
160      !!----------------------------------------------------------------------
161      INTEGER ::   ioptio, ios   ! Local integers
162      !!
163      NAMELIST/namtra_adv/ ln_traadv_cen2 , ln_traadv_tvd,     &
164         &                 ln_traadv_muscl, ln_traadv_muscl2,  &
165         &                 ln_traadv_ubs  , ln_traadv_qck,     &
166         &                 ln_traadv_msc_ups
167      !!----------------------------------------------------------------------
168      !
169      REWIND( numnam_ref )              ! Namelist namtra_adv in reference namelist : Tracer advection scheme
170      READ  ( numnam_ref, namtra_adv, IOSTAT = ios, ERR = 901)
171901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in reference namelist', lwp )
172      !
173      REWIND( numnam_cfg )              ! Namelist namtra_adv in configuration namelist : Tracer advection scheme
174      READ  ( numnam_cfg, namtra_adv, IOSTAT = ios, ERR = 902 )
175902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in configuration namelist', lwp )
176      WRITE ( numond, namtra_adv )
177      !
178      IF(lwp) THEN                    ! Namelist print
179         WRITE(numout,*)
180         WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
181         WRITE(numout,*) '~~~~~~~~~~~'
182         WRITE(numout,*) '   Namelist namtra_adv : chose a advection scheme for tracers'
183         WRITE(numout,*) '      2nd order advection scheme     ln_traadv_cen2    = ', ln_traadv_cen2
184         WRITE(numout,*) '      TVD advection scheme           ln_traadv_tvd     = ', ln_traadv_tvd
185         WRITE(numout,*) '      MUSCL  advection scheme        ln_traadv_muscl   = ', ln_traadv_muscl
186         WRITE(numout,*) '      MUSCL2 advection scheme        ln_traadv_muscl2  = ', ln_traadv_muscl2
187         WRITE(numout,*) '      UBS    advection scheme        ln_traadv_ubs     = ', ln_traadv_ubs
188         WRITE(numout,*) '      QUICKEST advection scheme      ln_traadv_qck     = ', ln_traadv_qck
189         WRITE(numout,*) '      upstream scheme within muscl   ln_traadv_msc_ups = ', ln_traadv_msc_ups
190      ENDIF
191
192      ioptio = 0                      ! Parameter control
193      IF( ln_traadv_cen2   )   ioptio = ioptio + 1
194      IF( ln_traadv_tvd    )   ioptio = ioptio + 1
195      IF( ln_traadv_muscl  )   ioptio = ioptio + 1
196      IF( ln_traadv_muscl2 )   ioptio = ioptio + 1
197      IF( ln_traadv_ubs    )   ioptio = ioptio + 1
198      IF( ln_traadv_qck    )   ioptio = ioptio + 1
199      IF( lk_esopa         )   ioptio =          1
200
201      IF( ioptio /= 1 )   CALL ctl_stop( 'Choose ONE advection scheme in namelist namtra_adv' )
202
203      !                              ! Set nadv
204      IF( ln_traadv_cen2   )   nadv =  1
205      IF( ln_traadv_tvd    )   nadv =  2
206      IF( ln_traadv_muscl  )   nadv =  3
207      IF( ln_traadv_muscl2 )   nadv =  4
208      IF( ln_traadv_ubs    )   nadv =  5
209      IF( ln_traadv_qck    )   nadv =  6
210      IF( lk_esopa         )   nadv = -1
211
212      IF(lwp) THEN                   ! Print the choice
213         WRITE(numout,*)
214         IF( nadv ==  1 )   WRITE(numout,*) '         2nd order scheme is used'
215         IF( nadv ==  2 )   WRITE(numout,*) '         TVD       scheme is used'
216         IF( nadv ==  3 )   WRITE(numout,*) '         MUSCL     scheme is used'
217         IF( nadv ==  4 )   WRITE(numout,*) '         MUSCL2    scheme is used'
218         IF( nadv ==  5 )   WRITE(numout,*) '         UBS       scheme is used'
219         IF( nadv ==  6 )   WRITE(numout,*) '         QUICKEST  scheme is used'
220         IF( nadv == -1 )   WRITE(numout,*) '         esopa test: use all advection scheme'
221      ENDIF
222      !
223      CALL tra_adv_mle_init          ! initialisation of the Mixed Layer Eddy parametrisation (MLE)
224      !
225   END SUBROUTINE tra_adv_init
226
227  !!======================================================================
228END MODULE traadv
Note: See TracBrowser for help on using the repository browser.