New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd.F90 in branches/2014/dev_CNRS_2014/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2014/dev_CNRS_2014/NEMOGCM/NEMO/LIM_SRC_3/limthd.F90 @ 4902

Last change on this file since 4902 was 4902, checked in by cetlod, 9 years ago

2014/dev_CNRS_2014 : Merge in the trunk changes between 4728 and 4879, see ticket #1415
  • Property svn:keywords set to Id
File size: 34.3 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec, lim_thd_con_dh and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3'                                      LIM3 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   lim_thd       : thermodynamic of sea ice
20   !!   lim_thd_init  : initialisation of sea-ice thermodynamic
21   !!----------------------------------------------------------------------
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain variables
24   USE oce     , ONLY : fraqsr_1lev 
25   USE ice            ! LIM: sea-ice variables
26   USE par_ice        ! LIM: sea-ice parameters
27   USE sbc_oce        ! Surface boundary condition: ocean fields
28   USE sbc_ice        ! Surface boundary condition: ice fields
29   USE thd_ice        ! LIM thermodynamic sea-ice variables
30   USE dom_ice        ! LIM sea-ice domain
31   USE domvvl         ! domain: variable volume level
32   USE limthd_dif     ! LIM: thermodynamics, vertical diffusion
33   USE limthd_dh      ! LIM: thermodynamics, ice and snow thickness variation
34   USE limthd_sal     ! LIM: thermodynamics, ice salinity
35   USE limthd_ent     ! LIM: thermodynamics, ice enthalpy redistribution
36   USE limtab         ! LIM: 1D <==> 2D transformation
37   USE limvar         ! LIM: sea-ice variables
38   USE lbclnk         ! lateral boundary condition - MPP links
39   USE lib_mpp        ! MPP library
40   USE wrk_nemo       ! work arrays
41   USE in_out_manager ! I/O manager
42   USE prtctl         ! Print control
43   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
44   USE timing         ! Timing
45   USE limcons        ! conservation tests
46
47   IMPLICIT NONE
48   PRIVATE
49
50   PUBLIC   lim_thd        ! called by limstp module
51   PUBLIC   lim_thd_init   ! called by iceini module
52
53   REAL(wp) ::   epsi10 = 1.e-10_wp   !
54
55   !! * Substitutions
56#  include "domzgr_substitute.h90"
57#  include "vectopt_loop_substitute.h90"
58   !!----------------------------------------------------------------------
59   !! NEMO/LIM3 3.3 , UCL - NEMO Consortium (2010)
60   !! $Id$
61   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
62   !!----------------------------------------------------------------------
63CONTAINS
64
65   SUBROUTINE lim_thd( kt )
66      !!-------------------------------------------------------------------
67      !!                ***  ROUTINE lim_thd  ***       
68      !! 
69      !! ** Purpose : This routine manages ice thermodynamics
70      !!         
71      !! ** Action : - Initialisation of some variables
72      !!             - Some preliminary computation (oceanic heat flux
73      !!               at the ice base, snow acc.,heat budget of the leads)
74      !!             - selection of the icy points and put them in an array
75      !!             - call lim_thd_dif  for vertical heat diffusion
76      !!             - call lim_thd_dh   for vertical ice growth and melt
77      !!             - call lim_thd_ent  for enthalpy remapping
78      !!             - call lim_thd_sal  for ice desalination
79      !!             - call lim_thd_temp to  retrieve temperature from ice enthalpy
80      !!             - back to the geographic grid
81      !!     
82      !! ** References :
83      !!---------------------------------------------------------------------
84      INTEGER, INTENT(in) ::   kt    ! number of iteration
85      !!
86      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
87      INTEGER  :: nbpb             ! nb of icy pts for thermo. cal.
88      INTEGER  :: ii, ij           ! temporary dummy loop index
89      REAL(wp) :: zfric_umin = 0._wp        ! lower bound for the friction velocity (cice value=5.e-04)
90      REAL(wp) :: zch        = 0.0057_wp    ! heat transfer coefficient
91      REAL(wp) :: zinda, zindb, zareamin 
92      REAL(wp) :: zfric_u, zqld, zqfr
93      !
94      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
95      !
96      REAL(wp), POINTER, DIMENSION(:,:) ::  zqsr, zqns
97      !!-------------------------------------------------------------------
98      CALL wrk_alloc( jpi, jpj, zqsr, zqns )
99
100      IF( nn_timing == 1 )  CALL timing_start('limthd')
101
102      ! conservation test
103      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
104
105      !------------------------------------------------------------------------------!
106      ! 1) Initialization of diagnostic variables                                    !
107      !------------------------------------------------------------------------------!
108
109      !--------------------
110      ! 1.2) Heat content   
111      !--------------------
112      ! Change the units of heat content; from global units to J.m3
113      DO jl = 1, jpl
114         DO jk = 1, nlay_i
115            DO jj = 1, jpj
116               DO ji = 1, jpi
117                  !0 if no ice and 1 if yes
118                  zindb = 1.0 - MAX(  0.0 , SIGN( 1.0 , - v_i(ji,jj,jl) + epsi10 )  )
119                  !Energy of melting q(S,T) [J.m-3]
120                  e_i(ji,jj,jk,jl) = zindb * e_i(ji,jj,jk,jl) / ( area(ji,jj) * MAX( v_i(ji,jj,jl) , epsi10 ) ) * REAL( nlay_i )
121                  !convert units ! very important that this line is here       
122                  e_i(ji,jj,jk,jl) = e_i(ji,jj,jk,jl) * unit_fac 
123               END DO
124            END DO
125         END DO
126         DO jk = 1, nlay_s
127            DO jj = 1, jpj
128               DO ji = 1, jpi
129                  !0 if no ice and 1 if yes
130                  zindb = 1.0 - MAX(  0.0 , SIGN( 1.0 , - v_s(ji,jj,jl) + epsi10 )  )
131                  !Energy of melting q(S,T) [J.m-3]
132                  e_s(ji,jj,jk,jl) = zindb * e_s(ji,jj,jk,jl) / ( area(ji,jj) * MAX( v_s(ji,jj,jl) , epsi10 ) ) * REAL( nlay_s )
133                  !convert units ! very important that this line is here
134                  e_s(ji,jj,jk,jl) = e_s(ji,jj,jk,jl) * unit_fac 
135               END DO
136            END DO
137         END DO
138      END DO
139
140      ! 2) Partial computation of forcing for the thermodynamic sea ice model.      !
141      !-----------------------------------------------------------------------------!
142
143      !--- Ocean solar and non solar fluxes to be used in zqld
144      IF ( .NOT. lk_cpl ) THEN   ! --- forced case, fluxes to the lead are the same as over the ocean
145         !
146         zqsr(:,:) = qsr(:,:)      ; zqns(:,:) = qns(:,:)
147         !
148      ELSE                       ! --- coupled case, fluxes to the lead are total - intercepted
149         !
150         zqsr(:,:) = qsr_tot(:,:)  ; zqns(:,:) = qns_tot(:,:)
151         !
152         DO jl = 1, jpl
153            DO jj = 1, jpj
154               DO ji = 1, jpi
155                  zqsr(ji,jj) = zqsr(ji,jj) - qsr_ice(ji,jj,jl) * a_i_b(ji,jj,jl)
156                  zqns(ji,jj) = zqns(ji,jj) - qns_ice(ji,jj,jl) * a_i_b(ji,jj,jl)
157               END DO
158            END DO
159         END DO
160         !
161      ENDIF
162
163!CDIR NOVERRCHK
164      DO jj = 1, jpj
165!CDIR NOVERRCHK
166         DO ji = 1, jpi
167            zinda          = tms(ji,jj) * ( 1._wp - MAX( 0._wp , SIGN( 1._wp , - at_i(ji,jj) + epsi10 ) ) ) ! 0 if no ice
168            !
169            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
170            !           !  practically no "direct lateral ablation"
171            !           
172            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
173            !           !  temperature and turbulent mixing (McPhee, 1992)
174            !
175
176            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
177            zqld =  tms(ji,jj) * rdt_ice *                                          &
178               &      ( pfrld(ji,jj) * ( zqsr(ji,jj) * fraqsr_1lev(ji,jj) + zqns(ji,jj) ) &
179               &    + ( pfrld(ji,jj)**betas - pfrld(ji,jj) ) * sprecip(ji,jj) *     & ! heat content of precip
180               &      ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rtt ) - lfus )  &
181               &    + ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rtt ) )
182               ! REMARK valid at least in forced mode from clem
183               ! precip is included in qns but not in qns_ice
184
185            !-- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
186            zqfr = tms(ji,jj) * rau0 * rcp * fse3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
187
188            !-- Energy Budget of the leads (J.m-2). Must be < 0 to form ice
189            qlead(ji,jj) = MIN( 0._wp , zqld - zqfr ) 
190
191            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
192            IF( at_i(ji,jj) > epsi10 .AND. zqld > 0._wp ) THEN
193               fhld (ji,jj) = zqld * r1_rdtice / at_i(ji,jj) ! divided by at_i since this is (re)multiplied by a_i in limthd_dh.F90
194               qlead(ji,jj) = 0._wp
195            ENDIF
196            !
197            !-- Energy from the turbulent oceanic heat flux --- !
198            !clem zfric_u        = MAX ( MIN( SQRT( ust2s(ji,jj) ) , zfric_umax ) , zfric_umin )
199            zfric_u      = MAX( SQRT( ust2s(ji,jj) ), zfric_umin ) 
200            fhtur(ji,jj) = MAX( 0._wp, zinda * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ) ! W.m-2
201            ! upper bound for fhtur: we do not want SST to drop below Tfreeze.
202            ! So we say that the heat retrieved from the ocean (fhtur+fhld) must be < to the heat necessary to reach Tfreeze (zqfr)   
203            ! This is not a clean budget, so that should be corrected at some point
204            fhtur(ji,jj) = zinda * MIN( fhtur(ji,jj), - fhld(ji,jj) - zqfr * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
205
206            ! -----------------------------------------
207            ! Net heat flux on top of ice-ocean [W.m-2]
208            ! -----------------------------------------
209            !     First  step here      : heat flux at the ocean surface + precip
210            !     Second step below     : heat flux at the ice   surface (after limthd_dif)
211            hfx_in(ji,jj) = hfx_in(ji,jj)                                                                                         & 
212               ! heat flux above the ocean
213               &    +             pfrld(ji,jj)   * ( zqns(ji,jj) + zqsr(ji,jj) )                                                  &
214               ! latent heat of precip (note that precip is included in qns but not in qns_ice)
215               &    +   ( 1._wp - pfrld(ji,jj) ) * sprecip(ji,jj) * ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rtt ) - lfus )  &
216               &    +   ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rtt )
217
218            ! -----------------------------------------------------------------------------
219            ! Net heat flux that is retroceded to the ocean or taken from the ocean [W.m-2]
220            ! -----------------------------------------------------------------------------
221            !     First  step here              :  non solar + precip - qlead - qturb
222            !     Second step in limthd_dh      :  heat remaining if total melt (zq_rema)
223            !     Third  step in limsbc         :  heat from ice-ocean mass exchange (zf_mass) + solar
224            hfx_out(ji,jj) = hfx_out(ji,jj)                                                                                                        & 
225               ! Non solar heat flux received by the ocean
226               &    +        pfrld(ji,jj) * qns(ji,jj)                                                                                             &
227               ! latent heat of precip (note that precip is included in qns but not in qns_ice)
228               &    +      ( pfrld(ji,jj)**betas - pfrld(ji,jj) ) * sprecip(ji,jj) * ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rtt ) - lfus )  &
229               &    +      ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rtt )                        &
230               ! heat flux taken from the ocean where there is open water ice formation
231               &    -      qlead(ji,jj) * r1_rdtice                                                                                                &
232               ! heat flux taken from the ocean during bottom growth/melt (fhld should be 0 while bott growth)
233               &    -      at_i(ji,jj) * fhtur(ji,jj)                                                                                              &
234               &    -      at_i(ji,jj) *  fhld(ji,jj)
235
236         END DO
237      END DO
238
239      !------------------------------------------------------------------------------!
240      ! 3) Select icy points and fulfill arrays for the vectorial grid.           
241      !------------------------------------------------------------------------------!
242
243      DO jl = 1, jpl      !loop over ice categories
244
245         IF( kt == nit000 .AND. lwp ) THEN
246            WRITE(numout,*) ' lim_thd : transfer to 1D vectors. Category no : ', jl 
247            WRITE(numout,*) ' ~~~~~~~~'
248         ENDIF
249
250         zareamin = epsi10
251         nbpb = 0
252         DO jj = 1, jpj
253            DO ji = 1, jpi
254               IF ( a_i(ji,jj,jl) .gt. zareamin ) THEN     
255                  nbpb      = nbpb  + 1
256                  npb(nbpb) = (jj - 1) * jpi + ji
257               ENDIF
258            END DO
259         END DO
260
261         ! debug point to follow
262         jiindex_1d = 0
263         IF( ln_nicep ) THEN
264            DO ji = mi0(jiindx), mi1(jiindx)
265               DO jj = mj0(jjindx), mj1(jjindx)
266                  jiindex_1d = (jj - 1) * jpi + ji
267                  WRITE(numout,*) ' lim_thd : Category no : ', jl 
268               END DO
269            END DO
270         ENDIF
271
272         !------------------------------------------------------------------------------!
273         ! 4) Thermodynamic computation
274         !------------------------------------------------------------------------------!
275
276         IF( lk_mpp )   CALL mpp_ini_ice( nbpb , numout )
277
278         IF( nbpb > 0 ) THEN  ! If there is no ice, do nothing.
279
280            !-------------------------
281            ! 4.1 Move to 1D arrays
282            !-------------------------
283
284            CALL tab_2d_1d( nbpb, at_i_1d     (1:nbpb), at_i            , jpi, jpj, npb(1:nbpb) )
285            CALL tab_2d_1d( nbpb, a_i_1d      (1:nbpb), a_i(:,:,jl)     , jpi, jpj, npb(1:nbpb) )
286            CALL tab_2d_1d( nbpb, ht_i_1d     (1:nbpb), ht_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
287            CALL tab_2d_1d( nbpb, ht_s_1d     (1:nbpb), ht_s(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
288
289            CALL tab_2d_1d( nbpb, t_su_1d     (1:nbpb), t_su(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
290            CALL tab_2d_1d( nbpb, sm_i_1d     (1:nbpb), sm_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
291            DO jk = 1, nlay_s
292               CALL tab_2d_1d( nbpb, t_s_1d(1:nbpb,jk), t_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
293               CALL tab_2d_1d( nbpb, q_s_1d(1:nbpb,jk), e_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
294            END DO
295            DO jk = 1, nlay_i
296               CALL tab_2d_1d( nbpb, t_i_1d(1:nbpb,jk), t_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
297               CALL tab_2d_1d( nbpb, q_i_1d(1:nbpb,jk), e_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
298               CALL tab_2d_1d( nbpb, s_i_1d(1:nbpb,jk), s_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
299            END DO
300
301            CALL tab_2d_1d( nbpb, tatm_ice_1d(1:nbpb), tatm_ice(:,:)   , jpi, jpj, npb(1:nbpb) )
302            CALL tab_2d_1d( nbpb, qsr_ice_1d (1:nbpb), qsr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
303            CALL tab_2d_1d( nbpb, fr1_i0_1d  (1:nbpb), fr1_i0          , jpi, jpj, npb(1:nbpb) )
304            CALL tab_2d_1d( nbpb, fr2_i0_1d  (1:nbpb), fr2_i0          , jpi, jpj, npb(1:nbpb) )
305            CALL tab_2d_1d( nbpb, qns_ice_1d (1:nbpb), qns_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
306            CALL tab_2d_1d( nbpb, ftr_ice_1d (1:nbpb), ftr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
307            IF( .NOT. lk_cpl ) THEN
308               CALL tab_2d_1d( nbpb, qla_ice_1d (1:nbpb), qla_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
309               CALL tab_2d_1d( nbpb, dqla_ice_1d(1:nbpb), dqla_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
310            ENDIF
311            CALL tab_2d_1d( nbpb, dqns_ice_1d(1:nbpb), dqns_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
312            CALL tab_2d_1d( nbpb, t_bo_1d     (1:nbpb), t_bo            , jpi, jpj, npb(1:nbpb) )
313            CALL tab_2d_1d( nbpb, sprecip_1d (1:nbpb), sprecip         , jpi, jpj, npb(1:nbpb) ) 
314            CALL tab_2d_1d( nbpb, fhtur_1d   (1:nbpb), fhtur           , jpi, jpj, npb(1:nbpb) )
315            CALL tab_2d_1d( nbpb, qlead_1d   (1:nbpb), qlead           , jpi, jpj, npb(1:nbpb) )
316            CALL tab_2d_1d( nbpb, fhld_1d    (1:nbpb), fhld            , jpi, jpj, npb(1:nbpb) )
317
318            CALL tab_2d_1d( nbpb, wfx_snw_1d (1:nbpb), wfx_snw         , jpi, jpj, npb(1:nbpb) )
319            CALL tab_2d_1d( nbpb, wfx_sub_1d (1:nbpb), wfx_sub         , jpi, jpj, npb(1:nbpb) )
320
321            CALL tab_2d_1d( nbpb, wfx_bog_1d (1:nbpb), wfx_bog         , jpi, jpj, npb(1:nbpb) )
322            CALL tab_2d_1d( nbpb, wfx_bom_1d (1:nbpb), wfx_bom         , jpi, jpj, npb(1:nbpb) )
323            CALL tab_2d_1d( nbpb, wfx_sum_1d (1:nbpb), wfx_sum         , jpi, jpj, npb(1:nbpb) )
324            CALL tab_2d_1d( nbpb, wfx_sni_1d (1:nbpb), wfx_sni         , jpi, jpj, npb(1:nbpb) )
325            CALL tab_2d_1d( nbpb, wfx_res_1d (1:nbpb), wfx_res         , jpi, jpj, npb(1:nbpb) )
326            CALL tab_2d_1d( nbpb, wfx_spr_1d (1:nbpb), wfx_spr         , jpi, jpj, npb(1:nbpb) )
327
328            CALL tab_2d_1d( nbpb, sfx_bog_1d (1:nbpb), sfx_bog         , jpi, jpj, npb(1:nbpb) )
329            CALL tab_2d_1d( nbpb, sfx_bom_1d (1:nbpb), sfx_bom         , jpi, jpj, npb(1:nbpb) )
330            CALL tab_2d_1d( nbpb, sfx_sum_1d (1:nbpb), sfx_sum         , jpi, jpj, npb(1:nbpb) )
331            CALL tab_2d_1d( nbpb, sfx_sni_1d (1:nbpb), sfx_sni         , jpi, jpj, npb(1:nbpb) )
332            CALL tab_2d_1d( nbpb, sfx_bri_1d (1:nbpb), sfx_bri         , jpi, jpj, npb(1:nbpb) )
333            CALL tab_2d_1d( nbpb, sfx_res_1d (1:nbpb), sfx_res         , jpi, jpj, npb(1:nbpb) )
334
335            CALL tab_2d_1d( nbpb, hfx_thd_1d (1:nbpb), hfx_thd         , jpi, jpj, npb(1:nbpb) )
336            CALL tab_2d_1d( nbpb, hfx_spr_1d (1:nbpb), hfx_spr         , jpi, jpj, npb(1:nbpb) )
337            CALL tab_2d_1d( nbpb, hfx_sum_1d (1:nbpb), hfx_sum         , jpi, jpj, npb(1:nbpb) )
338            CALL tab_2d_1d( nbpb, hfx_bom_1d (1:nbpb), hfx_bom         , jpi, jpj, npb(1:nbpb) )
339            CALL tab_2d_1d( nbpb, hfx_bog_1d (1:nbpb), hfx_bog         , jpi, jpj, npb(1:nbpb) )
340            CALL tab_2d_1d( nbpb, hfx_dif_1d (1:nbpb), hfx_dif         , jpi, jpj, npb(1:nbpb) )
341            CALL tab_2d_1d( nbpb, hfx_opw_1d (1:nbpb), hfx_opw         , jpi, jpj, npb(1:nbpb) )
342            CALL tab_2d_1d( nbpb, hfx_snw_1d (1:nbpb), hfx_snw         , jpi, jpj, npb(1:nbpb) )
343            CALL tab_2d_1d( nbpb, hfx_sub_1d (1:nbpb), hfx_sub         , jpi, jpj, npb(1:nbpb) )
344            CALL tab_2d_1d( nbpb, hfx_err_1d (1:nbpb), hfx_err         , jpi, jpj, npb(1:nbpb) )
345            CALL tab_2d_1d( nbpb, hfx_res_1d (1:nbpb), hfx_res         , jpi, jpj, npb(1:nbpb) )
346            CALL tab_2d_1d( nbpb, hfx_err_rem_1d (1:nbpb), hfx_err_rem , jpi, jpj, npb(1:nbpb) )
347
348            !--------------------------------
349            ! 4.3) Thermodynamic processes
350            !--------------------------------
351
352            !---------------------------------!
353            ! Ice/Snow Temperature profile    !
354            !---------------------------------!
355            CALL lim_thd_dif( 1, nbpb )
356
357            !---------------------------------!
358            ! Ice/Snow thicnkess              !
359            !---------------------------------!
360            CALL lim_thd_dh( 1, nbpb )   
361
362            ! --- Ice enthalpy remapping --- !
363            CALL lim_thd_ent( 1, nbpb, q_i_1d(1:nbpb,:) ) 
364                                           
365            !---------------------------------!
366            ! --- Ice salinity --- !
367            !---------------------------------!
368            CALL lim_thd_sal( 1, nbpb )   
369
370            !---------------------------------!
371            ! --- temperature update --- !
372            !---------------------------------!
373            CALL lim_thd_temp( 1, nbpb )
374
375            !--------------------------------
376            ! 4.4) Move 1D to 2D vectors
377            !--------------------------------
378
379               CALL tab_1d_2d( nbpb, at_i          , npb, at_i_1d    (1:nbpb)   , jpi, jpj )
380               CALL tab_1d_2d( nbpb, ht_i(:,:,jl)  , npb, ht_i_1d    (1:nbpb)   , jpi, jpj )
381               CALL tab_1d_2d( nbpb, ht_s(:,:,jl)  , npb, ht_s_1d    (1:nbpb)   , jpi, jpj )
382               CALL tab_1d_2d( nbpb, a_i (:,:,jl)  , npb, a_i_1d     (1:nbpb)   , jpi, jpj )
383               CALL tab_1d_2d( nbpb, t_su(:,:,jl)  , npb, t_su_1d    (1:nbpb)   , jpi, jpj )
384               CALL tab_1d_2d( nbpb, sm_i(:,:,jl)  , npb, sm_i_1d    (1:nbpb)   , jpi, jpj )
385            DO jk = 1, nlay_s
386               CALL tab_1d_2d( nbpb, t_s(:,:,jk,jl), npb, t_s_1d     (1:nbpb,jk), jpi, jpj)
387               CALL tab_1d_2d( nbpb, e_s(:,:,jk,jl), npb, q_s_1d     (1:nbpb,jk), jpi, jpj)
388            END DO
389            DO jk = 1, nlay_i
390               CALL tab_1d_2d( nbpb, t_i(:,:,jk,jl), npb, t_i_1d     (1:nbpb,jk), jpi, jpj)
391               CALL tab_1d_2d( nbpb, e_i(:,:,jk,jl), npb, q_i_1d     (1:nbpb,jk), jpi, jpj)
392               CALL tab_1d_2d( nbpb, s_i(:,:,jk,jl), npb, s_i_1d     (1:nbpb,jk), jpi, jpj)
393            END DO
394               CALL tab_1d_2d( nbpb, qlead         , npb, qlead_1d  (1:nbpb)   , jpi, jpj )
395
396               CALL tab_1d_2d( nbpb, wfx_snw       , npb, wfx_snw_1d(1:nbpb)   , jpi, jpj )
397               CALL tab_1d_2d( nbpb, wfx_sub       , npb, wfx_sub_1d(1:nbpb)   , jpi, jpj )
398
399               CALL tab_1d_2d( nbpb, wfx_bog       , npb, wfx_bog_1d(1:nbpb)   , jpi, jpj )
400               CALL tab_1d_2d( nbpb, wfx_bom       , npb, wfx_bom_1d(1:nbpb)   , jpi, jpj )
401               CALL tab_1d_2d( nbpb, wfx_sum       , npb, wfx_sum_1d(1:nbpb)   , jpi, jpj )
402               CALL tab_1d_2d( nbpb, wfx_sni       , npb, wfx_sni_1d(1:nbpb)   , jpi, jpj )
403               CALL tab_1d_2d( nbpb, wfx_res       , npb, wfx_res_1d(1:nbpb)   , jpi, jpj )
404               CALL tab_1d_2d( nbpb, wfx_spr       , npb, wfx_spr_1d(1:nbpb)   , jpi, jpj )
405
406               CALL tab_1d_2d( nbpb, sfx_bog       , npb, sfx_bog_1d(1:nbpb)   , jpi, jpj )
407               CALL tab_1d_2d( nbpb, sfx_bom       , npb, sfx_bom_1d(1:nbpb)   , jpi, jpj )
408               CALL tab_1d_2d( nbpb, sfx_sum       , npb, sfx_sum_1d(1:nbpb)   , jpi, jpj )
409               CALL tab_1d_2d( nbpb, sfx_sni       , npb, sfx_sni_1d(1:nbpb)   , jpi, jpj )
410               CALL tab_1d_2d( nbpb, sfx_res       , npb, sfx_res_1d(1:nbpb)   , jpi, jpj )
411            !
412            IF( num_sal == 2 ) THEN
413               CALL tab_1d_2d( nbpb, sfx_bri       , npb, sfx_bri_1d(1:nbpb)   , jpi, jpj )
414            ENDIF
415
416              CALL tab_1d_2d( nbpb, hfx_thd       , npb, hfx_thd_1d(1:nbpb)   , jpi, jpj )
417              CALL tab_1d_2d( nbpb, hfx_spr       , npb, hfx_spr_1d(1:nbpb)   , jpi, jpj )
418              CALL tab_1d_2d( nbpb, hfx_sum       , npb, hfx_sum_1d(1:nbpb)   , jpi, jpj )
419              CALL tab_1d_2d( nbpb, hfx_bom       , npb, hfx_bom_1d(1:nbpb)   , jpi, jpj )
420              CALL tab_1d_2d( nbpb, hfx_bog       , npb, hfx_bog_1d(1:nbpb)   , jpi, jpj )
421              CALL tab_1d_2d( nbpb, hfx_dif       , npb, hfx_dif_1d(1:nbpb)   , jpi, jpj )
422              CALL tab_1d_2d( nbpb, hfx_opw       , npb, hfx_opw_1d(1:nbpb)   , jpi, jpj )
423              CALL tab_1d_2d( nbpb, hfx_snw       , npb, hfx_snw_1d(1:nbpb)   , jpi, jpj )
424              CALL tab_1d_2d( nbpb, hfx_sub       , npb, hfx_sub_1d(1:nbpb)   , jpi, jpj )
425              CALL tab_1d_2d( nbpb, hfx_err       , npb, hfx_err_1d(1:nbpb)   , jpi, jpj )
426              CALL tab_1d_2d( nbpb, hfx_res       , npb, hfx_res_1d(1:nbpb)   , jpi, jpj )
427              CALL tab_1d_2d( nbpb, hfx_err_rem   , npb, hfx_err_rem_1d(1:nbpb)   , jpi, jpj )
428            !
429            !+++++       temporary stuff for a dummy version
430              CALL tab_1d_2d( nbpb, dh_i_surf2D, npb, dh_i_surf(1:nbpb)      , jpi, jpj )
431              CALL tab_1d_2d( nbpb, dh_i_bott2D, npb, dh_i_bott(1:nbpb)      , jpi, jpj )
432              CALL tab_1d_2d( nbpb, s_i_newice , npb, s_i_new  (1:nbpb)      , jpi, jpj )
433              CALL tab_1d_2d( nbpb, izero(:,:,jl) , npb, i0    (1:nbpb)      , jpi, jpj )
434            !+++++
435              CALL tab_1d_2d( nbpb, qns_ice(:,:,jl), npb, qns_ice_1d(1:nbpb) , jpi, jpj)
436              CALL tab_1d_2d( nbpb, ftr_ice(:,:,jl), npb, ftr_ice_1d(1:nbpb) , jpi, jpj )
437            !
438            IF( lk_mpp )   CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
439         ENDIF
440         !
441      END DO
442
443      !------------------------------------------------------------------------------!
444      ! 5) Global variables, diagnostics
445      !------------------------------------------------------------------------------!
446
447      !------------------------
448      ! 5.1) Ice heat content             
449      !------------------------
450      ! Enthalpies are global variables we have to readjust the units (heat content in Joules)
451      DO jl = 1, jpl
452         DO jk = 1, nlay_i
453            e_i(:,:,jk,jl) = e_i(:,:,jk,jl) * area(:,:) * a_i(:,:,jl) * ht_i(:,:,jl) / ( unit_fac * REAL( nlay_i ) )
454         END DO
455      END DO
456
457      !------------------------
458      ! 5.2) Snow heat content             
459      !------------------------
460      ! Enthalpies are global variables we have to readjust the units (heat content in Joules)
461      DO jl = 1, jpl
462         DO jk = 1, nlay_s
463            e_s(:,:,jk,jl) = e_s(:,:,jk,jl) * area(:,:) * a_i(:,:,jl) * ht_s(:,:,jl) / ( unit_fac * REAL( nlay_s ) )
464         END DO
465      END DO
466
467      !----------------------------------
468      ! 5.3) Change thickness to volume
469      !----------------------------------
470      CALL lim_var_eqv2glo
471
472      !--------------------------------------------
473      ! 5.4) Diagnostic thermodynamic growth rates
474      !--------------------------------------------
475      IF(ln_ctl) THEN            ! Control print
476         CALL prt_ctl_info(' ')
477         CALL prt_ctl_info(' - Cell values : ')
478         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
479         CALL prt_ctl(tab2d_1=area , clinfo1=' lim_thd  : cell area :')
480         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_thd  : at_i      :')
481         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_thd  : vt_i      :')
482         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_thd  : vt_s      :')
483         DO jl = 1, jpl
484            CALL prt_ctl_info(' ')
485            CALL prt_ctl_info(' - Category : ', ivar1=jl)
486            CALL prt_ctl_info('   ~~~~~~~~~~')
487            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_thd  : a_i      : ')
488            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_thd  : ht_i     : ')
489            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_thd  : ht_s     : ')
490            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_thd  : v_i      : ')
491            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_thd  : v_s      : ')
492            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_thd  : e_s      : ')
493            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_thd  : t_su     : ')
494            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_thd  : t_snow   : ')
495            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_thd  : sm_i     : ')
496            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_thd  : smv_i    : ')
497            DO jk = 1, nlay_i
498               CALL prt_ctl_info(' ')
499               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
500               CALL prt_ctl_info('   ~~~~~~~')
501               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_thd  : t_i      : ')
502               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_thd  : e_i      : ')
503            END DO
504         END DO
505      ENDIF
506      !
507      !
508      CALL wrk_dealloc( jpi, jpj, zqsr, zqns )
509
510      !
511      ! conservation test
512      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
513      !
514      IF( nn_timing == 1 )  CALL timing_stop('limthd')
515
516   END SUBROUTINE lim_thd 
517
518   SUBROUTINE lim_thd_temp( kideb, kiut )
519      !!-----------------------------------------------------------------------
520      !!                   ***  ROUTINE lim_thd_temp ***
521      !!                 
522      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
523      !!
524      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
525      !!-------------------------------------------------------------------
526      INTEGER, INTENT(in) ::   kideb, kiut   ! bounds for the spatial loop
527      !!
528      INTEGER  ::   ji, jk   ! dummy loop indices
529      REAL(wp) ::   ztmelts, zswitch, zaaa, zbbb, zccc, zdiscrim  ! local scalar
530      !!-------------------------------------------------------------------
531      ! Recover ice temperature
532      DO jk = 1, nlay_i
533         DO ji = kideb, kiut
534            ztmelts       =  -tmut * s_i_1d(ji,jk) + rtt
535            ! Conversion q(S,T) -> T (second order equation)
536            zaaa          =  cpic
537            zbbb          =  ( rcp - cpic ) * ( ztmelts - rtt ) + q_i_1d(ji,jk) / rhoic - lfus
538            zccc          =  lfus * ( ztmelts - rtt )
539            zdiscrim      =  SQRT( MAX( zbbb * zbbb - 4._wp * zaaa * zccc, 0._wp ) )
540            t_i_1d(ji,jk)  =  rtt - ( zbbb + zdiscrim ) / ( 2._wp * zaaa )
541           
542            ! mask temperature
543            zswitch      =  1._wp - MAX( 0._wp , SIGN( 1._wp , - ht_i_1d(ji) ) ) 
544            t_i_1d(ji,jk) =  zswitch * t_i_1d(ji,jk) + ( 1._wp - zswitch ) * rtt
545         END DO
546      END DO
547
548   END SUBROUTINE lim_thd_temp
549
550   SUBROUTINE lim_thd_init
551      !!-----------------------------------------------------------------------
552      !!                   ***  ROUTINE lim_thd_init ***
553      !!                 
554      !! ** Purpose :   Physical constants and parameters linked to the ice
555      !!              thermodynamics
556      !!
557      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
558      !!              parameter values called at the first timestep (nit000)
559      !!
560      !! ** input   :   Namelist namicether
561      !!-------------------------------------------------------------------
562      INTEGER  ::   ios                 ! Local integer output status for namelist read
563      NAMELIST/namicethd/ hmelt , hiccrit, fraz_swi, maxfrazb, vfrazb, Cfrazb,   &
564         &                hiclim, hnzst, parsub, betas,                          & 
565         &                kappa_i, nconv_i_thd, maxer_i_thd, thcon_i_swi
566      !!-------------------------------------------------------------------
567      !
568      IF(lwp) THEN
569         WRITE(numout,*)
570         WRITE(numout,*) 'lim_thd : Ice Thermodynamics'
571         WRITE(numout,*) '~~~~~~~'
572      ENDIF
573      !
574      REWIND( numnam_ice_ref )              ! Namelist namicethd in reference namelist : Ice thermodynamics
575      READ  ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901)
576901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp )
577
578      REWIND( numnam_ice_cfg )              ! Namelist namicethd in configuration namelist : Ice thermodynamics
579      READ  ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 )
580902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp )
581      IF(lwm) WRITE ( numoni, namicethd )
582
583      IF( lk_cpl .AND. parsub /= 0.0 )   CALL ctl_stop( 'In coupled mode, use parsub = 0. or send dqla' )
584      !
585      IF(lwp) THEN                          ! control print
586         WRITE(numout,*)
587         WRITE(numout,*)'   Namelist of ice parameters for ice thermodynamic computation '
588         WRITE(numout,*)'      maximum melting at the bottom                           hmelt        = ', hmelt
589         WRITE(numout,*)'      ice thick. for lateral accretion                        hiccrit      = ', hiccrit
590         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       fraz_swi     = ', fraz_swi
591         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   maxfrazb     = ', maxfrazb
592         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  vfrazb       = ', vfrazb
593         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          Cfrazb       = ', Cfrazb
594         WRITE(numout,*)'      minimum ice thickness                                   hiclim       = ', hiclim 
595         WRITE(numout,*)'      numerical carac. of the scheme for diffusion in ice '
596         WRITE(numout,*)'      thickness of the surf. layer in temp. computation       hnzst        = ', hnzst
597         WRITE(numout,*)'      switch for snow sublimation  (=1) or not (=0)           parsub       = ', parsub 
598         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          betas        = ', betas
599         WRITE(numout,*)'      extinction radiation parameter in sea ice (1.0)         kappa_i      = ', kappa_i
600         WRITE(numout,*)'      maximal n. of iter. for heat diffusion computation      nconv_i_thd  = ', nconv_i_thd
601         WRITE(numout,*)'      maximal err. on T for heat diffusion computation        maxer_i_thd  = ', maxer_i_thd
602         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     thcon_i_swi  = ', thcon_i_swi
603         WRITE(numout,*)'      check heat conservation in the ice/snow                 con_i        = ', con_i
604      ENDIF
605      !
606   END SUBROUTINE lim_thd_init
607
608#else
609   !!----------------------------------------------------------------------
610   !!   Default option         Dummy module          NO  LIM3 sea-ice model
611   !!----------------------------------------------------------------------
612#endif
613
614   !!======================================================================
615END MODULE limthd
Note: See TracBrowser for help on using the repository browser.