New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zpshde.F90 in branches/2014/dev_CNRS0_NOC1_LDF/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2014/dev_CNRS0_NOC1_LDF/NEMOGCM/NEMO/OPA_SRC/TRA/zpshde.F90 @ 4596

Last change on this file since 4596 was 4596, checked in by gm, 10 years ago

#1260: LDF simplification + bilap iso-neutral for TRA and GYRE
  • Property svn:keywords set to Id
File size: 10.9 KB
Line 
1MODULE zpshde
2   !!======================================================================
3   !!                       ***  MODULE zpshde   ***
4   !! z-coordinate + partial step : Horizontal Derivative at ocean bottom level
5   !!======================================================================
6   !! History :  OPA  !  2002-04  (A. Bozec)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec E. Durand)  Optimization and Free form
8   !!             -   !  2004-03  (C. Ethe)  adapted for passive tracers
9   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
10   !!======================================================================
11   
12   !!----------------------------------------------------------------------
13   !!   zps_hde      :  Horizontal DErivative of T, S and rd at the last
14   !!                   ocean level (Z-coord. with Partial Steps)
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean: dynamics and tracers variables
17   USE dom_oce         ! domain: ocean variables
18   USE phycst          ! physical constants
19   USE eosbn2          ! ocean equation of state
20   !
21   USE in_out_manager  ! I/O manager
22   USE lbclnk          ! lateral boundary conditions (or mpp link)
23   USE lib_mpp         ! MPP library
24   USE wrk_nemo        ! Memory allocation
25   USE timing          ! Timing
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   zps_hde    ! routine called by step.F90
31
32   !! * Substitutions
33#  include "domzgr_substitute.h90"
34#  include "vectopt_loop_substitute.h90"
35   !!----------------------------------------------------------------------
36   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
37   !! $Id$
38   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE zps_hde( kt, kjpt, pta, pgtu, pgtv,   &
43      &                          prd, pgru, pgrv    )
44      !!----------------------------------------------------------------------
45      !!                     ***  ROUTINE zps_hde  ***
46      !!                   
47      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
48      !!      at u- and v-points with a linear interpolation for z-coordinate
49      !!      with partial steps.
50      !!
51      !! ** Method  :   In z-coord with partial steps, scale factors on last
52      !!      levels are different for each grid point, so that T, S and rd
53      !!      points are not at the same depth as in z-coord. To have horizontal
54      !!      gradients again, we interpolate T and S at the good depth :
55      !!      Linear interpolation of T, S   
56      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
57      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
58      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
59      !!         This formulation computes the two cases:
60      !!                 CASE 1                   CASE 2 
61      !!         k-1  ___ ___________   k-1   ___ ___________
62      !!                    Ti  T~                  T~  Ti+1
63      !!                  _____                        _____
64      !!         k        |   |Ti+1     k           Ti |   |
65      !!                  |   |____                ____|   |
66      !!              ___ |   |   |           ___  |   |   |
67      !!                 
68      !!      case 1->   e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then
69      !!          t~ = t(i+1,j  ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1)
70      !!        ( t~ = t(i  ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1)  )
71      !!          or
72      !!      case 2->   e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then
73      !!          t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i )
74      !!        ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) )
75      !!          Idem for di(s) and dj(s)         
76      !!
77      !!      For rho, we call eos_insitu_2d which will compute rd~(t~,s~) at
78      !!      the good depth zh from interpolated T and S for the different
79      !!      formulation of the equation of state (eos).
80      !!      Gradient formulation for rho :
81      !!          di(rho) = rd~ - rd(i,j,k) or rd(i+1,j,k) - rd~
82      !!
83      !! ** Action  : - pgtu, pgtv: horizontal gradient of tracer at u- & v-points
84      !!              - pgru, pgrv: horizontal gradient of rho (if present) at u- & v-points
85      !!----------------------------------------------------------------------
86      INTEGER                              , INTENT(in   )           ::  kt          ! ocean time-step index
87      INTEGER                              , INTENT(in   )           ::  kjpt        ! number of tracers
88      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   )           ::  pta         ! 4D tracers fields
89      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
90      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ), OPTIONAL ::  prd         ! 3D density anomaly fields
91      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgru, pgrv  ! hor. grad. of prd at u- & v-pts
92      !
93      INTEGER  ::   ji, jj, jn      ! Dummy loop indices
94      INTEGER  ::   iku, ikv, ikum1, ikvm1   ! partial step level (ocean bottom level) at u- and v-points
95      REAL(wp) ::  ze3wu, ze3wv, zmaxu, zmaxv  ! temporary scalars
96      REAL(wp), POINTER, DIMENSION(:,:  ) ::  zri, zrj, zhi, zhj
97      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zti, ztj    ! interpolated value of tracer
98      !!----------------------------------------------------------------------
99      !
100      IF( nn_timing == 1 )  CALL timing_start( 'zps_hde')
101      !
102      CALL wrk_alloc( jpi, jpj,       zri, zrj, zhi, zhj ) 
103      CALL wrk_alloc( jpi, jpj, kjpt, zti, ztj           ) 
104      !
105      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
106         !
107# if defined key_vectopt_loop
108         jj = 1
109         DO ji = 1, jpij-jpi   ! vector opt. (forced unrolled)
110# else
111         DO jj = 1, jpjm1
112            DO ji = 1, jpim1
113# endif
114               iku = mbku(ji,jj)   ;   ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
115               ikv = mbkv(ji,jj)   ;   ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
116               ze3wu = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
117               ze3wv = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
118               !
119               ! i- direction
120               IF( ze3wu >= 0._wp ) THEN      ! case 1
121                  zmaxu =  ze3wu / fse3w(ji+1,jj,iku)
122                  ! interpolated values of tracers
123                  zti(ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
124                  ! gradient of  tracers
125                  pgtu(ji,jj,jn) = umask(ji,jj,1) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
126               ELSE                           ! case 2
127                  zmaxu = -ze3wu / fse3w(ji,jj,iku)
128                  ! interpolated values of tracers
129                  zti(ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
130                  ! gradient of tracers
131                  pgtu(ji,jj,jn) = umask(ji,jj,1) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
132               ENDIF
133               !
134               ! j- direction
135               IF( ze3wv >= 0._wp ) THEN      ! case 1
136                  zmaxv =  ze3wv / fse3w(ji,jj+1,ikv)
137                  ! interpolated values of tracers
138                  ztj(ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
139                  ! gradient of tracers
140                  pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
141               ELSE                           ! case 2
142                  zmaxv =  -ze3wv / fse3w(ji,jj,ikv)
143                  ! interpolated values of tracers
144                  ztj(ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
145                  ! gradient of tracers
146                  pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
147               ENDIF
148# if ! defined key_vectopt_loop
149            END DO
150# endif
151         END DO
152         CALL lbc_lnk( pgtu(:,:,jn), 'U', -1. )   ;   CALL lbc_lnk( pgtv(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
153         !
154      END DO
155
156      ! horizontal derivative of density anomalies (rd)
157      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
158# if defined key_vectopt_loop
159         jj = 1
160         DO ji = 1, jpij-jpi   ! vector opt. (forced unrolled)
161# else
162         DO jj = 1, jpjm1
163            DO ji = 1, jpim1
164# endif
165               iku = mbku(ji,jj)
166               ikv = mbkv(ji,jj)
167               ze3wu  = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
168               ze3wv  = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
169               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = fsdept(ji  ,jj,iku)     ! i-direction: case 1
170               ELSE                        ;   zhi(ji,jj) = fsdept(ji+1,jj,iku)     ! -     -      case 2
171               ENDIF
172               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = fsdept(ji,jj  ,ikv)     ! j-direction: case 1
173               ELSE                        ;   zhj(ji,jj) = fsdept(ji,jj+1,ikv)     ! -     -      case 2
174               ENDIF
175# if ! defined key_vectopt_loop
176            END DO
177# endif
178         END DO
179
180         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
181         ! step and store it in  zri, zrj for each  case
182         CALL eos( zti, zhi, zri ) 
183         CALL eos( ztj, zhj, zrj )
184
185         ! Gradient of density at the last level
186# if defined key_vectopt_loop
187         jj = 1
188         DO ji = 1, jpij-jpi   ! vector opt. (forced unrolled)
189# else
190         DO jj = 1, jpjm1
191            DO ji = 1, jpim1
192# endif
193               iku = mbku(ji,jj)
194               ikv = mbkv(ji,jj)
195               ze3wu  = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
196               ze3wv  = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
197               IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = umask(ji,jj,1) * ( zri(ji  ,jj) - prd(ji,jj,iku) )   ! i: 1
198               ELSE                        ;   pgru(ji,jj) = umask(ji,jj,1) * ( prd(ji+1,jj,iku) - zri(ji,jj) )   ! i: 2
199               ENDIF
200               IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( zrj(ji,jj  ) - prd(ji,jj,ikv) )   ! j: 1
201               ELSE                        ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( prd(ji,jj+1,ikv) - zrj(ji,jj) )   ! j: 2
202               ENDIF
203# if ! defined key_vectopt_loop
204            END DO
205# endif
206         END DO
207         CALL lbc_lnk( pgru , 'U', -1. )   ;   CALL lbc_lnk( pgrv , 'V', -1. )   ! Lateral boundary conditions
208         !
209      END IF
210      !
211      CALL wrk_dealloc( jpi, jpj,       zri, zrj, zhi, zhj ) 
212      CALL wrk_dealloc( jpi, jpj, kjpt, zti, ztj           ) 
213      !
214      IF( nn_timing == 1 )  CALL timing_stop( 'zps_hde')
215      !
216   END SUBROUTINE zps_hde
217
218   !!======================================================================
219END MODULE zpshde
Note: See TracBrowser for help on using the repository browser.