New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfgls.F90 in branches/2014/dev_CNRS0_NOC1_LDF/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: branches/2014/dev_CNRS0_NOC1_LDF/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfgls.F90 @ 4616

Last change on this file since 4616 was 4616, checked in by gm, 10 years ago

#1260 : see the associated wiki page for explanation
  • Property svn:keywords set to Id
File size: 61.0 KB
Line 
1MODULE zdfgls
2   !!======================================================================
3   !!                       ***  MODULE  zdfgls  ***
4   !! Ocean physics:  vertical mixing coefficient computed from the gls
5   !!                 turbulent closure parameterization
6   !!======================================================================
7   !! History :   3.0  !  2009-09  (G. Reffray)  Original code
8   !!             3.3  !  2010-10  (C. Bricaud)  Add in the reference
9   !!----------------------------------------------------------------------
10#if defined key_zdfgls   ||   defined key_esopa
11   !!----------------------------------------------------------------------
12   !!   'key_zdfgls'                 Generic Length Scale vertical physics
13   !!----------------------------------------------------------------------
14   !!   zdf_gls       : update momentum and tracer Kz from a gls scheme
15   !!   zdf_gls_init  : initialization, namelist read, and parameters control
16   !!   gls_rst       : read/write gls restart in ocean restart file
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   USE domvvl         ! ocean space and time domain : variable volume layer
21   USE zdf_oce        ! ocean vertical physics
22   USE sbc_oce        ! surface boundary condition: ocean
23   USE phycst         ! physical constants
24   USE zdfmxl         ! mixed layer
25   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
26   USE lib_mpp        ! MPP manager
27   USE wrk_nemo       ! work arrays
28   USE prtctl         ! Print control
29   USE in_out_manager ! I/O manager
30   USE iom            ! I/O manager library
31   USE timing         ! Timing
32   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   zdf_gls        ! routine called in step module
38   PUBLIC   zdf_gls_init   ! routine called in opa module
39   PUBLIC   gls_rst        ! routine called in step module
40
41   LOGICAL , PUBLIC, PARAMETER ::   lk_zdfgls = .TRUE.   !: TKE vertical mixing flag
42   !
43   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   en      !: now turbulent kinetic energy
44   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   mxln    !: now mixing length
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   zwall   !: wall function
46   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   avt_k   ! not enhanced Kz
47   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   avm_k   ! not enhanced Kz
48   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   avmu_k  ! not enhanced Kz
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   avmv_k  ! not enhanced Kz
50   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustars2 !: Squared surface velocity scale at T-points
51   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustarb2 !: Squared bottom  velocity scale at T-points
52
53   !                              !! ** Namelist  namzdf_gls  **
54   LOGICAL  ::   ln_crban          ! =T use Craig and Banner scheme
55   LOGICAL  ::   ln_length_lim     ! use limit on the dissipation rate under stable stratification (Galperin et al. 1988)
56   LOGICAL  ::   ln_sigpsi         ! Activate Burchard (2003) modification for k-eps closure & wave breaking mixing
57   INTEGER  ::   nn_tkebc_surf     ! TKE surface boundary condition (=0/1)
58   INTEGER  ::   nn_tkebc_bot      ! TKE bottom boundary condition (=0/1)
59   INTEGER  ::   nn_psibc_surf     ! PSI surface boundary condition (=0/1)
60   INTEGER  ::   nn_psibc_bot      ! PSI bottom boundary condition (=0/1)
61   INTEGER  ::   nn_stab_func      ! stability functions G88, KC or Canuto (=0/1/2)
62   INTEGER  ::   nn_clos           ! closure 0/1/2/3 MY82/k-eps/k-w/gen
63   REAL(wp) ::   rn_clim_galp      ! Holt 2008 value for k-eps: 0.267
64   REAL(wp) ::   rn_epsmin         ! minimum value of dissipation (m2/s3)
65   REAL(wp) ::   rn_emin           ! minimum value of TKE (m2/s2)
66   REAL(wp) ::   rn_charn          ! Charnock constant for surface breaking waves mixing : 1400. (standard) or 2.e5 (Stacey value)
67   REAL(wp) ::   rn_crban          ! Craig and Banner constant for surface breaking waves mixing
68
69   REAL(wp) ::   hsro          =  0.003_wp    ! Minimum surface roughness
70   REAL(wp) ::   hbro          =  0.003_wp    ! Bottom roughness (m)
71   REAL(wp) ::   rcm_sf        =  0.73_wp     ! Shear free turbulence parameters
72   REAL(wp) ::   ra_sf         = -2.0_wp      ! Must be negative -2 < ra_sf < -1
73   REAL(wp) ::   rl_sf         =  0.2_wp      ! 0 <rl_sf<vkarmn   
74   REAL(wp) ::   rghmin        = -0.28_wp
75   REAL(wp) ::   rgh0          =  0.0329_wp
76   REAL(wp) ::   rghcri        =  0.03_wp
77   REAL(wp) ::   ra1           =  0.92_wp
78   REAL(wp) ::   ra2           =  0.74_wp
79   REAL(wp) ::   rb1           = 16.60_wp
80   REAL(wp) ::   rb2           = 10.10_wp         
81   REAL(wp) ::   re2           =  1.33_wp         
82   REAL(wp) ::   rl1           =  0.107_wp
83   REAL(wp) ::   rl2           =  0.0032_wp
84   REAL(wp) ::   rl3           =  0.0864_wp
85   REAL(wp) ::   rl4           =  0.12_wp
86   REAL(wp) ::   rl5           = 11.9_wp
87   REAL(wp) ::   rl6           =  0.4_wp
88   REAL(wp) ::   rl7           =  0.0_wp
89   REAL(wp) ::   rl8           =  0.48_wp
90   REAL(wp) ::   rm1           =  0.127_wp
91   REAL(wp) ::   rm2           =  0.00336_wp
92   REAL(wp) ::   rm3           =  0.0906_wp
93   REAL(wp) ::   rm4           =  0.101_wp
94   REAL(wp) ::   rm5           = 11.2_wp
95   REAL(wp) ::   rm6           =  0.4_wp
96   REAL(wp) ::   rm7           =  0.0_wp
97   REAL(wp) ::   rm8           =  0.318_wp
98   
99   REAL(wp) ::   rc02, rc02r, rc03, rc04                          ! coefficients deduced from above parameters
100   REAL(wp) ::   rc03_sqrt2_galp                                  !     -           -           -        -
101   REAL(wp) ::   rsbc_tke1, rsbc_tke2, rsbc_tke3, rfact_tke       !     -           -           -        -
102   REAL(wp) ::   rsbc_psi1, rsbc_psi2, rsbc_psi3, rfact_psi       !     -           -           -        -
103   REAL(wp) ::   rsbc_mb  , rsbc_std , rsbc_zs                    !     -           -           -        -
104   REAL(wp) ::   rc0, rc2, rc3, rf6, rcff, rc_diff                !     -           -           -        -
105   REAL(wp) ::   rs0, rs1, rs2, rs4, rs5, rs6                     !     -           -           -        -
106   REAL(wp) ::   rd0, rd1, rd2, rd3, rd4, rd5                     !     -           -           -        -
107   REAL(wp) ::   rsc_tke, rsc_psi, rpsi1, rpsi2, rpsi3, rsc_psi0  !     -           -           -        -
108   REAL(wp) ::   rpsi3m, rpsi3p, rpp, rmm, rnn                    !     -           -           -        -
109
110   !! * Substitutions
111#  include "domzgr_substitute.h90"
112#  include "vectopt_loop_substitute.h90"
113   !!----------------------------------------------------------------------
114   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
115   !! $Id$
116   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
117   !!----------------------------------------------------------------------
118CONTAINS
119
120   INTEGER FUNCTION zdf_gls_alloc()
121      !!----------------------------------------------------------------------
122      !!                ***  FUNCTION zdf_gls_alloc  ***
123      !!----------------------------------------------------------------------
124      ALLOCATE( en(jpi,jpj,jpk),  mxln(jpi,jpj,jpk), zwall(jpi,jpj,jpk) ,     &
125         &      avt_k (jpi,jpj,jpk) , avm_k (jpi,jpj,jpk),                    &
126         &      avmu_k(jpi,jpj,jpk) , avmv_k(jpi,jpj,jpk),                    &
127         &      ustars2(jpi,jpj), ustarb2(jpi,jpj)                      , STAT= zdf_gls_alloc )
128         !
129      IF( lk_mpp             )   CALL mpp_sum ( zdf_gls_alloc )
130      IF( zdf_gls_alloc /= 0 )   CALL ctl_warn('zdf_gls_alloc: failed to allocate arrays')
131   END FUNCTION zdf_gls_alloc
132
133
134   SUBROUTINE zdf_gls( kt )
135      !!----------------------------------------------------------------------
136      !!                   ***  ROUTINE zdf_gls  ***
137      !!
138      !! ** Purpose :   Compute the vertical eddy viscosity and diffusivity
139      !!              coefficients using the GLS turbulent closure scheme.
140      !!----------------------------------------------------------------------
141      INTEGER, INTENT(in) ::   kt ! ocean time step
142      INTEGER  ::   ji, jj, jk, ibot, ibotm1, dir  ! dummy loop arguments
143      REAL(wp) ::   zesh2, zsigpsi, zcoef, zex1, zex2   ! local scalars
144      REAL(wp) ::   ztx2, zty2, zup, zdown, zcof        !   -      -
145      REAL(wp) ::   zratio, zrn2, zflxb, sh             !   -      -
146      REAL(wp) ::   prod, buoy, diss, zdiss, sm         !   -      -
147      REAL(wp) ::   gh, gm, shr, dif, zsqen, zav        !   -      -
148      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zdep
149      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zflxs       ! Turbulence fluxed induced by internal waves
150      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zhsro       ! Surface roughness (surface waves)
151      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eb          ! tke at time before
152      REAL(wp), POINTER, DIMENSION(:,:,:) ::   mxlb        ! mixing length at time before
153      REAL(wp), POINTER, DIMENSION(:,:,:) ::   shear       ! vertical shear
154      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eps         ! dissipation rate
155      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwall_psi   ! Wall function use in the wb case (ln_sigpsi.AND.ln_crban=T)
156      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_a, z_elem_b, z_elem_c, psi
157      !!--------------------------------------------------------------------
158      !
159      IF( nn_timing == 1 )  CALL timing_start('zdf_gls')
160      !
161      CALL wrk_alloc( jpi,jpj, zdep, zflxs, zhsro )
162      CALL wrk_alloc( jpi,jpj,jpk, eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi )
163
164      ! Preliminary computing
165
166      ustars2 = 0._wp   ;   ustarb2 = 0._wp   ;   psi  = 0._wp   ;   zwall_psi = 0._wp
167
168      IF( kt /= nit000 ) THEN   ! restore before value to compute tke
169         avt (:,:,:) = avt_k (:,:,:)
170         avm (:,:,:) = avm_k (:,:,:)
171         avmu(:,:,:) = avmu_k(:,:,:)
172         avmv(:,:,:) = avmv_k(:,:,:) 
173      ENDIF
174
175      ! Compute surface and bottom friction at T-points
176      DO jj = 2, jpjm1
177         DO ji = fs_2, fs_jpim1   ! vector opt.
178            !
179            ! surface friction
180            ustars2(ji,jj) = r1_rau0 * taum(ji,jj) * tmask(ji,jj,1)
181            !
182            ! bottom friction (explicit before friction)
183            ! Note that we chose here not to bound the friction as in dynbfr)
184            ztx2 = (  bfrua(ji,jj)  * ub(ji,jj,mbku(ji,jj)) + bfrua(ji-1,jj) * ub(ji-1,jj,mbku(ji-1,jj))  )   &
185               & * ( 1._wp - 0.5_wp * umask(ji,jj,1) * umask(ji-1,jj,1)  )
186            zty2 = (  bfrva(ji,jj)  * vb(ji,jj,mbkv(ji,jj)) + bfrva(ji,jj-1) * vb(ji,jj-1,mbkv(ji,jj-1))  )   &
187               & * ( 1._wp - 0.5_wp * vmask(ji,jj,1) * vmask(ji,jj-1,1)  )
188            ustarb2(ji,jj) = SQRT( ztx2 * ztx2 + zty2 * zty2 ) * tmask(ji,jj,1)
189         END DO
190      END DO 
191
192      ! In case of breaking surface waves mixing,
193      ! Compute surface roughness length according to Charnock formula:
194      IF( ln_crban ) THEN   ;   zhsro(:,:) = MAX(rsbc_zs * ustars2(:,:), hsro)
195      ELSE                  ;   zhsro(:,:) = hsro
196      ENDIF
197
198      ! Compute shear and dissipation rate
199      DO jk = 2, jpkm1
200         DO jj = 2, jpjm1
201            DO ji = fs_2, fs_jpim1   ! vector opt.
202               avmu(ji,jj,jk) = avmu(ji,jj,jk) * ( un(ji,jj,jk-1) - un(ji,jj,jk) )   &
203                  &                            * ( ub(ji,jj,jk-1) - ub(ji,jj,jk) )   &
204                  &                            / (  fse3uw_n(ji,jj,jk)               &
205                  &                            *    fse3uw_b(ji,jj,jk) )
206               avmv(ji,jj,jk) = avmv(ji,jj,jk) * ( vn(ji,jj,jk-1) - vn(ji,jj,jk) )   &
207                  &                            * ( vb(ji,jj,jk-1) - vb(ji,jj,jk) )   &
208                  &                            / (  fse3vw_n(ji,jj,jk)               &
209                  &                            *    fse3vw_b(ji,jj,jk) )
210               eps(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT(en(ji,jj,jk)) / mxln(ji,jj,jk)
211            END DO
212         END DO
213      END DO
214      !
215      ! Lateral boundary conditions (avmu,avmv) (sign unchanged)
216      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )
217
218      ! Save tke at before time step
219      eb  (:,:,:) = en  (:,:,:)
220      mxlb(:,:,:) = mxln(:,:,:)
221
222      IF( nn_clos == 0 ) THEN    ! Mellor-Yamada
223         DO jk = 2, jpkm1
224            DO jj = 2, jpjm1 
225               DO ji = fs_2, fs_jpim1   ! vector opt.
226                  zup   = mxln(ji,jj,jk) * fsdepw(ji,jj,mbkt(ji,jj)+1)
227                  zdown = vkarmn * fsdepw(ji,jj,jk) * ( -fsdepw(ji,jj,jk) + fsdepw(ji,jj,mbkt(ji,jj)+1) )
228                  zcoef = ( zup / MAX( zdown, rsmall ) )
229                  zwall (ji,jj,jk) = ( 1._wp + re2 * zcoef*zcoef ) * tmask(ji,jj,jk)
230               END DO
231            END DO
232         END DO
233      ENDIF
234
235      !!---------------------------------!!
236      !!   Equation to prognostic k      !!
237      !!---------------------------------!!
238      !
239      ! Now Turbulent kinetic energy (output in en)
240      ! -------------------------------
241      ! Resolution of a tridiagonal linear system by a "methode de chasse"
242      ! computation from level 2 to jpkm1  (e(1) computed after and e(jpk)=0 ).
243      ! The surface boundary condition are set after
244      ! The bottom boundary condition are also set after. In standard e(bottom)=0.
245      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
246      ! Warning : after this step, en : right hand side of the matrix
247
248      DO jk = 2, jpkm1
249         DO jj = 2, jpjm1
250            DO ji = fs_2, fs_jpim1   ! vector opt.
251               !
252               ! shear prod. at w-point weightened by mask
253               shear(ji,jj,jk) =  ( avmu(ji-1,jj,jk) + avmu(ji,jj,jk) ) / MAX( 1.e0 , umask(ji-1,jj,jk) + umask(ji,jj,jk) )   &
254                  &             + ( avmv(ji,jj-1,jk) + avmv(ji,jj,jk) ) / MAX( 1.e0 , vmask(ji,jj-1,jk) + vmask(ji,jj,jk) )
255               !
256               ! stratif. destruction
257               buoy = - avt(ji,jj,jk) * rn2(ji,jj,jk)
258               !
259               ! shear prod. - stratif. destruction
260               diss = eps(ji,jj,jk)
261               !
262               dir = 0.5_wp + SIGN( 0.5_wp, shear(ji,jj,jk) + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
263               !
264               zesh2 = dir*(shear(ji,jj,jk)+buoy)+(1._wp-dir)*shear(ji,jj,jk)          ! production term
265               zdiss = dir*(diss/en(ji,jj,jk))   +(1._wp-dir)*(diss-buoy)/en(ji,jj,jk) ! dissipation term
266               !
267               ! Compute a wall function from 1. to rsc_psi*zwall/rsc_psi0
268               ! Note that as long that Dirichlet boundary conditions are NOT set at the first and last levels (GOTM style)
269               ! there is no need to set a boundary condition for zwall_psi at the top and bottom boundaries.
270               ! Otherwise, this should be rsc_psi/rsc_psi0
271               IF( ln_sigpsi ) THEN
272                  zsigpsi = MIN( 1._wp, zesh2 / eps(ji,jj,jk) )     ! 0. <= zsigpsi <= 1.
273                  zwall_psi(ji,jj,jk) = rsc_psi /   & 
274                     &     (  zsigpsi * rsc_psi + (1._wp-zsigpsi) * rsc_psi0 / MAX( zwall(ji,jj,jk), 1._wp )  )
275               ELSE
276                  zwall_psi(ji,jj,jk) = 1._wp
277               ENDIF
278               !
279               ! building the matrix
280               zcof = rfact_tke * tmask(ji,jj,jk)
281               !
282               ! lower diagonal
283               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
284                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
285               !
286               ! upper diagonal
287               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
288                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
289               !
290               ! diagonal
291               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
292                  &                       + rdt * zdiss * tmask(ji,jj,jk) 
293               !
294               ! right hand side in en
295               en(ji,jj,jk) = en(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
296            END DO
297         END DO
298      END DO
299      !
300      z_elem_b(:,:,jpk) = 1._wp
301      !
302      ! Set surface condition on zwall_psi (1 at the bottom)
303      IF( ln_sigpsi ) THEN
304         zcoef = rsc_psi / rsc_psi0
305         DO jj = 2, jpjm1
306            DO ji = fs_2, fs_jpim1   ! vector opt.
307               zwall_psi(ji,jj,1) = zcoef
308            END DO
309         END DO
310      ENDIF
311
312      ! Surface boundary condition on tke
313      ! ---------------------------------
314      !
315      SELECT CASE ( nn_tkebc_surf )
316      !
317      CASE ( 0 )             ! Dirichlet case
318         !
319         IF (ln_crban) THEN     ! Wave induced mixing case
320            !                      ! en(1) = q2(1) = 0.5 * (15.8 * Ccb)^(2/3) * u*^2
321            !                      ! balance between the production and the dissipation terms including the wave effect
322            en(:,:,1) = MAX( rsbc_tke1 * ustars2(:,:), rn_emin )
323            z_elem_a(:,:,1) = en(:,:,1)
324            z_elem_c(:,:,1) = 0._wp
325            z_elem_b(:,:,1) = 1._wp
326            !
327            ! one level below
328            en(:,:,2) = MAX( rsbc_tke1 * ustars2(:,:) * ( (zhsro(:,:)+fsdepw(:,:,2))/zhsro(:,:) )**ra_sf, rn_emin )
329            z_elem_a(:,:,2) = 0._wp
330            z_elem_c(:,:,2) = 0._wp
331            z_elem_b(:,:,2) = 1._wp
332            !
333         ELSE                   ! No wave induced mixing case
334            !                      ! en(1) = u*^2/C0^2  &  l(1)  = K*zs
335            !                      ! balance between the production and the dissipation terms
336            en(:,:,1) = MAX( rc02r * ustars2(:,:), rn_emin )
337            z_elem_a(:,:,1) = en(:,:,1) 
338            z_elem_c(:,:,1) = 0._wp
339            z_elem_b(:,:,1) = 1._wp
340            !
341            ! one level below
342            en(:,:,2) = MAX( rc02r * ustars2(:,:), rn_emin )
343            z_elem_a(:,:,2) = 0._wp
344            z_elem_c(:,:,2) = 0._wp
345            z_elem_b(:,:,2) = 1._wp
346            !
347         ENDIF
348         !
349      CASE ( 1 )             ! Neumann boundary condition on d(e)/dz
350         !
351         IF (ln_crban) THEN ! Shear free case: d(e)/dz= Fw
352            !
353            ! Dirichlet conditions at k=1 (Cosmetic)
354            en(:,:,1) = MAX( rsbc_tke1 * ustars2(:,:), rn_emin )
355            z_elem_a(:,:,1) = en(:,:,1)
356            z_elem_c(:,:,1) = 0._wp
357            z_elem_b(:,:,1) = 1._wp
358            ! at k=2, set de/dz=Fw
359            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
360            z_elem_a(:,:,2) = 0._wp       
361            zflxs(:,:) = rsbc_tke3 * ustars2(:,:)**1.5_wp * ( (zhsro(:,:)+fsdept(:,:,1) ) / zhsro(:,:) )**(1.5*ra_sf)
362            en(:,:,2) = en(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
363            !
364         ELSE                   ! No wave induced mixing case: d(e)/dz=0.
365            !
366            ! Dirichlet conditions at k=1 (Cosmetic)
367            en(:,:,1) = MAX( rc02r * ustars2(:,:), rn_emin )
368            z_elem_a(:,:,1) = en(:,:,1)
369            z_elem_c(:,:,1) = 0._wp
370            z_elem_b(:,:,1) = 1._wp
371            ! at k=2 set de/dz=0.:
372            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2)  ! Remove z_elem_a from z_elem_b
373            z_elem_a(:,:,2) = 0._wp
374            !
375         ENDIF
376         !
377      END SELECT
378
379      ! Bottom boundary condition on tke
380      ! --------------------------------
381      !
382      SELECT CASE ( nn_tkebc_bot )
383      !
384      CASE ( 0 )             ! Dirichlet
385         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = rn_lmin
386         !                      ! Balance between the production and the dissipation terms
387         DO jj = 2, jpjm1
388            DO ji = fs_2, fs_jpim1   ! vector opt.
389               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
390               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
391               !
392               ! Bottom level Dirichlet condition:
393               z_elem_a(ji,jj,ibot  ) = 0._wp
394               z_elem_c(ji,jj,ibot  ) = 0._wp
395               z_elem_b(ji,jj,ibot  ) = 1._wp
396               en(ji,jj,ibot  ) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
397               !
398               ! Just above last level, Dirichlet condition again
399               z_elem_a(ji,jj,ibotm1) = 0._wp
400               z_elem_c(ji,jj,ibotm1) = 0._wp
401               z_elem_b(ji,jj,ibotm1) = 1._wp
402               en(ji,jj,ibotm1) = MAX( rc02r * ustarb2(ji,jj), rn_emin ) 
403            END DO
404         END DO
405         !
406      CASE ( 1 )             ! Neumman boundary condition
407         !                     
408         DO jj = 2, jpjm1
409            DO ji = fs_2, fs_jpim1   ! vector opt.
410               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
411               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
412               !
413               ! Bottom level Dirichlet condition:
414               z_elem_a(ji,jj,ibot) = 0._wp
415               z_elem_c(ji,jj,ibot) = 0._wp
416               z_elem_b(ji,jj,ibot) = 1._wp
417               en(ji,jj,ibot) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
418               !
419               ! Just above last level: Neumann condition
420               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1)   ! Remove z_elem_c from z_elem_b
421               z_elem_c(ji,jj,ibotm1) = 0._wp
422            END DO
423         END DO
424         !
425      END SELECT
426
427      ! Matrix inversion (en prescribed at surface and the bottom)
428      ! ----------------------------------------------------------
429      !
430      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
431         DO jj = 2, jpjm1
432            DO ji = fs_2, fs_jpim1    ! vector opt.
433               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
434            END DO
435         END DO
436      END DO
437      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
438         DO jj = 2, jpjm1
439            DO ji = fs_2, fs_jpim1    ! vector opt.
440               z_elem_a(ji,jj,jk) = en(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
441            END DO
442         END DO
443      END DO
444      DO jk = jpk-1, 2, -1                         ! thrid recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
445         DO jj = 2, jpjm1
446            DO ji = fs_2, fs_jpim1    ! vector opt.
447               en(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * en(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
448            END DO
449         END DO
450      END DO
451      !                                            ! set the minimum value of tke
452      en(:,:,:) = MAX( en(:,:,:), rn_emin )
453     
454      !!----------------------------------------!!
455      !!   Solve prognostic equation for psi    !!
456      !!----------------------------------------!!
457
458      ! Set psi to previous time step value
459      !
460      SELECT CASE ( nn_clos )
461      !
462      CASE( 0 )               ! k-kl  (Mellor-Yamada)
463         DO jk = 2, jpkm1
464            DO jj = 2, jpjm1
465               DO ji = fs_2, fs_jpim1   ! vector opt.
466                  psi(ji,jj,jk)  = eb(ji,jj,jk) * mxlb(ji,jj,jk)
467               END DO
468            END DO
469         END DO
470         !
471      CASE( 1 )               ! k-eps
472         DO jk = 2, jpkm1
473            DO jj = 2, jpjm1
474               DO ji = fs_2, fs_jpim1   ! vector opt.
475                  psi(ji,jj,jk)  = eps(ji,jj,jk)
476               END DO
477            END DO
478         END DO
479         !
480      CASE( 2 )               ! k-w
481         DO jk = 2, jpkm1
482            DO jj = 2, jpjm1
483               DO ji = fs_2, fs_jpim1   ! vector opt.
484                  psi(ji,jj,jk)  = SQRT( eb(ji,jj,jk) ) / ( rc0 * mxlb(ji,jj,jk) )
485               END DO
486            END DO
487         END DO
488         !
489      CASE( 3 )               ! generic
490         DO jk = 2, jpkm1
491            DO jj = 2, jpjm1
492               DO ji = fs_2, fs_jpim1   ! vector opt.
493                  psi(ji,jj,jk)  = rc02 * eb(ji,jj,jk) * mxlb(ji,jj,jk)**rnn 
494               END DO
495            END DO
496         END DO
497         !
498      END SELECT
499      !
500      ! Now gls (output in psi)
501      ! -------------------------------
502      ! Resolution of a tridiagonal linear system by a "methode de chasse"
503      ! computation from level 2 to jpkm1  (e(1) already computed and e(jpk)=0 ).
504      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
505      ! Warning : after this step, en : right hand side of the matrix
506
507      DO jk = 2, jpkm1
508         DO jj = 2, jpjm1
509            DO ji = fs_2, fs_jpim1   ! vector opt.
510               !
511               ! psi / k
512               zratio = psi(ji,jj,jk) / eb(ji,jj,jk) 
513               !
514               ! psi3+ : stable : B=-KhN²<0 => N²>0 if rn2>0 dir = 1 (stable) otherwise dir = 0 (unstable)
515               dir = 0.5_wp + SIGN( 0.5_wp, rn2(ji,jj,jk) )
516               !
517               rpsi3 = dir * rpsi3m + ( 1._wp - dir ) * rpsi3p
518               !
519               ! shear prod. - stratif. destruction
520               prod = rpsi1 * zratio * shear(ji,jj,jk)
521               !
522               ! stratif. destruction
523               buoy = rpsi3 * zratio * (- avt(ji,jj,jk) * rn2(ji,jj,jk) )
524               !
525               ! shear prod. - stratif. destruction
526               diss = rpsi2 * zratio * zwall(ji,jj,jk) * eps(ji,jj,jk)
527               !
528               dir = 0.5_wp + SIGN( 0.5_wp, prod + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
529               !
530               zesh2 = dir * ( prod + buoy )          + (1._wp - dir ) * prod                        ! production term
531               zdiss = dir * ( diss / psi(ji,jj,jk) ) + (1._wp - dir ) * (diss-buoy) / psi(ji,jj,jk) ! dissipation term
532               !                                                       
533               ! building the matrix
534               zcof = rfact_psi * zwall_psi(ji,jj,jk) * tmask(ji,jj,jk)
535               ! lower diagonal
536               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
537                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
538               ! upper diagonal
539               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
540                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
541               ! diagonal
542               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
543                  &                       + rdt * zdiss * tmask(ji,jj,jk)
544               !
545               ! right hand side in psi
546               psi(ji,jj,jk) = psi(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
547            END DO
548         END DO
549      END DO
550      !
551      z_elem_b(:,:,jpk) = 1._wp
552
553      ! Surface boundary condition on psi
554      ! ---------------------------------
555      !
556      SELECT CASE ( nn_psibc_surf )
557      !
558      CASE ( 0 )             ! Dirichlet boundary conditions
559         !
560         IF( ln_crban ) THEN       ! Wave induced mixing case
561            !                      ! en(1) = q2(1) = 0.5 * (15.8 * Ccb)^(2/3) * u*^2
562            !                      ! balance between the production and the dissipation terms including the wave effect
563            zdep(:,:) = rl_sf * zhsro(:,:)
564            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
565            z_elem_a(:,:,1) = psi(:,:,1)
566            z_elem_c(:,:,1) = 0._wp
567            z_elem_b(:,:,1) = 1._wp
568            !
569            ! one level below
570            zex1 = (rmm*ra_sf+rnn)
571            zex2 = (rmm*ra_sf)
572            zdep(:,:) = ( (zhsro(:,:) + fsdepw(:,:,2))**zex1 ) / zhsro(:,:)**zex2
573            psi (:,:,2) = rsbc_psi1 * ustars2(:,:)**rmm * zdep(:,:) * tmask(:,:,1)
574            z_elem_a(:,:,2) = 0._wp
575            z_elem_c(:,:,2) = 0._wp
576            z_elem_b(:,:,2) = 1._wp
577            !
578         ELSE                   ! No wave induced mixing case
579            !                      ! en(1) = u*^2/C0^2  &  l(1)  = K*zs
580            !                      ! balance between the production and the dissipation terms
581            !
582            zdep(:,:) = vkarmn * zhsro(:,:)
583            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
584            z_elem_a(:,:,1) = psi(:,:,1)
585            z_elem_c(:,:,1) = 0._wp
586            z_elem_b(:,:,1) = 1._wp
587            !
588            ! one level below
589            zdep(:,:) = vkarmn * ( zhsro(:,:) + fsdepw(:,:,2) )
590            psi (:,:,2) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
591            z_elem_a(:,:,2) = 0._wp
592            z_elem_c(:,:,2) = 0._wp
593            z_elem_b(:,:,2) = 1.
594            !
595         ENDIF
596         !
597      CASE ( 1 )             ! Neumann boundary condition on d(psi)/dz
598         !
599         IF( ln_crban ) THEN     ! Wave induced mixing case
600            !
601            zdep(:,:) = rl_sf * zhsro(:,:)
602            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
603            z_elem_a(:,:,1) = psi(:,:,1)
604            z_elem_c(:,:,1) = 0._wp
605            z_elem_b(:,:,1) = 1._wp
606            !
607            ! Neumann condition at k=2
608            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
609            z_elem_a(:,:,2) = 0._wp
610            !
611            ! Set psi vertical flux at the surface:
612            zdep(:,:) = (zhsro(:,:) + fsdept(:,:,1))**(rmm*ra_sf+rnn-1._wp) / zhsro(:,:)**(rmm*ra_sf)
613            zflxs(:,:) = rsbc_psi3 * ( zwall_psi(:,:,1)*avm(:,:,1) + zwall_psi(:,:,2)*avm(:,:,2) ) & 
614               &                   * en(:,:,1)**rmm * zdep         
615            psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
616            !
617      ELSE                   ! No wave induced mixing
618            !
619            zdep(:,:) = vkarmn * zhsro(:,:)
620            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
621            z_elem_a(:,:,1) = psi(:,:,1)
622            z_elem_c(:,:,1) = 0._wp
623            z_elem_b(:,:,1) = 1._wp
624            !
625            ! Neumann condition at k=2
626            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
627            z_elem_a(ji,jj,2) = 0._wp
628            !
629            ! Set psi vertical flux at the surface:
630            zdep(:,:)  = zhsro(:,:) + fsdept(:,:,1)
631            zflxs(:,:) = rsbc_psi2 * ( avm(:,:,1) + avm(:,:,2) ) * en(:,:,1)**rmm * zdep**(rnn-1._wp)
632            psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
633            !     
634         ENDIF
635         !
636      END SELECT
637
638      ! Bottom boundary condition on psi
639      ! --------------------------------
640      !
641      SELECT CASE ( nn_psibc_bot )
642      !
643      CASE ( 0 )             ! Dirichlet
644         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = vkarmn * hbro
645         !                      ! Balance between the production and the dissipation terms
646         DO jj = 2, jpjm1
647            DO ji = fs_2, fs_jpim1   ! vector opt.
648               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
649               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
650               zdep(ji,jj) = vkarmn * hbro
651               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
652               z_elem_a(ji,jj,ibot) = 0._wp
653               z_elem_c(ji,jj,ibot) = 0._wp
654               z_elem_b(ji,jj,ibot) = 1._wp
655               !
656               ! Just above last level, Dirichlet condition again (GOTM like)
657               zdep(ji,jj) = vkarmn * ( hbro + fse3t(ji,jj,ibotm1) )
658               psi (ji,jj,ibotm1) = rc0**rpp * en(ji,jj,ibot  )**rmm * zdep(ji,jj)**rnn
659               z_elem_a(ji,jj,ibotm1) = 0._wp
660               z_elem_c(ji,jj,ibotm1) = 0._wp
661               z_elem_b(ji,jj,ibotm1) = 1._wp
662            END DO
663         END DO
664         !
665      CASE ( 1 )             ! Neumman boundary condition
666         !                     
667         DO jj = 2, jpjm1
668            DO ji = fs_2, fs_jpim1   ! vector opt.
669               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
670               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
671               !
672               ! Bottom level Dirichlet condition:
673               zdep(ji,jj) = vkarmn * hbro
674               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
675               !
676               z_elem_a(ji,jj,ibot) = 0._wp
677               z_elem_c(ji,jj,ibot) = 0._wp
678               z_elem_b(ji,jj,ibot) = 1._wp
679               !
680               ! Just above last level: Neumann condition with flux injection
681               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1) ! Remove z_elem_c from z_elem_b
682               z_elem_c(ji,jj,ibotm1) = 0.
683               !
684               ! Set psi vertical flux at the bottom:
685               zdep(ji,jj) = hbro + 0.5_wp*fse3t(ji,jj,ibotm1)
686               zflxb = rsbc_psi2 * ( avm(ji,jj,ibot) + avm(ji,jj,ibotm1) )   &
687                  &  * (0.5_wp*(en(ji,jj,ibot)+en(ji,jj,ibotm1)))**rmm * zdep(ji,jj)**(rnn-1._wp)
688               psi(ji,jj,ibotm1) = psi(ji,jj,ibotm1) + zflxb / fse3w(ji,jj,ibotm1)
689            END DO
690         END DO
691         !
692      END SELECT
693
694      ! Matrix inversion
695      ! ----------------
696      !
697      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
698         DO jj = 2, jpjm1
699            DO ji = fs_2, fs_jpim1    ! vector opt.
700               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
701            END DO
702         END DO
703      END DO
704      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
705         DO jj = 2, jpjm1
706            DO ji = fs_2, fs_jpim1    ! vector opt.
707               z_elem_a(ji,jj,jk) = psi(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
708            END DO
709         END DO
710      END DO
711      DO jk = jpk-1, 2, -1                         ! Third recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
712         DO jj = 2, jpjm1
713            DO ji = fs_2, fs_jpim1    ! vector opt.
714               psi(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * psi(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
715            END DO
716         END DO
717      END DO
718
719      ! Set dissipation
720      !----------------
721
722      SELECT CASE ( nn_clos )
723      !
724      CASE( 0 )               ! k-kl  (Mellor-Yamada)
725         DO jk = 1, jpkm1
726            DO jj = 2, jpjm1
727               DO ji = fs_2, fs_jpim1   ! vector opt.
728                  eps(ji,jj,jk) = rc03 * en(ji,jj,jk) * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / psi(ji,jj,jk)
729               END DO
730            END DO
731         END DO
732         !
733      CASE( 1 )               ! k-eps
734         DO jk = 1, jpkm1
735            DO jj = 2, jpjm1
736               DO ji = fs_2, fs_jpim1   ! vector opt.
737                  eps(ji,jj,jk) = psi(ji,jj,jk)
738               END DO
739            END DO
740         END DO
741         !
742      CASE( 2 )               ! k-w
743         DO jk = 1, jpkm1
744            DO jj = 2, jpjm1
745               DO ji = fs_2, fs_jpim1   ! vector opt.
746                  eps(ji,jj,jk) = rc04 * en(ji,jj,jk) * psi(ji,jj,jk) 
747               END DO
748            END DO
749         END DO
750         !
751      CASE( 3 )               ! generic
752         zcoef = rc0**( 3._wp  + rpp/rnn )
753         zex1  =      ( 1.5_wp + rmm/rnn )
754         zex2  = -1._wp / rnn
755         DO jk = 1, jpkm1
756            DO jj = 2, jpjm1
757               DO ji = fs_2, fs_jpim1   ! vector opt.
758                  eps(ji,jj,jk) = zcoef * en(ji,jj,jk)**zex1 * psi(ji,jj,jk)**zex2
759               END DO
760            END DO
761         END DO
762         !
763      END SELECT
764
765      ! Limit dissipation rate under stable stratification
766      ! --------------------------------------------------
767      DO jk = 1, jpkm1 ! Note that this set boundary conditions on mxln at the same time
768         DO jj = 2, jpjm1
769            DO ji = fs_2, fs_jpim1    ! vector opt.
770               ! limitation
771               eps(ji,jj,jk)  = MAX( eps(ji,jj,jk), rn_epsmin )
772               mxln(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / eps(ji,jj,jk)
773               ! Galperin criterium (NOTE : Not required if the proper value of C3 in stable cases is calculated)
774               zrn2 = MAX( rn2(ji,jj,jk), rsmall )
775               mxln(ji,jj,jk) = MIN(  rn_clim_galp * SQRT( 2._wp * en(ji,jj,jk) / zrn2 ), mxln(ji,jj,jk)  )
776            END DO
777         END DO
778      END DO 
779
780      !
781      ! Stability function and vertical viscosity and diffusivity
782      ! ---------------------------------------------------------
783      !
784      SELECT CASE ( nn_stab_func )
785      !
786      CASE ( 0 , 1 )             ! Galperin or Kantha-Clayson stability functions
787         DO jk = 2, jpkm1
788            DO jj = 2, jpjm1
789               DO ji = fs_2, fs_jpim1   ! vector opt.
790                  ! zcof =  l²/q²
791                  zcof = mxlb(ji,jj,jk) * mxlb(ji,jj,jk) / ( 2._wp*eb(ji,jj,jk) )
792                  ! Gh = -N²l²/q²
793                  gh = - rn2(ji,jj,jk) * zcof
794                  gh = MIN( gh, rgh0   )
795                  gh = MAX( gh, rghmin )
796                  ! Stability functions from Kantha and Clayson (if C2=C3=0 => Galperin)
797                  sh = ra2*( 1._wp-6._wp*ra1/rb1 ) / ( 1.-3.*ra2*gh*(6.*ra1+rb2*( 1._wp-rc3 ) ) )
798                  sm = ( rb1**(-1._wp/3._wp) + ( 18._wp*ra1*ra1 + 9._wp*ra1*ra2*(1._wp-rc2) )*sh*gh ) / (1._wp-9._wp*ra1*ra2*gh)
799                  !
800                  ! Store stability function in avmu and avmv
801                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
802                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
803               END DO
804            END DO
805         END DO
806         !
807      CASE ( 2, 3 )               ! Canuto stability functions
808         DO jk = 2, jpkm1
809            DO jj = 2, jpjm1
810               DO ji = fs_2, fs_jpim1   ! vector opt.
811                  ! zcof =  l²/q²
812                  zcof = mxlb(ji,jj,jk)*mxlb(ji,jj,jk) / ( 2._wp * eb(ji,jj,jk) )
813                  ! Gh = -N²l²/q²
814                  gh = - rn2(ji,jj,jk) * zcof
815                  gh = MIN( gh, rgh0   )
816                  gh = MAX( gh, rghmin )
817                  gh = gh * rf6
818                  ! Gm =  M²l²/q² Shear number
819                  shr = shear(ji,jj,jk) / MAX( avm(ji,jj,jk), rsmall )
820                  gm = MAX( shr * zcof , 1.e-10 )
821                  gm = gm * rf6
822                  gm = MIN ( (rd0 - rd1*gh + rd3*gh*gh) / (rd2-rd4*gh) , gm )
823                  ! Stability functions from Canuto
824                  rcff = rd0 - rd1*gh +rd2*gm + rd3*gh*gh - rd4*gh*gm + rd5*gm*gm
825                  sm = (rs0 - rs1*gh + rs2*gm) / rcff
826                  sh = (rs4 - rs5*gh + rs6*gm) / rcff
827                  !
828                  ! Store stability function in avmu and avmv
829                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
830                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
831               END DO
832            END DO
833         END DO
834         !
835      END SELECT
836
837      ! Boundary conditions on stability functions for momentum (Neumann):
838      ! Lines below are useless if GOTM style Dirichlet conditions are used
839      zcoef = rcm_sf / SQRT( 2._wp )
840      DO jj = 2, jpjm1
841         DO ji = fs_2, fs_jpim1   ! vector opt.
842            avmv(ji,jj,1) = zcoef
843         END DO
844      END DO
845      zcoef = rc0 / SQRT( 2._wp )
846      DO jj = 2, jpjm1
847         DO ji = fs_2, fs_jpim1   ! vector opt.
848            avmv(ji,jj,mbkt(ji,jj)+1) = zcoef
849         END DO
850      END DO
851
852      ! Compute diffusivities/viscosities
853      ! The computation below could be restrained to jk=2 to jpkm1 if GOTM style Dirichlet conditions are used
854      DO jk = 1, jpk
855         DO jj = 2, jpjm1
856            DO ji = fs_2, fs_jpim1   ! vector opt.
857               zsqen         = SQRT( 2._wp * en(ji,jj,jk) ) * mxln(ji,jj,jk)
858               zav           = zsqen * avmu(ji,jj,jk)
859               avt(ji,jj,jk) = MAX( zav, avtb(jk) )*tmask(ji,jj,jk) ! apply mask for zdfmxl routine
860               zav           = zsqen * avmv(ji,jj,jk)
861               avm(ji,jj,jk) = MAX( zav, avmb(jk) ) ! Note that avm is not masked at the surface and the bottom
862            END DO
863         END DO
864      END DO
865      !
866      ! Lateral boundary conditions (sign unchanged)
867      avt(:,:,1)  = 0._wp
868      CALL lbc_lnk( avm, 'W', 1. )   ;   CALL lbc_lnk( avt, 'W', 1. )
869
870      DO jk = 2, jpkm1            !* vertical eddy viscosity at u- and v-points
871         DO jj = 2, jpjm1
872            DO ji = fs_2, fs_jpim1   ! vector opt.
873               avmu(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji+1,jj  ,jk) ) * umask(ji,jj,jk)
874               avmv(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji  ,jj+1,jk) ) * vmask(ji,jj,jk)
875            END DO
876         END DO
877      END DO
878      avmu(:,:,1) = 0._wp             ;   avmv(:,:,1) = 0._wp                 ! set surface to zero
879      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )       ! Lateral boundary conditions
880
881      IF(ln_ctl) THEN
882         CALL prt_ctl( tab3d_1=en  , clinfo1=' gls  - e: ', tab3d_2=avt, clinfo2=' t: ', ovlap=1, kdim=jpk)
883         CALL prt_ctl( tab3d_1=avmu, clinfo1=' gls  - u: ', mask1=umask,                   &
884            &          tab3d_2=avmv, clinfo2=       ' v: ', mask2=vmask, ovlap=1, kdim=jpk )
885      ENDIF
886      !
887      avt_k (:,:,:) = avt (:,:,:)
888      avm_k (:,:,:) = avm (:,:,:)
889      avmu_k(:,:,:) = avmu(:,:,:)
890      avmv_k(:,:,:) = avmv(:,:,:)
891      !
892      CALL wrk_dealloc( jpi,jpj, zdep, zflxs, zhsro )
893      CALL wrk_dealloc( jpi,jpj,jpk, eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi )
894      !
895      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls')
896      !
897      !
898   END SUBROUTINE zdf_gls
899
900
901   SUBROUTINE zdf_gls_init
902      !!----------------------------------------------------------------------
903      !!                  ***  ROUTINE zdf_gls_init  ***
904      !!                     
905      !! ** Purpose :   Initialization of the vertical eddy diffivity and
906      !!      viscosity when using a gls turbulent closure scheme
907      !!
908      !! ** Method  :   Read the namzdf_gls namelist and check the parameters
909      !!      called at the first timestep (nit000)
910      !!
911      !! ** input   :   Namlist namzdf_gls
912      !!
913      !! ** Action  :   Increase by 1 the nstop flag is setting problem encounter
914      !!
915      !!----------------------------------------------------------------------
916      USE dynzdf_exp
917      USE trazdf_exp
918      !
919      INTEGER ::   jk    ! dummy loop indices
920      INTEGER ::   ios   ! Local integer output status for namelist read
921      REAL(wp)::   zcr   ! local scalar
922      !!
923      NAMELIST/namzdf_gls/rn_emin, rn_epsmin, ln_length_lim, &
924         &            rn_clim_galp, ln_crban, ln_sigpsi,     &
925         &            rn_crban, rn_charn,                    &
926         &            nn_tkebc_surf, nn_tkebc_bot,           &
927         &            nn_psibc_surf, nn_psibc_bot,           &
928         &            nn_stab_func, nn_clos
929      !!----------------------------------------------------------
930      !
931      IF( nn_timing == 1 )  CALL timing_start('zdf_gls_init')
932      !
933      REWIND( numnam_ref )              ! Namelist namzdf_gls in reference namelist : Vertical eddy diffivity and viscosity using gls turbulent closure scheme
934      READ  ( numnam_ref, namzdf_gls, IOSTAT = ios, ERR = 901)
935901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_gls in reference namelist', lwp )
936
937      REWIND( numnam_cfg )              ! Namelist namzdf_gls in configuration namelist : Vertical eddy diffivity and viscosity using gls turbulent closure scheme
938      READ  ( numnam_cfg, namzdf_gls, IOSTAT = ios, ERR = 902 )
939902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_gls in configuration namelist', lwp )
940      WRITE ( numond, namzdf_gls )
941
942      IF(lwp) THEN                     !* Control print
943         WRITE(numout,*)
944         WRITE(numout,*) 'zdf_gls_init : gls turbulent closure scheme'
945         WRITE(numout,*) '~~~~~~~~~~~~'
946         WRITE(numout,*) '   Namelist namzdf_gls : set gls mixing parameters'
947         WRITE(numout,*) '      minimum value of en                           rn_emin       = ', rn_emin
948         WRITE(numout,*) '      minimum value of eps                          rn_epsmin     = ', rn_epsmin
949         WRITE(numout,*) '      Limit dissipation rate under stable stratif.  ln_length_lim = ', ln_length_lim
950         WRITE(numout,*) '      Galperin limit (Standard: 0.53, Holt: 0.26)   rn_clim_galp  = ', rn_clim_galp
951         WRITE(numout,*) '      TKE Surface boundary condition                nn_tkebc_surf = ', nn_tkebc_surf
952         WRITE(numout,*) '      TKE Bottom boundary condition                 nn_tkebc_bot  = ', nn_tkebc_bot
953         WRITE(numout,*) '      PSI Surface boundary condition                nn_psibc_surf = ', nn_psibc_surf
954         WRITE(numout,*) '      PSI Bottom boundary condition                 nn_psibc_bot  = ', nn_psibc_bot
955         WRITE(numout,*) '      Craig and Banner scheme                       ln_crban      = ', ln_crban
956         WRITE(numout,*) '      Modify psi Schmidt number (wb case)           ln_sigpsi     = ', ln_sigpsi
957         WRITE(numout,*) '      Craig and Banner coefficient                  rn_crban       = ', rn_crban
958         WRITE(numout,*) '      Charnock coefficient                          rn_charn       = ', rn_charn
959         WRITE(numout,*) '      Stability functions                           nn_stab_func   = ', nn_stab_func
960         WRITE(numout,*) '      Type of closure                               nn_clos        = ', nn_clos
961         WRITE(numout,*) '   Hard coded parameters'
962         WRITE(numout,*) '      Surface roughness (m)                         hsro          = ', hsro
963         WRITE(numout,*) '      Bottom roughness (m)                          hbro          = ', hbro
964      ENDIF
965
966      !                                !* allocate gls arrays
967      IF( zdf_gls_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_gls_init : unable to allocate arrays' )
968
969      !                                !* Check of some namelist values
970      IF( nn_tkebc_surf < 0 .OR. nn_tkebc_surf > 1 ) CALL ctl_stop( 'bad flag: nn_tkebc_surf is 0 or 1' )
971      IF( nn_psibc_surf < 0 .OR. nn_psibc_surf > 1 ) CALL ctl_stop( 'bad flag: nn_psibc_surf is 0 or 1' )
972      IF( nn_tkebc_bot  < 0 .OR. nn_tkebc_bot  > 1 ) CALL ctl_stop( 'bad flag: nn_tkebc_bot is 0 or 1' )
973      IF( nn_psibc_bot  < 0 .OR. nn_psibc_bot  > 1 ) CALL ctl_stop( 'bad flag: nn_psibc_bot is 0 or 1' )
974      IF( nn_stab_func  < 0 .OR. nn_stab_func  > 3 ) CALL ctl_stop( 'bad flag: nn_stab_func is 0, 1, 2 and 3' )
975      IF( nn_clos       < 0 .OR. nn_clos       > 3 ) CALL ctl_stop( 'bad flag: nn_clos is 0, 1, 2 or 3' )
976
977      SELECT CASE ( nn_clos )          !* set the parameters for the chosen closure
978      !
979      CASE( 0 )                              ! k-kl  (Mellor-Yamada)
980         !
981         IF(lwp) WRITE(numout,*) 'The choosen closure is k-kl closed to the classical Mellor-Yamada'
982         rpp     = 0._wp
983         rmm     = 1._wp
984         rnn     = 1._wp
985         rsc_tke = 1.96_wp
986         rsc_psi = 1.96_wp
987         rpsi1   = 0.9_wp
988         rpsi3p  = 1._wp
989         rpsi2   = 0.5_wp
990         !
991         SELECT CASE ( nn_stab_func )
992         CASE( 0, 1 )   ;   rpsi3m = 2.53_wp       ! G88 or KC stability functions
993         CASE( 2 )      ;   rpsi3m = 2.38_wp       ! Canuto A stability functions
994         CASE( 3 )      ;   rpsi3m = 2.38          ! Canuto B stability functions (caution : constant not identified)
995         END SELECT
996         !
997      CASE( 1 )                              ! k-eps
998         !
999         IF(lwp) WRITE(numout,*) 'The choosen closure is k-eps'
1000         rpp     =  3._wp
1001         rmm     =  1.5_wp
1002         rnn     = -1._wp
1003         rsc_tke =  1._wp
1004         rsc_psi =  1.3_wp  ! Schmidt number for psi
1005         rpsi1   =  1.44_wp
1006         rpsi3p  =  1._wp
1007         rpsi2   =  1.92_wp
1008         !
1009         SELECT CASE ( nn_stab_func )
1010         CASE( 0, 1 )   ;   rpsi3m = -0.52_wp      ! G88 or KC stability functions
1011         CASE( 2 )      ;   rpsi3m = -0.629_wp     ! Canuto A stability functions
1012         CASE( 3 )      ;   rpsi3m = -0.566        ! Canuto B stability functions
1013         END SELECT
1014         !
1015      CASE( 2 )                              ! k-omega
1016         !
1017         IF(lwp) WRITE(numout,*) 'The choosen closure is k-omega'
1018         rpp     = -1._wp
1019         rmm     =  0.5_wp
1020         rnn     = -1._wp
1021         rsc_tke =  2._wp
1022         rsc_psi =  2._wp
1023         rpsi1   =  0.555_wp
1024         rpsi3p  =  1._wp
1025         rpsi2   =  0.833_wp
1026         !
1027         SELECT CASE ( nn_stab_func )
1028         CASE( 0, 1 )   ;   rpsi3m = -0.58_wp       ! G88 or KC stability functions
1029         CASE( 2 )      ;   rpsi3m = -0.64_wp       ! Canuto A stability functions
1030         CASE( 3 )      ;   rpsi3m = -0.64_wp       ! Canuto B stability functions caution : constant not identified)
1031         END SELECT
1032         !
1033      CASE( 3 )                              ! generic
1034         !
1035         IF(lwp) WRITE(numout,*) 'The choosen closure is generic'
1036         rpp     = 2._wp
1037         rmm     = 1._wp
1038         rnn     = -0.67_wp
1039         rsc_tke = 0.8_wp
1040         rsc_psi = 1.07_wp
1041         rpsi1   = 1._wp
1042         rpsi3p  = 1._wp
1043         rpsi2   = 1.22_wp
1044         !
1045         SELECT CASE ( nn_stab_func )
1046         CASE( 0, 1 )   ;   rpsi3m = 0.1_wp         ! G88 or KC stability functions
1047         CASE( 2 )      ;   rpsi3m = 0.05_wp        ! Canuto A stability functions
1048         CASE( 3 )      ;   rpsi3m = 0.05_wp        ! Canuto B stability functions caution : constant not identified)
1049         END SELECT
1050         !
1051      END SELECT
1052
1053      !
1054      SELECT CASE ( nn_stab_func )     !* set the parameters of the stability functions
1055      !
1056      CASE ( 0 )                             ! Galperin stability functions
1057         !
1058         IF(lwp) WRITE(numout,*) 'Stability functions from Galperin'
1059         rc2     =  0._wp
1060         rc3     =  0._wp
1061         rc_diff =  1._wp
1062         rc0     =  0.5544_wp
1063         rcm_sf  =  0.9884_wp
1064         rghmin  = -0.28_wp
1065         rgh0    =  0.0233_wp
1066         rghcri  =  0.02_wp
1067         !
1068      CASE ( 1 )                             ! Kantha-Clayson stability functions
1069         !
1070         IF(lwp) WRITE(numout,*) 'Stability functions from Kantha-Clayson'
1071         rc2     =  0.7_wp
1072         rc3     =  0.2_wp
1073         rc_diff =  1._wp
1074         rc0     =  0.5544_wp
1075         rcm_sf  =  0.9884_wp
1076         rghmin  = -0.28_wp
1077         rgh0    =  0.0233_wp
1078         rghcri  =  0.02_wp
1079         !
1080      CASE ( 2 )                             ! Canuto A stability functions
1081         !
1082         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto A'
1083         rs0 = 1.5_wp * rl1 * rl5*rl5
1084         rs1 = -rl4*(rl6+rl7) + 2._wp*rl4*rl5*(rl1-(1._wp/3._wp)*rl2-rl3) + 1.5_wp*rl1*rl5*rl8
1085         rs2 = -(3._wp/8._wp) * rl1*(rl6*rl6-rl7*rl7)
1086         rs4 = 2._wp * rl5
1087         rs5 = 2._wp * rl4
1088         rs6 = (2._wp/3._wp) * rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.5_wp * rl5*rl1 * (3._wp*rl3-rl2)   &
1089            &                                                    + 0.75_wp * rl1 * ( rl6 - rl7 )
1090         rd0 = 3._wp * rl5*rl5
1091         rd1 = rl5 * ( 7._wp*rl4 + 3._wp*rl8 )
1092         rd2 = rl5*rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.75_wp*(rl6*rl6 - rl7*rl7 )
1093         rd3 = rl4 * ( 4._wp*rl4 + 3._wp*rl8)
1094         rd4 = rl4 * ( rl2 * rl6 - 3._wp*rl3*rl7 - rl5*(rl2*rl2 - rl3*rl3 ) ) + rl5*rl8 * ( 3._wp*rl3*rl3 - rl2*rl2 )
1095         rd5 = 0.25_wp * ( rl2*rl2 - 3._wp *rl3*rl3 ) * ( rl6*rl6 - rl7*rl7 )
1096         rc0 = 0.5268_wp
1097         rf6 = 8._wp / (rc0**6._wp)
1098         rc_diff = SQRT(2._wp) / (rc0**3._wp)
1099         rcm_sf  =  0.7310_wp
1100         rghmin  = -0.28_wp
1101         rgh0    =  0.0329_wp
1102         rghcri  =  0.03_wp
1103         !
1104      CASE ( 3 )                             ! Canuto B stability functions
1105         !
1106         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto B'
1107         rs0 = 1.5_wp * rm1 * rm5*rm5
1108         rs1 = -rm4 * (rm6+rm7) + 2._wp * rm4*rm5*(rm1-(1._wp/3._wp)*rm2-rm3) + 1.5_wp * rm1*rm5*rm8
1109         rs2 = -(3._wp/8._wp) * rm1 * (rm6*rm6-rm7*rm7 )
1110         rs4 = 2._wp * rm5
1111         rs5 = 2._wp * rm4
1112         rs6 = (2._wp/3._wp) * rm5 * (3._wp*rm3*rm3-rm2*rm2) - 0.5_wp * rm5*rm1*(3._wp*rm3-rm2) + 0.75_wp * rm1*(rm6-rm7)
1113         rd0 = 3._wp * rm5*rm5
1114         rd1 = rm5 * (7._wp*rm4 + 3._wp*rm8)
1115         rd2 = rm5*rm5 * (3._wp*rm3*rm3 - rm2*rm2) - 0.75_wp * (rm6*rm6 - rm7*rm7)
1116         rd3 = rm4 * ( 4._wp*rm4 + 3._wp*rm8 )
1117         rd4 = rm4 * ( rm2*rm6 -3._wp*rm3*rm7 - rm5*(rm2*rm2 - rm3*rm3) ) + rm5 * rm8 * ( 3._wp*rm3*rm3 - rm2*rm2 )
1118         rd5 = 0.25_wp * ( rm2*rm2 - 3._wp*rm3*rm3 ) * ( rm6*rm6 - rm7*rm7 )
1119         rc0 = 0.5268_wp            !!       rc0 = 0.5540_wp (Warner ...) to verify !
1120         rf6 = 8._wp / ( rc0**6._wp )
1121         rc_diff = SQRT(2._wp)/(rc0**3.)
1122         rcm_sf  =  0.7470_wp
1123         rghmin  = -0.28_wp
1124         rgh0    =  0.0444_wp
1125         rghcri  =  0.0414_wp
1126         !
1127      END SELECT
1128   
1129      !                                !* Set Schmidt number for psi diffusion in the wave breaking case
1130      !                                     ! See Eq. (13) of Carniel et al, OM, 30, 225-239, 2009
1131      !                                     !  or Eq. (17) of Burchard, JPO, 31, 3133-3145, 2001
1132      IF( ln_sigpsi .AND. ln_crban ) THEN
1133         zcr = SQRT( 1.5_wp*rsc_tke ) * rcm_sf / vkarmn
1134         rsc_psi0 = vkarmn*vkarmn / ( rpsi2 * rcm_sf*rcm_sf )                       & 
1135        &         * ( rnn*rnn - 4._wp/3._wp * zcr*rnn*rmm - 1._wp/3._wp * zcr*rnn   &
1136        &           + 2._wp/9._wp * rmm * zcr*zcr + 4._wp/9._wp * zcr*zcr * rmm*rmm )                                 
1137      ELSE
1138         rsc_psi0 = rsc_psi
1139      ENDIF
1140 
1141      !                                !* Shear free turbulence parameters
1142      !
1143      ra_sf  = -4._wp * rnn * SQRT( rsc_tke ) / ( (1._wp+4._wp*rmm) * SQRT( rsc_tke )   &
1144         &                                      - SQRT(rsc_tke + 24._wp*rsc_psi0*rpsi2 ) )
1145      rl_sf  = rc0 * SQRT( rc0 / rcm_sf )                                                                   &
1146         &         * SQRT(  (  (1._wp + 4._wp*rmm + 8._wp*rmm*rmm) * rsc_tke                                &
1147         &                   + 12._wp * rsc_psi0 * rpsi2                                                    &
1148         &                   - (1._wp + 4._wp*rmm) * SQRT( rsc_tke*(rsc_tke+ 24._wp*rsc_psi0*rpsi2) )  )    &
1149         &                / ( 12._wp*rnn*rnn )                                                              )
1150
1151      !
1152      IF(lwp) THEN                     !* Control print
1153         WRITE(numout,*)
1154         WRITE(numout,*) 'Limit values'
1155         WRITE(numout,*) '~~~~~~~~~~~~'
1156         WRITE(numout,*) 'Parameter  m = ',rmm
1157         WRITE(numout,*) 'Parameter  n = ',rnn
1158         WRITE(numout,*) 'Parameter  p = ',rpp
1159         WRITE(numout,*) 'rpsi1   = ',rpsi1
1160         WRITE(numout,*) 'rpsi2   = ',rpsi2
1161         WRITE(numout,*) 'rpsi3m  = ',rpsi3m
1162         WRITE(numout,*) 'rpsi3p  = ',rpsi3p
1163         WRITE(numout,*) 'rsc_tke = ',rsc_tke
1164         WRITE(numout,*) 'rsc_psi = ',rsc_psi
1165         WRITE(numout,*) 'rsc_psi0 = ',rsc_psi0
1166         WRITE(numout,*) 'rc0     = ',rc0
1167         WRITE(numout,*)
1168         WRITE(numout,*) 'Shear free turbulence parameters:'
1169         WRITE(numout,*) 'rcm_sf  = ',rcm_sf
1170         WRITE(numout,*) 'ra_sf   = ',ra_sf
1171         WRITE(numout,*) 'rl_sf   = ',rl_sf
1172         WRITE(numout,*)
1173      ENDIF
1174
1175      !                                !* Constants initialization
1176      rc02  = rc0  * rc0   ;   rc02r = 1. / rc02
1177      rc03  = rc02 * rc0
1178      rc04  = rc03 * rc0
1179      rc03_sqrt2_galp = rc03 / SQRT(2._wp) / rn_clim_galp
1180      rsbc_mb   = 0.5_wp * (15.8_wp*rn_crban)**(2._wp/3._wp)               ! Surf. bound. cond. from Mellor and Blumberg
1181      rsbc_std  = 3.75_wp                                                  ! Surf. bound. cond. standard (prod=diss)
1182      rsbc_tke1 = (-rsc_tke*rn_crban/(rcm_sf*ra_sf*rl_sf))**(2._wp/3._wp)  ! k_eps = 53.  Dirichlet + Wave breaking
1183      rsbc_tke2 = 0.5_wp / rau0
1184      rsbc_tke3 = rdt * rn_crban                                                         ! Neumann + Wave breaking
1185      rsbc_zs   = rn_charn / grav                                                        ! Charnock formula
1186      rsbc_psi1 = rc0**rpp * rsbc_tke1**rmm * rl_sf**rnn                           ! Dirichlet + Wave breaking
1187      rsbc_psi2 = -0.5_wp * rdt * rc0**rpp * rnn * vkarmn**rnn / rsc_psi                   ! Neumann + NO Wave breaking
1188      rsbc_psi3 = -0.5_wp * rdt * rc0**rpp * rl_sf**rnn / rsc_psi  * (rnn + rmm*ra_sf) ! Neumann + Wave breaking
1189      rfact_tke = -0.5_wp / rsc_tke * rdt               ! Cst used for the Diffusion term of tke
1190      rfact_psi = -0.5_wp / rsc_psi * rdt               ! Cst used for the Diffusion term of tke
1191
1192      !                                !* Wall proximity function
1193      zwall (:,:,:) = 1._wp * tmask(:,:,:)
1194
1195      !                                !* set vertical eddy coef. to the background value
1196      DO jk = 1, jpk
1197         avt (:,:,jk) = avtb(jk) * tmask(:,:,jk)
1198         avm (:,:,jk) = avmb(jk) * tmask(:,:,jk)
1199         avmu(:,:,jk) = avmb(jk) * umask(:,:,jk)
1200         avmv(:,:,jk) = avmb(jk) * vmask(:,:,jk)
1201      END DO
1202      !                             
1203      CALL gls_rst( nit000, 'READ' )   !* read or initialize all required files
1204      !
1205      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls_init')
1206      !
1207   END SUBROUTINE zdf_gls_init
1208
1209
1210   SUBROUTINE gls_rst( kt, cdrw )
1211      !!---------------------------------------------------------------------
1212      !!                   ***  ROUTINE ts_rst  ***
1213      !!                     
1214      !! ** Purpose :   Read or write TKE file (en) in restart file
1215      !!
1216      !! ** Method  :   use of IOM library
1217      !!                if the restart does not contain TKE, en is either
1218      !!                set to rn_emin or recomputed (nn_igls/=0)
1219      !!----------------------------------------------------------------------
1220      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1221      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1222      !
1223      INTEGER ::   jit, jk   ! dummy loop indices
1224      INTEGER ::   id1, id2, id3, id4, id5, id6
1225      INTEGER ::   ji, jj, ikbu, ikbv
1226      REAL(wp)::   cbx, cby
1227      !!----------------------------------------------------------------------
1228      !
1229      IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialise
1230         !                                   ! ---------------
1231         IF( ln_rstart ) THEN                   !* Read the restart file
1232            id1 = iom_varid( numror, 'en'   , ldstop = .FALSE. )
1233            id2 = iom_varid( numror, 'avt'  , ldstop = .FALSE. )
1234            id3 = iom_varid( numror, 'avm'  , ldstop = .FALSE. )
1235            id4 = iom_varid( numror, 'avmu' , ldstop = .FALSE. )
1236            id5 = iom_varid( numror, 'avmv' , ldstop = .FALSE. )
1237            id6 = iom_varid( numror, 'mxln' , ldstop = .FALSE. )
1238            !
1239            IF( MIN( id1, id2, id3, id4, id5, id6 ) > 0 ) THEN        ! all required arrays exist
1240               CALL iom_get( numror, jpdom_autoglo, 'en'    , en     )
1241               CALL iom_get( numror, jpdom_autoglo, 'avt'   , avt    )
1242               CALL iom_get( numror, jpdom_autoglo, 'avm'   , avm    )
1243               CALL iom_get( numror, jpdom_autoglo, 'avmu'  , avmu   )
1244               CALL iom_get( numror, jpdom_autoglo, 'avmv'  , avmv   )
1245               CALL iom_get( numror, jpdom_autoglo, 'mxln'  , mxln   )
1246            ELSE                       
1247               IF(lwp) WRITE(numout,*) ' ===>>>> : previous run without gls scheme, en and mxln computed by iterative loop'
1248               en  (:,:,:) = rn_emin
1249               mxln(:,:,:) = 0.001       
1250               DO jit = nit000 + 1, nit000 + 10   ;   CALL zdf_gls( jit )   ;   END DO
1251            ENDIF
1252         ELSE                                   !* Start from rest
1253            IF(lwp) WRITE(numout,*) ' ===>>>> : Initialisation of en and mxln by background values'
1254            en  (:,:,:) = rn_emin
1255            mxln(:,:,:) = 0.001       
1256         ENDIF
1257         !
1258      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
1259         !                                   ! -------------------
1260         IF(lwp) WRITE(numout,*) '---- gls-rst ----'
1261         CALL iom_rstput( kt, nitrst, numrow, 'en'   , en     )
1262         CALL iom_rstput( kt, nitrst, numrow, 'avt'  , avt_k  )
1263         CALL iom_rstput( kt, nitrst, numrow, 'avm'  , avm_k  )
1264         CALL iom_rstput( kt, nitrst, numrow, 'avmu' , avmu_k )
1265         CALL iom_rstput( kt, nitrst, numrow, 'avmv' , avmv_k )
1266         CALL iom_rstput( kt, nitrst, numrow, 'mxln' , mxln   )
1267         !
1268      ENDIF
1269      !
1270   END SUBROUTINE gls_rst
1271
1272#else
1273   !!----------------------------------------------------------------------
1274   !!   Dummy module :                                        NO TKE scheme
1275   !!----------------------------------------------------------------------
1276   LOGICAL, PUBLIC, PARAMETER ::   lk_zdfgls = .FALSE.   !: TKE flag
1277CONTAINS
1278   SUBROUTINE zdf_gls_init           ! Empty routine
1279      WRITE(*,*) 'zdf_gls_init: You should not have seen this print! error?'
1280   END SUBROUTINE zdf_gls_init
1281   SUBROUTINE zdf_gls( kt )          ! Empty routine
1282      WRITE(*,*) 'zdf_gls: You should not have seen this print! error?', kt
1283   END SUBROUTINE zdf_gls
1284   SUBROUTINE gls_rst( kt, cdrw )          ! Empty routine
1285      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1286      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1287      WRITE(*,*) 'gls_rst: You should not have seen this print! error?', kt, cdrw
1288   END SUBROUTINE gls_rst
1289#endif
1290
1291   !!======================================================================
1292END MODULE zdfgls
1293
Note: See TracBrowser for help on using the repository browser.