| 1 | MODULE traldf_iso_triad |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE traldf_iso_triad *** |
|---|
| 4 | !! Ocean tracers: horizontal component of the lateral tracer mixing trend |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.3 ! 2010-10 (G. Nurser, C. Harris, G. Madec) Griffies operator (original code) |
|---|
| 7 | !! 3.7 ! 2013-12 (F. Lemarie, G. Madec) triad operator (Griffies) + Method of Stabilizing Correction |
|---|
| 8 | !!---------------------------------------------------------------------- |
|---|
| 9 | |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | !! tra_ldf_iso_triad : update the tracer trend with the iso-neutral laplacian triad-operator |
|---|
| 12 | !! tra_ldf_iso_blp : update the tracer trend with the iso-neutral bilaplacian triad-operator |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | USE oce ! ocean dynamics and active tracers |
|---|
| 15 | USE dom_oce ! ocean space and time domain |
|---|
| 16 | USE phycst ! physical constants |
|---|
| 17 | USE trc_oce ! share passive tracers/Ocean variables |
|---|
| 18 | USE zdf_oce ! ocean vertical physics |
|---|
| 19 | USE ldftra ! lateral physics: eddy diffusivity |
|---|
| 20 | USE ldfslp ! lateral physics: iso-neutral slopes |
|---|
| 21 | USE traldf_iso ! lateral diffusion (Madec operator) (tra_ldf_iso routine) |
|---|
| 22 | USE diaptr ! poleward transport diagnostics |
|---|
| 23 | USE zpshde ! partial step: hor. derivative (zps_hde routine) |
|---|
| 24 | ! |
|---|
| 25 | USE in_out_manager ! I/O manager |
|---|
| 26 | USE iom ! I/O library |
|---|
| 27 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 28 | USE lib_mpp ! MPP library |
|---|
| 29 | USE wrk_nemo ! Memory Allocation |
|---|
| 30 | USE timing ! Timing |
|---|
| 31 | |
|---|
| 32 | IMPLICIT NONE |
|---|
| 33 | PRIVATE |
|---|
| 34 | |
|---|
| 35 | PUBLIC tra_ldf_iso_triad ! routine called by traldf.F90 |
|---|
| 36 | PUBLIC tra_ldf_iso_blp ! routine called by traldf.F90 |
|---|
| 37 | |
|---|
| 38 | REAL(wp), DIMENSION(:,:,:), ALLOCATABLE, SAVE :: zdkt3d !: vertical tracer gradient at 2 levels |
|---|
| 39 | |
|---|
| 40 | !! * Substitutions |
|---|
| 41 | # include "domzgr_substitute.h90" |
|---|
| 42 | # include "vectopt_loop_substitute.h90" |
|---|
| 43 | !!---------------------------------------------------------------------- |
|---|
| 44 | !! NEMO/OPA 3.7 , NEMO Consortium (2014) |
|---|
| 45 | !! $Id$ |
|---|
| 46 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 47 | !!---------------------------------------------------------------------- |
|---|
| 48 | CONTAINS |
|---|
| 49 | |
|---|
| 50 | SUBROUTINE tra_ldf_iso_triad( kt, kit000, cdtype, pgu, pgv , pahu, pahv , & |
|---|
| 51 | & ptb, ptbb, pta , kjpt , kpass ) |
|---|
| 52 | !!---------------------------------------------------------------------- |
|---|
| 53 | !! *** ROUTINE tra_ldf_iso_triad *** |
|---|
| 54 | !! |
|---|
| 55 | !! ** Purpose : Compute the before horizontal tracer (t & s) diffusive |
|---|
| 56 | !! trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and |
|---|
| 57 | !! add it to the general trend of tracer equation. |
|---|
| 58 | !! |
|---|
| 59 | !! ** Method : The horizontal component of the lateral diffusive trends |
|---|
| 60 | !! is provided by a 2nd order operator rotated along neural or geopo- |
|---|
| 61 | !! tential surfaces to which an eddy induced advection can be added |
|---|
| 62 | !! It is computed using before fields (forward in time) and isopyc- |
|---|
| 63 | !! nal or geopotential slopes computed in routine ldfslp. |
|---|
| 64 | !! |
|---|
| 65 | !! see documentation for the desciption |
|---|
| 66 | !! |
|---|
| 67 | !! ** Action : pta updated with the before rotated diffusion |
|---|
| 68 | !! akz stabilizing vertical diffusivity coefficient (used in trazdf_imp) |
|---|
| 69 | !!---------------------------------------------------------------------- |
|---|
| 70 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
|---|
| 71 | INTEGER , INTENT(in ) :: kit000 ! first time step index |
|---|
| 72 | CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator) |
|---|
| 73 | INTEGER , INTENT(in ) :: kjpt ! number of tracers |
|---|
| 74 | INTEGER , INTENT(in ) :: kpass ! =1/2 first or second passage |
|---|
| 75 | REAL(wp), DIMENSION(jpi,jpj ,kjpt), INTENT(in ) :: pgu , pgv ! tracer gradient at pstep levels |
|---|
| 76 | REAL(wp), DIMENSION(jpi,jpj,jpk) , INTENT(in ) :: pahu, pahv ! eddy diffusivity at u- and v-points [m2/s] |
|---|
| 77 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in ) :: ptb ! tracer (kpass=1) or laplacian of tracer (kpass=2) |
|---|
| 78 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in ) :: ptbb ! tracer (only used in kpass=2) |
|---|
| 79 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) :: pta ! tracer trend |
|---|
| 80 | ! |
|---|
| 81 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
|---|
| 82 | INTEGER :: ip,jp,kp ! dummy loop indices |
|---|
| 83 | INTEGER :: ierr ! local integer |
|---|
| 84 | REAL(wp) :: zmsku, zabe1, zcof1, zcoef3 ! local scalars |
|---|
| 85 | REAL(wp) :: zmskv, zabe2, zcof2, zcoef4 ! - - |
|---|
| 86 | REAL(wp) :: zcoef0, ze3w_2, zsign, z2dt, z1_2dt ! - - |
|---|
| 87 | ! |
|---|
| 88 | REAL(wp) :: zslope_skew, zslope_iso, zslope2, zbu, zbv |
|---|
| 89 | REAL(wp) :: ze1ur, ze2vr, ze3wr, zdxt, zdyt, zdzt |
|---|
| 90 | REAL(wp) :: zah, zah_slp, zaei_slp |
|---|
| 91 | #if defined key_diaar5 |
|---|
| 92 | REAL(wp) :: zztmp ! local scalar |
|---|
| 93 | #endif |
|---|
| 94 | REAL(wp), POINTER, DIMENSION(:,: ) :: z2d ! 2D workspace |
|---|
| 95 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zdit, zdjt, zftu, zftv, ztfw, zpsi_uw, zpsi_vw ! 3D - |
|---|
| 96 | !!---------------------------------------------------------------------- |
|---|
| 97 | ! |
|---|
| 98 | IF( nn_timing == 1 ) CALL timing_start('tra_ldf_iso_triad') |
|---|
| 99 | ! |
|---|
| 100 | CALL wrk_alloc( jpi, jpj, z2d ) |
|---|
| 101 | CALL wrk_alloc( jpi, jpj, jpk, zdit, zdjt, zftu, zftv, ztfw, zpsi_uw, zpsi_vw ) |
|---|
| 102 | IF( .NOT.ALLOCATED(zdkt3d) ) THEN |
|---|
| 103 | ALLOCATE( zdkt3d(jpi,jpj,0:1) , STAT=ierr ) |
|---|
| 104 | IF( lk_mpp ) CALL mpp_sum ( ierr ) |
|---|
| 105 | IF( ierr > 0 ) CALL ctl_stop('STOP', 'tra_ldf_iso_triad: unable to allocate arrays') |
|---|
| 106 | ENDIF |
|---|
| 107 | ! |
|---|
| 108 | IF( kpass == 1 .AND. kt == kit000 ) THEN |
|---|
| 109 | IF(lwp) WRITE(numout,*) |
|---|
| 110 | IF(lwp) WRITE(numout,*) 'tra_ldf_iso_triad : rotated laplacian diffusion operator on ', cdtype |
|---|
| 111 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~' |
|---|
| 112 | ENDIF |
|---|
| 113 | ! |
|---|
| 114 | ! ! set time step size (Euler/Leapfrog) |
|---|
| 115 | IF( neuler == 0 .AND. kt == nit000 ) THEN ; z2dt = rdttra(1) ! at nit000 (Euler) |
|---|
| 116 | ELSE ; z2dt = 2.* rdttra(1) ! (Leapfrog) |
|---|
| 117 | ENDIF |
|---|
| 118 | z1_2dt = 1._wp / z2dt |
|---|
| 119 | ! |
|---|
| 120 | IF( kpass == 1 ) THEN ; zsign = 1._wp ! bilaplacian operator require a minus sign (eddy diffusivity >0) |
|---|
| 121 | ELSE ; zsign = -1._wp |
|---|
| 122 | ENDIF |
|---|
| 123 | |
|---|
| 124 | !!---------------------------------------------------------------------- |
|---|
| 125 | !! 0 - calculate ah_wslp2, akz, and optionally zpsi_uw, zpsi_vw |
|---|
| 126 | !!---------------------------------------------------------------------- |
|---|
| 127 | ! |
|---|
| 128 | IF( kpass == 1 ) THEN !== first pass only and whatever the tracer is ==! |
|---|
| 129 | ! |
|---|
| 130 | akz (:,:,:) = 0._wp |
|---|
| 131 | ah_wslp2(:,:,:) = 0._wp |
|---|
| 132 | IF( ln_ldfeiv_dia ) THEN |
|---|
| 133 | zpsi_uw(:,:,:) = 0._wp |
|---|
| 134 | zpsi_vw(:,:,:) = 0._wp |
|---|
| 135 | ENDIF |
|---|
| 136 | ! |
|---|
| 137 | DO ip = 0, 1 ! i-k triads |
|---|
| 138 | DO kp = 0, 1 |
|---|
| 139 | DO jk = 1, jpkm1 |
|---|
| 140 | DO jj = 1, jpjm1 |
|---|
| 141 | DO ji = 1, fs_jpim1 |
|---|
| 142 | ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp) |
|---|
| 143 | zbu = e1e2u(ji,jj) * fse3u(ji,jj,jk) |
|---|
| 144 | zah = 0.25_wp * pahu(ji,jj,jk) |
|---|
| 145 | zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp) |
|---|
| 146 | ! Subtract s-coordinate slope at t-points to give slope rel to s-surfaces (do this by *adding* gradient of depth) |
|---|
| 147 | zslope2 = zslope_skew + ( fsdept(ji+1,jj,jk) - fsdept(ji,jj,jk) ) * r1_e1u(ji,jj) * umask(ji,jj,jk+kp) |
|---|
| 148 | zslope2 = zslope2 *zslope2 |
|---|
| 149 | ah_wslp2(ji+ip,jj,jk+kp) = ah_wslp2(ji+ip,jj,jk+kp) + zah * zbu * ze3wr * r1_e1e2t(ji+ip,jj) * zslope2 |
|---|
| 150 | akz (ji+ip,jj,jk+kp) = akz (ji+ip,jj,jk+kp) + zah / ( e1u(ji,jj) * e1u(ji,jj) ) * umask(ji,jj,jk+kp) |
|---|
| 151 | ! |
|---|
| 152 | IF( ln_ldfeiv_dia ) zpsi_uw(ji,jj,jk+kp) = zpsi_uw(ji,jj,jk+kp) & |
|---|
| 153 | & + 0.25_wp * aeiu(ji,jj,jk) * e2u(ji,jj) * zslope_skew |
|---|
| 154 | END DO |
|---|
| 155 | END DO |
|---|
| 156 | END DO |
|---|
| 157 | END DO |
|---|
| 158 | END DO |
|---|
| 159 | ! |
|---|
| 160 | DO jp = 0, 1 ! j-k triads |
|---|
| 161 | DO kp = 0, 1 |
|---|
| 162 | DO jk = 1, jpkm1 |
|---|
| 163 | DO jj = 1, jpjm1 |
|---|
| 164 | DO ji = 1, fs_jpim1 |
|---|
| 165 | ze3wr = 1.0_wp / fse3w(ji,jj+jp,jk+kp) |
|---|
| 166 | zbv = e1e2v(ji,jj) * fse3v(ji,jj,jk) |
|---|
| 167 | zah = 0.25_wp * pahv(ji,jj,jk) |
|---|
| 168 | zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp) |
|---|
| 169 | ! Subtract s-coordinate slope at t-points to give slope rel to s surfaces |
|---|
| 170 | ! (do this by *adding* gradient of depth) |
|---|
| 171 | zslope2 = zslope_skew + ( fsdept(ji,jj+1,jk) - fsdept(ji,jj,jk) ) * r1_e2v(ji,jj) * vmask(ji,jj,jk+kp) |
|---|
| 172 | zslope2 = zslope2 * zslope2 |
|---|
| 173 | ah_wslp2(ji,jj+jp,jk+kp) = ah_wslp2(ji,jj+jp,jk+kp) + zah * zbv * ze3wr / e1e2t(ji,jj+jp) * zslope2 |
|---|
| 174 | akz (ji,jj+jp,jk+kp) = akz (ji,jj+jp,jk+kp) + zah / ( e2v(ji,jj) * e2v(ji,jj) ) * vmask(ji,jj,jk+kp) |
|---|
| 175 | ! |
|---|
| 176 | IF( ln_ldfeiv_dia ) zpsi_vw(ji,jj,jk+kp) = zpsi_vw(ji,jj,jk+kp) & |
|---|
| 177 | & + 0.25 * aeiv(ji,jj,jk) * e1v(ji,jj) * zslope_skew |
|---|
| 178 | END DO |
|---|
| 179 | END DO |
|---|
| 180 | END DO |
|---|
| 181 | END DO |
|---|
| 182 | END DO |
|---|
| 183 | ! |
|---|
| 184 | IF( ln_traldf_msc ) THEN ! stabilizing vertical diffusivity coefficient |
|---|
| 185 | ! |
|---|
| 186 | IF( ln_traldf_blp ) THEN ! bilaplacian operator |
|---|
| 187 | DO jk = 2, jpkm1 |
|---|
| 188 | DO jj = 1, jpjm1 |
|---|
| 189 | DO ji = 1, fs_jpim1 |
|---|
| 190 | akz(ji,jj,jk) = 16._wp * ah_wslp2(ji,jj,jk) & |
|---|
| 191 | & * ( akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ( fse3w(ji,jj,jk) * fse3w(ji,jj,jk) ) ) |
|---|
| 192 | END DO |
|---|
| 193 | END DO |
|---|
| 194 | END DO |
|---|
| 195 | ELSEIF( ln_traldf_lap ) THEN ! laplacian operator |
|---|
| 196 | DO jk = 2, jpkm1 |
|---|
| 197 | DO jj = 1, jpjm1 |
|---|
| 198 | DO ji = 1, fs_jpim1 |
|---|
| 199 | ze3w_2 = fse3w(ji,jj,jk) * fse3w(ji,jj,jk) |
|---|
| 200 | zcoef0 = z2dt * ( akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ze3w_2 ) |
|---|
| 201 | akz(ji,jj,jk) = MAX( zcoef0 - 0.5_wp , 0._wp ) * ze3w_2 * z1_2dt |
|---|
| 202 | END DO |
|---|
| 203 | END DO |
|---|
| 204 | END DO |
|---|
| 205 | ENDIF |
|---|
| 206 | ! |
|---|
| 207 | ELSE ! 33 flux set to zero with akz=ah_wslp2 ==>> computed in full implicit |
|---|
| 208 | akz(:,:,:) = ah_wslp2(:,:,:) |
|---|
| 209 | ENDIF |
|---|
| 210 | ! |
|---|
| 211 | IF( ln_ldfeiv_dia .AND. cdtype == 'TRA' ) CALL ldf_eiv_dia( zpsi_uw, zpsi_vw ) |
|---|
| 212 | ! |
|---|
| 213 | ENDIF !== end 1st pass only ==! |
|---|
| 214 | ! |
|---|
| 215 | ! ! =========== |
|---|
| 216 | DO jn = 1, kjpt ! tracer loop |
|---|
| 217 | ! ! =========== |
|---|
| 218 | ! Zero fluxes for each tracer |
|---|
| 219 | !!gm this should probably be done outside the jn loop |
|---|
| 220 | ztfw(:,:,:) = 0._wp |
|---|
| 221 | zftu(:,:,:) = 0._wp |
|---|
| 222 | zftv(:,:,:) = 0._wp |
|---|
| 223 | ! |
|---|
| 224 | DO jk = 1, jpkm1 !== before lateral T & S gradients at T-level jk ==! |
|---|
| 225 | DO jj = 1, jpjm1 |
|---|
| 226 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 227 | zdit(ji,jj,jk) = ( ptb(ji+1,jj ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk) |
|---|
| 228 | zdjt(ji,jj,jk) = ( ptb(ji ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk) |
|---|
| 229 | END DO |
|---|
| 230 | END DO |
|---|
| 231 | END DO |
|---|
| 232 | IF( ln_zps.and.l_grad_zps ) THEN ! partial steps: correction at the last level |
|---|
| 233 | DO jj = 1, jpjm1 |
|---|
| 234 | DO ji = 1, jpim1 |
|---|
| 235 | zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn) |
|---|
| 236 | zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn) |
|---|
| 237 | END DO |
|---|
| 238 | END DO |
|---|
| 239 | ENDIF |
|---|
| 240 | |
|---|
| 241 | !!---------------------------------------------------------------------- |
|---|
| 242 | !! II - horizontal trend (full) |
|---|
| 243 | !!---------------------------------------------------------------------- |
|---|
| 244 | ! |
|---|
| 245 | DO jk = 1, jpkm1 |
|---|
| 246 | ! |
|---|
| 247 | ! !== Vertical tracer gradient at level jk and jk+1 |
|---|
| 248 | zdkt3d(:,:,1) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask(:,:,jk+1) |
|---|
| 249 | ! |
|---|
| 250 | ! ! surface boundary condition: zdkt3d(jk=0)=zdkt3d(jk=1) |
|---|
| 251 | IF( jk == 1 ) THEN ; zdkt3d(:,:,0) = zdkt3d(:,:,1) |
|---|
| 252 | ELSE ; zdkt3d(:,:,0) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask(:,:,jk) |
|---|
| 253 | ENDIF |
|---|
| 254 | ! |
|---|
| 255 | zaei_slp = 0._wp |
|---|
| 256 | ! |
|---|
| 257 | IF( ln_botmix_triad ) THEN |
|---|
| 258 | DO ip = 0, 1 !== Horizontal & vertical fluxes |
|---|
| 259 | DO kp = 0, 1 |
|---|
| 260 | DO jj = 1, jpjm1 |
|---|
| 261 | DO ji = 1, fs_jpim1 |
|---|
| 262 | ze1ur = r1_e1u(ji,jj) |
|---|
| 263 | zdxt = zdit(ji,jj,jk) * ze1ur |
|---|
| 264 | ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp) |
|---|
| 265 | zdzt = zdkt3d(ji+ip,jj,kp) * ze3wr |
|---|
| 266 | zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp) |
|---|
| 267 | zslope_iso = triadi (ji+ip,jj,jk,1-ip,kp) |
|---|
| 268 | |
|---|
| 269 | zbu = 0.25_wp * e1e2u(ji,jj) * fse3u(ji,jj,jk) |
|---|
| 270 | ! ln_botmix_triad is .T. don't mask zah for bottom half cells !!gm ????? ahu is masked.... |
|---|
| 271 | zah = pahu(ji,jj,jk) |
|---|
| 272 | zah_slp = zah * zslope_iso |
|---|
| 273 | IF( ln_ldfeiv ) zaei_slp = aeiu(ji,jj,jk) * zslope_skew |
|---|
| 274 | zftu(ji ,jj,jk ) = zftu(ji ,jj,jk ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur |
|---|
| 275 | ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - ( zah_slp + zaei_slp) * zdxt * zbu * ze3wr |
|---|
| 276 | END DO |
|---|
| 277 | END DO |
|---|
| 278 | END DO |
|---|
| 279 | END DO |
|---|
| 280 | |
|---|
| 281 | DO jp = 0, 1 |
|---|
| 282 | DO kp = 0, 1 |
|---|
| 283 | DO jj = 1, jpjm1 |
|---|
| 284 | DO ji = 1, fs_jpim1 |
|---|
| 285 | ze2vr =r1_e2v(ji,jj) |
|---|
| 286 | zdyt = zdjt(ji,jj,jk) * ze2vr |
|---|
| 287 | ze3wr = 1._wp / fse3w(ji,jj+jp,jk+kp) |
|---|
| 288 | zdzt = zdkt3d(ji,jj+jp,kp) * ze3wr |
|---|
| 289 | zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp) |
|---|
| 290 | zslope_iso = triadj(ji,jj+jp,jk,1-jp,kp) |
|---|
| 291 | zbv = 0.25_wp * e1e2v(ji,jj) * fse3v(ji,jj,jk) |
|---|
| 292 | ! ln_botmix_triad is .T. don't mask zah for bottom half cells !!gm ????? ahv is masked... |
|---|
| 293 | zah = pahv(ji,jj,jk) |
|---|
| 294 | zah_slp = zah * zslope_iso |
|---|
| 295 | IF( ln_ldfeiv ) zaei_slp = aeiv(ji,jj,jk) * zslope_skew |
|---|
| 296 | zftv(ji,jj ,jk ) = zftv(ji,jj ,jk ) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr |
|---|
| 297 | ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - ( zah_slp + zaei_slp ) * zdyt * zbv * ze3wr |
|---|
| 298 | END DO |
|---|
| 299 | END DO |
|---|
| 300 | END DO |
|---|
| 301 | END DO |
|---|
| 302 | |
|---|
| 303 | ELSE |
|---|
| 304 | |
|---|
| 305 | DO ip = 0, 1 !== Horizontal & vertical fluxes |
|---|
| 306 | DO kp = 0, 1 |
|---|
| 307 | DO jj = 1, jpjm1 |
|---|
| 308 | DO ji = 1, fs_jpim1 |
|---|
| 309 | ze1ur = r1_e1u(ji,jj) |
|---|
| 310 | zdxt = zdit(ji,jj,jk) * ze1ur |
|---|
| 311 | ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp) |
|---|
| 312 | zdzt = zdkt3d(ji+ip,jj,kp) * ze3wr |
|---|
| 313 | zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp) |
|---|
| 314 | zslope_iso = triadi(ji+ip,jj,jk,1-ip,kp) |
|---|
| 315 | |
|---|
| 316 | zbu = 0.25_wp * e1e2u(ji,jj) * fse3u(ji,jj,jk) |
|---|
| 317 | ! ln_botmix_triad is .F. mask zah for bottom half cells |
|---|
| 318 | zah = pahu(ji,jj,jk) * umask(ji,jj,jk+kp) ! pahu(ji+ip,jj,jk) ===>> ???? |
|---|
| 319 | zah_slp = zah * zslope_iso |
|---|
| 320 | IF( ln_ldfeiv ) zaei_slp = aeiu(ji,jj,jk) * zslope_skew ! fsaeit(ji+ip,jj,jk)*zslope_skew |
|---|
| 321 | zftu(ji ,jj,jk ) = zftu(ji ,jj,jk ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur |
|---|
| 322 | ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr |
|---|
| 323 | END DO |
|---|
| 324 | END DO |
|---|
| 325 | END DO |
|---|
| 326 | END DO |
|---|
| 327 | |
|---|
| 328 | DO jp = 0, 1 |
|---|
| 329 | DO kp = 0, 1 |
|---|
| 330 | DO jj = 1, jpjm1 |
|---|
| 331 | DO ji = 1, fs_jpim1 |
|---|
| 332 | ze2vr = r1_e2v(ji,jj) |
|---|
| 333 | zdyt = zdjt(ji,jj,jk) * ze2vr |
|---|
| 334 | ze3wr = 1._wp / fse3w(ji,jj+jp,jk+kp) |
|---|
| 335 | zdzt = zdkt3d(ji,jj+jp,kp) * ze3wr |
|---|
| 336 | zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp) |
|---|
| 337 | zslope_iso = triadj(ji,jj+jp,jk,1-jp,kp) |
|---|
| 338 | zbv = 0.25_wp * e1e2v(ji,jj) * fse3v(ji,jj,jk) |
|---|
| 339 | ! ln_botmix_triad is .F. mask zah for bottom half cells |
|---|
| 340 | zah = pahv(ji,jj,jk) * vmask(ji,jj,jk+kp) ! pahv(ji,jj+jp,jk) ???? |
|---|
| 341 | zah_slp = zah * zslope_iso |
|---|
| 342 | IF( ln_ldfeiv ) zaei_slp = aeiv(ji,jj,jk) * zslope_skew ! fsaeit(ji,jj+jp,jk)*zslope_skew |
|---|
| 343 | zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr |
|---|
| 344 | ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr |
|---|
| 345 | END DO |
|---|
| 346 | END DO |
|---|
| 347 | END DO |
|---|
| 348 | END DO |
|---|
| 349 | ENDIF |
|---|
| 350 | ! !== horizontal divergence and add to the general trend ==! |
|---|
| 351 | DO jj = 2 , jpjm1 |
|---|
| 352 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 353 | pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * ( zftu(ji-1,jj,jk) - zftu(ji,jj,jk) & |
|---|
| 354 | & + zftv(ji,jj-1,jk) - zftv(ji,jj,jk) ) & |
|---|
| 355 | & / ( e1e2t(ji,jj) * fse3t(ji,jj,jk) ) |
|---|
| 356 | END DO |
|---|
| 357 | END DO |
|---|
| 358 | ! |
|---|
| 359 | END DO |
|---|
| 360 | ! |
|---|
| 361 | ! !== add the vertical 33 flux ==! |
|---|
| 362 | IF( ln_traldf_lap ) THEN ! laplacian case: eddy coef = ah_wslp2 - akz |
|---|
| 363 | DO jk = 2, jpkm1 |
|---|
| 364 | DO jj = 1, jpjm1 |
|---|
| 365 | DO ji = fs_2, fs_jpim1 |
|---|
| 366 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / fse3w(ji,jj,jk) * tmask(ji,jj,jk) & |
|---|
| 367 | & * ( ah_wslp2(ji,jj,jk) - akz(ji,jj,jk) ) & |
|---|
| 368 | & * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) ) |
|---|
| 369 | END DO |
|---|
| 370 | END DO |
|---|
| 371 | END DO |
|---|
| 372 | ELSE ! bilaplacian |
|---|
| 373 | SELECT CASE( kpass ) |
|---|
| 374 | CASE( 1 ) ! 1st pass : eddy coef = ah_wslp2 |
|---|
| 375 | DO jk = 2, jpkm1 |
|---|
| 376 | DO jj = 1, jpjm1 |
|---|
| 377 | DO ji = fs_2, fs_jpim1 |
|---|
| 378 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / fse3w(ji,jj,jk) * tmask(ji,jj,jk) & |
|---|
| 379 | & * ah_wslp2(ji,jj,jk) * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) ) |
|---|
| 380 | END DO |
|---|
| 381 | END DO |
|---|
| 382 | END DO |
|---|
| 383 | CASE( 2 ) ! 2nd pass : eddy flux = ah_wslp2 and akz applied on ptb and ptbb gradients, resp. |
|---|
| 384 | DO jk = 2, jpkm1 |
|---|
| 385 | DO jj = 1, jpjm1 |
|---|
| 386 | DO ji = fs_2, fs_jpim1 |
|---|
| 387 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / fse3w(ji,jj,jk) * tmask(ji,jj,jk) & |
|---|
| 388 | & * ( ah_wslp2(ji,jj,jk) * ( ptb (ji,jj,jk-1,jn) - ptb (ji,jj,jk,jn) ) & |
|---|
| 389 | & + akz (ji,jj,jk) * ( ptbb(ji,jj,jk-1,jn) - ptbb(ji,jj,jk,jn) ) ) |
|---|
| 390 | END DO |
|---|
| 391 | END DO |
|---|
| 392 | END DO |
|---|
| 393 | END SELECT |
|---|
| 394 | ENDIF |
|---|
| 395 | ! |
|---|
| 396 | DO jk = 1, jpkm1 !== Divergence of vertical fluxes added to pta ==! |
|---|
| 397 | DO jj = 2, jpjm1 |
|---|
| 398 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 399 | pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * ( ztfw(ji,jj,jk+1) - ztfw(ji,jj,jk) ) & |
|---|
| 400 | & / ( e1e2t(ji,jj) * fse3t(ji,jj,jk) ) |
|---|
| 401 | END DO |
|---|
| 402 | END DO |
|---|
| 403 | END DO |
|---|
| 404 | ! |
|---|
| 405 | IF( ( kpass == 1 .AND. ln_traldf_lap ) .OR. & !== first pass only ( laplacian) ==! |
|---|
| 406 | ( kpass == 2 .AND. ln_traldf_blp ) ) THEN !== 2nd pass (bilaplacian) ==! |
|---|
| 407 | ! |
|---|
| 408 | ! ! "Poleward" diffusive heat or salt transports (T-S case only) |
|---|
| 409 | IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN |
|---|
| 410 | IF( jn == jp_tem) htr_ldf(:) = ptr_vj( zftv(:,:,:) ) ! 3.3 names |
|---|
| 411 | IF( jn == jp_sal) str_ldf(:) = ptr_vj( zftv(:,:,:) ) |
|---|
| 412 | ENDIF |
|---|
| 413 | |
|---|
| 414 | #if defined key_diaar5 |
|---|
| 415 | ! ! AR5 diagnostics: vertical integrated heat transport |
|---|
| 416 | IF( cdtype == 'TRA' .AND. jn == jp_tem ) THEN |
|---|
| 417 | z2d(:,:) = 0._wp |
|---|
| 418 | zztmp = rau0 * rcp |
|---|
| 419 | DO jk = 1, jpkm1 |
|---|
| 420 | DO jj = 2, jpjm1 |
|---|
| 421 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 422 | z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) |
|---|
| 423 | END DO |
|---|
| 424 | END DO |
|---|
| 425 | END DO |
|---|
| 426 | z2d(:,:) = zztmp * z2d(:,:) |
|---|
| 427 | CALL lbc_lnk( z2d, 'U', -1. ) |
|---|
| 428 | CALL iom_put( "udiff_heattr", z2d ) ! heat transport in i-direction |
|---|
| 429 | z2d(:,:) = 0._wp |
|---|
| 430 | DO jk = 1, jpkm1 |
|---|
| 431 | DO jj = 2, jpjm1 |
|---|
| 432 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 433 | z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) |
|---|
| 434 | END DO |
|---|
| 435 | END DO |
|---|
| 436 | END DO |
|---|
| 437 | z2d(:,:) = zztmp * z2d(:,:) |
|---|
| 438 | CALL lbc_lnk( z2d, 'V', -1. ) |
|---|
| 439 | CALL iom_put( "vdiff_heattr", z2d ) ! heat transport in j-direction |
|---|
| 440 | ENDIF |
|---|
| 441 | #endif |
|---|
| 442 | ENDIF !== end pass selection ==! |
|---|
| 443 | ! |
|---|
| 444 | ! ! =============== |
|---|
| 445 | END DO ! end tracer loop |
|---|
| 446 | ! ! =============== |
|---|
| 447 | ! |
|---|
| 448 | CALL wrk_dealloc( jpi, jpj, z2d ) |
|---|
| 449 | CALL wrk_dealloc( jpi, jpj, jpk, zdit, zdjt, ztfw ) |
|---|
| 450 | ! |
|---|
| 451 | IF( nn_timing == 1 ) CALL timing_stop('tra_ldf_iso_triad') |
|---|
| 452 | ! |
|---|
| 453 | END SUBROUTINE tra_ldf_iso_triad |
|---|
| 454 | |
|---|
| 455 | |
|---|
| 456 | SUBROUTINE tra_ldf_iso_blp( kt, kit000, cdtype, pgu, pgv, pahu, pahv, & |
|---|
| 457 | & ptb, pta, kjpt ) |
|---|
| 458 | !!---------------------------------------------------------------------- |
|---|
| 459 | !! *** ROUTINE tra_ldf_blp *** |
|---|
| 460 | !! |
|---|
| 461 | !! ** Purpose : Compute the before horizontal tracer diffusive |
|---|
| 462 | !! trend and add it to the general trend of tracer equation. |
|---|
| 463 | !! |
|---|
| 464 | !! ** Method : The lateral diffusive trends is provided by a bilaplacian |
|---|
| 465 | !! operator rotated along iso-neutral surfaces applied to before field |
|---|
| 466 | !! (forward in time). |
|---|
| 467 | !! It is computed by two successive calls to tra_ldf_iso_triad |
|---|
| 468 | !! routine (i.e. a laplacian triad-operator). |
|---|
| 469 | !! It requires ln_traldf_msc=T unless a very small time step is used |
|---|
| 470 | !! |
|---|
| 471 | !! ** Action : pta updated with the before rotated bilaplacian diffusion |
|---|
| 472 | !! akz stabilizing vertical diffusivity coefficient (used in trazdf_imp) |
|---|
| 473 | !!---------------------------------------------------------------------- |
|---|
| 474 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
|---|
| 475 | INTEGER , INTENT(in ) :: kit000 ! first time step index |
|---|
| 476 | CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator) |
|---|
| 477 | INTEGER , INTENT(in ) :: kjpt ! number of tracers |
|---|
| 478 | REAL(wp), DIMENSION(jpi,jpj ,kjpt), INTENT(in ) :: pgu, pgv ! tracer gradient at pstep levels |
|---|
| 479 | REAL(wp), DIMENSION(jpi,jpj,jpk) , INTENT(in ) :: pahu, pahv ! eddy diffusivity at u- and v-points [m2/s] |
|---|
| 480 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in ) :: ptb ! before and now tracer fields |
|---|
| 481 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) :: pta ! tracer trend |
|---|
| 482 | ! |
|---|
| 483 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
|---|
| 484 | REAL(wp), POINTER, DIMENSION(:,:,:,:) :: zlap ! laplacian at t-point |
|---|
| 485 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zglu, zglv ! gradient of the laplacian at partial step level (u- and v-points) |
|---|
| 486 | !!---------------------------------------------------------------------- |
|---|
| 487 | ! |
|---|
| 488 | IF( nn_timing == 1 ) CALL timing_start('tra_ldf_iso_blp') |
|---|
| 489 | ! |
|---|
| 490 | CALL wrk_alloc( jpi, jpj, jpk, kjpt, zlap ) |
|---|
| 491 | CALL wrk_alloc( jpi, jpj , kjpt, zglu, zglv ) |
|---|
| 492 | ! |
|---|
| 493 | IF( kt == kit000 ) THEN |
|---|
| 494 | IF(lwp) WRITE(numout,*) |
|---|
| 495 | IF(lwp) WRITE(numout,*) 'tra_ldf_iso_blp : iso-neutral biharmonic operator on ', cdtype |
|---|
| 496 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~' |
|---|
| 497 | ENDIF |
|---|
| 498 | |
|---|
| 499 | zlap(:,:,:,:) = 0._wp |
|---|
| 500 | ! ! rotated laplacian applied to ptb (output in zlap) |
|---|
| 501 | IF( ln_traldf_triad ) THEN ! triad operator (Griffies) |
|---|
| 502 | CALL tra_ldf_iso_triad( kt, kit000, cdtype, pgu, pgv, pahu, pahv, ptb, ptb, zlap, kjpt, 1 ) |
|---|
| 503 | ELSE ! Madec operator |
|---|
| 504 | CALL tra_ldf_iso ( kt, kit000, cdtype, pgu, pgv, pahu, pahv, ptb, ptb, zlap, kjpt, 1 ) |
|---|
| 505 | ENDIF |
|---|
| 506 | ! |
|---|
| 507 | DO jn = 1, kjpt |
|---|
| 508 | CALL lbc_lnk( zlap(:,:,:,jn) , 'T', 1. ) ! Lateral boundary conditions (unchanged sign) |
|---|
| 509 | END DO |
|---|
| 510 | ! |
|---|
| 511 | IF( ln_zps ) CALL zps_hde( kt, jpts, zlap, zglu, zglv ) ! Partial steps: hor. gradient of laplacian at the partial step level |
|---|
| 512 | |
|---|
| 513 | ! ! rotated laplacian applied to zlap (output in pta) |
|---|
| 514 | IF( ln_traldf_triad ) THEN ! triad operator (Griffies) |
|---|
| 515 | CALL tra_ldf_iso_triad( kt, kit000, cdtype, zglu, zglv, pahu, pahv, zlap, ptb, pta, kjpt, 2 ) |
|---|
| 516 | ELSE ! Madec operator |
|---|
| 517 | CALL tra_ldf_iso ( kt, kit000, cdtype, zglu, zglv, pahu, pahv, zlap, ptb, pta, kjpt, 2 ) |
|---|
| 518 | ENDIF |
|---|
| 519 | ! |
|---|
| 520 | CALL wrk_dealloc( jpi, jpj, jpk, kjpt, zlap ) |
|---|
| 521 | CALL wrk_dealloc( jpi, jpj , kjpt, zglu, zglv ) |
|---|
| 522 | ! |
|---|
| 523 | IF( nn_timing == 1 ) CALL timing_stop('tra_ldf_iso_blp') |
|---|
| 524 | ! |
|---|
| 525 | END SUBROUTINE tra_ldf_iso_blp |
|---|
| 526 | |
|---|
| 527 | !!============================================================================== |
|---|
| 528 | END MODULE traldf_iso_triad |
|---|
