New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_lap.F90 in branches/2014/dev_CNRS0_NOC1_LDF/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2014/dev_CNRS0_NOC1_LDF/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_lap.F90 @ 4616

Last change on this file since 4616 was 4616, checked in by gm, 10 years ago

#1260 : see the associated wiki page for explanation
  • Property svn:keywords set to Id
File size: 11.6 KB
Line 
1MODULE traldf_lap
2   !!==============================================================================
3   !!                       ***  MODULE  traldf_lap  ***
4   !! Ocean tracers:  lateral diffusivity trend  (laplacian and bilaplacian)
5   !!==============================================================================
6   !! History :  OPA  ! 1987-06  (P. Andrich, D. L Hostis)  Original code
7   !!                 ! 1991-11  (G. Madec)
8   !!                 ! 1995-11  (G. Madec)  suppress volumetric scale factors
9   !!                 ! 1996-01  (G. Madec)  statement function for e3
10   !!            NEMO ! 2002-06  (G. Madec)  F90: Free form and module
11   !!            1.0  ! 2004-08  (C. Talandier) New trends organization
12   !!                 ! 2005-11  (G. Madec)  add zps case
13   !!            3.0  ! 2010-06  (C. Ethe, G. Madec) Merge TRA-TRC
14   !!            3.7  ! 2014-01  (G. Madec) re-entrant laplacian
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!   tra_ldf_lap   : update the tracer trend with the lateral diffusion : iso-level laplacian operator
19   !!   tra_ldf_bilap : update the tracer trend with the lateral diffusion : iso-level bilaplacian operator
20   !!----------------------------------------------------------------------
21   USE oce             ! ocean dynamics and active tracers
22   USE dom_oce         ! ocean space and time domain
23   USE ldftra          ! lateral physics: eddy diffusivity
24   USE diaptr          ! poleward transport diagnostics
25   USE trc_oce         ! share passive tracers/Ocean variables
26   USE zpshde          ! partial step: hor. derivative     (zps_hde routine)
27   !
28   USE in_out_manager  ! I/O manager
29   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
30   USE lib_mpp         ! distribued memory computing library
31   USE timing          ! Timing
32   USE wrk_nemo        ! Memory allocation
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   tra_ldf_lap   ! routine called by step.F90
38   PUBLIC   tra_ldf_blp   ! routine called by step.F90
39
40   !! * Substitutions
41#  include "domzgr_substitute.h90"
42#  include "vectopt_loop_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
45   !! $Id$
46   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE tra_ldf_lap( kt, kit000, cdtype, pgu, pgv, pahu, pahv,   &
51      &                                        ptb, pta, kjpt, kpass ) 
52      !!----------------------------------------------------------------------
53      !!                  ***  ROUTINE tra_ldf_lap  ***
54      !!                   
55      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
56      !!      trend and add it to the general trend of tracer equation.
57      !!
58      !! ** Method  :   Second order diffusive operator evaluated using before
59      !!      fields (forward time scheme). The horizontal diffusive trends of
60      !!      the tracer is given by:
61      !!          difft = 1/(e1e2t*e3t) {  di-1[ pahu e2u*e3u/e1u di(tb) ]
62      !!                                 + dj-1[ pahv e1v*e3v/e2v dj(tb) ] }
63      !!      Add this trend to the general tracer trend pta :
64      !!          pta = pta + difft
65      !!
66      !! ** Action  : - Update pta arrays with the before iso-level
67      !!                harmonic mixing trend.
68      !!----------------------------------------------------------------------
69      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
70      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
71      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
72      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
73      INTEGER                              , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
74      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
75      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
76      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
77      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
78      !
79      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
80      INTEGER  ::   iku, ikv         ! local integers
81      REAL(wp) ::   zsign            ! local scalars
82      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztu, ztv, zaheeu, zaheev
83      !!----------------------------------------------------------------------
84      !
85      IF( kt == nit000 .AND. lwp )  THEN
86         WRITE(numout,*)
87         WRITE(numout,*) 'tra_ldf_lap : iso-level laplacian diffusion on ', cdtype, ', pass=', kpass
88         WRITE(numout,*) '~~~~~~~~~~~ '
89      ENDIF
90      !
91      IF( nn_timing == 1 )  CALL timing_start('tra_ldf_lap')
92      !
93      CALL wrk_alloc( jpi, jpj, jpk, ztu, ztv, zaheeu, zaheev ) 
94      !
95      DO jk = 1, jpkm1           !==  Initialization of metric arrays used for all tracers  ==!
96         DO jj = 1, jpjm1
97            DO ji = 1, fs_jpim1   ! vector opt.
98               zaheeu(ji,jj,jk) = pahu(ji,jj,jk) * e2_e1u(ji,jj) * fse3u(ji,jj,jk)   !!gm   * umask(ji,jj,jk)
99               zaheev(ji,jj,jk) = pahv(ji,jj,jk) * e1_e2v(ji,jj) * fse3v(ji,jj,jk)   !!gm   * vmask(ji,jj,jk)
100            END DO
101         END DO
102      END DO
103      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign (eddy diffusivity >0)
104      ELSE                    ;   zsign = -1._wp
105      ENDIF
106      !
107      !                             ! =========== !
108      DO jn = 1, kjpt               ! tracer loop !
109         !                          ! =========== !   
110         !                               
111         DO jk = 1, jpkm1              !== First derivative (gradient)  ==!
112            DO jj = 1, jpjm1
113               DO ji = 1, fs_jpim1
114                  ztu(ji,jj,jk) = zaheeu(ji,jj,jk) * ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) )
115                  ztv(ji,jj,jk) = zaheev(ji,jj,jk) * ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
116               END DO
117            END DO
118         END DO 
119         IF( ln_zps ) THEN                ! set gradient at partial step level
120            DO jj = 1, jpjm1
121               DO ji = 1, fs_jpim1
122                  iku = mbku(ji,jj)             ! last level
123                  ikv = mbkv(ji,jj)
124                  ztu(ji,jj,iku) = zaheeu(ji,jj,iku) * pgu(ji,jj,jn)
125                  ztv(ji,jj,ikv) = zaheev(ji,jj,ikv) * pgv(ji,jj,jn)
126               END DO
127            END DO 
128         ENDIF
129         !
130         DO jk = 1, jpkm1              !== Second derivative (divergence) added to the general tracer trends  ==!
131            DO jj = 2, jpjm1
132               DO ji = fs_2, fs_jpim1
133                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk)     &
134                     &                                          + ztv(ji,jj,jk) - ztv(ji,jj-1,jk) )   &
135                     &                                        / ( e1e2t(ji,jj) * fse3t(ji,jj,jk) )
136               END DO
137            END DO
138         END DO 
139         !
140         !                             !== "Poleward" diffusive heat or salt transports  ==!
141         IF( ( kpass == 1 .AND. .NOT.ln_traldf_blp ) .OR.  &     !==  first pass only (  laplacian)  ==!
142             ( kpass == 2 .AND.      ln_traldf_blp ) ) THEN      !==  2nd   pass only (bilaplacian)  ==!
143            IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
144               IF( jn  == jp_tem)   htr_ldf(:) = ptr_vj( ztv(:,:,:) )
145               IF( jn  == jp_sal)   str_ldf(:) = ptr_vj( ztv(:,:,:) )
146            ENDIF
147         ENDIF
148         !                          ! ==================
149      END DO                        ! end of tracer loop
150      !                             ! ==================
151      !
152      CALL wrk_dealloc( jpi, jpj, jpk, ztu, ztv, zaheeu, zaheev ) 
153      !
154      IF( nn_timing == 1 )  CALL timing_stop('tra_ldf_lap')
155      !
156   END SUBROUTINE tra_ldf_lap
157   
158
159   SUBROUTINE tra_ldf_blp( kt, kit000, cdtype, pgu, pgv, pahu, pahv,   &
160      &                                        ptb, pta, kjpt        )
161      !!----------------------------------------------------------------------
162      !!                 ***  ROUTINE tra_ldf_blp  ***
163      !!                   
164      !! ** Purpose :   Compute the before horizontal tracer diffusive
165      !!      trend and add it to the general trend of tracer equation.
166      !!
167      !! ** Method  :   The lateral diffusive trends is provided by a bilaplacian
168      !!      operator applied to before field (forward in time).
169      !!      It is computed by two successive calls to tra_ldf_lap routine
170      !!
171      !! ** Action :   pta   updated with the before rotated bilaplacian diffusion
172      !!----------------------------------------------------------------------
173      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
174      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
175      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
176      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
177      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
178      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
179      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
180      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
181      !
182      INTEGER ::   ji, jj, jk, jn   ! dummy loop indices
183      REAL(wp), POINTER, DIMENSION(:,:,:,:) :: zlap         ! laplacian at t-point
184      REAL(wp), POINTER, DIMENSION(:,:,:)   :: zglu, zglv   ! gradient of the laplacian at partial step level (u- and v-points)
185      !!----------------------------------------------------------------------
186      !
187      IF( nn_timing == 1 )  CALL timing_start('tra_ldf_iso_blp')
188      !
189      CALL wrk_alloc( jpi, jpj, jpk, kjpt, zlap ) 
190      CALL wrk_alloc( jpi, jpj     , kjpt, zglu, zglv ) 
191      !
192      IF( kt == nit000 )  THEN
193         IF(lwp) WRITE(numout,*)
194         IF(lwp) WRITE(numout,*) 'tra_ldf_iso_blp : iso-neutral biharmonic operator on ', cdtype
195         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~'
196      ENDIF
197
198      zlap(:,:,:,:) = 0._wp
199      CALL tra_ldf_lap( kt, kit000, cdtype, pgu, pgv, pahu, pahv, ptb, zlap, kjpt, 1 )   ! rotated laplacian applied to ptb (output in zlap)
200      !
201      DO jn = 1, kjpt
202         CALL lbc_lnk( zlap(:,:,:,jn) , 'T', 1. )                     ! Lateral boundary conditions (unchanged sign)
203      END DO
204      !
205      IF( ln_zps )   CALL zps_hde( kt, jpts, zlap, zglu, zglv )       ! Partial steps: hor. gradient of laplacian at the partial step level     
206      !
207      CALL tra_ldf_lap( kt, kit000, cdtype, pgu, pgv, pahu, pahv, zlap, pta, kjpt, 2 )   ! rotated laplacian applied to zlap (output in pta)
208      !
209      CALL wrk_dealloc( jpi, jpj, jpk, kjpt, zlap ) 
210      CALL wrk_dealloc( jpi, jpj     , kjpt, zglu, zglv ) 
211      !
212      IF( nn_timing == 1 )  CALL timing_stop('tra_ldf_iso_blp')
213      !
214   END SUBROUTINE tra_ldf_blp
215
216   !!==============================================================================
217END MODULE traldf_lap
Note: See TracBrowser for help on using the repository browser.